git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Use the C99 enabling flag found earlier
 101 AS_IF([test "$ac_cv_prog_cc_c99" != "no"],
 102       [CFLAGS="$ac_cv_prog_cc_c99 ${CFLAGS}"])
 103
 104 # Build optimized or debug version ?
 105 # First check for gcc and g++
 106 if test "$GCC" = "yes"
 107 then
 108   CFLAGS="-ggdb3 ${CFLAGS}"
 109   DEBUG_CFLAGS="-O0"
 110   OPTIMIZE_CFLAGS="-O3"
 111 fi
 112 if test "x$SUNCC" = "xyes"
 113 then
 114    CFLAGS="-g -mt ${CFLAGS}"
 115    CXXFLAGS="-g -mt -xlang=c99 ${CXXFLAGS}"
 116    OPTIMIZE_CFLAGS="-xO4 -xlibmil -xdepend -Xa -xstrconst"
 117 fi
 118
 119 ENABLE_64BIT
 120
 121 #--------------------------------------------------------------------
 122 # Check for libpthread
 123 #--------------------------------------------------------------------
 124
 125 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 126 LIBS="${PTHREAD_LIBS} ${LIBS}"
 127 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 128 CC="$PTHREAD_CC"
 129
 130
 131 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 132 AC_SEARCH_LIBS(socket, socket)
 133 AC_SEARCH_LIBS(gethostbyname, nsl)
 134
 135 save_LIBS="$LIBS"
 136 LIBS="$LIBS -lm"
 137 AC_LINK_IFELSE(
 138   [AC_LANG_PROGRAM(
 139     [[
 140 #include <stdlib.h>
 141     ]],[[
 142       float f= floorf((float) 1.0);
 143     ]],
 144     [LIBM="-lm"],[LIBM=""])])
 145
 146 AC_SUBST(LIBM)
 147 LIBS="$save_LIBS"
 148
 149 AC_SEARCH_LIBS(floorf, m)
 150
 151 dnl Specialty checks
 152 DETECT_BYTEORDER
 153 ENABLE_UTILLIB
 154 ENABLE_DTRACE
 155 SETSOCKOPT_SANITY
 156 ENABLE_HSIEH_HASH
 157 REQUIRE_POD2MAN
 158 PROTOCOL_BINARY_TEST
 159 WITH_MEMCACHED
 160
 161 dnl TODO: Remove this define once we are using 2.61 across the board.
 162 # AX_HEADER_ASSERT
 163 # ----------------
 164 # Check whether to enable assertions.
 165 AC_DEFUN([AX_HEADER_ASSERT],
 166 [
 167   AC_MSG_CHECKING([whether to enable assertions])
 168   AC_ARG_ENABLE([assert],
 169     [AS_HELP_STRING([--disable-assert],
 170        [Turn off assertions])],
 171     [ac_cv_assert="no"],
 172     [ac_cv_assert="yes"])
 173   AC_MSG_RESULT([$ac_cv_assert])
 174 ])
 175 AX_HEADER_ASSERT
 176
 177
 178 AC_ARG_WITH([debug],
 179     [AS_HELP_STRING([--with-debug],
 180        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 181     [with_debug=$withval],
 182     [with_debug=no])
 183 if test "$with_debug" = "yes"
 184 then
 185   # Debugging. No optimization.
 186   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 187 else
 188   # Optimized version. No debug
 189   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 190 fi
 191
 192 AC_ARG_ENABLE([profiling],
 193     [AS_HELP_STRING([--enable-profiling],
 194        [Toggle profiling @<:@default=off@:>@])],
 195     [ac_profiling="$enableval"],
 196     [ac_profiling="no"])
 197
 198 AC_ARG_ENABLE([coverage],
 199     [AS_HELP_STRING([--enable-coverage],
 200        [Toggle coverage @<:@default=off@:>@])],
 201     [ac_coverage="$enableval"],
 202     [ac_coverage="no"])
 203
 204 dnl We can't do this warning, so turn off
 205 W_STRICT_ALIASING="-Wno-strict-aliasing"
 206
 207 if test "$GCC" = "yes"
 208 then
 209
 210   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 211     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 212     [save_CFLAGS="$CFLAGS"
 213      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 214      AC_COMPILE_IFELSE(
 215        [AC_LANG_PROGRAM([],[])],
 216        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 217        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 218      CFLAGS="$save_CFLAGS"])
 219
 220   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 221         [
 222           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 223         ])
 224
 225
 226   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 227     [ac_cv_safe_to_use_wconversion_],
 228     [save_CFLAGS="$CFLAGS"
 229      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 230      AC_COMPILE_IFELSE(
 231        [AC_LANG_PROGRAM([[
 232 #include <stdbool.h>
 233 void foo(bool a)
 234 {
 235   (void)a;
 236 }
 237        ]],[[
 238 foo(0);
 239        ]])],
 240        [ac_cv_safe_to_use_wconversion_=yes],
 241        [ac_cv_safe_to_use_wconversion_=no])
 242      CFLAGS="$save_CFLAGS"])
 243   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 244     [W_CONVERSION="-Wconversion"
 245     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 246       [ac_cv_safe_to_use_Wconversion_],
 247       [save_CFLAGS="$CFLAGS"
 248        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 249        AC_COMPILE_IFELSE(
 250          [AC_LANG_PROGRAM(
 251            [[
 252 #include <netinet/in.h>
 253            ]],[[
 254 uint16_t x= htons(80);
 255            ]])],
 256          [ac_cv_safe_to_use_Wconversion_=yes],
 257          [ac_cv_safe_to_use_Wconversion_=no])
 258        CFLAGS="$save_CFLAGS"])
 259
 260     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 261           [
 262             NO_CONVERSION="-Wno-conversion"
 263           ])
 264     ])
 265
 266   W_STRICT_ALIASING="-Wno-strict-aliasing"
 267
 268   AS_IF([test "$ac_profiling" = "yes"],
 269         [CC_PROFILING="-pg"])
 270
 271   AS_IF([test "$ac_coverage" = "yes"],
 272         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 273
 274   AS_IF([test "$building_from_bzr" = "yes"],
 275         [W_FAIL="-Werror"])
 276
 277   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 278   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align -Wconversion"
 279   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long -Wconversion"
 280
 281
 282   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 283     [ac_cv_safe_to_use_Wlogical_op_],
 284     [save_CFLAGS="$CFLAGS"
 285      CFLAGS="-Wlogical-op"
 286      AC_COMPILE_IFELSE([
 287        AC_LANG_PROGRAM(
 288        [[
 289 #include <stdio>
 290        ]], [[]])
 291     ],
 292     [ac_cv_safe_to_use_Wlogical_op_=yes],
 293     [ac_cv_safe_to_use_Wlogical_op_=no])
 294   CFLAGS="$save_CFLAGS"])
 295   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 296         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 297
 298   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 299     [ac_cv_safe_to_use_Wredundant_decls_],
 300     [AC_LANG_PUSH(C++)
 301      save_CXXFLAGS="${CXXFLAGS}"
 302      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 303      AC_COMPILE_IFELSE(
 304        [AC_LANG_PROGRAM([
 305 template <typename E> struct C { void foo(); };
 306 template <typename E> void C<E>::foo() { }
 307 template <> void C<int>::foo();
 308           AC_INCLUDES_DEFAULT])],
 309         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 310         [ac_cv_safe_to_use_Wredundant_decls_=no])
 311       CXXFLAGS="${save_CXXFLAGS}"
 312       AC_LANG_POP()])
 313   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 314         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 315         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 316
 317   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 318 fi
 319 if test "$SUNCC" = "yes"
 320 then
 321
 322   AS_IF([test "$ac_profiling" = "yes"],
 323         [CC_PROFILING="-xinstrument=datarace"])
 324
 325   AS_IF([test "$building_from_bzr" = "yes"],
 326         [W_FAIL="-errwarn=%all"])
 327
 328   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 329     [ac_cv_paste_result],
 330     [
 331       save_CFLAGS="${CFLAGS}"
 332       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 333       AC_COMPILE_IFELSE(
 334         [AC_LANG_PROGRAM([
 335           AC_INCLUDES_DEFAULT
 336         ],[
 337           int x= 0;])],
 338         [ac_cv_paste_result=yes],
 339         [ac_cv_paste_result=no])
 340       CFLAGS="${save_CFLAGS}"
 341     ])
 342   AS_IF([test $ac_cv_paste_result = yes],
 343     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 344
 345
 346   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 347   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 348 fi
 349
 350 AC_SUBST(NO_CONVERSION)
 351 AC_SUBST(NO_REDUNDANT_DECLS)
 352
 353 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 354 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 355 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 356
 357 AC_SUBST([AM_CPPFLAGS])
 358 AC_SUBST([AM_CFLAGS])
 359 AC_SUBST([AM_CXXFLAGS])
 360
 361 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 362 CFLAGS=""
 363 CXXFLAGS=""
 364 CPPFLAGS=""
 365
 366 AC_CONFIG_FILES([
 367   Makefile
 368   clients/Makefile
 369   tests/Makefile
 370   docs/Makefile
 371   libmemcached/Makefile
 372   libmemcachedutil/Makefile
 373   support/Makefile
 374   support/libmemcached.pc
 375   support/libmemcached.spec
 376   support/libmemcached-fc.spec
 377   ])
 378 AC_OUTPUT
 379
 380 echo "---"
 381 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 382 echo ""
 383 echo "   * Installation prefix:       $prefix"
 384 echo "   * System type:               $host_vendor-$host_os"
 385 echo "   * Host CPU:                  $host_cpu"
 386 echo "   * C Compiler:                $CC_VERSION"
 387 echo "   * Assertions enabled:        $ac_cv_assert"
 388 echo "   * Debug enabled:             $with_debug"
 389 echo "   * Warnings as failure:       $building_from_bzr"
 390 echo ""
 391 echo "---"
 392