git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # libmemcached
   3 # Copyright (C) 2008 Brian Aker, Monty Taylor
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_PREREQ(2.59)
  10 AC_INIT([libmemcached],[0.41],[http://libmemcached.org/])
  11 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 PANDORA_CANONICAL_TARGET
  15
  16 #shared library versioning
  17 MEMCACHED_LIBRARY_VERSION=5:1:1
  18 #                         | | |
  19 #                  +------+ | +---+
  20 #                  |        |     |
  21 #                 current:revision:age
  22 #                  |        |     |
  23 #                  |        |     +- increment if interfaces have been added
  24 #                  |        |        set to zero if interfaces have been removed or changed
  25 #                  |        +- increment if source code has changed
  26 #                  |           set to zero if current is incremented
  27 #                  +- increment if interfaces have been added, removed or changed
  28 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  29
  30
  31 HASHKIT_LIBRARY_VERSION=0:0:0
  32 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  33
  34 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  35 AC_SEARCH_LIBS(gethostbyname, nsl)
  36
  37 AC_CHECK_FUNCS([getline])
  38
  39 PANDORA_HAVE_LIBGTEST
  40 PANDORA_HAVE_LIBEVENT
  41 PANDORA_REQUIRE_PTHREAD
  42 PANDORA_CXX_DEMANGLE
  43
  44 dnl Specialty checks
  45 DETECT_BYTEORDER
  46 ENABLE_UTILLIB
  47 SETSOCKOPT_SANITY
  48 ENABLE_HSIEH_HASH
  49 REQUIRE_POD2MAN
  50 REQUIRE_PODCHECKER
  51 PROTOCOL_BINARY_TEST
  52 WITH_MEMCACHED
  53 ENABLE_DEPRECATED
  54 PANDORA_HAVE_LIBINNODB
  55 PANDORA_PRINT_CALLSTACK
  56 PANDORA_HAVE_SASL
  57
  58 dnl The sasl functions should only be visible if we build with sasl support
  59 AS_IF([test "x$ac_cv_sasl" = "xyes"],
  60       [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"])
  61 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
  62
  63 AC_CHECK_HEADERS([atomic.h])
  64 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
  65       AC_CHECK_FUNCS(atomic_add_64)
  66       AC_CHECK_FUNCS(atomic_add_32)
  67       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
  68             AC_DEFINE([USE_ATOMIC_H],
  69                       [1],
  70                       [Define to true if you want to use functions from atomic.h])])])
  71
  72 AC_CONFIG_FILES([
  73   Makefile
  74   docs/Makefile
  75   libhashkit/configure.h
  76   libmemcached/configure.h
  77   support/libmemcached.pc
  78   support/libmemcached.spec
  79   support/libmemcached-fc.spec
  80   ])
  81 AC_OUTPUT
  82
  83 echo "---"
  84 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
  85 echo ""
  86 echo "   * Installation prefix:       $prefix"
  87 echo "   * System type:               $host_vendor-$host_os"
  88 echo "   * Host CPU:                  $host_cpu"
  89 echo "   * C Compiler:                $CC_VERSION"
  90 echo "   * Assertions enabled:        $ac_cv_assert"
  91 echo "   * Debug enabled:             $with_debug"
  92 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
  93 echo ""
  94 echo "---"
  95
  96 case "$host_os" in
  97   *freebsd*)
  98     echo "*****"
  99     echo "*"
 100     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 101     echo "*"
 102     echo "*   use 'gmake' To build libmemcached"
 103     echo "*"
 104     echo "*****"
 105   ;;
 106 esac
 107