git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Build optimized or debug version ?
 101 # First check for gcc and g++
 102 if test "$GCC" = "yes"
 103 then
 104   CFLAGS="-ggdb3 -std=gnu99 ${CFLAGS}"
 105   DEBUG_CFLAGS="-O0"
 106   OPTIMIZE_CFLAGS="-O3"
 107 fi
 108 if test "x$SUNCC" = "xyes"
 109 then
 110    CFLAGS="-g -mt -xc99=all $CFLAGS"
 111    CXXFLAGS="-g -mt -xlang=c99 $CXXFLAGS"
 112    OPTIMIZE_CFLAGS="-xO4 -xlibmil -xdepend -Xa -xstrconst"
 113 fi
 114
 115 SOLARIS_64BIT
 116
 117 #--------------------------------------------------------------------
 118 # Check for libpthread
 119 #--------------------------------------------------------------------
 120
 121 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 122 LIBS="${PTHREAD_LIBS} ${LIBS}"
 123 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 124 CC="$PTHREAD_CC"
 125
 126
 127 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 128 AC_SEARCH_LIBS(socket, socket)
 129 AC_SEARCH_LIBS(gethostbyname, nsl)
 130
 131 save_LIBS="$LIBS"
 132 LIBS="$LIBS -lm"
 133 AC_LINK_IFELSE(
 134   [AC_LANG_PROGRAM(
 135     [[
 136 #include <stdlib.h>
 137     ]],[[
 138       float f= floorf((float) 1.0);
 139     ]],
 140     [LIBM="-lm"],[LIBM=""])])
 141
 142 AC_SUBST(LIBM)
 143 LIBS="$save_LIBS"
 144
 145 AC_SEARCH_LIBS(floorf, m)
 146
 147 DETECT_BYTEORDER
 148 ENABLE_UTILLIB
 149
 150 sinclude(m4/pod2man.m4)
 151 sinclude(m4/dtrace.m4)
 152 sinclude(m4/protocol_binary.m4)
 153 sinclude(m4/memcached.m4)
 154 sinclude(m4/setsockopt.m4)
 155 sinclude(m4/hsieh.m4)
 156
 157 dnl TODO: Remove this define once we are using 2.61 across the board.
 158 # AX_HEADER_ASSERT
 159 # ----------------
 160 # Check whether to enable assertions.
 161 AC_DEFUN([AX_HEADER_ASSERT],
 162 [
 163   AC_MSG_CHECKING([whether to enable assertions])
 164   AC_ARG_ENABLE([assert],
 165     [AS_HELP_STRING([--disable-assert],
 166        [Turn off assertions])],
 167     [ac_cv_assert="no"],
 168     [ac_cv_assert="yes"])
 169   AC_MSG_RESULT([$ac_cv_assert])
 170 ])
 171 AX_HEADER_ASSERT
 172
 173
 174 AC_ARG_WITH([debug],
 175     [AS_HELP_STRING([--with-debug],
 176        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 177     [with_debug=$withval],
 178     [with_debug=no])
 179 if test "$with_debug" = "yes"
 180 then
 181   # Debugging. No optimization.
 182   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 183 else
 184   # Optimized version. No debug
 185   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 186 fi
 187
 188 AC_ARG_ENABLE([profiling],
 189     [AS_HELP_STRING([--enable-profiling],
 190        [Toggle profiling @<:@default=off@:>@])],
 191     [ac_profiling="$enableval"],
 192     [ac_profiling="no"])
 193
 194 AC_ARG_ENABLE([coverage],
 195     [AS_HELP_STRING([--enable-coverage],
 196        [Toggle coverage @<:@default=off@:>@])],
 197     [ac_coverage="$enableval"],
 198     [ac_coverage="no"])
 199
 200 AC_ARG_ENABLE([unreachable],
 201   [AS_HELP_STRING([--enable-unreachable],
 202     [Enable warnings about unreachable code @<:@default=no@:>@])],
 203   [ac_warn_unreachable="$enableval"],
 204   [ac_warn_unreachable="no"])
 205
 206
 207 dnl We can't do these two warnings, so turn them off
 208 W_STRICT_ALIASING="-Wno-strict-aliasing"
 209
 210 if test "$GCC" = "yes"
 211 then
 212
 213
 214   AS_IF([test "$ac_profiling" = "yes"],
 215         [CC_PROFILING="-pg"])
 216
 217   AS_IF([test "$ac_coverage" = "yes"],
 218         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 219
 220   AS_IF([test "$building_from_bzr" = "yes"],
 221         [W_FAIL="-Werror"])
 222
 223   AS_IF([test "$ac_warn_unreachable" = "yes"],
 224         [W_UNREACHABLE="-Wunreachable-code"])
 225
 226   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef  -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING}"
 227   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 228   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long"
 229
 230
 231   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 232     [ac_cv_safe_to_use_Wlogical_op_],
 233     [save_CFLAGS="$CFLAGS"
 234      CFLAGS="-Wlogical-op"
 235      AC_COMPILE_IFELSE([
 236        AC_LANG_PROGRAM(
 237        [[
 238 #include <stdio>
 239        ]], [[]])
 240     ],
 241     [ac_cv_safe_to_use_Wlogical_op_=yes],
 242     [ac_cv_safe_to_use_Wlogical_op_=no])
 243   CFLAGS="$save_CFLAGS"])
 244   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 245         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 246
 247   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 248     [ac_cv_safe_to_use_Wredundant_decls_],
 249     [AC_LANG_PUSH(C++)
 250      save_CXXFLAGS="${CXXFLAGS}"
 251      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 252      AC_COMPILE_IFELSE(
 253        [AC_LANG_PROGRAM([
 254 template <typename E> struct C { void foo(); };
 255 template <typename E> void C<E>::foo() { }
 256 template <> void C<int>::foo();
 257           AC_INCLUDES_DEFAULT])],
 258         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 259         [ac_cv_safe_to_use_Wredundant_decls_=no])
 260       CXXFLAGS="${save_CXXFLAGS}"
 261       AC_LANG_POP()])
 262   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 263         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 264         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 265
 266   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 267 fi
 268 if test "$SUNCC" = "yes"
 269 then
 270
 271   AS_IF([test "$ac_profiling" = "yes"],
 272         [CC_PROFILING="-xinstrument=datarace"])
 273
 274   AS_IF([test "$building_from_bzr" = "yes"],
 275         [W_FAIL="-errwarn=%all"])
 276
 277   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 278     [ac_cv_paste_result],
 279     [
 280       save_CFLAGS="${CFLAGS}"
 281       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 282       AC_COMPILE_IFELSE(
 283         [AC_LANG_PROGRAM([
 284           AC_INCLUDES_DEFAULT
 285         ],[
 286           int x= 0;])],
 287         [ac_cv_paste_result=yes],
 288         [ac_cv_paste_result=no])
 289       CFLAGS="${save_CFLAGS}"
 290     ])
 291   AS_IF([test $ac_cv_paste_result = yes],
 292     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 293
 294
 295   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 296   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 297 fi
 298
 299 AC_SUBST(NO_REDUNDANT_DECLS)
 300
 301 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 302 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 303 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 304
 305 AC_SUBST([AM_CPPFLAGS])
 306 AC_SUBST([AM_CFLAGS])
 307 AC_SUBST([AM_CXXFLAGS])
 308
 309 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 310 CFLAGS=""
 311 CXXFLAGS=""
 312 CPPFLAGS=""
 313
 314 AC_CONFIG_FILES([
 315   Makefile
 316   clients/Makefile
 317   tests/Makefile
 318   docs/Makefile
 319   libmemcached/Makefile
 320   libmemcachedutil/Makefile
 321   support/Makefile
 322   support/libmemcached.pc
 323   support/libmemcached.spec
 324   support/libmemcached-fc.spec
 325   ])
 326 AC_OUTPUT