git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_canonical.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Which version of the canonical setup we're using
   7 AC_DEFUN([PANDORA_CANONICAL_VERSION],[0.134])
   8
   9 AC_DEFUN([PANDORA_FORCE_DEPEND_TRACKING],[
  10   AC_ARG_ENABLE([fat-binaries],
  11     [AS_HELP_STRING([--enable-fat-binaries],
  12       [Enable fat binary support on OSX @<:@default=off@:>@])],
  13     [ac_enable_fat_binaries="$enableval"],
  14     [ac_enable_fat_binaries="no"])
  15
  16   dnl Force dependency tracking on for Sun Studio builds
  17   AS_IF([test "x${enable_dependency_tracking}" = "x"],[
  18     enable_dependency_tracking=yes
  19   ])
  20   dnl If we're building OSX Fat Binaries, we have to turn off -M options
  21   AS_IF([test "x${ac_enable_fat_binaries}" = "xyes"],[
  22     enable_dependency_tracking=no
  23   ])
  24 ])
  25
  26 dnl The standard setup for how we build Pandora projects
  27 AC_DEFUN([PANDORA_CANONICAL_TARGET],[
  28   AC_REQUIRE([PANDORA_FORCE_DEPEND_TRACKING])
  29   ifdef([m4_define],,[define([m4_define],   defn([define]))])
  30   ifdef([m4_undefine],,[define([m4_undefine],   defn([undefine]))])
  31   m4_define([PCT_ALL_ARGS],[$*])
  32   m4_define([PCT_REQUIRE_CXX],[no])
  33   m4_define([PCT_FORCE_GCC42],[no])
  34   m4_define([PCT_DONT_SUPPRESS_INCLUDE],[no])
  35   m4_define([PCT_VERSION_FROM_VC],[no])
  36   m4_define([PCT_USE_VISIBILITY],[yes])
  37   m4_foreach([pct_arg],[$*],[
  38     m4_case(pct_arg,
  39       [require-cxx], [
  40         m4_undefine([PCT_REQUIRE_CXX])
  41         m4_define([PCT_REQUIRE_CXX],[yes])
  42       ],
  43       [force-gcc42], [
  44         m4_undefine([PCT_FORCE_GCC42])
  45         m4_define([PCT_FORCE_GCC42],[yes])
  46       ],
  47       [skip-visibility], [
  48         m4_undefine([PCT_USE_VISIBILITY])
  49         m4_define([PCT_USE_VISIBILITY],[no])
  50       ],
  51       [dont-suppress-include], [
  52         m4_undefine([PCT_DONT_SUPPRESS_INCLUDE])
  53         m4_define([PCT_DONT_SUPPRESS_INCLUDE],[yes])
  54       ],
  55       [version-from-vc], [
  56         m4_undefine([PCT_VERSION_FROM_VC])
  57         m4_define([PCT_VERSION_FROM_VC],[yes])
  58     ])
  59   ])
  60
  61   AC_CONFIG_MACRO_DIR([m4])
  62
  63   m4_if(m4_substr(m4_esyscmd(test -d src && echo 0),0,1),0,[
  64     AC_CONFIG_HEADERS([src/config.h])
  65   ],[
  66     AC_CONFIG_HEADERS([config.h])
  67   ])
  68
  69   # We need to prevent canonical target
  70   # from injecting -O2 into CFLAGS - but we won't modify anything if we have
  71   # set CFLAGS on the command line, since that should take ultimate precedence
  72   AS_IF([test "x${ac_cv_env_CFLAGS_set}" = "x"],
  73         [CFLAGS=""])
  74   AS_IF([test "x${ac_cv_env_CXXFLAGS_set}" = "x"],
  75         [CXXFLAGS=""])
  76
  77   AC_CANONICAL_TARGET
  78
  79   m4_if(PCT_DONT_SUPRESS_INCLUDE,yes,[
  80     AM_INIT_AUTOMAKE(-Wall -Werror -Wno-portability subdir-objects foreign)
  81   ],[
  82     AM_INIT_AUTOMAKE(-Wall -Werror -Wno-portability nostdinc subdir-objects foreign)
  83   ])
  84
  85   m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  86
  87   m4_if(m4_substr(m4_esyscmd(test -d gnulib && echo 0),0,1),0,[
  88     gl_EARLY
  89   ])
  90
  91   AC_REQUIRE([AC_PROG_CC])
  92   m4_if(PCT_FORCE_GCC42, [yes], [
  93     AC_REQUIRE([PANDORA_ENSURE_GCC_VERSION])
  94   ])
  95   AC_REQUIRE([PANDORA_64BIT])
  96
  97   m4_if(PCT_VERSION_FROM_VC,yes,[
  98     PANDORA_VC_VERSION
  99   ],[
 100     PANDORA_TEST_VC_DIR
 101   ])
 102   PANDORA_VERSION
 103
 104   dnl Once we can use a modern autoconf, we can use this
 105   dnl AC_PROG_CC_C99
 106   AC_REQUIRE([AC_PROG_CXX])
 107   PANDORA_EXTENSIONS
 108   AM_PROG_CC_C_O
 109
 110
 111
 112   PANDORA_PLATFORM
 113
 114   PANDORA_LIBTOOL
 115
 116   dnl autoconf doesn't automatically provide a fail-if-no-C++ macro
 117   dnl so we check c++98 features and fail if we don't have them, mainly
 118   dnl for that reason
 119   PANDORA_CHECK_CXX_STANDARD
 120   m4_if(PCT_REQUIRE_CXX, [yes], [
 121     AS_IF([test "$ac_cv_cxx_stdcxx_98" = "no"],[
 122       AC_MSG_ERROR([No working C++ Compiler has been found. ${PACKAGE} requires a C++ compiler that can handle C++98])
 123     ])
 124
 125   ])
 126
 127   m4_if(m4_substr(m4_esyscmd(test -d gnulib && echo 0),0,1),0,[
 128     gl_INIT
 129     AC_CONFIG_LIBOBJ_DIR([gnulib])
 130   ])
 131
 132   PANDORA_CHECK_C_VERSION
 133   PANDORA_CHECK_CXX_VERSION
 134
 135   AC_C_BIGENDIAN
 136   AC_C_CONST
 137   AC_C_INLINE
 138   AC_C_VOLATILE
 139   AC_C_RESTRICT
 140
 141   AC_HEADER_TIME
 142   AC_STRUCT_TM
 143   AC_TYPE_SIZE_T
 144   AC_SYS_LARGEFILE
 145   PANDORA_CLOCK_GETTIME
 146
 147   # off_t is not a builtin type
 148   AC_CHECK_SIZEOF(off_t, 4)
 149   AS_IF([test "$ac_cv_sizeof_off_t" -eq 0],[
 150     AC_MSG_ERROR("${PACKAGE} needs an off_t type.")
 151   ])
 152
 153   AC_CHECK_SIZEOF(size_t)
 154   AS_IF([test "$ac_cv_sizeof_size_t" -eq 0],[
 155     AC_MSG_ERROR("${PACKAGE} needs an size_t type.")
 156   ])
 157
 158   AC_DEFINE_UNQUOTED([SIZEOF_SIZE_T],[$ac_cv_sizeof_size_t],[Size of size_t as computed by sizeof()])
 159   AC_CHECK_SIZEOF(long long)
 160   AC_DEFINE_UNQUOTED([SIZEOF_LONG_LONG],[$ac_cv_sizeof_long_long],[Size of long long as computed by sizeof()])
 161   AC_CACHE_CHECK([if time_t is unsigned], [ac_cv_time_t_unsigned],[
 162   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 163       [[
 164 #include <time.h>
 165       ]],
 166       [[
 167       int array[(((time_t)-1) > 0) ? 1 : -1];
 168       ]])
 169     ],[
 170       ac_cv_time_t_unsigned=yes
 171     ],[
 172       ac_cv_time_t_unsigned=no
 173     ])
 174   ])
 175   AS_IF([test "$ac_cv_time_t_unsigned" = "yes"],[
 176     AC_DEFINE([TIME_T_UNSIGNED], 1, [Define to 1 if time_t is unsigned])
 177   ])
 178
 179   AC_CHECK_LIBM
 180   dnl Bug on FreeBSD - LIBM check doesn't set the damn variable
 181   AC_SUBST([LIBM])
 182
 183   AC_CHECK_FUNC(setsockopt, [], [AC_CHECK_LIB(socket, setsockopt)])
 184   AC_CHECK_FUNC(bind, [], [AC_CHECK_LIB(bind, bind)])
 185
 186
 187
 188   PANDORA_OPTIMIZE
 189
 190   AC_LANG_PUSH(C++)
 191   # Test whether madvise() is declared in C++ code -- it is not on some
 192   # systems, such as Solaris
 193   AC_CHECK_DECLS([madvise], [], [], [AC_INCLUDES_DEFAULT[
 194   #if HAVE_SYS_MMAN_H
 195   #include <sys/types.h>
 196   #include <sys/mman.h>
 197   #endif
 198   ]])
 199   AC_LANG_POP()
 200
 201   PANDORA_HAVE_GCC_ATOMICS
 202
 203   m4_if(PCT_USE_VISIBILITY,[yes],[
 204     dnl We need to inject error into the cflags to test if visibility works or not
 205     save_CFLAGS="${CFLAGS}"
 206     CFLAGS="${CFLAGS} -Werror"
 207     PANDORA_VISIBILITY
 208     CFLAGS="${save_CFLAGS}"
 209   ])
 210
 211   PANDORA_HEADER_ASSERT
 212
 213   PANDORA_WARNINGS(PCT_ALL_ARGS)
 214
 215   PANDORA_ENABLE_DTRACE
 216
 217   AC_LIB_PREFIX
 218   PANDORA_HAVE_BETTER_MALLOC
 219
 220   AC_CHECK_PROGS([DOXYGEN], [doxygen])
 221   AC_CHECK_PROGS([PERL], [perl])
 222   AC_CHECK_PROGS([DPKG_GENSYMBOLS], [dpkg-gensymbols], [:])
 223
 224   AM_CONDITIONAL(HAVE_DPKG_GENSYMBOLS,[test "x${DPKG_GENSYMBOLS}" != "x:"])
 225
 226   PANDORA_WITH_GETTEXT
 227
 228   AS_IF([test "x${gl_LIBOBJS}" != "x"],[
 229     AS_IF([test "$GCC" = "yes"],[
 230       AM_CPPFLAGS="-isystem \${top_srcdir}/gnulib -isystem \${top_builddir}/gnulib ${AM_CPPFLAGS}"
 231     ],[
 232     AM_CPPFLAGS="-I\${top_srcdir}/gnulib -I\${top_builddir}/gnulib ${AM_CPPFLAGS}"
 233     ])
 234   ])
 235   m4_if(m4_substr(m4_esyscmd(test -d src && echo 0),0,1),0,[
 236     AM_CPPFLAGS="-I\$(top_srcdir)/src -I\$(top_builddir)/src ${AM_CPPFLAGS}"
 237   ],[
 238     AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${AM_CPPFLAGS}"
 239   ])
 240
 241   PANDORA_USE_PIPE
 242
 243
 244   AM_CFLAGS="${AM_CFLAGS} ${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE}"
 245   AM_CXXFLAGS="${AM_CXXFLAGS} ${CXX_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE}"
 246
 247   AC_SUBST([AM_CFLAGS])
 248   AC_SUBST([AM_CXXFLAGS])
 249   AC_SUBST([AM_CPPFLAGS])
 250   AC_SUBST([AM_LDFLAGS])
 251
 252 ])