git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Use the C99 enabling flag found earlier
 101 AS_IF([test "$ac_cv_prog_cc_c99" != "no"],
 102       [CFLAGS="$ac_cv_prog_cc_c99 ${CFLAGS}"])
 103
 104 # Build optimized or debug version ?
 105 # First check for gcc and g++
 106 if test "$GCC" = "yes"
 107 then
 108   CFLAGS="-ggdb3 ${CFLAGS}"
 109   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 110
 111   DEBUG_CFLAGS="-O0"
 112   DEBUG_CXXFLAGS="-O0"
 113
 114   OPTIMIZE_CFLAGS="-O3"
 115   OPTIMIZE_CXXFLAGS="-O3"
 116 fi
 117 if test "x$SUNCC" = "xyes"
 118 then
 119   CFLAGS="-g -mt ${CFLAGS}"
 120   CXXFLAGS="-g -mt -xlang=c99 ${CXXFLAGS}"
 121
 122   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin -lmopt"
 123   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 124   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 125
 126 fi
 127
 128 SOLARIS_64BIT
 129
 130 #--------------------------------------------------------------------
 131 # Check for libpthread
 132 #--------------------------------------------------------------------
 133
 134 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 135 LIBS="${PTHREAD_LIBS} ${LIBS}"
 136 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 137 CC="$PTHREAD_CC"
 138
 139
 140 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 141 AC_SEARCH_LIBS(socket, socket)
 142 AC_SEARCH_LIBS(gethostbyname, nsl)
 143
 144 save_LIBS="$LIBS"
 145 LIBS="$LIBS -lm"
 146 AC_LINK_IFELSE(
 147   [AC_LANG_PROGRAM(
 148     [[
 149 #include <stdlib.h>
 150     ]],[[
 151       float f= floorf((float) 1.0);
 152     ]],
 153     [LIBM="-lm"],[LIBM=""])])
 154
 155 AC_SUBST(LIBM)
 156 LIBS="$save_LIBS"
 157
 158 AC_SEARCH_LIBS(floorf, m)
 159
 160 dnl Specialty checks
 161 DETECT_BYTEORDER
 162 ENABLE_UTILLIB
 163 ENABLE_DTRACE
 164 SETSOCKOPT_SANITY
 165 ENABLE_HSIEH_HASH
 166 REQUIRE_POD2MAN
 167 PROTOCOL_BINARY_TEST
 168 WITH_MEMCACHED
 169
 170 dnl TODO: Remove this define once we are using 2.61 across the board.
 171 # AX_HEADER_ASSERT
 172 # ----------------
 173 # Check whether to enable assertions.
 174 AC_DEFUN([AX_HEADER_ASSERT],
 175 [
 176   AC_MSG_CHECKING([whether to enable assertions])
 177   AC_ARG_ENABLE([assert],
 178     [AS_HELP_STRING([--disable-assert],
 179        [Turn off assertions])],
 180     [ac_cv_assert="no"],
 181     [ac_cv_assert="yes"])
 182   AC_MSG_RESULT([$ac_cv_assert])
 183 ])
 184 AX_HEADER_ASSERT
 185
 186
 187 AC_ARG_WITH([debug],
 188     [AS_HELP_STRING([--with-debug],
 189        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 190     [with_debug=$withval],
 191     [with_debug=no])
 192 if test "$with_debug" = "yes"
 193 then
 194   # Debugging. No optimization.
 195   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 196 else
 197   # Optimized version. No debug
 198   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 199 fi
 200
 201 AC_ARG_ENABLE([profiling],
 202     [AS_HELP_STRING([--enable-profiling],
 203        [Toggle profiling @<:@default=off@:>@])],
 204     [ac_profiling="$enableval"],
 205     [ac_profiling="no"])
 206
 207 AC_ARG_ENABLE([coverage],
 208     [AS_HELP_STRING([--enable-coverage],
 209        [Toggle coverage @<:@default=off@:>@])],
 210     [ac_coverage="$enableval"],
 211     [ac_coverage="no"])
 212
 213 dnl We can't do this warning, so turn off
 214 W_STRICT_ALIASING="-Wno-strict-aliasing"
 215
 216 if test "$GCC" = "yes"
 217 then
 218
 219
 220   AS_IF([test "$ac_profiling" = "yes"],
 221         [CC_PROFILING="-pg"])
 222
 223   AS_IF([test "$ac_coverage" = "yes"],
 224         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 225
 226   AS_IF([test "$building_from_bzr" = "yes"],
 227         [W_FAIL="-Werror"])
 228
 229   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef  -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING}"
 230   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 231   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long"
 232
 233
 234   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 235     [ac_cv_safe_to_use_Wlogical_op_],
 236     [save_CFLAGS="$CFLAGS"
 237      CFLAGS="-Wlogical-op"
 238      AC_COMPILE_IFELSE([
 239        AC_LANG_PROGRAM(
 240        [[
 241 #include <stdio>
 242        ]], [[]])
 243     ],
 244     [ac_cv_safe_to_use_Wlogical_op_=yes],
 245     [ac_cv_safe_to_use_Wlogical_op_=no])
 246   CFLAGS="$save_CFLAGS"])
 247   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 248         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 249
 250   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 251     [ac_cv_safe_to_use_Wredundant_decls_],
 252     [AC_LANG_PUSH(C++)
 253      save_CXXFLAGS="${CXXFLAGS}"
 254      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 255      AC_COMPILE_IFELSE(
 256        [AC_LANG_PROGRAM([
 257 template <typename E> struct C { void foo(); };
 258 template <typename E> void C<E>::foo() { }
 259 template <> void C<int>::foo();
 260           AC_INCLUDES_DEFAULT])],
 261         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 262         [ac_cv_safe_to_use_Wredundant_decls_=no])
 263       CXXFLAGS="${save_CXXFLAGS}"
 264       AC_LANG_POP()])
 265   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 266         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 267         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 268
 269   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 270 fi
 271 if test "$SUNCC" = "yes"
 272 then
 273
 274   AS_IF([test "$ac_profiling" = "yes"],
 275         [CC_PROFILING="-xinstrument=datarace"])
 276
 277   AS_IF([test "$building_from_bzr" = "yes"],
 278         [W_FAIL="-errwarn=%all"])
 279
 280   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 281     [ac_cv_paste_result],
 282     [
 283       save_CFLAGS="${CFLAGS}"
 284       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 285       AC_COMPILE_IFELSE(
 286         [AC_LANG_PROGRAM([
 287           AC_INCLUDES_DEFAULT
 288         ],[
 289           int x= 0;])],
 290         [ac_cv_paste_result=yes],
 291         [ac_cv_paste_result=no])
 292       CFLAGS="${save_CFLAGS}"
 293     ])
 294   AS_IF([test $ac_cv_paste_result = yes],
 295     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 296
 297
 298   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 299   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 300 fi
 301
 302 AC_SUBST(NO_REDUNDANT_DECLS)
 303
 304 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 305 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 306 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 307
 308 AC_SUBST([AM_CPPFLAGS])
 309 AC_SUBST([AM_CFLAGS])
 310 AC_SUBST([AM_CXXFLAGS])
 311
 312 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 313 CFLAGS=""
 314 CXXFLAGS=""
 315 CPPFLAGS=""
 316
 317 AC_CONFIG_FILES([
 318   Makefile
 319   clients/Makefile
 320   tests/Makefile
 321   docs/Makefile
 322   libmemcached/Makefile
 323   libmemcachedutil/Makefile
 324   support/Makefile
 325   support/libmemcached.pc
 326   support/libmemcached.spec
 327   support/libmemcached-fc.spec
 328   ])
 329 AC_OUTPUT
 330
 331 echo "---"
 332 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 333 echo ""
 334 echo "   * Installation prefix:       $prefix"
 335 echo "   * System type:               $host_vendor-$host_os"
 336 echo "   * Host CPU:                  $host_cpu"
 337 echo "   * C Compiler:                $CC_VERSION"
 338 echo "   * Assertions enabled:        $ac_cv_assert"
 339 echo "   * Debug enabled:             $with_debug"
 340 echo "   * Warnings as failure:       $building_from_bzr"
 341 echo ""
 342 echo "---"
 343