git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 #shared library versioning
  16 MEMCACHED_LIBRARY_VERSION=2:0:0
  17 #                         | | |
  18 #                  +------+ | +---+
  19 #                  |        |     |
  20 #                 current:revision:age
  21 #                  |        |     |
  22 #                  |        |     +- increment if interfaces have been added
  23 #                  |        |        set to zero if interfaces have been removed or changed
  24 #                  |        +- increment if source code has changed
  25 #                  |           set to zero if current is incremented
  26 #                  +- increment if interfaces have been added, removed or changed
  27 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  28 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  29 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  30
  31 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  32 SAVE_CFLAGS=${CFLAGS}
  33 SAVE_CXXFLAGS=${CXXFLAGS}
  34 CFLAGS=
  35 CXXFLAGS=
  36
  37 AC_CANONICAL_TARGET
  38
  39 CFLAGS=${SAVE_CFLAGS}
  40 CXXFLAGS=${SAVE_CXXFLAGS}
  41
  42 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  43
  44 if test "x${enable_dependency_tracking}" = "x"
  45 then
  46   enable_dependency_tracking=yes
  47 fi
  48
  49 if test -d "${srcdir}/.bzr"
  50 then
  51   building_from_bzr=yes
  52 else
  53   building_from_bzr=no
  54 fi
  55
  56 AC_PROG_CC_C99
  57 AC_PROG_CXX
  58
  59 ACX_USE_SYSTEM_EXTENSIONS
  60
  61 AC_PROG_CPP
  62 AM_PROG_CC_C_O
  63
  64 AC_C_BIGENDIAN
  65 AC_C_CONST
  66 AC_HEADER_TIME
  67 AC_TYPE_SIZE_T
  68 AC_TYPE_SSIZE_T
  69 AC_FUNC_MALLOC
  70 AC_FUNC_REALLOC
  71
  72 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  73
  74 # We use libtool
  75 AC_PROG_LIBTOOL
  76
  77 AC_MSG_CHECKING("C Compiler version")
  78 if test "$GCC" = "yes"
  79 then
  80   CC_VERSION=`$CC --version | sed 1q`
  81 elif test "$SUNCC" = "yes"
  82 then
  83   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  84 else
  85   CC_VERSION=""
  86 fi
  87 AC_MSG_RESULT("$CC_VERSION")
  88 AC_SUBST(CC_VERSION)
  89
  90 # libmemcached versioning when linked with GNU ld.
  91 if test "$lt_cv_prog_gnu_ld" = "yes"
  92 then
  93     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  94     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  95 fi
  96 AC_SUBST(LD_VERSION_SCRIPT)
  97 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  98
  99 # Build optimized or debug version ?
 100 # First check for gcc and g++
 101 if test "$GCC" = "yes"
 102 then
 103   CFLAGS="-ggdb3 ${CFLAGS}"
 104   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 105
 106   DEBUG_CFLAGS="-O0"
 107   DEBUG_CXXFLAGS="-O0"
 108
 109   OPTIMIZE_CFLAGS="-O3"
 110   OPTIMIZE_CXXFLAGS="-O3"
 111 fi
 112 if test "x$SUNCC" = "xyes"
 113 then
 114   CFLAGS="-g -mt ${CFLAGS}"
 115   CXXFLAGS="-xlang=c99 -g -mt -compat=5 -library=stlport4 -template=no%extdef ${CXXFLAGS}"
 116
 117   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin"
 118   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 119   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 120
 121 fi
 122
 123 ENABLE_64BIT
 124
 125 #--------------------------------------------------------------------
 126 # Check for libpthread
 127 #--------------------------------------------------------------------
 128
 129 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 130 LIBS="${PTHREAD_LIBS} ${LIBS}"
 131 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 132 CC="$PTHREAD_CC"
 133
 134
 135 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 136 AC_SEARCH_LIBS(socket, socket)
 137 AC_SEARCH_LIBS(gethostbyname, nsl)
 138
 139 save_LIBS="$LIBS"
 140 LIBS="$LIBS -lm"
 141 AC_LINK_IFELSE(
 142   [AC_LANG_PROGRAM(
 143     [[
 144 #include <stdlib.h>
 145     ]],[[
 146       float f= floorf((float) 1.0);
 147     ]],
 148     [LIBM="-lm"],[LIBM=""])])
 149
 150 AC_SUBST(LIBM)
 151 LIBS="$save_LIBS"
 152
 153 AC_SEARCH_LIBS(floorf, m)
 154
 155 dnl Specialty checks
 156 DETECT_BYTEORDER
 157 ENABLE_UTILLIB
 158 ENABLE_DTRACE
 159 SETSOCKOPT_SANITY
 160 ENABLE_HSIEH_HASH
 161 REQUIRE_POD2MAN
 162 PROTOCOL_BINARY_TEST
 163 WITH_MEMCACHED
 164
 165 dnl TODO: Remove this define once we are using 2.61 across the board.
 166 # AX_HEADER_ASSERT
 167 # ----------------
 168 # Check whether to enable assertions.
 169 AC_DEFUN([AX_HEADER_ASSERT],
 170 [
 171   AC_MSG_CHECKING([whether to enable assertions])
 172   AC_ARG_ENABLE([assert],
 173     [AS_HELP_STRING([--disable-assert],
 174        [Turn off assertions])],
 175     [ac_cv_assert="no"],
 176     [ac_cv_assert="yes"])
 177   AC_MSG_RESULT([$ac_cv_assert])
 178 ])
 179 AX_HEADER_ASSERT
 180
 181
 182 AC_ARG_WITH([debug],
 183     [AS_HELP_STRING([--with-debug],
 184        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 185     [with_debug=$withval],
 186     [with_debug=no])
 187 if test "$with_debug" = "yes"
 188 then
 189   # Debugging. No optimization.
 190   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 191   CXXFLAGS="${DEBUG_CXXFLAGS} -DDEBUG ${CXXFLAGS}"
 192 else
 193   # Optimized version. No debug
 194   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 195   CXXFLAGS="${OPTIMIZE_CXXFLAGS} ${CXXFLAGS}"
 196 fi
 197
 198 AC_ARG_ENABLE([profiling],
 199     [AS_HELP_STRING([--enable-profiling],
 200        [Toggle profiling @<:@default=off@:>@])],
 201     [ac_profiling="$enableval"],
 202     [ac_profiling="no"])
 203
 204 AC_ARG_ENABLE([coverage],
 205     [AS_HELP_STRING([--enable-coverage],
 206        [Toggle coverage @<:@default=off@:>@])],
 207     [ac_coverage="$enableval"],
 208     [ac_coverage="no"])
 209
 210 if test "$GCC" = "yes"
 211 then
 212
 213   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 214     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 215     [save_CFLAGS="$CFLAGS"
 216      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 217      AC_COMPILE_IFELSE(
 218        [AC_LANG_PROGRAM([],[])],
 219        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 220        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 221      CFLAGS="$save_CFLAGS"])
 222
 223   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 224         [
 225           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 226         ])
 227
 228   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 229     [ac_cv_safe_to_use_wconversion_],
 230     [save_CFLAGS="$CFLAGS"
 231      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 232      AC_COMPILE_IFELSE(
 233        [AC_LANG_PROGRAM([[
 234 #include <stdbool.h>
 235 void foo(bool a)
 236 {
 237   (void)a;
 238 }
 239        ]],[[
 240 foo(0);
 241        ]])],
 242        [ac_cv_safe_to_use_wconversion_=yes],
 243        [ac_cv_safe_to_use_wconversion_=no])
 244      CFLAGS="$save_CFLAGS"])
 245
 246   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 247     [W_CONVERSION="-Wconversion"
 248     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 249       [ac_cv_safe_to_use_Wconversion_],
 250       [save_CFLAGS="$CFLAGS"
 251        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 252        AC_COMPILE_IFELSE(
 253          [AC_LANG_PROGRAM(
 254            [[
 255 #include <netinet/in.h>
 256            ]],[[
 257 uint16_t x= htons(80);
 258            ]])],
 259          [ac_cv_safe_to_use_Wconversion_=yes],
 260          [ac_cv_safe_to_use_Wconversion_=no])
 261        CFLAGS="$save_CFLAGS"])
 262
 263     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 264           [
 265             NO_CONVERSION="-Wno-conversion"
 266           ])
 267     ])
 268
 269   W_STRICT_ALIASING="-Wno-strict-aliasing"
 270
 271   AS_IF([test "$ac_profiling" = "yes"],
 272         [CC_PROFILING="-pg"])
 273
 274   AS_IF([test "$ac_coverage" = "yes"],
 275         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 276
 277   AS_IF([test "$building_from_bzr" = "yes"],
 278         [W_FAIL="-Werror"])
 279
 280   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 281   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 282   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wold-style-cast -Weffc++ -Wno-long-long"
 283
 284   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 285     [ac_cv_safe_to_use_Wlogical_op_],
 286     [save_CFLAGS="$CFLAGS"
 287      CFLAGS="-Wlogical-op"
 288      AC_COMPILE_IFELSE([
 289        AC_LANG_PROGRAM(
 290        [[
 291 #include <stdio>
 292        ]], [[]])
 293     ],
 294     [ac_cv_safe_to_use_Wlogical_op_=yes],
 295     [ac_cv_safe_to_use_Wlogical_op_=no])
 296   CFLAGS="$save_CFLAGS"])
 297   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 298         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 299
 300   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 301     [ac_cv_safe_to_use_Wredundant_decls_],
 302     [AC_LANG_PUSH(C++)
 303      save_CXXFLAGS="${CXXFLAGS}"
 304      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 305      AC_COMPILE_IFELSE(
 306        [AC_LANG_PROGRAM([
 307 template <typename E> struct C { void foo(); };
 308 template <typename E> void C<E>::foo() { }
 309 template <> void C<int>::foo();
 310           AC_INCLUDES_DEFAULT])],
 311         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 312         [ac_cv_safe_to_use_Wredundant_decls_=no])
 313       CXXFLAGS="${save_CXXFLAGS}"
 314       AC_LANG_POP()])
 315   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 316         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 317         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 318
 319   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 320 fi
 321 if test "$SUNCC" = "yes"
 322 then
 323
 324   AS_IF([test "$ac_profiling" = "yes"],
 325         [CC_PROFILING="-xinstrument=datarace"])
 326
 327   AS_IF([test "$building_from_bzr" = "yes"],
 328         [W_FAIL="-errwarn=%all"])
 329
 330   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 331     [ac_cv_paste_result],
 332     [
 333       save_CFLAGS="${CFLAGS}"
 334       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 335       AC_COMPILE_IFELSE(
 336         [AC_LANG_PROGRAM([
 337           AC_INCLUDES_DEFAULT
 338         ],[
 339           int x= 0;])],
 340         [ac_cv_paste_result=yes],
 341         [ac_cv_paste_result=no])
 342       CFLAGS="${save_CFLAGS}"
 343     ])
 344   AS_IF([test $ac_cv_paste_result = yes],
 345     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 346
 347
 348   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 349   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 350 fi
 351
 352 AC_SUBST(NO_CONVERSION)
 353 AC_SUBST(NO_REDUNDANT_DECLS)
 354
 355 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 356 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 357 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 358
 359 AC_SUBST([AM_CPPFLAGS])
 360 AC_SUBST([AM_CFLAGS])
 361 AC_SUBST([AM_CXXFLAGS])
 362
 363 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 364 CFLAGS=""
 365 CXXFLAGS=""
 366 CPPFLAGS=""
 367
 368 AC_CONFIG_FILES([
 369   Makefile
 370   clients/Makefile
 371   tests/Makefile
 372   docs/Makefile
 373   libmemcached/Makefile
 374   libmemcachedutil/Makefile
 375   support/Makefile
 376   support/libmemcached.pc
 377   support/libmemcached.spec
 378   support/libmemcached-fc.spec
 379   ])
 380 AC_OUTPUT
 381
 382 echo "---"
 383 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 384 echo ""
 385 echo "   * Installation prefix:       $prefix"
 386 echo "   * System type:               $host_vendor-$host_os"
 387 echo "   * Host CPU:                  $host_cpu"
 388 echo "   * C Compiler:                $CC_VERSION"
 389 echo "   * Assertions enabled:        $ac_cv_assert"
 390 echo "   * Debug enabled:             $with_debug"
 391 echo "   * Warnings as failure:       $building_from_bzr"
 392 echo ""
 393 echo "---"
 394