git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Build optimized or debug version ?
 101 # First check for gcc and g++
 102 if test "$GCC" = "yes"
 103 then
 104   CFLAGS="-ggdb3 -std=gnu99 ${CFLAGS}"
 105   DEBUG_CFLAGS="-O0"
 106   OPTIMIZE_CFLAGS="-O3"
 107 fi
 108 if test "x$SUNCC" = "xyes"
 109 then
 110    CFLAGS="-g -mt -xc99=all $CFLAGS"
 111    CXXFLAGS="-g -mt -xlang=c99 $CXXFLAGS"
 112    OPTIMIZE_CFLAGS="-xO4 -xlibmil -xdepend -Xa -xstrconst"
 113 fi
 114
 115 SOLARIS_64BIT
 116
 117 #--------------------------------------------------------------------
 118 # Check for libpthread
 119 #--------------------------------------------------------------------
 120
 121 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 122 LIBS="${PTHREAD_LIBS} ${LIBS}"
 123 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 124 CC="$PTHREAD_CC"
 125
 126
 127 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 128 AC_SEARCH_LIBS(socket, socket)
 129 AC_SEARCH_LIBS(gethostbyname, nsl)
 130
 131 save_LIBS="$LIBS"
 132 LIBS="$LIBS -lm"
 133 AC_LINK_IFELSE(
 134   [AC_LANG_PROGRAM(
 135     [[
 136 #include <stdlib.h>
 137     ]],[[
 138       float f= floorf((float) 1.0);
 139     ]],
 140     [LIBM="-lm"],[LIBM=""])])
 141
 142 AC_SUBST(LIBM)
 143 LIBS="$save_LIBS"
 144
 145 AC_SEARCH_LIBS(floorf, m)
 146
 147 DETECT_BYTEORDER
 148 ENABLE_UTILLIB
 149
 150 sinclude(m4/pod2man.m4)
 151 sinclude(m4/dtrace.m4)
 152 sinclude(m4/protocol_binary.m4)
 153 sinclude(m4/memcached.m4)
 154 sinclude(m4/setsockopt.m4)
 155 sinclude(m4/hsieh.m4)
 156
 157 dnl TODO: Remove this define once we are using 2.61 across the board.
 158 # AX_HEADER_ASSERT
 159 # ----------------
 160 # Check whether to enable assertions.
 161 AC_DEFUN([AX_HEADER_ASSERT],
 162 [
 163   AC_MSG_CHECKING([whether to enable assertions])
 164   AC_ARG_ENABLE([assert],
 165     [AS_HELP_STRING([--disable-assert],
 166        [Turn off assertions])],
 167     [ac_cv_assert="no"],
 168     [ac_cv_assert="yes"])
 169   AC_MSG_RESULT([$ac_cv_assert])
 170 ])
 171 AX_HEADER_ASSERT
 172
 173
 174 AC_ARG_WITH([debug],
 175     [AS_HELP_STRING([--with-debug],
 176        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 177     [with_debug=$withval],
 178     [with_debug=no])
 179 if test "$with_debug" = "yes"
 180 then
 181   # Debugging. No optimization.
 182   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 183 else
 184   # Optimized version. No debug
 185   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 186 fi
 187
 188 AC_ARG_ENABLE([profiling],
 189     [AS_HELP_STRING([--enable-profiling],
 190        [Toggle profiling @<:@default=off@:>@])],
 191     [ac_profiling="$enableval"],
 192     [ac_profiling="no"])
 193
 194 AC_ARG_ENABLE([coverage],
 195     [AS_HELP_STRING([--enable-coverage],
 196        [Toggle coverage @<:@default=off@:>@])],
 197     [ac_coverage="$enableval"],
 198     [ac_coverage="no"])
 199
 200 AC_ARG_ENABLE([unreachable],
 201   [AS_HELP_STRING([--enable-unreachable],
 202     [Enable warnings about unreachable code @<:@default=no@:>@])],
 203   [ac_warn_unreachable="$enableval"],
 204   [ac_warn_unreachable="no"])
 205
 206
 207 if test "$GCC" = "yes"
 208 then
 209
 210   W_STRICT_ALIASING="-Wno-strict-aliasing"
 211
 212   AS_IF([test "$ac_profiling" = "yes"],
 213         [CC_PROFILING="-pg"])
 214
 215   AS_IF([test "$ac_coverage" = "yes"],
 216         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 217
 218   AS_IF([test "$building_from_bzr" = "yes"],
 219         [W_FAIL="-Werror"])
 220
 221   AS_IF([test "$ac_warn_unreachable" = "yes"],
 222         [W_UNREACHABLE="-Wunreachable-code"])
 223
 224   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef  -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING}"
 225   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 226   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long"
 227
 228   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 229     [ac_cv_safe_to_use_Wconversion_],
 230     [save_CFLAGS="$CFLAGS"
 231      CFLAGS="-Werror -Wconversion"
 232      AC_COMPILE_IFELSE(
 233        [AC_LANG_PROGRAM(
 234          [[
 235 #include <netinet/in.h>
 236 void foo(in_port_t port)
 237 {
 238   return;
 239 }
 240          ]],[[
 241 in_port_t x= 0;
 242 foo(x);
 243          ]])],
 244        [ac_cv_safe_to_use_Wconversion_=yes],
 245        [ac_cv_safe_to_use_Wconversion_=no])
 246      CFLAGS="$save_CFLAGS"])
 247   dnl disable -Wconversion for now. Will fix later
 248   AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "disabled"],
 249         [
 250           CC_WARNINGS="${CC_WARNINGS} -Wconversion"
 251           CXX_WARNINGS="${CXX_WARNINGS} -Wconversion"
 252         ])
 253
 254   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 255     [ac_cv_safe_to_use_Wlogical_op_],
 256     [save_CFLAGS="$CFLAGS"
 257      CFLAGS="-Wlogical-op"
 258      AC_COMPILE_IFELSE([
 259        AC_LANG_PROGRAM(
 260        [[
 261 #include <stdio>
 262        ]], [[]])
 263     ],
 264     [ac_cv_safe_to_use_Wlogical_op_=yes],
 265     [ac_cv_safe_to_use_Wlogical_op_=no])
 266   CFLAGS="$save_CFLAGS"])
 267   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 268         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 269
 270   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 271     [ac_cv_safe_to_use_Wredundant_decls_],
 272     [AC_LANG_PUSH(C++)
 273      save_CXXFLAGS="${CXXFLAGS}"
 274      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 275      AC_COMPILE_IFELSE(
 276        [AC_LANG_PROGRAM([
 277 template <typename E> struct C { void foo(); };
 278 template <typename E> void C<E>::foo() { }
 279 template <> void C<int>::foo();
 280           AC_INCLUDES_DEFAULT])],
 281         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 282         [ac_cv_safe_to_use_Wredundant_decls_=no])
 283       CXXFLAGS="${save_CXXFLAGS}"
 284       AC_LANG_POP()])
 285   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 286         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 287         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 288
 289   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 290 fi
 291 if test "$SUNCC" = "yes"
 292 then
 293
 294   AS_IF([test "$ac_profiling" = "yes"],
 295         [CC_PROFILING="-xinstrument=datarace"])
 296
 297   AS_IF([test "$ac_warn_fail" = "yes"],
 298         [W_FAIL="-errwarn=%all"])
 299
 300   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 301     [ac_cv_paste_result],
 302     [
 303       save_CFLAGS="${CFLAGS}"
 304       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 305       AC_COMPILE_IFELSE(
 306         [AC_LANG_PROGRAM([
 307           AC_INCLUDES_DEFAULT
 308         ],[
 309           int x= 0;])],
 310         [ac_cv_paste_result=yes],
 311         [ac_cv_paste_result=no])
 312       CFLAGS="${save_CFLAGS}"
 313     ])
 314   AS_IF([test $ac_cv_paste_result = yes],
 315     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 316
 317
 318   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 319   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 320 fi
 321
 322 AC_SUBST(NO_REDUNDANT_DECLS)
 323
 324 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 325 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 326 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 327
 328 AC_SUBST([AM_CPPFLAGS])
 329 AC_SUBST([AM_CFLAGS])
 330 AC_SUBST([AM_CXXFLAGS])
 331
 332 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 333 CFLAGS=""
 334 CXXFLAGS=""
 335 CPPFLAGS=""
 336
 337 AC_CONFIG_FILES([
 338   Makefile
 339   clients/Makefile
 340   tests/Makefile
 341   docs/Makefile
 342   libmemcached/Makefile
 343   libmemcachedutil/Makefile
 344   support/Makefile
 345   support/libmemcached.pc
 346   support/libmemcached.spec
 347   support/libmemcached-fc.spec
 348   ])
 349 AC_OUTPUT