git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # libmemcached
   3 # Copyright (C) 2008 Brian Aker, Monty Taylor
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_PREREQ(2.59)
  10 AC_INIT([libmemcached],[0.42],[http://libmemcached.org/])
  11 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 PANDORA_CANONICAL_TARGET
  15
  16 #shared library versioning
  17 MEMCACHED_UTIL_LIBRARY_VERSION=1:0:0
  18 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  19 MEMCACHED_LIBRARY_VERSION=5:1:0
  20 #                         | | |
  21 #                  +------+ | +---+
  22 #                  |        |     |
  23 #                 current:revision:age
  24 #                  |        |     |
  25 #                  |        |     +- increment if interfaces have been added
  26 #                  |        |        set to zero if interfaces have been removed or changed
  27 #                  |        +- increment if source code has changed
  28 #                  |           set to zero if current is incremented
  29 #                  +- increment if interfaces have been added, removed or changed
  30 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  31 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  32 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  33
  34
  35 HASHKIT_LIBRARY_VERSION=0:0:0
  36 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  37
  38 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  39 AC_SEARCH_LIBS(gethostbyname, nsl)
  40
  41 AC_CHECK_FUNCS([getline])
  42
  43 PANDORA_HAVE_LIBGTEST
  44 PANDORA_HAVE_LIBEVENT
  45 PANDORA_REQUIRE_PTHREAD
  46 PANDORA_CXX_DEMANGLE
  47
  48 dnl Specialty checks
  49 DETECT_BYTEORDER
  50 ENABLE_UTILLIB
  51 SETSOCKOPT_SANITY
  52 ENABLE_HSIEH_HASH
  53 PROTOCOL_BINARY_TEST
  54 WITH_MEMCACHED
  55 ENABLE_DEPRECATED
  56 PANDORA_HAVE_LIBINNODB
  57 PANDORA_PRINT_CALLSTACK
  58 PANDORA_HAVE_SASL
  59
  60 dnl The sasl functions should only be visible if we build with sasl support
  61 AS_IF([test "x$ac_cv_sasl" = "xyes"],
  62       [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"])
  63 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
  64
  65 AC_CHECK_HEADERS([atomic.h])
  66 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
  67       AC_CHECK_FUNCS(atomic_add_64)
  68       AC_CHECK_FUNCS(atomic_add_32)
  69       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
  70             AC_DEFINE([USE_ATOMIC_H],
  71                       [1],
  72                       [Define to true if you want to use functions from atomic.h])])])
  73
  74 AC_ARG_WITH([docs],
  75   [AS_HELP_STRING([--with-docs],
  76     [Generate documentation (yes|no) @<:@default=yes@:>@])],
  77   [with_docs=$withval],
  78   [with_docs=yes])
  79
  80 AS_IF([test "$with_docs" = "yes"],
  81   [
  82     REQUIRE_POD2MAN
  83     REQUIRE_PODCHECKER
  84   ])
  85 AM_CONDITIONAL(BUILD_DOCS, test "$with_docs" = "yes")
  86
  87
  88 AC_CONFIG_FILES([
  89   Makefile
  90   docs/Makefile
  91   libhashkit/configure.h
  92   libmemcached/configure.h
  93   support/libmemcached.pc
  94   support/libmemcached.spec
  95   support/libmemcached-fc.spec
  96   ])
  97 AC_OUTPUT
  98
  99 echo "---"
 100 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 101 echo ""
 102 echo "   * Installation prefix:       $prefix"
 103 echo "   * System type:               $host_vendor-$host_os"
 104 echo "   * Host CPU:                  $host_cpu"
 105 echo "   * C Compiler:                $CC_VERSION"
 106 echo "   * Assertions enabled:        $ac_cv_assert"
 107 echo "   * Debug enabled:             $with_debug"
 108 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 109 echo ""
 110 echo "---"
 111
 112 case "$host_os" in
 113   *freebsd*)
 114     echo "*****"
 115     echo "*"
 116     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 117     echo "*"
 118     echo "*   use 'gmake' To build libmemcached"
 119     echo "*"
 120     echo "*****"
 121   ;;
 122 esac
 123
 124 AS_IF(test "$with_docs" = "no",
 125   [
 126     echo "*****"
 127     echo "*"
 128     echo "*  WARNING: You are not generating any documentation."
 129     echo "*           Please don't ship libmemcached to an end user"
 130     echo "*           without documentation..."
 131     echo "*"
 132     echo "*****"
 133   ])