git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER([config.h])
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 #shared library versioning
  16 MEMCACHED_LIBRARY_VERSION=2:0:0
  17 #                         | | |
  18 #                  +------+ | +---+
  19 #                  |        |     |
  20 #                 current:revision:age
  21 #                  |        |     |
  22 #                  |        |     +- increment if interfaces have been added
  23 #                  |        |        set to zero if interfaces have been removed or changed
  24 #                  |        +- increment if source code has changed
  25 #                  |           set to zero if current is incremented
  26 #                  +- increment if interfaces have been added, removed or changed
  27 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  28 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  29 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  30
  31 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  32 SAVE_CFLAGS=${CFLAGS}
  33 SAVE_CXXFLAGS=${CXXFLAGS}
  34 CFLAGS=
  35 CXXFLAGS=
  36
  37 AC_CANONICAL_TARGET
  38
  39 CFLAGS=${SAVE_CFLAGS}
  40 CXXFLAGS=${SAVE_CXXFLAGS}
  41
  42 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  43
  44 if test "x${enable_dependency_tracking}" = "x"
  45 then
  46   enable_dependency_tracking=yes
  47 fi
  48
  49 if test -d "${srcdir}/.bzr"
  50 then
  51   building_from_bzr=yes
  52 else
  53   building_from_bzr=no
  54 fi
  55
  56 AC_PROG_CXX
  57
  58 ACX_USE_SYSTEM_EXTENSIONS
  59
  60 AC_PROG_CPP
  61 AM_PROG_CC_C_O
  62
  63 FORCE_MAC_GCC42
  64 dnl Once we can use a modern autoconf, we can use this
  65 dnl AC_PROG_CC_C99
  66
  67 AC_C_BIGENDIAN
  68 AC_C_CONST
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_FUNC_MALLOC
  72 AC_FUNC_REALLOC
  73
  74 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  75
  76 # We use libtool
  77 AC_PROG_LIBTOOL
  78
  79 AC_MSG_CHECKING("C Compiler version")
  80 if test "$GCC" = "yes"
  81 then
  82   CC_VERSION=`$CC --version | sed 1q`
  83 elif test "$SUNCC" = "yes"
  84 then
  85   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  86 else
  87   CC_VERSION=""
  88 fi
  89 AC_MSG_RESULT("$CC_VERSION")
  90 AC_SUBST(CC_VERSION)
  91
  92 # libmemcached versioning when linked with GNU ld.
  93 if test "$lt_cv_prog_gnu_ld" = "yes"
  94 then
  95     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  96     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  97 fi
  98 AC_SUBST(LD_VERSION_SCRIPT)
  99 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
 100
 101 gl_VISIBILITY
 102
 103 # Build optimized or debug version ?
 104 # First check for gcc and g++
 105 if test "$GCC" = "yes"
 106 then
 107
 108   dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
 109   dnl with using AC_CC_STD_C99 above
 110   CC="${CC} -std=gnu99"
 111
 112   CFLAGS="-ggdb3 ${CFLAGS}"
 113   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 114
 115   DEBUG_CFLAGS="-O0"
 116   DEBUG_CXXFLAGS="-O0"
 117
 118   OPTIMIZE_CFLAGS="-O3"
 119   OPTIMIZE_CXXFLAGS="-O3"
 120 fi
 121 if test "x$SUNCC" = "xyes"
 122 then
 123   dnl Once we can use a modern autoconf, we can replace the -xc99=all here
 124   dnl with using AC_CC_STD_C99 above
 125   CC="${CC} -xc99=all"
 126
 127   CFLAGS="-g -mt ${CFLAGS}"
 128   CXXFLAGS="-xlang=c99 -g -mt -compat=5 -library=stlport4 -template=no%extdef ${CXXFLAGS}"
 129
 130   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin"
 131   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 132   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 133
 134 fi
 135
 136 ENABLE_64BIT
 137
 138 #--------------------------------------------------------------------
 139 # Check for libpthread
 140 #--------------------------------------------------------------------
 141
 142 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 143 LIBS="${PTHREAD_LIBS} ${LIBS}"
 144 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 145 CC="$PTHREAD_CC"
 146
 147
 148 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 149 AC_SEARCH_LIBS(socket, socket)
 150 AC_SEARCH_LIBS(gethostbyname, nsl)
 151
 152 save_LIBS="$LIBS"
 153 LIBS="$LIBS -lm"
 154 AC_LINK_IFELSE(
 155   [AC_LANG_PROGRAM(
 156     [[
 157 #include <stdlib.h>
 158     ]],[[
 159       float f= floorf((float) 1.0);
 160     ]],
 161     [LIBM="-lm"],[LIBM=""])])
 162
 163 AC_SUBST(LIBM)
 164 LIBS="$save_LIBS"
 165
 166 AC_SEARCH_LIBS(floorf, m)
 167
 168 dnl Specialty checks
 169 DETECT_BYTEORDER
 170 ENABLE_UTILLIB
 171 ENABLE_DTRACE
 172 SETSOCKOPT_SANITY
 173 ENABLE_HSIEH_HASH
 174 REQUIRE_POD2MAN
 175 PROTOCOL_BINARY_TEST
 176 WITH_MEMCACHED
 177 ENABLE_DEPRECATED
 178
 179 dnl TODO: Remove this define once we are using 2.61 across the board.
 180 # AX_HEADER_ASSERT
 181 # ----------------
 182 # Check whether to enable assertions.
 183 AC_DEFUN([AX_HEADER_ASSERT],
 184 [
 185   AC_MSG_CHECKING([whether to enable assertions])
 186   AC_ARG_ENABLE([assert],
 187     [AS_HELP_STRING([--disable-assert],
 188        [Turn off assertions])],
 189     [ac_cv_assert="no"],
 190     [ac_cv_assert="yes"])
 191   AC_MSG_RESULT([$ac_cv_assert])
 192 ])
 193 AX_HEADER_ASSERT
 194
 195
 196 AC_ARG_WITH([debug],
 197     [AS_HELP_STRING([--with-debug],
 198        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 199     [with_debug=$withval],
 200     [with_debug=no])
 201 if test "$with_debug" = "yes"
 202 then
 203   # Debugging. No optimization.
 204   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 205   CXXFLAGS="${DEBUG_CXXFLAGS} -DDEBUG ${CXXFLAGS}"
 206 else
 207   # Optimized version. No debug
 208   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 209   CXXFLAGS="${OPTIMIZE_CXXFLAGS} ${CXXFLAGS}"
 210 fi
 211
 212 AC_ARG_ENABLE([profiling],
 213     [AS_HELP_STRING([--enable-profiling],
 214        [Toggle profiling @<:@default=off@:>@])],
 215     [ac_profiling="$enableval"],
 216     [ac_profiling="no"])
 217
 218 AC_ARG_ENABLE([coverage],
 219     [AS_HELP_STRING([--enable-coverage],
 220        [Toggle coverage @<:@default=off@:>@])],
 221     [ac_coverage="$enableval"],
 222     [ac_coverage="no"])
 223
 224 if test "$GCC" = "yes"
 225 then
 226
 227   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 228     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 229     [save_CFLAGS="$CFLAGS"
 230      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 231      AC_COMPILE_IFELSE(
 232        [AC_LANG_PROGRAM([],[])],
 233        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 234        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 235      CFLAGS="$save_CFLAGS"])
 236
 237   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 238         [
 239           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 240         ])
 241
 242   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 243     [ac_cv_safe_to_use_wconversion_],
 244     [save_CFLAGS="$CFLAGS"
 245      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 246      AC_COMPILE_IFELSE(
 247        [AC_LANG_PROGRAM([[
 248 #include <stdbool.h>
 249 void foo(bool a)
 250 {
 251   (void)a;
 252 }
 253        ]],[[
 254 foo(0);
 255        ]])],
 256        [ac_cv_safe_to_use_wconversion_=yes],
 257        [ac_cv_safe_to_use_wconversion_=no])
 258      CFLAGS="$save_CFLAGS"])
 259
 260   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 261     [W_CONVERSION="-Wconversion"
 262     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 263       [ac_cv_safe_to_use_Wconversion_],
 264       [save_CFLAGS="$CFLAGS"
 265        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 266        AC_COMPILE_IFELSE(
 267          [AC_LANG_PROGRAM(
 268            [[
 269 #include <netinet/in.h>
 270            ]],[[
 271 uint16_t x= htons(80);
 272            ]])],
 273          [ac_cv_safe_to_use_Wconversion_=yes],
 274          [ac_cv_safe_to_use_Wconversion_=no])
 275        CFLAGS="$save_CFLAGS"])
 276
 277     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 278           [
 279             NO_CONVERSION="-Wno-conversion"
 280           ])
 281     ])
 282
 283   AS_IF([test "$ac_profiling" = "yes"],
 284         [CC_PROFILING="-pg"])
 285
 286   AS_IF([test "$ac_coverage" = "yes"],
 287         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 288
 289   AS_IF([test "$building_from_bzr" = "yes"],
 290         [W_FAIL=""])
 291         #[W_FAIL="-Werror"])
 292
 293   BASE_WARNINGS="-pedantic -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations -Wstrict-aliasing -Wformat=2 ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 294   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 295   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wold-style-cast -Weffc++ -Wno-long-long"
 296
 297   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 298     [ac_cv_safe_to_use_Wlogical_op_],
 299     [save_CFLAGS="$CFLAGS"
 300      CFLAGS="-Wlogical-op"
 301      AC_COMPILE_IFELSE([
 302        AC_LANG_PROGRAM(
 303        [[
 304 #include <stdio>
 305        ]], [[]])
 306     ],
 307     [ac_cv_safe_to_use_Wlogical_op_=yes],
 308     [ac_cv_safe_to_use_Wlogical_op_=no])
 309   CFLAGS="$save_CFLAGS"])
 310   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 311         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 312
 313   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 314     [ac_cv_safe_to_use_Wredundant_decls_],
 315     [AC_LANG_PUSH(C++)
 316      save_CXXFLAGS="${CXXFLAGS}"
 317      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 318      AC_COMPILE_IFELSE(
 319        [AC_LANG_PROGRAM([
 320 template <typename E> struct C { void foo(); };
 321 template <typename E> void C<E>::foo() { }
 322 template <> void C<int>::foo();
 323           AC_INCLUDES_DEFAULT])],
 324         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 325         [ac_cv_safe_to_use_Wredundant_decls_=no])
 326       CXXFLAGS="${save_CXXFLAGS}"
 327       AC_LANG_POP()])
 328   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 329         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 330         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 331
 332   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 333 fi
 334 if test "$SUNCC" = "yes"
 335 then
 336
 337   AS_IF([test "$ac_profiling" = "yes"],
 338         [CC_PROFILING="-xinstrument=datarace"])
 339
 340   AS_IF([test "$building_from_bzr" = "yes"],
 341         [W_FAIL="-errwarn=%all"])
 342
 343   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 344     [ac_cv_paste_result],
 345     [
 346       save_CFLAGS="${CFLAGS}"
 347       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 348       AC_COMPILE_IFELSE(
 349         [AC_LANG_PROGRAM([
 350           AC_INCLUDES_DEFAULT
 351         ],[
 352           int x= 0;])],
 353         [ac_cv_paste_result=yes],
 354         [ac_cv_paste_result=no])
 355       CFLAGS="${save_CFLAGS}"
 356     ])
 357   AS_IF([test $ac_cv_paste_result = yes],
 358     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 359
 360
 361   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 362   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 363 fi
 364
 365 AC_SUBST(NO_CONVERSION)
 366 AC_SUBST(NO_REDUNDANT_DECLS)
 367
 368 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 369 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 370 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 371
 372 AC_SUBST([AM_CPPFLAGS])
 373 AC_SUBST([AM_CFLAGS])
 374 AC_SUBST([AM_CXXFLAGS])
 375
 376 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 377 CFLAGS=""
 378 CXXFLAGS=""
 379 CPPFLAGS=""
 380
 381 AC_CONFIG_FILES([
 382   Makefile
 383   clients/Makefile
 384   tests/Makefile
 385   docs/Makefile
 386   libmemcached/Makefile
 387   libmemcached/memcached_configure.h
 388   libmemcachedutil/Makefile
 389   support/Makefile
 390   support/libmemcached.pc
 391   support/libmemcached.spec
 392   support/libmemcached-fc.spec
 393   ])
 394 AC_OUTPUT
 395
 396 echo "---"
 397 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 398 echo ""
 399 echo "   * Installation prefix:       $prefix"
 400 echo "   * System type:               $host_vendor-$host_os"
 401 echo "   * Host CPU:                  $host_cpu"
 402 echo "   * C Compiler:                $CC_VERSION"
 403 echo "   * Assertions enabled:        $ac_cv_assert"
 404 echo "   * Debug enabled:             $with_debug"
 405 echo "   * Warnings as failure:       $building_from_bzr"
 406 echo ""
 407 echo "---"
 408