git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 #shared library versioning
  16 MEMCACHED_LIBRARY_VERSION=2:0:0
  17 #                         | | |
  18 #                  +------+ | +---+
  19 #                  |        |     |
  20 #                 current:revision:age
  21 #                  |        |     |
  22 #                  |        |     +- increment if interfaces have been added
  23 #                  |        |        set to zero if interfaces have been removed or changed
  24 #                  |        +- increment if source code has changed
  25 #                  |           set to zero if current is incremented
  26 #                  +- increment if interfaces have been added, removed or changed
  27 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  28 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  29 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  30
  31 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  32 SAVE_CFLAGS=${CFLAGS}
  33 SAVE_CXXFLAGS=${CXXFLAGS}
  34 CFLAGS=
  35 CXXFLAGS=
  36
  37 AC_CANONICAL_TARGET
  38
  39 CFLAGS=${SAVE_CFLAGS}
  40 CXXFLAGS=${SAVE_CXXFLAGS}
  41
  42 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  43
  44 if test "x${enable_dependency_tracking}" = "x"
  45 then
  46   enable_dependency_tracking=yes
  47 fi
  48
  49 if test -d "${srcdir}/.bzr"
  50 then
  51   building_from_bzr=yes
  52 else
  53   building_from_bzr=no
  54 fi
  55
  56 AC_PROG_CXX
  57
  58 ACX_USE_SYSTEM_EXTENSIONS
  59
  60 AC_PROG_CPP
  61 AM_PROG_CC_C_O
  62
  63 FORCE_MAC_GCC42
  64 dnl Once we can use a modern autoconf, we can use this
  65 dnl AC_PROG_CC_C99
  66
  67 AC_C_BIGENDIAN
  68 AC_C_CONST
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_FUNC_MALLOC
  72 AC_FUNC_REALLOC
  73
  74 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  75
  76 # We use libtool
  77 AC_PROG_LIBTOOL
  78
  79 AC_MSG_CHECKING("C Compiler version")
  80 if test "$GCC" = "yes"
  81 then
  82   CC_VERSION=`$CC --version | sed 1q`
  83 elif test "$SUNCC" = "yes"
  84 then
  85   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  86 else
  87   CC_VERSION=""
  88 fi
  89 AC_MSG_RESULT("$CC_VERSION")
  90 AC_SUBST(CC_VERSION)
  91
  92 # libmemcached versioning when linked with GNU ld.
  93 if test "$lt_cv_prog_gnu_ld" = "yes"
  94 then
  95     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  96     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  97 fi
  98 AC_SUBST(LD_VERSION_SCRIPT)
  99 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
 100
 101 # Build optimized or debug version ?
 102 # First check for gcc and g++
 103 if test "$GCC" = "yes"
 104 then
 105
 106   dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
 107   dnl with using AC_CC_STD_C99 above
 108   CC="${CC} -std=gnu99"
 109
 110   CFLAGS="-ggdb3 ${CFLAGS}"
 111   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 112
 113   DEBUG_CFLAGS="-O0"
 114   DEBUG_CXXFLAGS="-O0"
 115
 116   OPTIMIZE_CFLAGS="-O3"
 117   OPTIMIZE_CXXFLAGS="-O3"
 118 fi
 119 if test "x$SUNCC" = "xyes"
 120 then
 121   dnl Once we can use a modern autoconf, we can replace the -xc99=all here
 122   dnl with using AC_CC_STD_C99 above
 123   CC="${CC} -xc99=all"
 124
 125   CFLAGS="-g -mt ${CFLAGS}"
 126   CXXFLAGS="-xlang=c99 -g -mt -compat=5 -library=stlport4 -template=no%extdef ${CXXFLAGS}"
 127
 128   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin"
 129   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 130   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 131
 132 fi
 133
 134 ENABLE_64BIT
 135
 136 #--------------------------------------------------------------------
 137 # Check for libpthread
 138 #--------------------------------------------------------------------
 139
 140 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 141 LIBS="${PTHREAD_LIBS} ${LIBS}"
 142 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 143 CC="$PTHREAD_CC"
 144
 145
 146 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 147 AC_SEARCH_LIBS(socket, socket)
 148 AC_SEARCH_LIBS(gethostbyname, nsl)
 149
 150 save_LIBS="$LIBS"
 151 LIBS="$LIBS -lm"
 152 AC_LINK_IFELSE(
 153   [AC_LANG_PROGRAM(
 154     [[
 155 #include <stdlib.h>
 156     ]],[[
 157       float f= floorf((float) 1.0);
 158     ]],
 159     [LIBM="-lm"],[LIBM=""])])
 160
 161 AC_SUBST(LIBM)
 162 LIBS="$save_LIBS"
 163
 164 AC_SEARCH_LIBS(floorf, m)
 165
 166 dnl Specialty checks
 167 DETECT_BYTEORDER
 168 ENABLE_UTILLIB
 169 ENABLE_DTRACE
 170 SETSOCKOPT_SANITY
 171 ENABLE_HSIEH_HASH
 172 REQUIRE_POD2MAN
 173 PROTOCOL_BINARY_TEST
 174 WITH_MEMCACHED
 175 ENABLE_DEPRECATED
 176
 177 dnl TODO: Remove this define once we are using 2.61 across the board.
 178 # AX_HEADER_ASSERT
 179 # ----------------
 180 # Check whether to enable assertions.
 181 AC_DEFUN([AX_HEADER_ASSERT],
 182 [
 183   AC_MSG_CHECKING([whether to enable assertions])
 184   AC_ARG_ENABLE([assert],
 185     [AS_HELP_STRING([--disable-assert],
 186        [Turn off assertions])],
 187     [ac_cv_assert="no"],
 188     [ac_cv_assert="yes"])
 189   AC_MSG_RESULT([$ac_cv_assert])
 190 ])
 191 AX_HEADER_ASSERT
 192
 193
 194 AC_ARG_WITH([debug],
 195     [AS_HELP_STRING([--with-debug],
 196        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 197     [with_debug=$withval],
 198     [with_debug=no])
 199 if test "$with_debug" = "yes"
 200 then
 201   # Debugging. No optimization.
 202   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 203   CXXFLAGS="${DEBUG_CXXFLAGS} -DDEBUG ${CXXFLAGS}"
 204 else
 205   # Optimized version. No debug
 206   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 207   CXXFLAGS="${OPTIMIZE_CXXFLAGS} ${CXXFLAGS}"
 208 fi
 209
 210 AC_ARG_ENABLE([profiling],
 211     [AS_HELP_STRING([--enable-profiling],
 212        [Toggle profiling @<:@default=off@:>@])],
 213     [ac_profiling="$enableval"],
 214     [ac_profiling="no"])
 215
 216 AC_ARG_ENABLE([coverage],
 217     [AS_HELP_STRING([--enable-coverage],
 218        [Toggle coverage @<:@default=off@:>@])],
 219     [ac_coverage="$enableval"],
 220     [ac_coverage="no"])
 221
 222 if test "$GCC" = "yes"
 223 then
 224
 225   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 226     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 227     [save_CFLAGS="$CFLAGS"
 228      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 229      AC_COMPILE_IFELSE(
 230        [AC_LANG_PROGRAM([],[])],
 231        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 232        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 233      CFLAGS="$save_CFLAGS"])
 234
 235   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 236         [
 237           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 238         ])
 239
 240   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 241     [ac_cv_safe_to_use_wconversion_],
 242     [save_CFLAGS="$CFLAGS"
 243      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 244      AC_COMPILE_IFELSE(
 245        [AC_LANG_PROGRAM([[
 246 #include <stdbool.h>
 247 void foo(bool a)
 248 {
 249   (void)a;
 250 }
 251        ]],[[
 252 foo(0);
 253        ]])],
 254        [ac_cv_safe_to_use_wconversion_=yes],
 255        [ac_cv_safe_to_use_wconversion_=no])
 256      CFLAGS="$save_CFLAGS"])
 257
 258   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 259     [W_CONVERSION="-Wconversion"
 260     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 261       [ac_cv_safe_to_use_Wconversion_],
 262       [save_CFLAGS="$CFLAGS"
 263        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 264        AC_COMPILE_IFELSE(
 265          [AC_LANG_PROGRAM(
 266            [[
 267 #include <netinet/in.h>
 268            ]],[[
 269 uint16_t x= htons(80);
 270            ]])],
 271          [ac_cv_safe_to_use_Wconversion_=yes],
 272          [ac_cv_safe_to_use_Wconversion_=no])
 273        CFLAGS="$save_CFLAGS"])
 274
 275     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 276           [
 277             NO_CONVERSION="-Wno-conversion"
 278           ])
 279     ])
 280
 281   W_STRICT_ALIASING="-Wno-strict-aliasing"
 282
 283   AS_IF([test "$ac_profiling" = "yes"],
 284         [CC_PROFILING="-pg"])
 285
 286   AS_IF([test "$ac_coverage" = "yes"],
 287         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 288
 289   AS_IF([test "$building_from_bzr" = "yes"],
 290         [W_FAIL="-Werror"])
 291
 292   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 293   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 294   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wold-style-cast -Weffc++ -Wno-long-long"
 295
 296   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 297     [ac_cv_safe_to_use_Wlogical_op_],
 298     [save_CFLAGS="$CFLAGS"
 299      CFLAGS="-Wlogical-op"
 300      AC_COMPILE_IFELSE([
 301        AC_LANG_PROGRAM(
 302        [[
 303 #include <stdio>
 304        ]], [[]])
 305     ],
 306     [ac_cv_safe_to_use_Wlogical_op_=yes],
 307     [ac_cv_safe_to_use_Wlogical_op_=no])
 308   CFLAGS="$save_CFLAGS"])
 309   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 310         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 311
 312   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 313     [ac_cv_safe_to_use_Wredundant_decls_],
 314     [AC_LANG_PUSH(C++)
 315      save_CXXFLAGS="${CXXFLAGS}"
 316      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 317      AC_COMPILE_IFELSE(
 318        [AC_LANG_PROGRAM([
 319 template <typename E> struct C { void foo(); };
 320 template <typename E> void C<E>::foo() { }
 321 template <> void C<int>::foo();
 322           AC_INCLUDES_DEFAULT])],
 323         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 324         [ac_cv_safe_to_use_Wredundant_decls_=no])
 325       CXXFLAGS="${save_CXXFLAGS}"
 326       AC_LANG_POP()])
 327   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 328         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 329         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 330
 331   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 332 fi
 333 if test "$SUNCC" = "yes"
 334 then
 335
 336   AS_IF([test "$ac_profiling" = "yes"],
 337         [CC_PROFILING="-xinstrument=datarace"])
 338
 339   AS_IF([test "$building_from_bzr" = "yes"],
 340         [W_FAIL="-errwarn=%all"])
 341
 342   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 343     [ac_cv_paste_result],
 344     [
 345       save_CFLAGS="${CFLAGS}"
 346       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 347       AC_COMPILE_IFELSE(
 348         [AC_LANG_PROGRAM([
 349           AC_INCLUDES_DEFAULT
 350         ],[
 351           int x= 0;])],
 352         [ac_cv_paste_result=yes],
 353         [ac_cv_paste_result=no])
 354       CFLAGS="${save_CFLAGS}"
 355     ])
 356   AS_IF([test $ac_cv_paste_result = yes],
 357     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 358
 359
 360   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 361   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 362 fi
 363
 364 AC_SUBST(NO_CONVERSION)
 365 AC_SUBST(NO_REDUNDANT_DECLS)
 366
 367 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 368 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 369 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 370
 371 AC_SUBST([AM_CPPFLAGS])
 372 AC_SUBST([AM_CFLAGS])
 373 AC_SUBST([AM_CXXFLAGS])
 374
 375 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 376 CFLAGS=""
 377 CXXFLAGS=""
 378 CPPFLAGS=""
 379
 380 AC_CONFIG_FILES([
 381   Makefile
 382   clients/Makefile
 383   tests/Makefile
 384   docs/Makefile
 385   libmemcached/Makefile
 386   libmemcached/memcached_configure.h
 387   libmemcachedutil/Makefile
 388   support/Makefile
 389   support/libmemcached.pc
 390   support/libmemcached.spec
 391   support/libmemcached-fc.spec
 392   ])
 393 AC_OUTPUT
 394
 395 echo "---"
 396 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 397 echo ""
 398 echo "   * Installation prefix:       $prefix"
 399 echo "   * System type:               $host_vendor-$host_os"
 400 echo "   * Host CPU:                  $host_cpu"
 401 echo "   * C Compiler:                $CC_VERSION"
 402 echo "   * Assertions enabled:        $ac_cv_assert"
 403 echo "   * Debug enabled:             $with_debug"
 404 echo "   * Warnings as failure:       $building_from_bzr"
 405 echo ""
 406 echo "---"
 407