git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_INIT([libmemcached],[1.0.17],[http://libmemcached.org/])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_ARG_PROGRAM
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  18
  19 AC_PREREQ([2.61])
  20
  21 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  22 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  23 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  24
  25 #shared library versioning
  26 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  27 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  28 MEMCACHED_LIBRARY_VERSION=11:0:0
  29 #                         | | |
  30 #                  +------+ | +---+
  31 #                  |        |     |
  32 #                 current:revision:age
  33 #                  |        |     |
  34 #                  |        |     +- increment if interfaces have been added
  35 #                  |        |        set to zero if interfaces have been removed or changed
  36 #                  |        +- increment if source code has changed
  37 #                  |           set to zero if current is incremented
  38 #                  +- increment if interfaces have been added, removed or changed
  39 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  40 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  41 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  42
  43 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  44 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  45
  46 m4_include([libhashkit/include.m4])
  47
  48 LT_PREREQ([2.2])
  49 LT_INIT
  50 LT_LANG([C++])
  51 LT_LIB_M
  52
  53 AC_PROG_CC_C99
  54 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  55
  56 AX_ASSERT
  57
  58 AX_PLATFORM
  59
  60 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  61
  62 AX_CXX_HEADER_STDCXX_98
  63 AS_IF([test "x$ax_cv_cxx_stdcxx_98" = "xno"],
  64       [AC_MSG_ERROR([Your system lacks a new enough C++ compiler])])
  65
  66 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  67          [AC_ARG_ENABLE([libmemcachedprotocol],
  68                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  69                                         [Enable libmemcachedprotocol])],
  70                                         [ax_enable_libmemcachedprotocol=yes],
  71                                         [ax_enable_libmemcachedprotocol=no])
  72
  73          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  74
  75          AC_MSG_CHECKING([for libmemcachedprotocol])
  76          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  77          ])
  78 LIBMEMCACHED_PROTOCOL
  79
  80 # Adding support for libtest
  81 m4_include([libtest/yatl.m4])
  82
  83 CHECK_FOR_GEARMAND
  84 CHECK_FOR_LIBGEARMAND
  85
  86 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  87 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
  88 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
  89 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
  90
  91 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
  92
  93 # Specialty checks
  94 AX_CXX_CINTTYPES
  95 CONFIG_EXTRA
  96 DETECT_BYTEORDER
  97 SETSOCKOPT_SANITY
  98 ENABLE_HSIEH_HASH
  99 ENABLE_MURMUR_HASH
 100 ENABLE_FNV64_HASH
 101 ENABLE_MEMASLAP
 102 PROTOCOL_BINARY_TEST
 103 ENABLE_DEPRECATED
 104
 105 # Checks for programs.
 106 AC_PROG_AWK
 107 AC_PROG_SED
 108 AC_PROG_MKDIR_P
 109 AC_CHECK_PROGS([LEX],['flex'],[:])
 110 AC_CHECK_PROGS([YACC],['bison'],[:])
 111 AX_PROG_SPHINX_BUILD
 112 AX_PROG_MEMCACHED
 113
 114 # Checks for libraries.
 115 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 116 AC_SEARCH_LIBS([gethostbyname],[nsl])
 117
 118 # Checks for header files.
 119 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 120 AC_CHECK_HEADERS_ONCE([errno.h])
 121 AC_CHECK_HEADERS_ONCE([execinfo.h])
 122 AC_CHECK_HEADERS_ONCE([fcntl.h])
 123 AC_CHECK_HEADERS_ONCE([features.h])
 124 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 125 AC_CHECK_HEADERS_ONCE([inttypes.h])
 126 AC_CHECK_HEADERS_ONCE([libintl.h])
 127 AC_CHECK_HEADERS_ONCE([limits.h])
 128 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 129 AC_CHECK_HEADERS_ONCE([malloc.h])
 130 AC_CHECK_HEADERS_ONCE([math.h])
 131 AC_CHECK_HEADERS_ONCE([netdb.h])
 132 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 133 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 134 AC_CHECK_HEADERS_ONCE([poll.h])
 135 AC_CHECK_HEADERS_ONCE([pthread.h])
 136 AC_CHECK_HEADERS_ONCE([spawn.h])
 137 AC_CHECK_HEADERS_ONCE([stdarg.h])
 138 AC_CHECK_HEADERS_ONCE([stddef.h])
 139 AC_CHECK_HEADERS_ONCE([stdio.h])
 140 AC_CHECK_HEADERS_ONCE([stdlib.h])
 141 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 142 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 143 AC_CHECK_HEADERS_ONCE([sys/time.h])
 144 AC_CHECK_HEADERS_ONCE([sys/types.h])
 145 AC_CHECK_HEADERS_ONCE([sys/un.h])
 146 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 147 AC_CHECK_HEADERS_ONCE([syslog.h])
 148 AC_CHECK_HEADERS_ONCE([time.h])
 149 AC_CHECK_HEADERS_ONCE([unistd.h])
 150
 151 # Windows only
 152 AC_CHECK_HEADERS_ONCE([winsock2.h])
 153 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 154
 155 # Checks for typedefs, structures, and compiler characteristics.
 156
 157 # Checks for library functions.
 158
 159 AC_CHECK_FUNCS([alarm])
 160 AC_CHECK_FUNCS([atexit])
 161 AC_CHECK_FUNCS([clock_gettime])
 162 AC_CHECK_FUNCS([dup2])
 163 AC_CHECK_FUNCS([fcntl])
 164 AC_CHECK_FUNCS([floor])
 165 AC_CHECK_FUNCS([getcwd])
 166 AC_CHECK_FUNCS([getline])
 167 AC_CHECK_FUNCS([gettimeofday])
 168 AC_CHECK_FUNCS([inet_ntoa])
 169 AC_CHECK_FUNCS([memchr])
 170 AC_CHECK_FUNCS([memmove])
 171 AC_CHECK_FUNCS([memset])
 172 AC_CHECK_FUNCS([pipe2])
 173 AC_CHECK_FUNCS([putenv])
 174 AC_CHECK_FUNCS([select])
 175 AC_CHECK_FUNCS([setenv])
 176 AC_CHECK_FUNCS([sigignore])
 177 AC_CHECK_FUNCS([socket])
 178 AC_CHECK_FUNCS([sqrt])
 179 AC_CHECK_FUNCS([strcasecmp])
 180 AC_CHECK_FUNCS([strchr])
 181 AC_CHECK_FUNCS([strdup])
 182 AC_CHECK_FUNCS([strerror])
 183 AC_CHECK_FUNCS([strstr])
 184 AC_CHECK_FUNCS([strtol])
 185 AC_CHECK_FUNCS([strtoul])
 186 AC_CHECK_FUNCS([strtoull])
 187 AC_FUNC_ALLOCA
 188 AC_FUNC_ERROR_AT_LINE
 189 AC_FUNC_FORK
 190 AC_FUNC_STRERROR_R
 191
 192 AC_CHECK_HEADER([umem.h],
 193                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 194                 build_cache=no],
 195                 [build_cache=yes])
 196
 197 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 198
 199 AX_COMPILER_VENDOR
 200
 201 AC_CHECK_TYPES([in_port_t],,,[[
 202                 #ifdef HAVE_SYS_TYPES_H
 203                 # include <sys/types.h>
 204                 #endif
 205                 #ifdef HAVE_NETINET_IN_H
 206                 # include <netinet/in.h>
 207                 #endif
 208                 #ifdef HAVE_NETDB_H
 209                 # include <netdb.h>
 210                 #endif]])
 211 AC_CHECK_TYPES([ptrdiff_t])
 212 AC_HEADER_STDBOOL
 213 AC_TYPE_INT16_T
 214 AC_TYPE_INT32_T
 215 AC_TYPE_INT64_T
 216 AC_TYPE_INT8_T
 217 AC_TYPE_OFF_T
 218 AC_TYPE_PID_T
 219 AC_TYPE_SSIZE_T
 220 AC_TYPE_UINT16_T
 221 AC_TYPE_UINT32_T
 222 AC_TYPE_UINT64_T
 223 AC_TYPE_UINT8_T
 224
 225 AC_C_BIGENDIAN
 226 AC_C_CONST
 227 AC_C_INLINE
 228 AC_C_VOLATILE
 229 AC_C_RESTRICT
 230
 231 AX_CXX_GCC_ABI_DEMANGLE
 232
 233 AX_LIBEVENT
 234
 235 AC_CHECK_LIB([rt],[clock_gettime],
 236              [AC_SUBST([RT_LIB],[-lrt])
 237              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 238              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 239
 240
 241 # Check for the ability to call dlopen (used in libhostile)
 242 AX_DLOPEN
 243
 244 AC_CHECK_HEADERS([atomic.h])
 245 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 246       [AC_CHECK_FUNCS([atomic_add_64])
 247       AC_CHECK_FUNCS([atomic_add_32])
 248       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 249             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 250
 251 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 252 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 253 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 254 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 255 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 256 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 257
 258 # Check for the requirements for running memcached with less privileges
 259 # than the default privilege set. On Solaris we need setppriv and priv.h
 260 # If you want to add support for other platforms you should check for
 261 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 262 # the source file containing the implementation into memcached_SOURCE
 263 # in Makefile.am
 264 AC_CHECK_FUNCS([setppriv],
 265                [AC_CHECK_HEADER([priv.h],
 266                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 267                                            [1],
 268                                            [Define this if you have an implementation of drop_privileges()])
 269                                 build_solaris_privs=yes])
 270                ])
 271
 272 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 273 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 274 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 275       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 276        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 277        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 278        ])
 279 SOCKET_SEND_FLAGS
 280
 281 AX_UUID_GENERATE_TIME_SAFE
 282
 283 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 284          [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 285          AX_PTHREAD_TIMEDJOIN_NP
 286
 287          # The sasl functions should only be visible if we build with sasl support
 288          #
 289          AX_SASL_OPTION
 290          AS_IF([test "x$ac_enable_sasl" = xyes],
 291                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 292                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 293          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 294          ])
 295 CHECK_FOR_PTHREAD_AND_SASL
 296
 297 # backtrace(), others require shared builds
 298 AC_DEFUN([__ENABLE_SHARED],
 299          [AC_REQUIRE([AX_PLATFORM])
 300          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 301          AS_IF([test "x$enable_shared" = "xyes"],
 302                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 303 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 304
 305 PANDORA_ENABLE_DTRACE
 306 HAVE_GCC_ATOMICS
 307 AX_ENDIAN
 308 AX_ASSERT
 309 AX_HARDEN_COMPILER_FLAGS
 310
 311 AX_AM_JOBSERVER([yes])
 312
 313 AC_CONFIG_FILES([Makefile
 314                  docs/conf.py
 315                  libmemcached-1.0/configure.h
 316                  support/libmemcached.pc
 317                  support/libmemcached.spec
 318                  ])
 319 AC_OUTPUT
 320
 321 echo "---"
 322 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 323 echo ""
 324 echo "   * Installation prefix:       $prefix"
 325 echo "   * System type:               $host_vendor-$host_os"
 326 echo "   * Host CPU:                  $host_cpu"
 327 echo "   * C Compiler:                $CC_VERSION"
 328 echo "   * C Flags:                   $CFLAGS"
 329 echo "   * C++ Compiler:              $CXX_VERSION"
 330 echo "   * C++ Flags:                 $CXXFLAGS"
 331 echo "   * CPP Flags:                 $CPPFLAGS"
 332 echo "   * LIB Flags:                 $LIB"
 333 echo "   * Assertions enabled:        $ax_enable_assert"
 334 echo "   * Debug enabled:             $ax_enable_debug"
 335 echo "   * Shared:                    $enable_shared"
 336 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 337 echo "   * SASL support:              $ac_enable_sasl"
 338 echo "   * make -j:                   $enable_jobserver"
 339 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 340 echo ""
 341 echo "---"
 342
 343 case "$host_os" in
 344   *freebsd*)
 345     echo "*****"
 346     echo "*"
 347     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 348     echo "*"
 349     echo "*   use 'gmake' To build libmemcached"
 350     echo "*"
 351     echo "*****"
 352   ;;
 353 esac
 354