git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Build optimized or debug version ?
 101 # First check for gcc and g++
 102 if test "$GCC" = "yes"
 103 then
 104   CFLAGS="-ggdb3 -std=gnu99 ${CFLAGS}"
 105   DEBUG_CFLAGS="-O0"
 106   OPTIMIZE_CFLAGS="-O3"
 107 fi
 108 if test "x$SUNCC" = "xyes"
 109 then
 110    CFLAGS="-g -mt -xc99=all $CFLAGS"
 111    CXXFLAGS="-g -mt -xlang=c99 $CXXFLAGS"
 112    OPTIMIZE_CFLAGS="-xO4 -xlibmil -xdepend -Xa -xstrconst"
 113 fi
 114
 115 SOLARIS_64BIT
 116
 117 #--------------------------------------------------------------------
 118 # Check for libpthread
 119 #--------------------------------------------------------------------
 120
 121 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 122 LIBS="${PTHREAD_LIBS} ${LIBS}"
 123 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 124 CC="$PTHREAD_CC"
 125
 126
 127 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 128 AC_SEARCH_LIBS(socket, socket)
 129 AC_SEARCH_LIBS(gethostbyname, nsl)
 130
 131 save_LIBS="$LIBS"
 132 LIBS="$LIBS -lm"
 133 AC_LINK_IFELSE(
 134   [AC_LANG_PROGRAM(
 135     [[
 136 #include <stdlib.h>
 137     ]],[[
 138       float f= floorf((float) 1.0);
 139     ]],
 140     [LIBM="-lm"],[LIBM=""])])
 141
 142 AC_SUBST(LIBM)
 143 LIBS="$save_LIBS"
 144
 145 AC_SEARCH_LIBS(floorf, m)
 146
 147 DETECT_BYTEORDER
 148 ENABLE_UTILLIB
 149
 150 sinclude(m4/pod2man.m4)
 151 sinclude(m4/dtrace.m4)
 152 sinclude(m4/protocol_binary.m4)
 153 sinclude(m4/memcached.m4)
 154 sinclude(m4/setsockopt.m4)
 155 sinclude(m4/hsieh.m4)
 156
 157 dnl TODO: Remove this define once we are using 2.61 across the board.
 158 # AX_HEADER_ASSERT
 159 # ----------------
 160 # Check whether to enable assertions.
 161 AC_DEFUN([AX_HEADER_ASSERT],
 162 [
 163   AC_MSG_CHECKING([whether to enable assertions])
 164   AC_ARG_ENABLE([assert],
 165     [AS_HELP_STRING([--disable-assert],
 166        [Turn off assertions])],
 167     [ac_cv_assert="no"],
 168     [ac_cv_assert="yes"])
 169   AC_MSG_RESULT([$ac_cv_assert])
 170 ])
 171 AX_HEADER_ASSERT
 172
 173
 174 AC_ARG_WITH([debug],
 175     [AS_HELP_STRING([--with-debug],
 176        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 177     [with_debug=$withval],
 178     [with_debug=no])
 179 if test "$with_debug" = "yes"
 180 then
 181   # Debugging. No optimization.
 182   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 183 else
 184   # Optimized version. No debug
 185   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 186 fi
 187
 188 AC_ARG_ENABLE([profiling],
 189     [AS_HELP_STRING([--enable-profiling],
 190        [Toggle profiling @<:@default=off@:>@])],
 191     [ac_profiling="$enableval"],
 192     [ac_profiling="no"])
 193
 194 AC_ARG_ENABLE([coverage],
 195     [AS_HELP_STRING([--enable-coverage],
 196        [Toggle coverage @<:@default=off@:>@])],
 197     [ac_coverage="$enableval"],
 198     [ac_coverage="no"])
 199
 200 dnl We can't do this warning, so turn off
 201 W_STRICT_ALIASING="-Wno-strict-aliasing"
 202
 203 if test "$GCC" = "yes"
 204 then
 205
 206
 207   AS_IF([test "$ac_profiling" = "yes"],
 208         [CC_PROFILING="-pg"])
 209
 210   AS_IF([test "$ac_coverage" = "yes"],
 211         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 212
 213   AS_IF([test "$building_from_bzr" = "yes"],
 214         [W_FAIL="-Werror"])
 215
 216   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef  -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING}"
 217   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 218   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long"
 219
 220
 221   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 222     [ac_cv_safe_to_use_Wlogical_op_],
 223     [save_CFLAGS="$CFLAGS"
 224      CFLAGS="-Wlogical-op"
 225      AC_COMPILE_IFELSE([
 226        AC_LANG_PROGRAM(
 227        [[
 228 #include <stdio>
 229        ]], [[]])
 230     ],
 231     [ac_cv_safe_to_use_Wlogical_op_=yes],
 232     [ac_cv_safe_to_use_Wlogical_op_=no])
 233   CFLAGS="$save_CFLAGS"])
 234   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 235         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 236
 237   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 238     [ac_cv_safe_to_use_Wredundant_decls_],
 239     [AC_LANG_PUSH(C++)
 240      save_CXXFLAGS="${CXXFLAGS}"
 241      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 242      AC_COMPILE_IFELSE(
 243        [AC_LANG_PROGRAM([
 244 template <typename E> struct C { void foo(); };
 245 template <typename E> void C<E>::foo() { }
 246 template <> void C<int>::foo();
 247           AC_INCLUDES_DEFAULT])],
 248         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 249         [ac_cv_safe_to_use_Wredundant_decls_=no])
 250       CXXFLAGS="${save_CXXFLAGS}"
 251       AC_LANG_POP()])
 252   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 253         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 254         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 255
 256   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 257 fi
 258 if test "$SUNCC" = "yes"
 259 then
 260
 261   AS_IF([test "$ac_profiling" = "yes"],
 262         [CC_PROFILING="-xinstrument=datarace"])
 263
 264   AS_IF([test "$building_from_bzr" = "yes"],
 265         [W_FAIL="-errwarn=%all"])
 266
 267   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 268     [ac_cv_paste_result],
 269     [
 270       save_CFLAGS="${CFLAGS}"
 271       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 272       AC_COMPILE_IFELSE(
 273         [AC_LANG_PROGRAM([
 274           AC_INCLUDES_DEFAULT
 275         ],[
 276           int x= 0;])],
 277         [ac_cv_paste_result=yes],
 278         [ac_cv_paste_result=no])
 279       CFLAGS="${save_CFLAGS}"
 280     ])
 281   AS_IF([test $ac_cv_paste_result = yes],
 282     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 283
 284
 285   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 286   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 287 fi
 288
 289 AC_SUBST(NO_REDUNDANT_DECLS)
 290
 291 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 292 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 293 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 294
 295 AC_SUBST([AM_CPPFLAGS])
 296 AC_SUBST([AM_CFLAGS])
 297 AC_SUBST([AM_CXXFLAGS])
 298
 299 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 300 CFLAGS=""
 301 CXXFLAGS=""
 302 CPPFLAGS=""
 303
 304 AC_CONFIG_FILES([
 305   Makefile
 306   clients/Makefile
 307   tests/Makefile
 308   docs/Makefile
 309   libmemcached/Makefile
 310   libmemcachedutil/Makefile
 311   support/Makefile
 312   support/libmemcached.pc
 313   support/libmemcached.spec
 314   support/libmemcached-fc.spec
 315   ])
 316 AC_OUTPUT