git.m6w6.name Git - awesomized/libmemcached/blob - libmemcached/options/parser.yy

   1 /*  vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
   2  *
   3  *  Libmemcached Scanner and Parser
   4  *
   5  *  Copyright (C) 2011 DataDifferental, http://datadifferential.com
   6  *
   7  *  This program is free software: you can redistribute it and/or modify
   8  *  it under the terms of the GNU Affero General Public License as
   9  *  published by the Free Software Foundation, either version 3 of the
  10  *  License, or (at your option) any later version.
  11  *
  12  *  This program is distributed in the hope that it will be useful,
  13  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  *  GNU Affero General Public License for more details.
  16  *
  17  *  You should have received a copy of the GNU Affero General Public License
  18  *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 %{
  22
  23 #include <config.h>
  24
  25 #include <stdint.h>
  26 #include <iostream>
  27 #include <sstream>
  28 #include <string>
  29
  30 #include <libmemcached/options/type.h>
  31 #include <libmemcached/options/string.h>
  32 #include <libmemcached/options/symbol.h>
  33
  34 #pragma GCC diagnostic ignored "-Wold-style-cast"
  35 #include <libmemcached/options/scanner.h>
  36
  37 inline void libmemcached_error(YYLTYPE *locp, type_st *parser, yyscan_t *scanner, const char *str)
  38 {
  39   memcached_string_t local_string;
  40   local_string.size= strlen(str);
  41   local_string.c_str= str;
  42   memcached_set_error(parser->memc, MEMCACHED_FAILURE, &local_string);
  43 }
  44
  45
  46 %}
  47
  48 %error-verbose
  49 %debug
  50 %defines
  51 %expect 0
  52 %output "libmemcached/options/parser.cc"
  53 %defines "libmemcached/options/parser.h"
  54 %lex-param { yyscan_t *scanner }
  55 %name-prefix="libmemcached_"
  56 %parse-param { type_st *parser }
  57 %parse-param { yyscan_t *scanner }
  58 %locations
  59 %pure-parser
  60 %require "2.2"
  61 %start statement
  62 %verbose
  63
  64 %token COMMENT
  65 %token CONFIGURE_FILE
  66 %token EMPTY_LINE
  67 %token SERVER
  68 %token SERVERS
  69 %token UNKNOWN
  70
  71 %token DASH_OPTION
  72
  73 /* All behavior options */
  74 %token AUTO_EJECT_HOSTS
  75 %token BINARY_PROTOCOL
  76 %token BUFFER_REQUESTS
  77 %token CACHE_LOOKUPS
  78 %token CONNECT_TIMEOUT
  79 %token _CORK
  80 %token DISTRIBUTION
  81 %token HASH
  82 %token HASH_WITH_PREFIX_KEY
  83 %token IO_BYTES_WATERMARK
  84 %token IO_KEY_PREFETCH
  85 %token IO_MSG_WATERMARK
  86 %token KETAMA
  87 %token KETAMA_HASH
  88 %token KETAMA_WEIGHTED
  89 %token NOREPLY
  90 %token NUMBER_OF_REPLICAS
  91 %token POLL_TIMEOUT
  92 %token RANDOMIZE_REPLICA_READ
  93 %token RCV_TIMEOUT
  94 %token RETRY_TIMEOUT
  95 %token SERVER_FAILURE_LIMIT
  96 %token SND_TIMEOUT
  97 %token SOCKET_RECV_SIZE
  98 %token SOCKET_SEND_SIZE
  99 %token SORT_HOSTS
 100 %token SUPPORT_CAS
 101 %token _TCP_NODELAY
 102 %token _TCP_KEEPALIVE
 103 %token _TCP_KEEPIDLE
 104 %token USER_DATA
 105 %token USE_UDP
 106 %token VERIFY_KEY
 107
 108 /* Callbacks */
 109 %token PREFIX_KEY
 110
 111 /* Hash types */
 112 %token MD5
 113 %token CRC
 114 %token FNV1_64
 115 %token FNV1A_64
 116 %token FNV1_32
 117 %token FNV1A_32
 118 %token HSIEH
 119 %token MURMUR
 120 %token JENKINS
 121
 122 /* Distributions */
 123 %token CONSISTENT
 124 %token MODULA
 125 %token RANDOM
 126
 127 %nonassoc ','
 128 %nonassoc '='
 129
 130 %token <number> NUMBER
 131 %token <number> FLOAT
 132 %token <string> HOSTNAME
 133 %token <string> HOSTNAME_WITH_PORT
 134 %token <string> IPADDRESS
 135 %token <string> IPADDRESS_WITH_PORT
 136 %token <string> STRING
 137 %token <string> QUOTED_STRING
 138
 139 %type <server> server
 140 %type <string> string
 141 %type <distribution> distribution
 142 %type <hash> hash
 143 %type <behavior> behavior_boolean
 144 %type <behavior> behavior_number
 145
 146 %%
 147
 148 statement:
 149          DASH_OPTION expression
 150           { }
 151         | statement ' ' DASH_OPTION expression
 152           { }
 153         | COMMENT
 154           { }
 155         | EMPTY_LINE
 156           { }
 157         ;
 158
 159
 160 expression:
 161           SERVER '=' server
 162           {
 163             if (memcached_server_add_parsed(parser->memc, $3.c_str, $3.length, $3.port, 0) != MEMCACHED_SUCCESS)
 164               YYERROR;
 165           }
 166         | SERVERS '=' server_list
 167           {
 168           }
 169         | CONFIGURE_FILE '=' string
 170           {
 171             memcached_set_configuration_file(parser->memc, $3.c_str, $3.length);
 172           }
 173         | behaviors
 174         ;
 175
 176 behaviors:
 177           PREFIX_KEY '=' string
 178           {
 179             memcached_return_t rc;
 180             if ((rc= memcached_callback_set(parser->memc, MEMCACHED_CALLBACK_PREFIX_KEY, std::string($3.c_str, $3.length).c_str())) != MEMCACHED_SUCCESS)
 181             {
 182               std::stringstream ss;
 183               ss << "--PREFIX-KEY" << $3;
 184               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 185               YYERROR;
 186             }
 187           }
 188         | DISTRIBUTION '=' distribution
 189           {
 190             memcached_return_t rc;
 191             if ((rc= memcached_behavior_set(parser->memc, MEMCACHED_BEHAVIOR_DISTRIBUTION, $3)) != MEMCACHED_SUCCESS)
 192             {
 193               std::stringstream ss;
 194               ss << "--DISTRIBUTION=" << libmemcached_string_distribution($3);
 195               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 196               YYERROR;
 197             }
 198           }
 199         | HASH '=' hash
 200           {
 201             memcached_return_t rc;
 202             if ((rc= memcached_behavior_set(parser->memc, MEMCACHED_BEHAVIOR_HASH, $3)) != MEMCACHED_SUCCESS)
 203             {
 204               std::stringstream ss;
 205               ss << "--HASH=" << libmemcached_string_hash($3);
 206               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 207               YYERROR;
 208             }
 209           }
 210         | KETAMA_HASH '=' hash
 211           {
 212             memcached_return_t rc;
 213             if ((rc= memcached_behavior_set(parser->memc, MEMCACHED_BEHAVIOR_KETAMA_HASH, $3)) != MEMCACHED_SUCCESS)
 214             {
 215               std::stringstream ss;
 216               ss << "--KETAMA-HASH=" << libmemcached_string_hash($3);
 217               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 218               YYERROR;
 219             }
 220           }
 221         | behavior_number '=' NUMBER
 222           {
 223             memcached_return_t rc;
 224             if ((rc= memcached_behavior_set(parser->memc, $1, $3)) != MEMCACHED_SUCCESS)
 225             {
 226               std::stringstream ss;
 227               ss << "--" << libmemcached_string_behavior($1) << "=" << $3;
 228               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 229               YYERROR;
 230             }
 231           }
 232         | behavior_boolean
 233           {
 234             memcached_return_t rc;
 235             if ((rc= memcached_behavior_set(parser->memc, $1, true)) != MEMCACHED_SUCCESS)
 236             {
 237               std::stringstream ss;
 238               ss << "--" << libmemcached_string_behavior($1);
 239               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 240               YYERROR;
 241             }
 242           }
 243         |  USER_DATA
 244           {
 245           }
 246         ;
 247
 248 behavior_number:
 249           CONNECT_TIMEOUT
 250           {
 251             $$= MEMCACHED_BEHAVIOR_CONNECT_TIMEOUT;
 252           }
 253         | IO_MSG_WATERMARK
 254           {
 255             $$= MEMCACHED_BEHAVIOR_IO_MSG_WATERMARK;
 256           }
 257         | IO_BYTES_WATERMARK
 258           {
 259             $$= MEMCACHED_BEHAVIOR_IO_BYTES_WATERMARK;
 260           }
 261         | IO_KEY_PREFETCH
 262           {
 263             $$= MEMCACHED_BEHAVIOR_IO_KEY_PREFETCH;
 264           }
 265         | NUMBER_OF_REPLICAS
 266           {
 267             $$= MEMCACHED_BEHAVIOR_NUMBER_OF_REPLICAS;
 268           }
 269         | POLL_TIMEOUT
 270           {
 271             $$= MEMCACHED_BEHAVIOR_POLL_TIMEOUT;
 272           }
 273         |  RCV_TIMEOUT
 274           {
 275             $$= MEMCACHED_BEHAVIOR_RCV_TIMEOUT;
 276           }
 277         |  RETRY_TIMEOUT
 278           {
 279             $$= MEMCACHED_BEHAVIOR_RETRY_TIMEOUT;
 280           }
 281         |  SERVER_FAILURE_LIMIT
 282           {
 283             $$= MEMCACHED_BEHAVIOR_SERVER_FAILURE_LIMIT;
 284           }
 285         |  SND_TIMEOUT
 286           {
 287             $$= MEMCACHED_BEHAVIOR_SND_TIMEOUT;
 288           }
 289         |  SOCKET_RECV_SIZE
 290           {
 291             $$= MEMCACHED_BEHAVIOR_SOCKET_RECV_SIZE;
 292           }
 293         |  SOCKET_SEND_SIZE
 294           {
 295             $$= MEMCACHED_BEHAVIOR_SOCKET_SEND_SIZE;
 296           }
 297         ;
 298
 299 behavior_boolean:
 300           AUTO_EJECT_HOSTS
 301           {
 302             $$= MEMCACHED_BEHAVIOR_AUTO_EJECT_HOSTS;
 303           }
 304         | BINARY_PROTOCOL
 305           {
 306             $$= MEMCACHED_BEHAVIOR_BINARY_PROTOCOL;
 307           }
 308         | BUFFER_REQUESTS
 309           {
 310             $$= MEMCACHED_BEHAVIOR_BUFFER_REQUESTS;
 311           }
 312         | CACHE_LOOKUPS
 313           {
 314             $$= MEMCACHED_BEHAVIOR_CACHE_LOOKUPS;
 315           }
 316         | _CORK
 317           {
 318             $$= MEMCACHED_BEHAVIOR_CORK;
 319           }
 320         | HASH_WITH_PREFIX_KEY
 321           {
 322             $$= MEMCACHED_BEHAVIOR_HASH_WITH_PREFIX_KEY;
 323           }
 324         | KETAMA
 325           {
 326             $$= MEMCACHED_BEHAVIOR_KETAMA;
 327           }
 328         | KETAMA_WEIGHTED
 329           {
 330             $$= MEMCACHED_BEHAVIOR_KETAMA_WEIGHTED;
 331           }
 332         | NOREPLY
 333           {
 334             $$= MEMCACHED_BEHAVIOR_NOREPLY;
 335           }
 336         |  RANDOMIZE_REPLICA_READ
 337           {
 338             $$= MEMCACHED_BEHAVIOR_RANDOMIZE_REPLICA_READ;
 339           }
 340         |  SORT_HOSTS
 341           {
 342             $$= MEMCACHED_BEHAVIOR_SORT_HOSTS;
 343           }
 344         |  SUPPORT_CAS
 345           {
 346             $$= MEMCACHED_BEHAVIOR_SUPPORT_CAS;
 347           }
 348         |  _TCP_NODELAY
 349           {
 350             $$= MEMCACHED_BEHAVIOR_TCP_NODELAY;
 351           }
 352         |  _TCP_KEEPALIVE
 353           {
 354             $$= MEMCACHED_BEHAVIOR_TCP_KEEPALIVE;
 355           }
 356         |  _TCP_KEEPIDLE
 357           {
 358             $$= MEMCACHED_BEHAVIOR_TCP_KEEPIDLE;
 359           }
 360         |  USE_UDP
 361           {
 362             $$= MEMCACHED_BEHAVIOR_USE_UDP;
 363           }
 364         |  VERIFY_KEY
 365           {
 366             $$= MEMCACHED_BEHAVIOR_VERIFY_KEY;
 367           }
 368
 369
 370 server_list:
 371            server
 372           {
 373             memcached_return_t rc;
 374             if ((rc= memcached_server_add_parsed(parser->memc, $1.c_str, $1.length, $1.port, 0)) != MEMCACHED_SUCCESS)
 375             {
 376               std::stringstream ss;
 377               ss << "--SERVER=" << $1;
 378               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 379               YYERROR;
 380             }
 381           }
 382         | server_list ',' server
 383           {
 384             memcached_return_t rc;
 385             if ((rc= memcached_server_add_parsed(parser->memc, $3.c_str, $3.length, $3.port, 0)) != MEMCACHED_SUCCESS)
 386             {
 387               std::stringstream ss;
 388               ss << "--SERVERS=" << $3;
 389               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 390               YYERROR;
 391             }
 392           }
 393         ;
 394
 395 server:
 396           HOSTNAME_WITH_PORT NUMBER
 397           {
 398             $$.c_str= $1.c_str;
 399             $$.length= $1.length -1;
 400             $$.port= $2;
 401           }
 402         | HOSTNAME
 403           {
 404             $$.c_str= $1.c_str;
 405             $$.length= $1.length;
 406             $$.port= MEMCACHED_DEFAULT_PORT;
 407           }
 408         | STRING /* a match can be against "localhost" which is just a string */
 409           {
 410             $$.c_str= $1.c_str;
 411             $$.length= $1.length;
 412             $$.port= MEMCACHED_DEFAULT_PORT;
 413           }
 414         | IPADDRESS_WITH_PORT NUMBER
 415           {
 416             $$.c_str= $1.c_str;
 417             $$.length= $1.length -1;
 418             $$.port= $2;
 419           }
 420         | IPADDRESS
 421           {
 422             $$.c_str= $1.c_str;
 423             $$.length= $1.length;
 424             $$.port= MEMCACHED_DEFAULT_PORT;
 425           }
 426         ;
 427
 428 hash:
 429           MD5
 430           {
 431             $$= MEMCACHED_HASH_MD5;
 432           }
 433         | CRC
 434           {
 435             $$= MEMCACHED_HASH_CRC;
 436           }
 437         | FNV1_64
 438           {
 439             $$= MEMCACHED_HASH_FNV1_64;
 440           }
 441         | FNV1A_64
 442           {
 443             $$= MEMCACHED_HASH_FNV1A_64;
 444           }
 445         | FNV1_32
 446           {
 447             $$= MEMCACHED_HASH_FNV1_32;
 448           }
 449         | FNV1A_32
 450           {
 451             $$= MEMCACHED_HASH_FNV1A_32;
 452           }
 453         | HSIEH
 454           {
 455             $$= MEMCACHED_HASH_HSIEH;
 456           }
 457         | MURMUR
 458           {
 459             $$= MEMCACHED_HASH_MURMUR;
 460           }
 461         | JENKINS
 462           {
 463             $$= MEMCACHED_HASH_JENKINS;
 464           }
 465         ;
 466
 467 string:
 468           STRING
 469           {
 470             $$= $1;
 471           }
 472         | QUOTED_STRING
 473           {
 474             $$.c_str= $1.c_str +1;
 475             $$.length= $1.length -2;
 476           }
 477         ;
 478
 479 distribution:
 480           CONSISTENT
 481           {
 482             $$= MEMCACHED_DISTRIBUTION_CONSISTENT;
 483           }
 484         | MODULA
 485           {
 486             $$= MEMCACHED_DISTRIBUTION_MODULA;
 487           }
 488         | RANDOM
 489           {
 490             $$= MEMCACHED_DISTRIBUTION_RANDOM;
 491           }
 492         ;