git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # LibmemcacheD
   3 # Copyright (C) 2011-2012 Data Differential, http://datadifferential.com/
   4 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   5 # All rights reserved.
   6 #
   7 # Use and distribution licensed under the BSD license.  See
   8 # the COPYING file in this directory for full text.
   9
  10 AC_INIT([libmemcached],[1.0.4],[http://libmemcached.org/])
  11
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 AC_CANONICAL_TARGET
  15
  16 AM_INIT_AUTOMAKE
  17
  18 AC_CANONICAL_HOST
  19 AC_CANONICAL_BUILD
  20
  21 AC_PREREQ([2.61])
  22
  23 AC_CONFIG_MACRO_DIR(m4)
  24
  25 AC_CONFIG_HEADERS([config.h:config.in])dnl Keep filename to 8.3 for MS-DOS.
  26
  27 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  28
  29 PANDORA_CANONICAL_TARGET(no-vc-changelog)
  30 AC_CHECK_PROGS([YACC], ['bison'], [:])
  31 AC_CHECK_PROGS([LEX], ['flex'], [:])
  32
  33 #shared library versioning
  34 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  35 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  36 MEMCACHED_LIBRARY_VERSION=9:0:0
  37 #                         | | |
  38 #                  +------+ | +---+
  39 #                  |        |     |
  40 #                 current:revision:age
  41 #                  |        |     |
  42 #                  |        |     +- increment if interfaces have been added
  43 #                  |        |        set to zero if interfaces have been removed or changed
  44 #                  |        +- increment if source code has changed
  45 #                  |           set to zero if current is incremented
  46 #                  +- increment if interfaces have been added, removed or changed
  47 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  48 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  49 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  50
  51
  52 HASHKIT_LIBRARY_VERSION=1:0:0
  53 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  54
  55 LT_PREREQ([2.2])
  56 LT_INIT()
  57 LT_LANG([C++])
  58 LT_LANG([C])
  59 gl_VISIBILITY
  60
  61 m4_include([m4/memcached.m4])
  62 m4_include([m4/memcached_sasl.m4])
  63 m4_include([m4/gearmand.m4])
  64 m4_include([m4/libgearman.m4])
  65
  66 AM_CONDITIONAL(BUILDING_LIBMEMCACHED, true)
  67 AM_CONDITIONAL(HAVE_LIBMEMCACHED, false)
  68 AC_DEFINE([HAVE_LIBMEMCACHED], [1], [Enables libmemcached Support])
  69
  70 AM_CONDITIONAL(BUILDING_GEARMAN, false)
  71
  72 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  73 AC_SEARCH_LIBS(gethostbyname, nsl)
  74
  75 PANDORA_HAVE_LIBEVENT
  76
  77 case "$target_os" in
  78   *linux*)
  79        AS_IF([test "x$GCC" = "xyes"],
  80              [
  81               LDFLAGS="$LDFLAGS -z relro -z now"
  82               ])
  83    ;;
  84    esac
  85
  86 dnl Specialty checks
  87 AX_PTHREAD
  88 AX_CXX_CSTDINT
  89 CONFIG_EXTRA
  90 DETECT_BYTEORDER
  91 ENABLE_UTILLIB
  92 SETSOCKOPT_SANITY
  93 ENABLE_HSIEH_HASH
  94 ENABLE_MURMUR_HASH
  95 ENABLE_FNV64_HASH
  96 ENABLE_MEMASLAP
  97 PROTOCOL_BINARY_TEST
  98 ENABLE_DEPRECATED
  99 PANDORA_HAVE_LIBINNODB
 100 PANDORA_HAVE_SASL
 101
 102 AC_CHECK_FUNCS([alarm])
 103 AC_CHECK_FUNCS([dup2])
 104 AC_CHECK_FUNCS([getline])
 105 AC_CHECK_FUNCS([gettimeofday])
 106 AC_CHECK_FUNCS([memchr])
 107 AC_CHECK_FUNCS([memmove])
 108 AC_CHECK_FUNCS([memset])
 109 AC_CHECK_FUNCS([select])
 110 AC_CHECK_FUNCS([setenv])
 111 AC_CHECK_FUNCS([socket])
 112 AC_CHECK_FUNCS([sqrt])
 113 AC_CHECK_FUNCS([strcasecmp])
 114 AC_CHECK_FUNCS([strchr])
 115 AC_CHECK_FUNCS([strdup])
 116 AC_CHECK_FUNCS([strerror])
 117 AC_CHECK_FUNCS([strtol])
 118 AC_CHECK_FUNCS([strtoul])
 119 AC_CHECK_FUNCS([strtoull])
 120
 121 AC_CHECK_HEADERS([arpa/inet.h])
 122 AC_CHECK_HEADERS([fcntl.h])
 123 AC_CHECK_HEADERS([libintl.h])
 124 AC_CHECK_HEADERS([limits.h])
 125 AC_CHECK_HEADERS([malloc.h])
 126 AC_CHECK_HEADERS([netdb.h])
 127 AC_CHECK_HEADERS([netinet/in.h])
 128 AC_CHECK_HEADERS([stddef.h])
 129 AC_CHECK_HEADERS([sys/time.h])
 130 AC_CHECK_HEADERS([sasl/sasl.h])
 131 AC_CHECK_HEADERS([execinfo.h])
 132 AC_CHECK_HEADERS([cxxabi.h],
 133                  AC_DEFINE([HAVE_CXXABI_H], [1], [Have cxxabi.h]),
 134                  AC_DEFINE([HAVE_CXXABI_H], [0], [Have cxxabi.h]))
 135
 136 AX_COMPILER_VENDOR
 137 AC_CXX_HEADER_STDCXX_98
 138
 139 AC_FUNC_ALLOCA
 140 AC_FUNC_ERROR_AT_LINE
 141 AC_FUNC_FORK
 142 AC_FUNC_MALLOC
 143 AC_FUNC_REALLOC
 144 AC_FUNC_STRERROR_R
 145 AC_HEADER_STDBOOL
 146 AC_TYPE_INT16_T
 147 AC_TYPE_INT32_T
 148 AC_TYPE_INT64_T
 149 AC_TYPE_INT8_T
 150 AC_TYPE_OFF_T
 151 AC_TYPE_PID_T
 152 AC_TYPE_SSIZE_T
 153 AC_TYPE_UINT16_T
 154 AC_TYPE_UINT32_T
 155 AC_TYPE_UINT64_T
 156 AC_TYPE_UINT8_T
 157
 158 AC_C_BIGENDIAN
 159 AC_C_CONST
 160 AC_C_INLINE
 161 AC_C_VOLATILE
 162 AC_C_RESTRICT
 163
 164 AX_CXX_GCC_ABI_DEMANGLE
 165
 166 AC_CHECK_LIB([rt], [clock_gettime],
 167              [
 168               RT_LIB="-lrt"
 169               AC_SUBST(RT_LIB)
 170               AC_DEFINE([HAVE_LIBRT], [ 1 ], [Have clock_gettime])
 171               ],
 172              [
 173               AC_DEFINE([HAVE_LIBRT], [ 0 ], [Have clock_gettime])
 174               ])
 175
 176 AC_CHECK_LIB([m], [floor])
 177
 178 dnl The sasl functions should only be visible if we build with sasl support
 179 AS_IF([test "x$ac_cv_sasl" = "xyes"],
 180       [
 181         [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1" ]
 182       ],
 183       [
 184         [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0" ]
 185        ]
 186       )
 187 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
 188
 189 AC_CHECK_HEADERS([atomic.h])
 190 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
 191       AC_CHECK_FUNCS(atomic_add_64)
 192       AC_CHECK_FUNCS(atomic_add_32)
 193       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
 194             AC_DEFINE([USE_ATOMIC_H],
 195                       [1],
 196                       [Define to true if you want to use functions from atomic.h])])])
 197
 198 AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
 199 AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
 200 AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
 201 AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
 202       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 203        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 204        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 205       ])
 206 SOCKET_SEND_FLAGS
 207
 208 AC_CONFIG_FILES([
 209   Makefile
 210   docs/conf.py
 211   libhashkit-1.0/configure.h
 212   libmemcached-1.0/configure.h
 213   libmemcached-1.2/configure.h
 214   libmemcached-2.0/configure.h
 215   support/libmemcached.pc
 216   support/libmemcached.spec
 217   support/libmemcached-fc.spec
 218   libtest/version.h
 219   ])
 220 AC_OUTPUT
 221
 222 echo "---"
 223 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 224 echo ""
 225 echo "   * Installation prefix:       $prefix"
 226 echo "   * System type:               $host_vendor-$host_os"
 227 echo "   * Host CPU:                  $host_cpu"
 228 echo "   * C Compiler:                $CC_VERSION"
 229 echo "   * Assertions enabled:        $ac_cv_assert"
 230 echo "   * Debug enabled:             $with_debug"
 231 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 232 echo ""
 233 echo "---"
 234
 235 case "$host_os" in
 236   *freebsd*)
 237     echo "*****"
 238     echo "*"
 239     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 240     echo "*"
 241     echo "*   use 'gmake' To build libmemcached"
 242     echo "*"
 243     echo "*****"
 244   ;;
 245 esac
 246