git.m6w6.name Git - awesomized/libmemcached/blob - m4/ax_pthread_timedjoin_np.m4

   1 # ===========================================================================
   2 # http://
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PTHREAD_TIMEDJOIN_NP()
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check for pthread_timedjoin_np support.
  12 #
  13 # LICENSE
  14 #
  15 #   Copyright (c) 2012 Brian Aker <brian@tangent.org>
  16 #
  17 #   Copying and distribution of this file, with or without modification, are
  18 #   permitted in any medium without royalty provided the copyright notice
  19 #   and this notice are preserved. This file is offered as-is, without any
  20 #   warranty.
  21
  22 #serial 6
  23
  24 AC_DEFUN([AX_PTHREAD_TIMEDJOIN_NP],
  25     [AC_PREREQ([2.63])dnl
  26     AC_REQUIRE([AX_PTHREAD])
  27     AC_CACHE_CHECK([check for pthread_timedjoin_np], [ax_cv_pthread_timedjoin_np],
  28       [AX_SAVE_FLAGS
  29       CFLAGS="$PTHREAD_CFLAGS"
  30       LIBS="$PTHREAD_LIBS"
  31       AC_LANG_PUSH([C])
  32       AC_LINK_IFELSE(
  33         [AC_LANG_PROGRAM(
  34           [
  35 #include <pthread.h>
  36 #include <stdlib.h>
  37           ],[
  38           pthread_t thread;
  39           pthread_timedjoin_np(thread, NULL, NULL);
  40           ])],
  41         [ax_cv_pthread_timedjoin_np=yes],[])
  42
  43       AC_LANG_POP
  44       AX_RESTORE_FLAGS
  45       ])
  46
  47     AS_IF([test "$ax_cv_pthread_timedjoin_np" = yes],
  48         [AC_DEFINE(HAVE_PTHREAD_TIMEDJOIN_NP,[1],[Define if pthread_timedjoin_np is present in pthread.h.])],
  49         [AC_DEFINE(HAVE_PTHREAD_TIMEDJOIN_NP,[0],[Define if pthread_timedjoin_np is present in pthread.h.])])
  50     ])