git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # LibmemcacheD
   3 # Copyright (C) 2011 Data Differential, http://datadifferential.com/
   4 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   5 # All rights reserved.
   6 #
   7 # Use and distribution licensed under the BSD license.  See
   8 # the COPYING file in this directory for full text.
   9
  10 AC_INIT([libmemcached],[0.52],[http://libmemcached.org/])
  11
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 AC_CANONICAL_TARGET
  15
  16 AM_INIT_AUTOMAKE
  17
  18 AC_CANONICAL_HOST
  19 AC_CANONICAL_BUILD
  20
  21 AC_PREREQ([2.61])
  22
  23 AC_CONFIG_MACRO_DIR(m4)
  24
  25 AC_CONFIG_HEADERS([config.h:config.in])dnl Keep filename to 8.3 for MS-DOS.
  26
  27 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  28
  29 PANDORA_CANONICAL_TARGET(no-vc-changelog)
  30 AC_CHECK_PROGS([YACC], ['bison'], [:])
  31 AC_CHECK_PROGS([LEX], ['flex'], [:])
  32
  33 #shared library versioning
  34 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  35 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  36 MEMCACHED_LIBRARY_VERSION=8:0:0
  37 #                         | | |
  38 #                  +------+ | +---+
  39 #                  |        |     |
  40 #                 current:revision:age
  41 #                  |        |     |
  42 #                  |        |     +- increment if interfaces have been added
  43 #                  |        |        set to zero if interfaces have been removed or changed
  44 #                  |        +- increment if source code has changed
  45 #                  |           set to zero if current is incremented
  46 #                  +- increment if interfaces have been added, removed or changed
  47 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  48 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  49 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  50
  51
  52 HASHKIT_LIBRARY_VERSION=1:0:0
  53 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  54
  55 LT_INIT
  56 m4_include([m4/memcached.m4])
  57 m4_include([m4/memcached_sasl.m4])
  58 m4_include([m4/gearmand.m4])
  59
  60 AM_CONDITIONAL(BUILDING_LIBMEMCACHED, true)
  61 AM_CONDITIONAL(HAVE_LIBMEMCACHED, false)
  62 AC_DEFINE([HAVE_LIBMEMCACHED], [1], [Enables libmemcached Support])
  63
  64 AM_CONDITIONAL(BUILDING_GEARMAN, false)
  65 AM_CONDITIONAL(HAVE_LIBGEARMAN, false)
  66 AC_DEFINE([HAVE_LIBGEARMAN], [0], [Enables libgearman Support])
  67
  68 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  69 AC_SEARCH_LIBS(gethostbyname, nsl)
  70
  71 PANDORA_HAVE_LIBEVENT
  72
  73 case "$target_os" in
  74   *linux*)
  75        AS_IF([test "x$GCC" = "xyes"],
  76              [
  77               LDFLAGS="$LDFLAGS -z relro -z now"
  78               ])
  79    ;;
  80    esac
  81
  82 dnl Specialty checks
  83 ACX_PTHREAD
  84 CONFIG_EXTRA
  85 DETECT_BYTEORDER
  86 ENABLE_UTILLIB
  87 SETSOCKOPT_SANITY
  88 ENABLE_HSIEH_HASH
  89 ENABLE_MURMUR_HASH
  90 ENABLE_MEMASLAP
  91 PROTOCOL_BINARY_TEST
  92 ENABLE_DEPRECATED
  93 PANDORA_HAVE_LIBINNODB
  94 PANDORA_HAVE_SASL
  95
  96 AC_CHECK_FUNCS([alarm])
  97 AC_CHECK_FUNCS([dup2])
  98 AC_CHECK_FUNCS([getline])
  99 AC_CHECK_FUNCS([gettimeofday])
 100 AC_CHECK_FUNCS([memchr])
 101 AC_CHECK_FUNCS([memmove])
 102 AC_CHECK_FUNCS([memset])
 103 AC_CHECK_FUNCS([select])
 104 AC_CHECK_FUNCS([setenv])
 105 AC_CHECK_FUNCS([socket])
 106 AC_CHECK_FUNCS([sqrt])
 107 AC_CHECK_FUNCS([strcasecmp])
 108 AC_CHECK_FUNCS([strchr])
 109 AC_CHECK_FUNCS([strdup])
 110 AC_CHECK_FUNCS([strerror])
 111 AC_CHECK_FUNCS([strtol])
 112 AC_CHECK_FUNCS([strtoul])
 113 AC_CHECK_FUNCS([strtoull])
 114 AC_CHECK_HEADERS([arpa/inet.h])
 115 AC_CHECK_HEADERS([fcntl.h])
 116 AC_CHECK_HEADERS([libintl.h])
 117 AC_CHECK_HEADERS([limits.h])
 118 AC_CHECK_HEADERS([malloc.h])
 119 AC_CHECK_HEADERS([netdb.h])
 120 AC_CHECK_HEADERS([netinet/in.h])
 121 AC_CHECK_HEADERS([stddef.h])
 122 AC_CHECK_HEADERS([sys/time.h])
 123 AC_CHECK_HEADERS([sasl/sasl.h])
 124 AC_FUNC_ALLOCA
 125 AC_FUNC_ERROR_AT_LINE
 126 AC_FUNC_FORK
 127 AC_FUNC_MALLOC
 128 AC_FUNC_REALLOC
 129 AC_FUNC_STRERROR_R
 130 AC_HEADER_STDBOOL
 131 AC_TYPE_INT16_T
 132 AC_TYPE_INT32_T
 133 AC_TYPE_INT64_T
 134 AC_TYPE_INT8_T
 135 AC_TYPE_OFF_T
 136 AC_TYPE_PID_T
 137 AC_TYPE_SSIZE_T
 138 AC_TYPE_UINT16_T
 139 AC_TYPE_UINT32_T
 140 AC_TYPE_UINT64_T
 141 AC_TYPE_UINT8_T
 142
 143 dnl The sasl functions should only be visible if we build with sasl support
 144 AS_IF([test "x$ac_cv_sasl" = "xyes"],
 145       [
 146         [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1" ]
 147       ],
 148       [
 149         [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0" ]
 150        ]
 151       )
 152 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
 153
 154 AC_CHECK_HEADERS([atomic.h])
 155 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
 156       AC_CHECK_FUNCS(atomic_add_64)
 157       AC_CHECK_FUNCS(atomic_add_32)
 158       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
 159             AC_DEFINE([USE_ATOMIC_H],
 160                       [1],
 161                       [Define to true if you want to use functions from atomic.h])])])
 162
 163 AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
 164 AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
 165 AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
 166 AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
 167       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 168        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 169        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 170       ])
 171 DETECT_EAGAIN
 172 SOCKET_SEND_FLAGS
 173
 174 AC_CONFIG_FILES([
 175   Makefile
 176   docs/conf.py
 177   libhashkit/configure.h
 178   libmemcached/configure.h
 179   support/libmemcached.pc
 180   support/libmemcached.spec
 181   support/libmemcached-fc.spec
 182   libtest/version.h
 183   ])
 184 AC_OUTPUT
 185
 186 echo "---"
 187 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 188 echo ""
 189 echo "   * Installation prefix:       $prefix"
 190 echo "   * System type:               $host_vendor-$host_os"
 191 echo "   * Host CPU:                  $host_cpu"
 192 echo "   * C Compiler:                $CC_VERSION"
 193 echo "   * Assertions enabled:        $ac_cv_assert"
 194 echo "   * Debug enabled:             $with_debug"
 195 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 196 echo ""
 197 echo "---"
 198
 199 case "$host_os" in
 200   *freebsd*)
 201     echo "*****"
 202     echo "*"
 203     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 204     echo "*"
 205     echo "*   use 'gmake' To build libmemcached"
 206     echo "*"
 207     echo "*****"
 208   ;;
 209 esac
 210