git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_canonical.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems, Inc.
   2 dnl This file is free software; Sun Microsystems, Inc.
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Which version of the canonical setup we're using
   7 AC_DEFUN([PANDORA_CANONICAL_VERSION],[0.175])
   8
   9 AC_DEFUN([PANDORA_FORCE_DEPEND_TRACKING],[
  10   AC_ARG_ENABLE([fat-binaries],
  11     [AS_HELP_STRING([--enable-fat-binaries],
  12       [Enable fat binary support on OSX @<:@default=off@:>@])],
  13     [ac_enable_fat_binaries="$enableval"],
  14     [ac_enable_fat_binaries="no"])
  15
  16   dnl Force dependency tracking on for Sun Studio builds
  17   AS_IF([test "x${enable_dependency_tracking}" = "x"],[
  18     enable_dependency_tracking=yes
  19   ])
  20   dnl If we're building OSX Fat Binaries, we have to turn off -M options
  21   AS_IF([test "x${ac_enable_fat_binaries}" = "xyes"],[
  22     enable_dependency_tracking=no
  23   ])
  24 ])
  25
  26 AC_DEFUN([PANDORA_BLOCK_BAD_OPTIONS],[
  27   AS_IF([test "x${prefix}" = "x"],[
  28     AC_MSG_ERROR([--prefix requires an argument])
  29   ])
  30 ])
  31
  32 dnl The standard setup for how we build Pandora projects
  33 AC_DEFUN([PANDORA_CANONICAL_TARGET],[
  34   AC_REQUIRE([PANDORA_FORCE_DEPEND_TRACKING])
  35   ifdef([m4_define],,[define([m4_define],   defn([define]))])
  36   ifdef([m4_undefine],,[define([m4_undefine],   defn([undefine]))])
  37   m4_define([PCT_ALL_ARGS],[$*])
  38   m4_define([PCT_REQUIRE_CXX],[no])
  39   m4_define([PCT_FORCE_GCC42],[no])
  40   m4_define([PCT_DONT_SUPPRESS_INCLUDE],[no])
  41   m4_define([PCT_NO_VC_CHANGELOG],[no])
  42   m4_define([PCT_VERSION_FROM_VC],[no])
  43   m4_define([PCT_USE_VISIBILITY],[yes])
  44   m4_foreach([pct_arg],[$*],[
  45     m4_case(pct_arg,
  46       [require-cxx], [
  47         m4_undefine([PCT_REQUIRE_CXX])
  48         m4_define([PCT_REQUIRE_CXX],[yes])
  49       ],
  50       [force-gcc42], [
  51         m4_undefine([PCT_FORCE_GCC42])
  52         m4_define([PCT_FORCE_GCC42],[yes])
  53       ],
  54       [skip-visibility], [
  55         m4_undefine([PCT_USE_VISIBILITY])
  56         m4_define([PCT_USE_VISIBILITY],[no])
  57       ],
  58       [dont-suppress-include], [
  59         m4_undefine([PCT_DONT_SUPPRESS_INCLUDE])
  60         m4_define([PCT_DONT_SUPPRESS_INCLUDE],[yes])
  61       ],
  62       [no-vc-changelog], [
  63         m4_undefine([PCT_NO_VC_CHANGELOG])
  64         m4_define([PCT_NO_VC_CHANGELOG],[yes])
  65       ],
  66       [version-from-vc], [
  67         m4_undefine([PCT_VERSION_FROM_VC])
  68         m4_define([PCT_VERSION_FROM_VC],[yes])
  69     ])
  70   ])
  71
  72   PANDORA_BLOCK_BAD_OPTIONS
  73
  74   # We need to prevent canonical target
  75   # from injecting -O2 into CFLAGS - but we won't modify anything if we have
  76   # set CFLAGS on the command line, since that should take ultimate precedence
  77   AS_IF([test "x${ac_cv_env_CFLAGS_set}" = "x"],
  78         [CFLAGS=""])
  79   AS_IF([test "x${ac_cv_env_CXXFLAGS_set}" = "x"],
  80         [CXXFLAGS=""])
  81
  82   m4_if(PCT_DONT_SUPRESS_INCLUDE,yes,[
  83     AM_INIT_AUTOMAKE(-Wall -Werror -Wno-portability subdir-objects foreign tar-ustar)
  84   ],[
  85     AM_INIT_AUTOMAKE(-Wall -Werror -Wno-portability nostdinc subdir-objects foreign tar-ustar)
  86   ])
  87
  88   m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  89
  90   m4_if(m4_substr(m4_esyscmd(test -d gnulib && echo 0),0,1),0,[
  91     gl_EARLY
  92   ],[
  93     PANDORA_EXTENSIONS
  94   ])
  95
  96   AC_REQUIRE([AC_PROG_CC])
  97   m4_if(PCT_FORCE_GCC42, [yes], [
  98     AC_REQUIRE([PANDORA_ENSURE_GCC_VERSION])
  99   ])
 100   AC_REQUIRE([PANDORA_64BIT])
 101
 102   m4_if(PCT_NO_VC_CHANGELOG,yes,[
 103     vc_changelog=no
 104   ],[
 105     vc_changelog=yes
 106   ])
 107   m4_if(PCT_VERSION_FROM_VC,yes,[
 108     PANDORA_VC_INFO_HEADER
 109   ],[
 110     PANDORA_TEST_VC_DIR
 111
 112     changequote(<<, >>)dnl
 113     PANDORA_RELEASE_ID=`echo $VERSION | sed 's/[^0-9]//g'`
 114     changequote([, ])dnl
 115
 116     PANDORA_RELEASE_COMMENT=""
 117     AC_DEFINE_UNQUOTED([PANDORA_RELEASE_VERSION],["$VERSION"],
 118                        [Version of the software])
 119
 120     AC_SUBST(PANDORA_RELEASE_COMMENT)
 121     AC_SUBST(PANDORA_RELEASE_VERSION)
 122     AC_SUBST(PANDORA_RELEASE_ID)
 123   ])
 124   PANDORA_VERSION
 125
 126   dnl Once we can use a modern autoconf, we can use this
 127   dnl AC_PROG_CC_C99
 128   AC_REQUIRE([AC_PROG_CXX])
 129   PANDORA_EXTENSIONS
 130   AM_PROG_CC_C_O
 131
 132
 133
 134   PANDORA_PLATFORM
 135
 136   PANDORA_LIBTOOL
 137
 138   dnl autoconf doesn't automatically provide a fail-if-no-C++ macro
 139   dnl so we check c++98 features and fail if we don't have them, mainly
 140   dnl for that reason
 141   PANDORA_CHECK_CXX_STANDARD
 142   m4_if(PCT_REQUIRE_CXX, [yes], [
 143     AS_IF([test "$ac_cv_cxx_stdcxx_98" = "no"],[
 144       AC_MSG_ERROR([No working C++ Compiler has been found. ${PACKAGE} requires a C++ compiler that can handle C++98])
 145     ])
 146   ])
 147   PANDORA_CXX_CSTDINT
 148   PANDORA_CXX_CINTTYPES
 149
 150   m4_if(m4_substr(m4_esyscmd(test -d gnulib && echo 0),0,1),0,[
 151     gl_INIT
 152     AC_CONFIG_LIBOBJ_DIR([gnulib])
 153   ])
 154
 155   PANDORA_CHECK_C_VERSION
 156   PANDORA_CHECK_CXX_VERSION
 157
 158   AC_C_BIGENDIAN
 159   AC_C_CONST
 160   AC_C_INLINE
 161   AC_C_VOLATILE
 162   AC_C_RESTRICT
 163
 164   AC_HEADER_TIME
 165   AC_STRUCT_TM
 166   AC_TYPE_SIZE_T
 167   AC_SYS_LARGEFILE
 168   PANDORA_CLOCK_GETTIME
 169
 170   AC_CHECK_HEADERS(sys/socket.h)
 171
 172   # off_t is not a builtin type
 173   AC_CHECK_SIZEOF(off_t, 4)
 174   AS_IF([test "$ac_cv_sizeof_off_t" -eq 0],[
 175     AC_MSG_ERROR("${PACKAGE} needs an off_t type.")
 176   ])
 177
 178   AC_CHECK_SIZEOF(size_t)
 179   AS_IF([test "$ac_cv_sizeof_size_t" -eq 0],[
 180     AC_MSG_ERROR("${PACKAGE} needs an size_t type.")
 181   ])
 182
 183   AC_DEFINE_UNQUOTED([SIZEOF_SIZE_T],[$ac_cv_sizeof_size_t],[Size of size_t as computed by sizeof()])
 184   AC_CHECK_SIZEOF(long long)
 185   AC_DEFINE_UNQUOTED([SIZEOF_LONG_LONG],[$ac_cv_sizeof_long_long],[Size of long long as computed by sizeof()])
 186   AC_CACHE_CHECK([if time_t is unsigned], [ac_cv_time_t_unsigned],[
 187   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 188       [[
 189 #include <time.h>
 190       ]],
 191       [[
 192       int array[(((time_t)-1) > 0) ? 1 : -1];
 193       ]])
 194     ],[
 195       ac_cv_time_t_unsigned=yes
 196     ],[
 197       ac_cv_time_t_unsigned=no
 198     ])
 199   ])
 200   AS_IF([test "$ac_cv_time_t_unsigned" = "yes"],[
 201     AC_DEFINE([TIME_T_UNSIGNED], 1, [Define to 1 if time_t is unsigned])
 202   ])
 203
 204   AC_CACHE_CHECK([if system defines RUSAGE_THREAD], [ac_cv_rusage_thread],[
 205   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 206       [[
 207 #include <sys/time.h>
 208 #include <sys/resource.h>
 209       ]],[[
 210       int x= RUSAGE_THREAD;
 211       ]])
 212     ],[
 213       ac_cv_rusage_thread=yes
 214     ],[
 215       ac_cv_rusage_thread=no
 216     ])
 217   ])
 218   AS_IF([test "$ac_cv_rusage_thread" = "no"],[
 219     AC_DEFINE([RUSAGE_THREAD], [RUSAGE_SELF],
 220       [Define if system doesn't define])
 221   ])
 222
 223   AC_CHECK_LIBM
 224   dnl Bug on FreeBSD - LIBM check doesn't set the damn variable
 225   AC_SUBST([LIBM])
 226
 227   AC_CHECK_FUNC(setsockopt, [], [AC_CHECK_LIB(socket, setsockopt)])
 228   AC_CHECK_FUNC(bind, [], [AC_CHECK_LIB(bind, bind)])
 229
 230
 231
 232   PANDORA_OPTIMIZE
 233
 234   AC_LANG_PUSH(C++)
 235   # Test whether madvise() is declared in C++ code -- it is not on some
 236   # systems, such as Solaris
 237   AC_CHECK_DECLS([madvise], [], [], [AC_INCLUDES_DEFAULT[
 238   #if HAVE_SYS_MMAN_H
 239   #include <sys/types.h>
 240   #include <sys/mman.h>
 241   #endif
 242   ]])
 243   AC_LANG_POP()
 244
 245   PANDORA_HAVE_GCC_ATOMICS
 246
 247   m4_if(PCT_USE_VISIBILITY,[yes],[
 248     PANDORA_ENABLE_VISIBILITY
 249     ],[
 250     PANDORA_CHECK_VISIBILITY
 251   ])
 252
 253   PANDORA_HEADER_ASSERT
 254
 255   PANDORA_WARNINGS(PCT_ALL_ARGS)
 256
 257   PANDORA_ENABLE_DTRACE
 258
 259   AC_LIB_PREFIX
 260   PANDORA_HAVE_BETTER_MALLOC
 261   PANDORA_WITH_VALGRIND
 262
 263   AC_CHECK_PROGS([DOXYGEN], [doxygen])
 264   AC_CHECK_PROGS([PERL], [perl])
 265   AC_CHECK_PROGS([DPKG_GENSYMBOLS], [dpkg-gensymbols], [:])
 266   AC_CHECK_PROGS([LCOV], [lcov], [echo lcov not found])
 267   AC_CHECK_PROGS([LCOV_GENHTML], [genhtml], [echo genhtml not found])
 268
 269   AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build], [:])
 270   AS_IF([test "x${SPHINXBUILD}" != "x:"],[
 271     AC_CACHE_CHECK([if sphinx is new enough],[ac_cv_recent_sphinx],[
 272
 273     ${SPHINXBUILD} -Q -C -b man -d conftest.d . . >/dev/null 2>&1
 274     AS_IF([test $? -eq 0],[ac_cv_recent_sphinx=yes],
 275           [ac_cv_recent_sphinx=no])
 276     rm -rf conftest.d
 277     ])
 278   ])
 279
 280   AM_CONDITIONAL(HAVE_DPKG_GENSYMBOLS,[test "x${DPKG_GENSYMBOLS}" != "x:"])
 281   AM_CONDITIONAL(HAVE_SPHINX,[test "x${SPHINXBUILD}" != "x:"])
 282   AM_CONDITIONAL(HAVE_RECENT_SPHINX,[test "x${ac_cv_recent_sphinx}" = "xyes"])
 283
 284   m4_if(m4_substr(m4_esyscmd(test -d po && echo 0),0,1),0, [
 285     AM_PO_SUBDIRS
 286     IT_PROG_INTLTOOL([0.35],[no-xml])
 287
 288     GETTEXT_PACKAGE=$PACKAGE
 289     AC_CHECK_LIB(intl, libintl_gettext)
 290     AC_SUBST([GETTEXT_PACKAGE])
 291     AS_IF([test "x${USE_NLS}" = "xyes" -a "x${pandora_have_intltool}" = "xyes"],
 292           [AC_DEFINE([ENABLE_NLS],[1],[Turn on language support])
 293            AC_CONFIG_FILES([po/Makefile.in])
 294       ])
 295   ])
 296   AM_CONDITIONAL(BUILD_PO,[test "x${USE_NLS}" = "xyes" -a "x${pandora_have_intltool}" = "xyes"])
 297
 298   AS_IF([test "x${gl_LIBOBJS}" != "x"],[
 299     AS_IF([test "$GCC" = "yes"],[
 300       AM_CPPFLAGS="-isystem \${top_srcdir}/gnulib -isystem \${top_builddir}/gnulib ${AM_CPPFLAGS}"
 301     ],[
 302     AM_CPPFLAGS="-I\${top_srcdir}/gnulib -I\${top_builddir}/gnulib ${AM_CPPFLAGS}"
 303     ])
 304   ])
 305   m4_if(m4_substr(m4_esyscmd(test -d src && echo 0),0,1),0,[
 306     AM_CPPFLAGS="-I\$(top_srcdir)/src -I\$(top_builddir)/src ${AM_CPPFLAGS}"
 307   ],[
 308     AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${AM_CPPFLAGS}"
 309   ])
 310
 311   PANDORA_USE_PIPE
 312
 313   AM_CFLAGS="${AM_CFLAGS} ${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE}"
 314   AM_CXXFLAGS="${AM_CXXFLAGS} ${CXX_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE}"
 315
 316   AC_SUBST([AM_CFLAGS])
 317   AC_SUBST([AM_CXXFLAGS])
 318   AC_SUBST([AM_CPPFLAGS])
 319   AC_SUBST([AM_LDFLAGS])
 320
 321 ])