git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # LibmemcacheD
   3 # Copyright (C) 2011 Data Differential, http://datadifferential.com/
   4 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   5 # All rights reserved.
   6 #
   7 # Use and distribution licensed under the BSD license.  See
   8 # the COPYING file in this directory for full text.
   9
  10 AC_INIT([libmemcached],[0.52],[http://libmemcached.org/])
  11
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 AC_CANONICAL_TARGET
  15
  16 AM_INIT_AUTOMAKE
  17
  18 AC_CANONICAL_HOST
  19 AC_CANONICAL_BUILD
  20
  21 AC_PREREQ([2.61])
  22
  23 AC_CONFIG_MACRO_DIR(m4)
  24
  25 AC_CONFIG_HEADERS([config.h:config.in])dnl Keep filename to 8.3 for MS-DOS.
  26
  27 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  28
  29 PANDORA_CANONICAL_TARGET(no-vc-changelog)
  30 AC_CHECK_PROGS([YACC], ['bison'], [:])
  31 AC_CHECK_PROGS([LEX], ['flex'], [:])
  32
  33 #shared library versioning
  34 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  35 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  36 MEMCACHED_LIBRARY_VERSION=8:0:0
  37 #                         | | |
  38 #                  +------+ | +---+
  39 #                  |        |     |
  40 #                 current:revision:age
  41 #                  |        |     |
  42 #                  |        |     +- increment if interfaces have been added
  43 #                  |        |        set to zero if interfaces have been removed or changed
  44 #                  |        +- increment if source code has changed
  45 #                  |           set to zero if current is incremented
  46 #                  +- increment if interfaces have been added, removed or changed
  47 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  48 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  49 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  50
  51
  52 HASHKIT_LIBRARY_VERSION=1:0:0
  53 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  54
  55 LT_PREREQ([2.2])
  56 LT_INIT()
  57 LT_LANG([C++])
  58 LT_LANG([C])
  59 gl_VISIBILITY
  60
  61 m4_include([m4/memcached.m4])
  62 m4_include([m4/memcached_sasl.m4])
  63 m4_include([m4/gearmand.m4])
  64
  65 AM_CONDITIONAL(BUILDING_LIBMEMCACHED, true)
  66 AM_CONDITIONAL(HAVE_LIBMEMCACHED, false)
  67 AC_DEFINE([HAVE_LIBMEMCACHED], [1], [Enables libmemcached Support])
  68
  69 AM_CONDITIONAL(BUILDING_GEARMAN, false)
  70 AM_CONDITIONAL(HAVE_LIBGEARMAN, false)
  71 AC_DEFINE([HAVE_LIBGEARMAN], [0], [Enables libgearman Support])
  72
  73 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  74 AC_SEARCH_LIBS(gethostbyname, nsl)
  75
  76 PANDORA_HAVE_LIBEVENT
  77
  78 case "$target_os" in
  79   *linux*)
  80        AS_IF([test "x$GCC" = "xyes"],
  81              [
  82               LDFLAGS="$LDFLAGS -z relro -z now"
  83               ])
  84    ;;
  85    esac
  86
  87 dnl Specialty checks
  88 AX_PTHREAD
  89 CONFIG_EXTRA
  90 DETECT_BYTEORDER
  91 ENABLE_UTILLIB
  92 SETSOCKOPT_SANITY
  93 ENABLE_HSIEH_HASH
  94 ENABLE_MURMUR_HASH
  95 ENABLE_MEMASLAP
  96 PROTOCOL_BINARY_TEST
  97 ENABLE_DEPRECATED
  98 PANDORA_HAVE_LIBINNODB
  99 PANDORA_HAVE_SASL
 100
 101 AC_CHECK_FUNCS([alarm])
 102 AC_CHECK_FUNCS([dup2])
 103 AC_CHECK_FUNCS([getline])
 104 AC_CHECK_FUNCS([gettimeofday])
 105 AC_CHECK_FUNCS([memchr])
 106 AC_CHECK_FUNCS([memmove])
 107 AC_CHECK_FUNCS([memset])
 108 AC_CHECK_FUNCS([select])
 109 AC_CHECK_FUNCS([setenv])
 110 AC_CHECK_FUNCS([socket])
 111 AC_CHECK_FUNCS([sqrt])
 112 AC_CHECK_FUNCS([strcasecmp])
 113 AC_CHECK_FUNCS([strchr])
 114 AC_CHECK_FUNCS([strdup])
 115 AC_CHECK_FUNCS([strerror])
 116 AC_CHECK_FUNCS([strtol])
 117 AC_CHECK_FUNCS([strtoul])
 118 AC_CHECK_FUNCS([strtoull])
 119 AC_CHECK_HEADERS([arpa/inet.h])
 120 AC_CHECK_HEADERS([fcntl.h])
 121 AC_CHECK_HEADERS([libintl.h])
 122 AC_CHECK_HEADERS([limits.h])
 123 AC_CHECK_HEADERS([malloc.h])
 124 AC_CHECK_HEADERS([netdb.h])
 125 AC_CHECK_HEADERS([netinet/in.h])
 126 AC_CHECK_HEADERS([stddef.h])
 127 AC_CHECK_HEADERS([sys/time.h])
 128 AC_CHECK_HEADERS([sasl/sasl.h])
 129 AC_FUNC_ALLOCA
 130 AC_FUNC_ERROR_AT_LINE
 131 AC_FUNC_FORK
 132 AC_FUNC_MALLOC
 133 AC_FUNC_REALLOC
 134 AC_FUNC_STRERROR_R
 135 AC_HEADER_STDBOOL
 136 AC_TYPE_INT16_T
 137 AC_TYPE_INT32_T
 138 AC_TYPE_INT64_T
 139 AC_TYPE_INT8_T
 140 AC_TYPE_OFF_T
 141 AC_TYPE_PID_T
 142 AC_TYPE_SSIZE_T
 143 AC_TYPE_UINT16_T
 144 AC_TYPE_UINT32_T
 145 AC_TYPE_UINT64_T
 146 AC_TYPE_UINT8_T
 147
 148 dnl The sasl functions should only be visible if we build with sasl support
 149 AS_IF([test "x$ac_cv_sasl" = "xyes"],
 150       [
 151         [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1" ]
 152       ],
 153       [
 154         [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0" ]
 155        ]
 156       )
 157 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
 158
 159 AC_CHECK_HEADERS([atomic.h])
 160 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
 161       AC_CHECK_FUNCS(atomic_add_64)
 162       AC_CHECK_FUNCS(atomic_add_32)
 163       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
 164             AC_DEFINE([USE_ATOMIC_H],
 165                       [1],
 166                       [Define to true if you want to use functions from atomic.h])])])
 167
 168 AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
 169 AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
 170 AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
 171 AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
 172       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 173        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 174        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 175       ])
 176 DETECT_EAGAIN
 177 SOCKET_SEND_FLAGS
 178
 179 AC_CONFIG_FILES([
 180   Makefile
 181   docs/conf.py
 182   libhashkit/configure.h
 183   libmemcached/configure.h
 184   support/libmemcached.pc
 185   support/libmemcached.spec
 186   support/libmemcached-fc.spec
 187   libtest/version.h
 188   ])
 189 AC_OUTPUT
 190
 191 echo "---"
 192 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 193 echo ""
 194 echo "   * Installation prefix:       $prefix"
 195 echo "   * System type:               $host_vendor-$host_os"
 196 echo "   * Host CPU:                  $host_cpu"
 197 echo "   * C Compiler:                $CC_VERSION"
 198 echo "   * Assertions enabled:        $ac_cv_assert"
 199 echo "   * Debug enabled:             $with_debug"
 200 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 201 echo ""
 202 echo "---"
 203
 204 case "$host_os" in
 205   *freebsd*)
 206     echo "*****"
 207     echo "*"
 208     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 209     echo "*"
 210     echo "*   use 'gmake' To build libmemcached"
 211     echo "*"
 212     echo "*****"
 213   ;;
 214 esac
 215