git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # libmemcached
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_PREREQ(2.59)
  10 AC_INIT([libmemcached],[0.46],[http://libmemcached.org/])
  11 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 PANDORA_CANONICAL_TARGET(no-vc-changelog)
  15
  16 #shared library versioning
  17 MEMCACHED_UTIL_LIBRARY_VERSION=1:0:0
  18 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  19 MEMCACHED_LIBRARY_VERSION=6:0:0
  20 #                         | | |
  21 #                  +------+ | +---+
  22 #                  |        |     |
  23 #                 current:revision:age
  24 #                  |        |     |
  25 #                  |        |     +- increment if interfaces have been added
  26 #                  |        |        set to zero if interfaces have been removed or changed
  27 #                  |        +- increment if source code has changed
  28 #                  |           set to zero if current is incremented
  29 #                  +- increment if interfaces have been added, removed or changed
  30 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  31 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  32 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  33
  34
  35 HASHKIT_LIBRARY_VERSION=0:0:0
  36 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  37
  38 AH_TOP([
  39 #ifndef CONFIG_H
  40 #define CONFIG_H
  41
  42 #ifdef _SYS_FEATURE_TESTS_H
  43 #error "You should include config.h as your first include file"
  44 #endif
  45
  46 #ifdef WIN32
  47 #define _WIN32_WINNT 0x0501
  48 #endif
  49 ])
  50
  51 AH_BOTTOM([
  52 #ifdef HAVE_SYS_WAIT_H
  53 #include <sys/wait.h>
  54 #endif
  55
  56 #ifdef HAVE_FNMATCH_H
  57 #include <fnmatch.h>
  58 #endif
  59
  60 #ifdef HAVE_POLL_H
  61 #include <poll.h>
  62 #else
  63 #include "poll/poll.h"
  64 #endif
  65
  66 /* To hide the platform differences between MS Windows and Unix, I am
  67  * going to use the Microsoft way and #define the Microsoft-specific
  68  * functions to the unix way. Microsoft use a separate subsystem for sockets,
  69  * but Unix normally just use a filedescriptor on the same functions. It is
  70  * a lot easier to map back to the unix way with macros than going the other
  71  * way without side effect ;-)
  72  */
  73 #ifdef WIN32
  74 #include "win32/wrappers.h"
  75 #define get_socket_errno() WSAGetLastError()
  76 #else
  77 #define INVALID_SOCKET -1
  78 #define SOCKET_ERROR -1
  79 #define closesocket(a) close(a)
  80 #define get_socket_errno() errno
  81 #endif
  82 #endif
  83 ])
  84
  85 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  86 AC_SEARCH_LIBS(gethostbyname, nsl)
  87
  88 AC_CHECK_FUNCS([getline])
  89
  90 PANDORA_HAVE_LIBGTEST
  91 PANDORA_HAVE_LIBEVENT
  92 my_saved_libs="$LIBS"
  93 LIBS=
  94 PANDORA_REQUIRE_PTHREAD
  95 LIBS="$my_saved_libs"
  96 PANDORA_CXX_DEMANGLE
  97
  98 dnl Specialty checks
  99 DETECT_BYTEORDER
 100 ENABLE_UTILLIB
 101 SETSOCKOPT_SANITY
 102 ENABLE_HSIEH_HASH
 103 PROTOCOL_BINARY_TEST
 104 WITH_MEMCACHED
 105 ENABLE_DEPRECATED
 106 PANDORA_HAVE_LIBINNODB
 107 PANDORA_PRINT_CALLSTACK
 108 PANDORA_HAVE_SASL
 109
 110 dnl The sasl functions should only be visible if we build with sasl support
 111 AS_IF([test "x$ac_cv_sasl" = "xyes"],
 112       [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"])
 113 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
 114
 115 AC_CHECK_HEADERS([atomic.h])
 116 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
 117       AC_CHECK_FUNCS(atomic_add_64)
 118       AC_CHECK_FUNCS(atomic_add_32)
 119       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
 120             AC_DEFINE([USE_ATOMIC_H],
 121                       [1],
 122                       [Define to true if you want to use functions from atomic.h])])])
 123
 124 AC_ARG_WITH([docs],
 125   [AS_HELP_STRING([--with-docs],
 126     [Generate documentation (yes|no) @<:@default=yes@:>@])],
 127   [with_docs=$withval],
 128   [with_docs=yes])
 129
 130 AS_IF([test "$with_docs" = "yes"],
 131   [
 132     REQUIRE_POD2MAN
 133     REQUIRE_PODCHECKER
 134   ])
 135 AM_CONDITIONAL(BUILD_DOCS, test "$with_docs" = "yes")
 136
 137 AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
 138 AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
 139 AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
 140 AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
 141       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 142        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 143        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 144       ])
 145 DETECT_EAGAIN
 146
 147 AC_CONFIG_FILES([
 148   Makefile
 149   docs/Makefile
 150   libhashkit/configure.h
 151   libmemcached/configure.h
 152   support/libmemcached.pc
 153   support/libmemcached.spec
 154   support/libmemcached-fc.spec
 155   ])
 156 AC_OUTPUT
 157
 158 echo "---"
 159 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 160 echo ""
 161 echo "   * Installation prefix:       $prefix"
 162 echo "   * System type:               $host_vendor-$host_os"
 163 echo "   * Host CPU:                  $host_cpu"
 164 echo "   * C Compiler:                $CC_VERSION"
 165 echo "   * Assertions enabled:        $ac_cv_assert"
 166 echo "   * Debug enabled:             $with_debug"
 167 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 168 echo ""
 169 echo "---"
 170
 171 case "$host_os" in
 172   *freebsd*)
 173     echo "*****"
 174     echo "*"
 175     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 176     echo "*"
 177     echo "*   use 'gmake' To build libmemcached"
 178     echo "*"
 179     echo "*****"
 180   ;;
 181 esac
 182
 183 AS_IF(test "$with_docs" = "no",
 184   [
 185     echo "*****"
 186     echo "*"
 187     echo "*  WARNING: You are not generating any documentation."
 188     echo "*           Please don't ship libmemcached to an end user"
 189     echo "*           without documentation..."
 190     echo "*"
 191     echo "*****"
 192   ])