git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 #shared library versioning
  16 MEMCACHED_LIBRARY_VERSION=2:0:0
  17 #                         | | |
  18 #                  +------+ | +---+
  19 #                  |        |     |
  20 #                 current:revision:age
  21 #                  |        |     |
  22 #                  |        |     +- increment if interfaces have been added
  23 #                  |        |        set to zero if interfaces have been removed or changed
  24 #                  |        +- increment if source code has changed
  25 #                  |           set to zero if current is incremented
  26 #                  +- increment if interfaces have been added, removed or changed
  27 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  28 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  29 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  30
  31 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  32 SAVE_CFLAGS=${CFLAGS}
  33 SAVE_CXXFLAGS=${CXXFLAGS}
  34 CFLAGS=
  35 CXXFLAGS=
  36
  37 AC_CANONICAL_TARGET
  38
  39 CFLAGS=${SAVE_CFLAGS}
  40 CXXFLAGS=${SAVE_CXXFLAGS}
  41
  42 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  43
  44 if test "x${enable_dependency_tracking}" = "x"
  45 then
  46   enable_dependency_tracking=yes
  47 fi
  48
  49 if test -d "${srcdir}/.bzr"
  50 then
  51   building_from_bzr=yes
  52 else
  53   building_from_bzr=no
  54 fi
  55
  56 AC_PROG_CXX
  57
  58 ACX_USE_SYSTEM_EXTENSIONS
  59
  60 AC_PROG_CPP
  61 AM_PROG_CC_C_O
  62
  63 FORCE_MAC_GCC42
  64 dnl Once we can use a modern autoconf, we can use this
  65 dnl AC_PROG_CC_C99
  66
  67 AC_C_BIGENDIAN
  68 AC_C_CONST
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_FUNC_MALLOC
  72 AC_FUNC_REALLOC
  73
  74 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  75
  76 # We use libtool
  77 AC_PROG_LIBTOOL
  78
  79 AC_MSG_CHECKING("C Compiler version")
  80 if test "$GCC" = "yes"
  81 then
  82   CC_VERSION=`$CC --version | sed 1q`
  83 elif test "$SUNCC" = "yes"
  84 then
  85   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  86 else
  87   CC_VERSION=""
  88 fi
  89 AC_MSG_RESULT("$CC_VERSION")
  90 AC_SUBST(CC_VERSION)
  91
  92 # libmemcached versioning when linked with GNU ld.
  93 if test "$lt_cv_prog_gnu_ld" = "yes"
  94 then
  95     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  96     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  97 fi
  98 AC_SUBST(LD_VERSION_SCRIPT)
  99 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
 100
 101 # Build optimized or debug version ?
 102 # First check for gcc and g++
 103 if test "$GCC" = "yes"
 104 then
 105
 106   dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
 107   dnl with using AC_CC_STD_C99 above
 108   CC="${CC} -std=gnu99"
 109
 110   CFLAGS="-ggdb3 ${CFLAGS}"
 111   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 112
 113   DEBUG_CFLAGS="-O0"
 114   DEBUG_CXXFLAGS="-O0"
 115
 116   OPTIMIZE_CFLAGS="-O3"
 117   OPTIMIZE_CXXFLAGS="-O3"
 118 fi
 119 if test "x$SUNCC" = "xyes"
 120 then
 121   dnl Once we can use a modern autoconf, we can replace the -xc99=all here
 122   dnl with using AC_CC_STD_C99 above
 123   CC="${CC} -xc99=all"
 124
 125   CFLAGS="-g -mt ${CFLAGS}"
 126   CXXFLAGS="-xlang=c99 -g -mt -compat=5 -library=stlport4 -template=no%extdef ${CXXFLAGS}"
 127
 128   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin"
 129   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 130   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 131
 132 fi
 133
 134 ENABLE_64BIT
 135
 136 #--------------------------------------------------------------------
 137 # Check for libpthread
 138 #--------------------------------------------------------------------
 139
 140 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 141 LIBS="${PTHREAD_LIBS} ${LIBS}"
 142 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 143 CC="$PTHREAD_CC"
 144
 145
 146 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 147 AC_SEARCH_LIBS(socket, socket)
 148 AC_SEARCH_LIBS(gethostbyname, nsl)
 149
 150 save_LIBS="$LIBS"
 151 LIBS="$LIBS -lm"
 152 AC_LINK_IFELSE(
 153   [AC_LANG_PROGRAM(
 154     [[
 155 #include <stdlib.h>
 156     ]],[[
 157       float f= floorf((float) 1.0);
 158     ]],
 159     [LIBM="-lm"],[LIBM=""])])
 160
 161 AC_SUBST(LIBM)
 162 LIBS="$save_LIBS"
 163
 164 AC_SEARCH_LIBS(floorf, m)
 165
 166 dnl Specialty checks
 167 DETECT_BYTEORDER
 168 ENABLE_UTILLIB
 169 ENABLE_DTRACE
 170 SETSOCKOPT_SANITY
 171 ENABLE_HSIEH_HASH
 172 REQUIRE_POD2MAN
 173 PROTOCOL_BINARY_TEST
 174 WITH_MEMCACHED
 175
 176 dnl TODO: Remove this define once we are using 2.61 across the board.
 177 # AX_HEADER_ASSERT
 178 # ----------------
 179 # Check whether to enable assertions.
 180 AC_DEFUN([AX_HEADER_ASSERT],
 181 [
 182   AC_MSG_CHECKING([whether to enable assertions])
 183   AC_ARG_ENABLE([assert],
 184     [AS_HELP_STRING([--disable-assert],
 185        [Turn off assertions])],
 186     [ac_cv_assert="no"],
 187     [ac_cv_assert="yes"])
 188   AC_MSG_RESULT([$ac_cv_assert])
 189 ])
 190 AX_HEADER_ASSERT
 191
 192
 193 AC_ARG_WITH([debug],
 194     [AS_HELP_STRING([--with-debug],
 195        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 196     [with_debug=$withval],
 197     [with_debug=no])
 198 if test "$with_debug" = "yes"
 199 then
 200   # Debugging. No optimization.
 201   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 202   CXXFLAGS="${DEBUG_CXXFLAGS} -DDEBUG ${CXXFLAGS}"
 203 else
 204   # Optimized version. No debug
 205   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 206   CXXFLAGS="${OPTIMIZE_CXXFLAGS} ${CXXFLAGS}"
 207 fi
 208
 209 AC_ARG_ENABLE([profiling],
 210     [AS_HELP_STRING([--enable-profiling],
 211        [Toggle profiling @<:@default=off@:>@])],
 212     [ac_profiling="$enableval"],
 213     [ac_profiling="no"])
 214
 215 AC_ARG_ENABLE([coverage],
 216     [AS_HELP_STRING([--enable-coverage],
 217        [Toggle coverage @<:@default=off@:>@])],
 218     [ac_coverage="$enableval"],
 219     [ac_coverage="no"])
 220
 221 if test "$GCC" = "yes"
 222 then
 223
 224   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 225     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 226     [save_CFLAGS="$CFLAGS"
 227      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 228      AC_COMPILE_IFELSE(
 229        [AC_LANG_PROGRAM([],[])],
 230        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 231        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 232      CFLAGS="$save_CFLAGS"])
 233
 234   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 235         [
 236           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 237         ])
 238
 239   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 240     [ac_cv_safe_to_use_wconversion_],
 241     [save_CFLAGS="$CFLAGS"
 242      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 243      AC_COMPILE_IFELSE(
 244        [AC_LANG_PROGRAM([[
 245 #include <stdbool.h>
 246 void foo(bool a)
 247 {
 248   (void)a;
 249 }
 250        ]],[[
 251 foo(0);
 252        ]])],
 253        [ac_cv_safe_to_use_wconversion_=yes],
 254        [ac_cv_safe_to_use_wconversion_=no])
 255      CFLAGS="$save_CFLAGS"])
 256
 257   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 258     [W_CONVERSION="-Wconversion"
 259     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 260       [ac_cv_safe_to_use_Wconversion_],
 261       [save_CFLAGS="$CFLAGS"
 262        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 263        AC_COMPILE_IFELSE(
 264          [AC_LANG_PROGRAM(
 265            [[
 266 #include <netinet/in.h>
 267            ]],[[
 268 uint16_t x= htons(80);
 269            ]])],
 270          [ac_cv_safe_to_use_Wconversion_=yes],
 271          [ac_cv_safe_to_use_Wconversion_=no])
 272        CFLAGS="$save_CFLAGS"])
 273
 274     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 275           [
 276             NO_CONVERSION="-Wno-conversion"
 277           ])
 278     ])
 279
 280   W_STRICT_ALIASING="-Wno-strict-aliasing"
 281
 282   AS_IF([test "$ac_profiling" = "yes"],
 283         [CC_PROFILING="-pg"])
 284
 285   AS_IF([test "$ac_coverage" = "yes"],
 286         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 287
 288   AS_IF([test "$building_from_bzr" = "yes"],
 289         [W_FAIL="-Werror"])
 290
 291   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 292   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 293   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wold-style-cast -Weffc++ -Wno-long-long"
 294
 295   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 296     [ac_cv_safe_to_use_Wlogical_op_],
 297     [save_CFLAGS="$CFLAGS"
 298      CFLAGS="-Wlogical-op"
 299      AC_COMPILE_IFELSE([
 300        AC_LANG_PROGRAM(
 301        [[
 302 #include <stdio>
 303        ]], [[]])
 304     ],
 305     [ac_cv_safe_to_use_Wlogical_op_=yes],
 306     [ac_cv_safe_to_use_Wlogical_op_=no])
 307   CFLAGS="$save_CFLAGS"])
 308   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 309         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 310
 311   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 312     [ac_cv_safe_to_use_Wredundant_decls_],
 313     [AC_LANG_PUSH(C++)
 314      save_CXXFLAGS="${CXXFLAGS}"
 315      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 316      AC_COMPILE_IFELSE(
 317        [AC_LANG_PROGRAM([
 318 template <typename E> struct C { void foo(); };
 319 template <typename E> void C<E>::foo() { }
 320 template <> void C<int>::foo();
 321           AC_INCLUDES_DEFAULT])],
 322         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 323         [ac_cv_safe_to_use_Wredundant_decls_=no])
 324       CXXFLAGS="${save_CXXFLAGS}"
 325       AC_LANG_POP()])
 326   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 327         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 328         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 329
 330   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 331 fi
 332 if test "$SUNCC" = "yes"
 333 then
 334
 335   AS_IF([test "$ac_profiling" = "yes"],
 336         [CC_PROFILING="-xinstrument=datarace"])
 337
 338   AS_IF([test "$building_from_bzr" = "yes"],
 339         [W_FAIL="-errwarn=%all"])
 340
 341   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 342     [ac_cv_paste_result],
 343     [
 344       save_CFLAGS="${CFLAGS}"
 345       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 346       AC_COMPILE_IFELSE(
 347         [AC_LANG_PROGRAM([
 348           AC_INCLUDES_DEFAULT
 349         ],[
 350           int x= 0;])],
 351         [ac_cv_paste_result=yes],
 352         [ac_cv_paste_result=no])
 353       CFLAGS="${save_CFLAGS}"
 354     ])
 355   AS_IF([test $ac_cv_paste_result = yes],
 356     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 357
 358
 359   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 360   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 361 fi
 362
 363 AC_SUBST(NO_CONVERSION)
 364 AC_SUBST(NO_REDUNDANT_DECLS)
 365
 366 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 367 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 368 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 369
 370 AC_SUBST([AM_CPPFLAGS])
 371 AC_SUBST([AM_CFLAGS])
 372 AC_SUBST([AM_CXXFLAGS])
 373
 374 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 375 CFLAGS=""
 376 CXXFLAGS=""
 377 CPPFLAGS=""
 378
 379 AC_CONFIG_FILES([
 380   Makefile
 381   clients/Makefile
 382   tests/Makefile
 383   docs/Makefile
 384   libmemcached/Makefile
 385   libmemcachedutil/Makefile
 386   support/Makefile
 387   support/libmemcached.pc
 388   support/libmemcached.spec
 389   support/libmemcached-fc.spec
 390   ])
 391 AC_OUTPUT
 392
 393 echo "---"
 394 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 395 echo ""
 396 echo "   * Installation prefix:       $prefix"
 397 echo "   * System type:               $host_vendor-$host_os"
 398 echo "   * Host CPU:                  $host_cpu"
 399 echo "   * C Compiler:                $CC_VERSION"
 400 echo "   * Assertions enabled:        $ac_cv_assert"
 401 echo "   * Debug enabled:             $with_debug"
 402 echo "   * Warnings as failure:       $building_from_bzr"
 403 echo ""
 404 echo "---"
 405