git.m6w6.name Git - m6w6/libmemcached/blob - m4/pandora_enable_dtrace.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl ---------------------------------------------------------------------------
   7 dnl Macro: PANDORA_ENABLE_DTRACE
   8 dnl ---------------------------------------------------------------------------
   9 AC_DEFUN([PANDORA_ENABLE_DTRACE],[
  10   AC_ARG_ENABLE([dtrace],
  11     [AS_HELP_STRING([--enable-dtrace],
  12             [Build with support for the DTRACE. @<:@default=off@:>@])],
  13     [ac_cv_enable_dtrace="yes"],
  14     [ac_cv_enable_dtrace="no"])
  15
  16   AS_IF([test "$ac_cv_enable_dtrace" = "yes"],[
  17     AC_CHECK_PROGS([DTRACE], [dtrace])
  18     AS_IF([test "x$ac_cv_prog_DTRACE" = "xdtrace"],[
  19       AC_DEFINE([HAVE_DTRACE], [1], [Enables DTRACE Support])
  20       dnl DTrace on MacOSX does not use -G option
  21       cat >conftest.d <<_ACEOF
  22 provider Example {
  23   probe increment(int);
  24 };
  25 _ACEOF
  26       $DTRACE -G -o conftest.d.o -s conftest.d 2>/dev/zero
  27       AS_IF([test $? -eq 0],[ac_cv_dtrace_needs_objects=yes])
  28       rm -f conftest.d.o conftest.d
  29
  30       AC_SUBST(DTRACEFLAGS) dnl TODO: test for -G on OSX
  31       ac_cv_have_dtrace=yes
  32     ])])
  33
  34 AM_CONDITIONAL([HAVE_DTRACE], [test "x$ac_cv_have_dtrace" = "xyes"])
  35 AM_CONDITIONAL([DTRACE_NEEDS_OBJECTS],
  36                [test "x$ac_cv_dtrace_needs_objects" = "xyes"])
  37
  38 ])
  39 dnl ---------------------------------------------------------------------------
  40 dnl End Macro: PANDORA_ENABLE_DTRACE
  41 dnl ---------------------------------------------------------------------------