git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 m4_include([version.m4])
  10 AC_INIT([libmemcached],VERSION_NUMBER,[http://libmemcached.org/])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AC_CANONICAL_TARGET
  15 AC_ARG_PROGRAM
  16 AC_USE_SYSTEM_EXTENSIONS
  17
  18 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  19
  20 AC_PREREQ([2.61])
  21
  22 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  23 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  24 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  25
  26 #shared library versioning
  27 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  28 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  29 MEMCACHED_LIBRARY_VERSION=11:0:0
  30 #                         | | |
  31 #                  +------+ | +---+
  32 #                  |        |     |
  33 #                 current:revision:age
  34 #                  |        |     |
  35 #                  |        |     +- increment if interfaces have been added
  36 #                  |        |        set to zero if interfaces have been removed or changed
  37 #                  |        +- increment if source code has changed
  38 #                  |           set to zero if current is incremented
  39 #                  +- increment if interfaces have been added, removed or changed
  40 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  41 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  42 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  43
  44 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  45 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  46
  47 m4_include([libhashkit/include.m4])
  48
  49 LT_PREREQ([2.2])
  50 LT_INIT
  51 LT_LANG([C++])
  52 LT_LIB_M
  53
  54 AC_PROG_CC_C99
  55 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  56
  57 AX_ASSERT
  58
  59 AX_PLATFORM
  60
  61 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  62
  63 AX_CXX_HEADER_STDCXX_98
  64 AS_IF([test "x$ax_cv_cxx_stdcxx_98" = "xno"],
  65       [AC_MSG_ERROR([Your system lacks a new enough C++ compiler])])
  66
  67 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  68          [AC_ARG_ENABLE([libmemcachedprotocol],
  69                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  70                                         [Enable libmemcachedprotocol])],
  71                                         [ax_enable_libmemcachedprotocol=yes],
  72                                         [ax_enable_libmemcachedprotocol=no])
  73
  74          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  75
  76          AC_MSG_CHECKING([for libmemcachedprotocol])
  77          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  78          ])
  79 LIBMEMCACHED_PROTOCOL
  80
  81 # Adding support for libtest
  82 m4_include([libtest/yatl.m4])
  83
  84 CHECK_FOR_GEARMAND
  85 CHECK_FOR_LIBGEARMAND
  86
  87 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  88 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
  89 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
  90 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
  91
  92 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
  93
  94 # Specialty checks
  95 AX_CXX_CINTTYPES
  96 CONFIG_EXTRA
  97 DETECT_BYTEORDER
  98 SETSOCKOPT_SANITY
  99 ENABLE_HSIEH_HASH
 100 ENABLE_MURMUR_HASH
 101 ENABLE_FNV64_HASH
 102 ENABLE_MEMASLAP
 103 PROTOCOL_BINARY_TEST
 104 ENABLE_DEPRECATED
 105
 106 # Checks for programs.
 107 AC_CHECK_PROGS([DPKG_GENSYMBOLS],[dpkg-gensymbols])
 108 AC_CHECK_PROGS([LEX],['flex'],[:])
 109 AC_CHECK_PROGS([PERL],[perl])
 110 AC_CHECK_PROGS([VALGRIND],['valgrind'])
 111 AC_CHECK_PROGS([WINE],['wine'])
 112 AC_CHECK_PROGS([YACC],['bison --warnings=all'],[:])
 113 AC_PROG_AWK
 114 AC_PROG_MKDIR_P
 115 AC_PROG_SED
 116 AX_PROG_MEMCACHED
 117 AX_PROG_SPHINX_BUILD(,[AC_MSG_WARN([sphinx-build version 1.0 or greater is required to build man pages])])
 118 AX_WITH_PROG([LCOV],[lcov])
 119 AX_WITH_PROG([LCOV_GENHTML],[genhtml])
 120 AC_DEFINE([HAVE_MEMCACHED_SASL_BINARY],[0],[If Memcached binary with sasl support is available])
 121
 122 # Checks for libraries.
 123 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 124 AC_SEARCH_LIBS([gethostbyname],[nsl])
 125
 126 # Checks for header files.
 127 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 128 AC_CHECK_HEADERS_ONCE([errno.h])
 129 AC_CHECK_HEADERS_ONCE([execinfo.h])
 130 AC_CHECK_HEADERS_ONCE([fcntl.h])
 131 AC_CHECK_HEADERS_ONCE([features.h])
 132 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 133 AC_CHECK_HEADERS_ONCE([inttypes.h])
 134 AC_CHECK_HEADERS_ONCE([libintl.h])
 135 AC_CHECK_HEADERS_ONCE([limits.h])
 136 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 137 AC_CHECK_HEADERS_ONCE([malloc.h])
 138 AC_CHECK_HEADERS_ONCE([math.h])
 139 AC_CHECK_HEADERS_ONCE([netdb.h])
 140 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 141 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 142 AC_CHECK_HEADERS_ONCE([poll.h])
 143 AC_CHECK_HEADERS_ONCE([pthread.h])
 144 AC_CHECK_HEADERS_ONCE([spawn.h])
 145 AC_CHECK_HEADERS_ONCE([stdarg.h])
 146 AC_CHECK_HEADERS_ONCE([stddef.h])
 147 AC_CHECK_HEADERS_ONCE([stdio.h])
 148 AC_CHECK_HEADERS_ONCE([stdlib.h])
 149 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 150 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 151 AC_CHECK_HEADERS_ONCE([sys/time.h])
 152 AC_CHECK_HEADERS_ONCE([sys/types.h])
 153 AC_CHECK_HEADERS_ONCE([sys/un.h])
 154 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 155 AC_CHECK_HEADERS_ONCE([syslog.h])
 156 AC_CHECK_HEADERS_ONCE([time.h])
 157 AC_CHECK_HEADERS_ONCE([unistd.h])
 158
 159 # Windows only
 160 AC_CHECK_HEADERS_ONCE([winsock2.h])
 161 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 162
 163 # Checks for typedefs, structures, and compiler characteristics.
 164
 165 # Checks for library functions.
 166
 167 AC_CHECK_FUNCS([alarm])
 168 AC_CHECK_FUNCS([atexit])
 169 AC_CHECK_FUNCS([clock_gettime])
 170 AC_CHECK_FUNCS([dup2])
 171 AC_CHECK_FUNCS([fcntl])
 172 AC_CHECK_FUNCS([floor])
 173 AC_CHECK_FUNCS([getcwd])
 174 AC_CHECK_FUNCS([getline])
 175 AC_CHECK_FUNCS([gettimeofday])
 176 AC_CHECK_FUNCS([inet_ntoa])
 177 AC_CHECK_FUNCS([memchr])
 178 AC_CHECK_FUNCS([memmove])
 179 AC_CHECK_FUNCS([memset])
 180 AC_CHECK_FUNCS([pipe2])
 181 AC_CHECK_FUNCS([putenv])
 182 AC_CHECK_FUNCS([select])
 183 AC_CHECK_FUNCS([setenv])
 184 AC_CHECK_FUNCS([sigignore])
 185 AC_CHECK_FUNCS([socket])
 186 AC_CHECK_FUNCS([sqrt])
 187 AC_CHECK_FUNCS([strcasecmp])
 188 AC_CHECK_FUNCS([strchr])
 189 AC_CHECK_FUNCS([strdup])
 190 AC_CHECK_FUNCS([strerror])
 191 AC_CHECK_FUNCS([strstr])
 192 AC_CHECK_FUNCS([strtol])
 193 AC_CHECK_FUNCS([strtoul])
 194 AC_CHECK_FUNCS([strtoull])
 195 AC_FUNC_ALLOCA
 196 AC_FUNC_ERROR_AT_LINE
 197 AC_FUNC_FORK
 198 AC_FUNC_STRERROR_R
 199
 200 AC_CHECK_HEADER([umem.h],
 201                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 202                 build_cache=no],
 203                 [build_cache=yes])
 204
 205 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 206
 207 AX_COMPILER_VENDOR
 208
 209 AC_CHECK_TYPES([in_port_t],,,[[
 210                 #ifdef HAVE_SYS_TYPES_H
 211                 # include <sys/types.h>
 212                 #endif
 213                 #ifdef HAVE_NETINET_IN_H
 214                 # include <netinet/in.h>
 215                 #endif
 216                 #ifdef HAVE_NETDB_H
 217                 # include <netdb.h>
 218                 #endif]])
 219 AC_CHECK_TYPES([ptrdiff_t])
 220 AC_HEADER_STDBOOL
 221 AC_TYPE_INT16_T
 222 AC_TYPE_INT32_T
 223 AC_TYPE_INT64_T
 224 AC_TYPE_INT8_T
 225 AC_TYPE_OFF_T
 226 AC_TYPE_PID_T
 227 AC_TYPE_SSIZE_T
 228 AC_TYPE_UINT16_T
 229 AC_TYPE_UINT32_T
 230 AC_TYPE_UINT64_T
 231 AC_TYPE_UINT8_T
 232
 233 AC_C_BIGENDIAN
 234 AC_C_CONST
 235 AC_C_INLINE
 236 AC_C_VOLATILE
 237 AC_C_RESTRICT
 238
 239 AX_CXX_GCC_ABI_DEMANGLE
 240
 241 AX_LIBEVENT
 242
 243 AC_CHECK_LIB([rt],[clock_gettime],
 244              [AC_SUBST([RT_LIB],[-lrt])
 245              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 246              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 247
 248
 249 # Check for the ability to call dlopen (used in libhostile)
 250 AX_DLOPEN
 251
 252 AC_CHECK_HEADERS([atomic.h])
 253 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 254       [AC_CHECK_FUNCS([atomic_add_64])
 255       AC_CHECK_FUNCS([atomic_add_32])
 256       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 257             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 258
 259 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 260 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 261 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 262 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 263 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 264 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 265
 266 # Check for the requirements for running memcached with less privileges
 267 # than the default privilege set. On Solaris we need setppriv and priv.h
 268 # If you want to add support for other platforms you should check for
 269 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 270 # the source file containing the implementation into memcached_SOURCE
 271 # in Makefile.am
 272 AC_CHECK_FUNCS([setppriv],
 273                [AC_CHECK_HEADER([priv.h],
 274                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 275                                            [1],
 276                                            [Define this if you have an implementation of drop_privileges()])
 277                                 build_solaris_privs=yes])
 278                ])
 279
 280 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 281 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 282 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 283       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 284        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 285        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 286        ])
 287 SOCKET_SEND_FLAGS
 288
 289 AX_UUID_GENERATE_TIME_SAFE
 290
 291 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 292          [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 293          AX_PTHREAD_TIMEDJOIN_NP
 294
 295          # The sasl functions should only be visible if we build with sasl support
 296          #
 297          AX_SASL_OPTION
 298          AS_IF([test "x$ac_enable_sasl" = xyes],
 299                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 300                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 301          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 302          ])
 303 CHECK_FOR_PTHREAD_AND_SASL
 304
 305 # backtrace(), others require shared builds
 306 AC_DEFUN([__ENABLE_SHARED],
 307          [AC_REQUIRE([AX_PLATFORM])
 308          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 309          AS_IF([test "x$enable_shared" = "xyes"],
 310                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 311 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 312
 313 PANDORA_ENABLE_DTRACE
 314 HAVE_GCC_ATOMICS
 315 AX_ENDIAN
 316 AX_ASSERT
 317 AX_HARDEN_COMPILER_FLAGS
 318
 319 AX_AM_JOBSERVER([yes])
 320
 321 AC_CONFIG_FILES([Makefile
 322                  docs/conf.py
 323                  libmemcached-1.0/configure.h
 324                  support/libmemcached.pc
 325                  support/libmemcached.spec
 326                  ])
 327 AC_OUTPUT
 328
 329 echo "---"
 330 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 331 echo ""
 332 echo "   * Installation prefix:       $prefix"
 333 echo "   * System type:               $host_vendor-$host_os"
 334 echo "   * Host CPU:                  $host_cpu"
 335 echo "   * C Compiler:                $CC_VERSION"
 336 echo "   * C Flags:                   $CFLAGS"
 337 echo "   * C++ Compiler:              $CXX_VERSION"
 338 echo "   * C++ Flags:                 $CXXFLAGS"
 339 echo "   * CPP Flags:                 $CPPFLAGS"
 340 echo "   * LIB Flags:                 $LIB"
 341 echo "   * Assertions enabled:        $ax_enable_assert"
 342 echo "   * Debug enabled:             $ax_enable_debug"
 343 echo "   * Shared:                    $enable_shared"
 344 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 345 echo "   * SASL support:              $ac_enable_sasl"
 346 echo "   * make -j:                   $enable_jobserver"
 347 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 348 echo ""
 349 echo "---"
 350
 351 case "$host_os" in
 352   *freebsd*)
 353     echo "*****"
 354     echo "*"
 355     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 356     echo "*"
 357     echo "*   use 'gmake' To build libmemcached"
 358     echo "*"
 359     echo "*****"
 360   ;;
 361 esac
 362