git.m6w6.name Git - awesomized/libmemcached/blob - libmemcached/options/parser.yy

   1 /*  vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
   2  *
   3  *  Libmemcached Scanner and Parser
   4  *
   5  *  Copyright (C) 2011 DataDifferental, http://datadifferential.com
   6  *
   7  *  This program is free software: you can redistribute it and/or modify
   8  *  it under the terms of the GNU Affero General Public License as
   9  *  published by the Free Software Foundation, either version 3 of the
  10  *  License, or (at your option) any later version.
  11  *
  12  *  This program is distributed in the hope that it will be useful,
  13  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  *  GNU Affero General Public License for more details.
  16  *
  17  *  You should have received a copy of the GNU Affero General Public License
  18  *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 %error-verbose
  22 %debug
  23 %defines
  24 %expect 0
  25 %output "libmemcached/options/parser.cc"
  26 %defines "libmemcached/options/parser.h"
  27 %lex-param { yyscan_t *scanner }
  28 %name-prefix="libmemcached_"
  29 %parse-param { Context *parser }
  30 %parse-param { yyscan_t *scanner }
  31 %locations
  32 %pure-parser
  33 %require "2.2"
  34 %start statement
  35 %verbose
  36
  37 %{
  38
  39 #include <config.h>
  40
  41 #include <stdint.h>
  42 #include <iostream>
  43 #include <sstream>
  44 #include <string>
  45
  46 #include <libmemcached/options/context.h>
  47 #include <libmemcached/options/string.h>
  48 #include <libmemcached/options/symbol.h>
  49
  50 #pragma GCC diagnostic ignored "-Wold-style-cast"
  51 #include <libmemcached/options/scanner.h>
  52
  53 int libmemcached_lex(YYSTYPE* lvalp, YYLTYPE* llocp, void* scanner);
  54
  55 inline void libmemcached_error(YYLTYPE *locp, Context *context, yyscan_t *scanner, const char *error)
  56 {
  57   memcached_string_t local_string;
  58   std::cerr << " Error " << error << std::endl;
  59   local_string.size= strlen(context->begin);
  60   local_string.c_str= context->begin;
  61   memcached_set_error(context->memc, MEMCACHED_PARSE_ERROR, &local_string);
  62 }
  63
  64 %}
  65
  66 %token COMMENT
  67 %token CONFIGURE_FILE
  68 %token EMPTY_LINE
  69 %token SERVER
  70 %token SERVERS
  71 %token UNKNOWN
  72
  73 %token DASH_OPTION
  74
  75 /* All behavior options */
  76 %token AUTO_EJECT_HOSTS
  77 %token BINARY_PROTOCOL
  78 %token BUFFER_REQUESTS
  79 %token CACHE_LOOKUPS
  80 %token CONNECT_TIMEOUT
  81 %token _CORK
  82 %token DISTRIBUTION
  83 %token HASH
  84 %token HASH_WITH_PREFIX_KEY
  85 %token IO_BYTES_WATERMARK
  86 %token IO_KEY_PREFETCH
  87 %token IO_MSG_WATERMARK
  88 %token KETAMA
  89 %token KETAMA_HASH
  90 %token KETAMA_WEIGHTED
  91 %token NOREPLY
  92 %token NUMBER_OF_REPLICAS
  93 %token POLL_TIMEOUT
  94 %token RANDOMIZE_REPLICA_READ
  95 %token RCV_TIMEOUT
  96 %token RETRY_TIMEOUT
  97 %token SERVER_FAILURE_LIMIT
  98 %token SND_TIMEOUT
  99 %token SOCKET_RECV_SIZE
 100 %token SOCKET_SEND_SIZE
 101 %token SORT_HOSTS
 102 %token SUPPORT_CAS
 103 %token _TCP_NODELAY
 104 %token _TCP_KEEPALIVE
 105 %token _TCP_KEEPIDLE
 106 %token USER_DATA
 107 %token USE_UDP
 108 %token VERIFY_KEY
 109
 110 /* Callbacks */
 111 %token PREFIX_KEY
 112
 113 /* Hash types */
 114 %token MD5
 115 %token CRC
 116 %token FNV1_64
 117 %token FNV1A_64
 118 %token FNV1_32
 119 %token FNV1A_32
 120 %token HSIEH
 121 %token MURMUR
 122 %token JENKINS
 123
 124 /* Distributions */
 125 %token CONSISTENT
 126 %token MODULA
 127 %token RANDOM
 128
 129 %nonassoc ','
 130 %nonassoc '='
 131
 132 %token <number> NUMBER
 133 %token <number> FLOAT
 134 %token <string> HOSTNAME
 135 %token <string> HOSTNAME_WITH_PORT
 136 %token <string> IPADDRESS
 137 %token <string> IPADDRESS_WITH_PORT
 138 %token <string> STRING
 139 %token <string> QUOTED_STRING
 140
 141 %type <server> server
 142 %type <string> string
 143 %type <distribution> distribution
 144 %type <hash> hash
 145 %type <behavior> behavior_boolean
 146 %type <behavior> behavior_number
 147
 148 %%
 149
 150 statement:
 151          DASH_OPTION expression
 152           { }
 153         | statement ' ' DASH_OPTION expression
 154           { }
 155         | COMMENT
 156           { }
 157         | EMPTY_LINE
 158           { }
 159         ;
 160
 161
 162 expression:
 163           SERVER '=' server
 164           {
 165             if (memcached_server_add_parsed(parser->memc, $3.c_str, $3.length, $3.port, 0) != MEMCACHED_SUCCESS)
 166               YYERROR;
 167           }
 168         | SERVERS '=' server_list
 169           {
 170           }
 171         | CONFIGURE_FILE '=' string
 172           {
 173             memcached_set_configuration_file(parser->memc, $3.c_str, $3.length);
 174           }
 175         | behaviors
 176         ;
 177
 178 behaviors:
 179           PREFIX_KEY '=' string
 180           {
 181             memcached_return_t rc;
 182             if ((rc= memcached_callback_set(parser->memc, MEMCACHED_CALLBACK_PREFIX_KEY, std::string($3.c_str, $3.length).c_str())) != MEMCACHED_SUCCESS)
 183             {
 184               std::stringstream ss;
 185               ss << "--PREFIX-KEY" << $3;
 186               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 187               YYERROR;
 188             }
 189           }
 190         | DISTRIBUTION '=' distribution
 191           {
 192             memcached_return_t rc;
 193             if ((rc= memcached_behavior_set(parser->memc, MEMCACHED_BEHAVIOR_DISTRIBUTION, $3)) != MEMCACHED_SUCCESS)
 194             {
 195               std::stringstream ss;
 196               ss << "--DISTRIBUTION=" << libmemcached_string_distribution($3);
 197               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 198               YYERROR;
 199             }
 200           }
 201         | HASH '=' hash
 202           {
 203             memcached_return_t rc;
 204             if ((rc= memcached_behavior_set(parser->memc, MEMCACHED_BEHAVIOR_HASH, $3)) != MEMCACHED_SUCCESS)
 205             {
 206               std::stringstream ss;
 207               ss << "--HASH=" << libmemcached_string_hash($3);
 208               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 209               YYERROR;
 210             }
 211           }
 212         | KETAMA_HASH '=' hash
 213           {
 214             memcached_return_t rc;
 215             if ((rc= memcached_behavior_set(parser->memc, MEMCACHED_BEHAVIOR_KETAMA_HASH, $3)) != MEMCACHED_SUCCESS)
 216             {
 217               std::stringstream ss;
 218               ss << "--KETAMA-HASH=" << libmemcached_string_hash($3);
 219               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 220               YYERROR;
 221             }
 222           }
 223         | behavior_number '=' NUMBER
 224           {
 225             memcached_return_t rc;
 226             if ((rc= memcached_behavior_set(parser->memc, $1, $3)) != MEMCACHED_SUCCESS)
 227             {
 228               std::stringstream ss;
 229               ss << "--" << libmemcached_string_behavior($1) << "=" << $3;
 230               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 231               YYERROR;
 232             }
 233           }
 234         | behavior_boolean
 235           {
 236             memcached_return_t rc;
 237             if ((rc= memcached_behavior_set(parser->memc, $1, true)) != MEMCACHED_SUCCESS)
 238             {
 239               std::stringstream ss;
 240               ss << "--" << libmemcached_string_behavior($1);
 241               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 242               YYERROR;
 243             }
 244           }
 245         |  USER_DATA
 246           {
 247           }
 248         ;
 249
 250 behavior_number:
 251           CONNECT_TIMEOUT
 252           {
 253             $$= MEMCACHED_BEHAVIOR_CONNECT_TIMEOUT;
 254           }
 255         | IO_MSG_WATERMARK
 256           {
 257             $$= MEMCACHED_BEHAVIOR_IO_MSG_WATERMARK;
 258           }
 259         | IO_BYTES_WATERMARK
 260           {
 261             $$= MEMCACHED_BEHAVIOR_IO_BYTES_WATERMARK;
 262           }
 263         | IO_KEY_PREFETCH
 264           {
 265             $$= MEMCACHED_BEHAVIOR_IO_KEY_PREFETCH;
 266           }
 267         | NUMBER_OF_REPLICAS
 268           {
 269             $$= MEMCACHED_BEHAVIOR_NUMBER_OF_REPLICAS;
 270           }
 271         | POLL_TIMEOUT
 272           {
 273             $$= MEMCACHED_BEHAVIOR_POLL_TIMEOUT;
 274           }
 275         |  RCV_TIMEOUT
 276           {
 277             $$= MEMCACHED_BEHAVIOR_RCV_TIMEOUT;
 278           }
 279         |  RETRY_TIMEOUT
 280           {
 281             $$= MEMCACHED_BEHAVIOR_RETRY_TIMEOUT;
 282           }
 283         |  SERVER_FAILURE_LIMIT
 284           {
 285             $$= MEMCACHED_BEHAVIOR_SERVER_FAILURE_LIMIT;
 286           }
 287         |  SND_TIMEOUT
 288           {
 289             $$= MEMCACHED_BEHAVIOR_SND_TIMEOUT;
 290           }
 291         |  SOCKET_RECV_SIZE
 292           {
 293             $$= MEMCACHED_BEHAVIOR_SOCKET_RECV_SIZE;
 294           }
 295         |  SOCKET_SEND_SIZE
 296           {
 297             $$= MEMCACHED_BEHAVIOR_SOCKET_SEND_SIZE;
 298           }
 299         ;
 300
 301 behavior_boolean:
 302           AUTO_EJECT_HOSTS
 303           {
 304             $$= MEMCACHED_BEHAVIOR_AUTO_EJECT_HOSTS;
 305           }
 306         | BINARY_PROTOCOL
 307           {
 308             $$= MEMCACHED_BEHAVIOR_BINARY_PROTOCOL;
 309           }
 310         | BUFFER_REQUESTS
 311           {
 312             $$= MEMCACHED_BEHAVIOR_BUFFER_REQUESTS;
 313           }
 314         | CACHE_LOOKUPS
 315           {
 316             $$= MEMCACHED_BEHAVIOR_CACHE_LOOKUPS;
 317           }
 318         | _CORK
 319           {
 320             $$= MEMCACHED_BEHAVIOR_CORK;
 321           }
 322         | HASH_WITH_PREFIX_KEY
 323           {
 324             $$= MEMCACHED_BEHAVIOR_HASH_WITH_PREFIX_KEY;
 325           }
 326         | KETAMA
 327           {
 328             $$= MEMCACHED_BEHAVIOR_KETAMA;
 329           }
 330         | KETAMA_WEIGHTED
 331           {
 332             $$= MEMCACHED_BEHAVIOR_KETAMA_WEIGHTED;
 333           }
 334         | NOREPLY
 335           {
 336             $$= MEMCACHED_BEHAVIOR_NOREPLY;
 337           }
 338         |  RANDOMIZE_REPLICA_READ
 339           {
 340             $$= MEMCACHED_BEHAVIOR_RANDOMIZE_REPLICA_READ;
 341           }
 342         |  SORT_HOSTS
 343           {
 344             $$= MEMCACHED_BEHAVIOR_SORT_HOSTS;
 345           }
 346         |  SUPPORT_CAS
 347           {
 348             $$= MEMCACHED_BEHAVIOR_SUPPORT_CAS;
 349           }
 350         |  _TCP_NODELAY
 351           {
 352             $$= MEMCACHED_BEHAVIOR_TCP_NODELAY;
 353           }
 354         |  _TCP_KEEPALIVE
 355           {
 356             $$= MEMCACHED_BEHAVIOR_TCP_KEEPALIVE;
 357           }
 358         |  _TCP_KEEPIDLE
 359           {
 360             $$= MEMCACHED_BEHAVIOR_TCP_KEEPIDLE;
 361           }
 362         |  USE_UDP
 363           {
 364             $$= MEMCACHED_BEHAVIOR_USE_UDP;
 365           }
 366         |  VERIFY_KEY
 367           {
 368             $$= MEMCACHED_BEHAVIOR_VERIFY_KEY;
 369           }
 370
 371
 372 server_list:
 373            server
 374           {
 375             memcached_return_t rc;
 376             if ((rc= memcached_server_add_parsed(parser->memc, $1.c_str, $1.length, $1.port, 0)) != MEMCACHED_SUCCESS)
 377             {
 378               std::stringstream ss;
 379               ss << "--SERVER=" << $1;
 380               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 381               YYERROR;
 382             }
 383           }
 384         | server_list ',' server
 385           {
 386             memcached_return_t rc;
 387             if ((rc= memcached_server_add_parsed(parser->memc, $3.c_str, $3.length, $3.port, 0)) != MEMCACHED_SUCCESS)
 388             {
 389               std::stringstream ss;
 390               ss << "--SERVERS=" << $3;
 391               memcached_set_error_string(parser->memc, rc, ss.str().c_str(), ss.str().length());
 392               YYERROR;
 393             }
 394           }
 395         ;
 396
 397 server:
 398           HOSTNAME_WITH_PORT NUMBER
 399           {
 400             $$.c_str= $1.c_str;
 401             $$.length= $1.length -1;
 402             $$.port= $2;
 403           }
 404         | HOSTNAME
 405           {
 406             $$.c_str= $1.c_str;
 407             $$.length= $1.length;
 408             $$.port= MEMCACHED_DEFAULT_PORT;
 409           }
 410         | STRING /* a match can be against "localhost" which is just a string */
 411           {
 412             $$.c_str= $1.c_str;
 413             $$.length= $1.length;
 414             $$.port= MEMCACHED_DEFAULT_PORT;
 415           }
 416         | IPADDRESS_WITH_PORT NUMBER
 417           {
 418             $$.c_str= $1.c_str;
 419             $$.length= $1.length -1;
 420             $$.port= $2;
 421           }
 422         | IPADDRESS
 423           {
 424             $$.c_str= $1.c_str;
 425             $$.length= $1.length;
 426             $$.port= MEMCACHED_DEFAULT_PORT;
 427           }
 428         ;
 429
 430 hash:
 431           MD5
 432           {
 433             $$= MEMCACHED_HASH_MD5;
 434           }
 435         | CRC
 436           {
 437             $$= MEMCACHED_HASH_CRC;
 438           }
 439         | FNV1_64
 440           {
 441             $$= MEMCACHED_HASH_FNV1_64;
 442           }
 443         | FNV1A_64
 444           {
 445             $$= MEMCACHED_HASH_FNV1A_64;
 446           }
 447         | FNV1_32
 448           {
 449             $$= MEMCACHED_HASH_FNV1_32;
 450           }
 451         | FNV1A_32
 452           {
 453             $$= MEMCACHED_HASH_FNV1A_32;
 454           }
 455         | HSIEH
 456           {
 457             $$= MEMCACHED_HASH_HSIEH;
 458           }
 459         | MURMUR
 460           {
 461             $$= MEMCACHED_HASH_MURMUR;
 462           }
 463         | JENKINS
 464           {
 465             $$= MEMCACHED_HASH_JENKINS;
 466           }
 467         ;
 468
 469 string:
 470           STRING
 471           {
 472             $$= $1;
 473           }
 474         | QUOTED_STRING
 475           {
 476             $$.c_str= $1.c_str +1;
 477             $$.length= $1.length -2;
 478           }
 479         ;
 480
 481 distribution:
 482           CONSISTENT
 483           {
 484             $$= MEMCACHED_DISTRIBUTION_CONSISTENT;
 485           }
 486         | MODULA
 487           {
 488             $$= MEMCACHED_DISTRIBUTION_MODULA;
 489           }
 490         | RANDOM
 491           {
 492             $$= MEMCACHED_DISTRIBUTION_RANDOM;
 493           }
 494         ;