git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # libmemcached
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_PREREQ(2.59)
  10 AC_INIT([libmemcached],[0.42],[http://libmemcached.org/])
  11 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 PANDORA_CANONICAL_TARGET
  15
  16 #shared library versioning
  17 MEMCACHED_UTIL_LIBRARY_VERSION=1:0:0
  18 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  19 MEMCACHED_LIBRARY_VERSION=5:1:0
  20 #                         | | |
  21 #                  +------+ | +---+
  22 #                  |        |     |
  23 #                 current:revision:age
  24 #                  |        |     |
  25 #                  |        |     +- increment if interfaces have been added
  26 #                  |        |        set to zero if interfaces have been removed or changed
  27 #                  |        +- increment if source code has changed
  28 #                  |           set to zero if current is incremented
  29 #                  +- increment if interfaces have been added, removed or changed
  30 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  31 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  32 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  33
  34
  35 HASHKIT_LIBRARY_VERSION=0:0:0
  36 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  37
  38 AH_TOP([
  39 #ifndef CONFIG_H
  40 #define CONFIG_H
  41
  42 #ifdef _SYS_FEATURE_TESTS_H
  43 #error "You should include config.h as your first include file"
  44 #endif
  45
  46 #ifdef WIN32
  47 #define _WIN32_WINNT 0x0501
  48 #endif
  49 ])
  50
  51 AH_BOTTOM([
  52 #ifdef HAVE_SYS_WAIT_H
  53 #include <sys/wait.h>
  54 #endif
  55
  56 #ifdef HAVE_FNMATCH_H
  57 #include <fnmatch.h>
  58 #endif
  59
  60 #ifdef HAVE_POLL_H
  61 #include <poll.h>
  62 #else
  63 #include "poll/poll.h"
  64 #endif
  65
  66 /* To hide the platform differences between MS Windows and Unix, I am
  67  * going to use the Microsoft way and #define the Microsoft-specific
  68  * functions to the unix way. Microsoft use a separate subsystem for sockets,
  69  * but Unix normally just use a filedescriptor on the same functions. It is
  70  * a lot easier to map back to the unix way with macros than going the other
  71  * way without side effect ;-)
  72  */
  73 #ifdef WIN32
  74 #include "win32/wrappers.h"
  75 #define get_socket_errno() WSAGetLastError()
  76 #else
  77 #define INVALID_SOCKET -1
  78 #define SOCKET_ERROR -1
  79 #define closesocket(a) close(a)
  80 #define get_socket_errno() errno
  81 #endif
  82
  83 #endif
  84 ])
  85
  86 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  87 AC_SEARCH_LIBS(gethostbyname, nsl)
  88
  89 AC_CHECK_FUNCS([getline])
  90
  91 PANDORA_HAVE_LIBGTEST
  92 PANDORA_HAVE_LIBEVENT
  93 PANDORA_REQUIRE_PTHREAD
  94 PANDORA_CXX_DEMANGLE
  95
  96 dnl Specialty checks
  97 DETECT_BYTEORDER
  98 ENABLE_UTILLIB
  99 SETSOCKOPT_SANITY
 100 ENABLE_HSIEH_HASH
 101 PROTOCOL_BINARY_TEST
 102 WITH_MEMCACHED
 103 ENABLE_DEPRECATED
 104 PANDORA_HAVE_LIBINNODB
 105 PANDORA_PRINT_CALLSTACK
 106 PANDORA_HAVE_SASL
 107
 108 dnl The sasl functions should only be visible if we build with sasl support
 109 AS_IF([test "x$ac_cv_sasl" = "xyes"],
 110       [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"])
 111 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
 112
 113 AC_CHECK_HEADERS([atomic.h])
 114 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
 115       AC_CHECK_FUNCS(atomic_add_64)
 116       AC_CHECK_FUNCS(atomic_add_32)
 117       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
 118             AC_DEFINE([USE_ATOMIC_H],
 119                       [1],
 120                       [Define to true if you want to use functions from atomic.h])])])
 121
 122 AC_ARG_WITH([docs],
 123   [AS_HELP_STRING([--with-docs],
 124     [Generate documentation (yes|no) @<:@default=yes@:>@])],
 125   [with_docs=$withval],
 126   [with_docs=yes])
 127
 128 AS_IF([test "$with_docs" = "yes"],
 129   [
 130     REQUIRE_POD2MAN
 131     REQUIRE_PODCHECKER
 132   ])
 133 AM_CONDITIONAL(BUILD_DOCS, test "$with_docs" = "yes")
 134
 135 AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
 136 AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
 137 AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
 138 AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
 139       AM_LDFLAGS="$AM_LDFLAGS -lws2_32")
 140
 141 #
 142 # Some platforms define EWOULDBLOCK == EAGAIN, causing our switch for error
 143 # codes to be illegal (POSIX.1-2001 allows both return codes from recv, so
 144 # we need to test both if they differ...)
 145 #
 146 AC_MSG_CHECKING([if EWOULDBLOCK == EAGAIN])
 147 AC_RUN_IFELSE(
 148   [AC_LANG_PROGRAM([
 149 #include <errno.h>
 150      ], [dnl
 151    return EAGAIN == EWOULDBLOCK ? 0 : 1;
 152      ])
 153   ],[
 154    AC_MSG_RESULT([yes])
 155   ], [
 156    AC_MSG_RESULT([no])
 157    AC_DEFINE([USE_EAGAIN], [1], [Define to true if you need to test for eagain])
 158   ])
 159
 160 AC_CONFIG_FILES([
 161   Makefile
 162   docs/Makefile
 163   libhashkit/configure.h
 164   libmemcached/configure.h
 165   support/libmemcached.pc
 166   support/libmemcached.spec
 167   support/libmemcached-fc.spec
 168   ])
 169 AC_OUTPUT
 170
 171 echo "---"
 172 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 173 echo ""
 174 echo "   * Installation prefix:       $prefix"
 175 echo "   * System type:               $host_vendor-$host_os"
 176 echo "   * Host CPU:                  $host_cpu"
 177 echo "   * C Compiler:                $CC_VERSION"
 178 echo "   * Assertions enabled:        $ac_cv_assert"
 179 echo "   * Debug enabled:             $with_debug"
 180 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 181 echo ""
 182 echo "---"
 183
 184 case "$host_os" in
 185   *freebsd*)
 186     echo "*****"
 187     echo "*"
 188     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 189     echo "*"
 190     echo "*   use 'gmake' To build libmemcached"
 191     echo "*"
 192     echo "*****"
 193   ;;
 194 esac
 195
 196 AS_IF(test "$with_docs" = "no",
 197   [
 198     echo "*****"
 199     echo "*"
 200     echo "*  WARNING: You are not generating any documentation."
 201     echo "*           Please don't ship libmemcached to an end user"
 202     echo "*           without documentation..."
 203     echo "*"
 204     echo "*****"
 205   ])