git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker, Monty Taylor
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.34],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER([config.h])
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 PANDORA_CANONICAL_TARGET
  16
  17 #shared library versioning
  18 MEMCACHED_LIBRARY_VERSION=3:0:0
  19 #                         | | |
  20 #                  +------+ | +---+
  21 #                  |        |     |
  22 #                 current:revision:age
  23 #                  |        |     |
  24 #                  |        |     +- increment if interfaces have been added
  25 #                  |        |        set to zero if interfaces have been removed or changed
  26 #                  |        +- increment if source code has changed
  27 #                  |           set to zero if current is incremented
  28 #                  +- increment if interfaces have been added, removed or changed
  29 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  30 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  31 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  32 MEMCACHEDPROTOCOL_LIBRARY_VERSION=0:0:0
  33 AC_SUBST(MEMCACHEDPROTOCOL_LIBRARY_VERSION)
  34
  35
  36 # libmemcached versioning when linked with GNU ld.
  37 if test "$lt_cv_prog_gnu_ld" = "yes"
  38 then
  39     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  40     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/util/libmemcachedutil.ver"
  41     LD_PROTOCOL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/protocol/libmemcachedprotocol.ver"
  42 fi
  43 AC_SUBST(LD_VERSION_SCRIPT)
  44 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  45 AC_SUBST(LD_PROTOCOL_VERSION_SCRIPT)
  46
  47
  48 #--------------------------------------------------------------------
  49 # Check for libpthread
  50 #--------------------------------------------------------------------
  51
  52 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
  53 LIBS="${PTHREAD_LIBS} ${LIBS}"
  54 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
  55 CC="$PTHREAD_CC"
  56
  57
  58 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  59 AC_SEARCH_LIBS(socket, socket)
  60 AC_SEARCH_LIBS(gethostbyname, nsl)
  61
  62 save_LIBS="$LIBS"
  63 LIBS="$LIBS -lm"
  64 AC_LINK_IFELSE(
  65   [AC_LANG_PROGRAM(
  66     [[
  67 #include <stdlib.h>
  68     ]],[[
  69       float f= floorf((float) 1.0);
  70     ]],
  71     [LIBM="-lm"],[LIBM=""])])
  72
  73 AC_SUBST(LIBM)
  74 LIBS="$save_LIBS"
  75
  76 AC_SEARCH_LIBS(floorf, m)
  77
  78 dnl Specialty checks
  79 DETECT_BYTEORDER
  80 ENABLE_UTILLIB
  81 SETSOCKOPT_SANITY
  82 ENABLE_HSIEH_HASH
  83 REQUIRE_POD2MAN
  84 PROTOCOL_BINARY_TEST
  85 WITH_MEMCACHED
  86 ENABLE_DEPRECATED
  87 PANDORA_HAVE_LIBINNODB
  88
  89 AC_CONFIG_FILES([
  90   Makefile
  91   clients/Makefile
  92   tests/Makefile
  93   docs/Makefile
  94   example/Makefile
  95   libmemcached/Makefile
  96   libmemcached/memcached_configure.h
  97   support/Makefile
  98   support/libmemcached.pc
  99   support/libmemcached.spec
 100   support/libmemcached-fc.spec
 101   ])
 102 AC_OUTPUT
 103
 104 echo "---"
 105 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 106 echo ""
 107 echo "   * Installation prefix:       $prefix"
 108 echo "   * System type:               $host_vendor-$host_os"
 109 echo "   * Host CPU:                  $host_cpu"
 110 echo "   * C Compiler:                $CC_VERSION"
 111 echo "   * Assertions enabled:        $ac_cv_assert"
 112 echo "   * Debug enabled:             $with_debug"
 113 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 114 echo ""
 115 echo "---"
 116