git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 #shared library versioning
  16 MEMCACHED_LIBRARY_VERSION=2:0:0
  17 #                         | | |
  18 #                  +------+ | +---+
  19 #                  |        |     |
  20 #                 current:revision:age
  21 #                  |        |     |
  22 #                  |        |     +- increment if interfaces have been added
  23 #                  |        |        set to zero if interfaces have been removed or changed
  24 #                  |        +- increment if source code has changed
  25 #                  |           set to zero if current is incremented
  26 #                  +- increment if interfaces have been added, removed or changed
  27 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  28 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  29 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  30
  31 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  32 SAVE_CFLAGS=${CFLAGS}
  33 SAVE_CXXFLAGS=${CXXFLAGS}
  34 CFLAGS=
  35 CXXFLAGS=
  36
  37 AC_CANONICAL_TARGET
  38
  39 CFLAGS=${SAVE_CFLAGS}
  40 CXXFLAGS=${SAVE_CXXFLAGS}
  41
  42 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  43
  44 if test "x${enable_dependency_tracking}" = "x"
  45 then
  46   enable_dependency_tracking=yes
  47 fi
  48
  49 if test -d "${srcdir}/.bzr"
  50 then
  51   building_from_bzr=yes
  52 else
  53   building_from_bzr=no
  54 fi
  55
  56 AC_PROG_CC
  57 AC_PROG_CC_C99
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Use the C99 enabling flag found earlier
 101 AS_IF([test "$ac_cv_prog_cc_c99" != "no"],
 102       [CFLAGS="$ac_cv_prog_cc_c99 ${CFLAGS}"])
 103
 104 # Build optimized or debug version ?
 105 # First check for gcc and g++
 106 if test "$GCC" = "yes"
 107 then
 108   CFLAGS="-ggdb3 ${CFLAGS}"
 109   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 110
 111   DEBUG_CFLAGS="-O0"
 112   DEBUG_CXXFLAGS="-O0"
 113
 114   OPTIMIZE_CFLAGS="-O3"
 115   OPTIMIZE_CXXFLAGS="-O3"
 116 fi
 117 if test "x$SUNCC" = "xyes"
 118 then
 119   CFLAGS="-g -mt ${CFLAGS}"
 120   CXXFLAGS="-xlang=c99 -g -mt -compat=5 -library=stlport4 -template=no%extdef ${CXXFLAGS}"
 121
 122   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin"
 123   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 124   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 125
 126 fi
 127
 128 ENABLE_64BIT
 129
 130 #--------------------------------------------------------------------
 131 # Check for libpthread
 132 #--------------------------------------------------------------------
 133
 134 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 135 LIBS="${PTHREAD_LIBS} ${LIBS}"
 136 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 137 CC="$PTHREAD_CC"
 138
 139
 140 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 141 AC_SEARCH_LIBS(socket, socket)
 142 AC_SEARCH_LIBS(gethostbyname, nsl)
 143
 144 save_LIBS="$LIBS"
 145 LIBS="$LIBS -lm"
 146 AC_LINK_IFELSE(
 147   [AC_LANG_PROGRAM(
 148     [[
 149 #include <stdlib.h>
 150     ]],[[
 151       float f= floorf((float) 1.0);
 152     ]],
 153     [LIBM="-lm"],[LIBM=""])])
 154
 155 AC_SUBST(LIBM)
 156 LIBS="$save_LIBS"
 157
 158 AC_SEARCH_LIBS(floorf, m)
 159
 160 dnl Specialty checks
 161 DETECT_BYTEORDER
 162 ENABLE_UTILLIB
 163 ENABLE_DTRACE
 164 SETSOCKOPT_SANITY
 165 ENABLE_HSIEH_HASH
 166 REQUIRE_POD2MAN
 167 PROTOCOL_BINARY_TEST
 168 WITH_MEMCACHED
 169
 170 dnl TODO: Remove this define once we are using 2.61 across the board.
 171 # AX_HEADER_ASSERT
 172 # ----------------
 173 # Check whether to enable assertions.
 174 AC_DEFUN([AX_HEADER_ASSERT],
 175 [
 176   AC_MSG_CHECKING([whether to enable assertions])
 177   AC_ARG_ENABLE([assert],
 178     [AS_HELP_STRING([--disable-assert],
 179        [Turn off assertions])],
 180     [ac_cv_assert="no"],
 181     [ac_cv_assert="yes"])
 182   AC_MSG_RESULT([$ac_cv_assert])
 183 ])
 184 AX_HEADER_ASSERT
 185
 186
 187 AC_ARG_WITH([debug],
 188     [AS_HELP_STRING([--with-debug],
 189        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 190     [with_debug=$withval],
 191     [with_debug=no])
 192 if test "$with_debug" = "yes"
 193 then
 194   # Debugging. No optimization.
 195   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 196   CXXFLAGS="${DEBUG_CXXFLAGS} -DDEBUG ${CXXFLAGS}"
 197 else
 198   # Optimized version. No debug
 199   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 200   CXXFLAGS="${OPTIMIZE_CXXFLAGS} ${CXXFLAGS}"
 201 fi
 202
 203 AC_ARG_ENABLE([profiling],
 204     [AS_HELP_STRING([--enable-profiling],
 205        [Toggle profiling @<:@default=off@:>@])],
 206     [ac_profiling="$enableval"],
 207     [ac_profiling="no"])
 208
 209 AC_ARG_ENABLE([coverage],
 210     [AS_HELP_STRING([--enable-coverage],
 211        [Toggle coverage @<:@default=off@:>@])],
 212     [ac_coverage="$enableval"],
 213     [ac_coverage="no"])
 214
 215 if test "$GCC" = "yes"
 216 then
 217
 218   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 219     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 220     [save_CFLAGS="$CFLAGS"
 221      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 222      AC_COMPILE_IFELSE(
 223        [AC_LANG_PROGRAM([],[])],
 224        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 225        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 226      CFLAGS="$save_CFLAGS"])
 227
 228   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 229         [
 230           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 231         ])
 232
 233   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 234     [ac_cv_safe_to_use_wconversion_],
 235     [save_CFLAGS="$CFLAGS"
 236      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 237      AC_COMPILE_IFELSE(
 238        [AC_LANG_PROGRAM([[
 239 #include <stdbool.h>
 240 void foo(bool a)
 241 {
 242   (void)a;
 243 }
 244        ]],[[
 245 foo(0);
 246        ]])],
 247        [ac_cv_safe_to_use_wconversion_=yes],
 248        [ac_cv_safe_to_use_wconversion_=no])
 249      CFLAGS="$save_CFLAGS"])
 250
 251   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 252     [W_CONVERSION="-Wconversion"
 253     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 254       [ac_cv_safe_to_use_Wconversion_],
 255       [save_CFLAGS="$CFLAGS"
 256        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 257        AC_COMPILE_IFELSE(
 258          [AC_LANG_PROGRAM(
 259            [[
 260 #include <netinet/in.h>
 261            ]],[[
 262 uint16_t x= htons(80);
 263            ]])],
 264          [ac_cv_safe_to_use_Wconversion_=yes],
 265          [ac_cv_safe_to_use_Wconversion_=no])
 266        CFLAGS="$save_CFLAGS"])
 267
 268     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 269           [
 270             NO_CONVERSION="-Wno-conversion"
 271           ])
 272     ])
 273
 274
 275   W_STRICT_ALIASING="-Wno-strict-aliasing"
 276
 277   AS_IF([test "$ac_profiling" = "yes"],
 278         [CC_PROFILING="-pg"])
 279
 280   AS_IF([test "$ac_coverage" = "yes"],
 281         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 282
 283   AS_IF([test "$building_from_bzr" = "yes"],
 284         [W_FAIL="-Werror"])
 285
 286   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 287   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 288   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wold-style-cast -Weffc++ -Wno-long-long"
 289
 290   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 291     [ac_cv_safe_to_use_Wlogical_op_],
 292     [save_CFLAGS="$CFLAGS"
 293      CFLAGS="-Wlogical-op"
 294      AC_COMPILE_IFELSE([
 295        AC_LANG_PROGRAM(
 296        [[
 297 #include <stdio>
 298        ]], [[]])
 299     ],
 300     [ac_cv_safe_to_use_Wlogical_op_=yes],
 301     [ac_cv_safe_to_use_Wlogical_op_=no])
 302   CFLAGS="$save_CFLAGS"])
 303   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 304         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 305
 306   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 307     [ac_cv_safe_to_use_Wredundant_decls_],
 308     [AC_LANG_PUSH(C++)
 309      save_CXXFLAGS="${CXXFLAGS}"
 310      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 311      AC_COMPILE_IFELSE(
 312        [AC_LANG_PROGRAM([
 313 template <typename E> struct C { void foo(); };
 314 template <typename E> void C<E>::foo() { }
 315 template <> void C<int>::foo();
 316           AC_INCLUDES_DEFAULT])],
 317         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 318         [ac_cv_safe_to_use_Wredundant_decls_=no])
 319       CXXFLAGS="${save_CXXFLAGS}"
 320       AC_LANG_POP()])
 321   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 322         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 323         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 324
 325   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 326 fi
 327 if test "$SUNCC" = "yes"
 328 then
 329
 330   AS_IF([test "$ac_profiling" = "yes"],
 331         [CC_PROFILING="-xinstrument=datarace"])
 332
 333   AS_IF([test "$building_from_bzr" = "yes"],
 334         [W_FAIL="-errwarn=%all"])
 335
 336   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 337     [ac_cv_paste_result],
 338     [
 339       save_CFLAGS="${CFLAGS}"
 340       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 341       AC_COMPILE_IFELSE(
 342         [AC_LANG_PROGRAM([
 343           AC_INCLUDES_DEFAULT
 344         ],[
 345           int x= 0;])],
 346         [ac_cv_paste_result=yes],
 347         [ac_cv_paste_result=no])
 348       CFLAGS="${save_CFLAGS}"
 349     ])
 350   AS_IF([test $ac_cv_paste_result = yes],
 351     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 352
 353
 354   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 355   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 356 fi
 357
 358 AC_SUBST(NO_REDUNDANT_DECLS)
 359
 360 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 361 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 362 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 363
 364 AC_SUBST([AM_CPPFLAGS])
 365 AC_SUBST([AM_CFLAGS])
 366 AC_SUBST([AM_CXXFLAGS])
 367
 368 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 369 CFLAGS=""
 370 CXXFLAGS=""
 371 CPPFLAGS=""
 372
 373 AC_CONFIG_FILES([
 374   Makefile
 375   clients/Makefile
 376   tests/Makefile
 377   docs/Makefile
 378   libmemcached/Makefile
 379   libmemcachedutil/Makefile
 380   support/Makefile
 381   support/libmemcached.pc
 382   support/libmemcached.spec
 383   support/libmemcached-fc.spec
 384   ])
 385 AC_OUTPUT
 386
 387 echo "---"
 388 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 389 echo ""
 390 echo "   * Installation prefix:       $prefix"
 391 echo "   * System type:               $host_vendor-$host_os"
 392 echo "   * Host CPU:                  $host_cpu"
 393 echo "   * C Compiler:                $CC_VERSION"
 394 echo "   * Assertions enabled:        $ac_cv_assert"
 395 echo "   * Debug enabled:             $with_debug"
 396 echo "   * Warnings as failure:       $building_from_bzr"
 397 echo ""
 398 echo "---"
 399