git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Use the C99 enabling flag found earlier
 101 AS_IF([test "$ac_cv_prog_cc_c99" != "no"],
 102       [CFLAGS="$ac_cv_prog_cc_c99 ${CFLAGS}"])
 103
 104 # Build optimized or debug version ?
 105 # First check for gcc and g++
 106 if test "$GCC" = "yes"
 107 then
 108   CFLAGS="-ggdb3 ${CFLAGS}"
 109   DEBUG_CFLAGS="-O0"
 110   OPTIMIZE_CFLAGS="-O3"
 111 fi
 112 if test "x$SUNCC" = "xyes"
 113 then
 114    CFLAGS="-g -mt ${CFLAGS}"
 115    CXXFLAGS="-g -mt -xlang=c99 ${CXXFLAGS}"
 116    OPTIMIZE_CFLAGS="-xO4 -xlibmil -xdepend -Xa -xstrconst"
 117 fi
 118
 119 SOLARIS_64BIT
 120
 121 #--------------------------------------------------------------------
 122 # Check for libpthread
 123 #--------------------------------------------------------------------
 124
 125 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 126 LIBS="${PTHREAD_LIBS} ${LIBS}"
 127 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 128 CC="$PTHREAD_CC"
 129
 130
 131 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 132 AC_SEARCH_LIBS(socket, socket)
 133 AC_SEARCH_LIBS(gethostbyname, nsl)
 134
 135 save_LIBS="$LIBS"
 136 LIBS="$LIBS -lm"
 137 AC_LINK_IFELSE(
 138   [AC_LANG_PROGRAM(
 139     [[
 140 #include <stdlib.h>
 141     ]],[[
 142       float f= floorf((float) 1.0);
 143     ]],
 144     [LIBM="-lm"],[LIBM=""])])
 145
 146 AC_SUBST(LIBM)
 147 LIBS="$save_LIBS"
 148
 149 AC_SEARCH_LIBS(floorf, m)
 150
 151 dnl Specialty checks
 152 DETECT_BYTEORDER
 153 ENABLE_UTILLIB
 154 ENABLE_DTRACE
 155 SETSOCKOPT_SANITY
 156 ENABLE_HSIEH_HASH
 157 REQUIRE_POD2MAN
 158 PROTOCOL_BINARY_TEST
 159 WITH_MEMCACHED
 160
 161 dnl TODO: Remove this define once we are using 2.61 across the board.
 162 # AX_HEADER_ASSERT
 163 # ----------------
 164 # Check whether to enable assertions.
 165 AC_DEFUN([AX_HEADER_ASSERT],
 166 [
 167   AC_MSG_CHECKING([whether to enable assertions])
 168   AC_ARG_ENABLE([assert],
 169     [AS_HELP_STRING([--disable-assert],
 170        [Turn off assertions])],
 171     [ac_cv_assert="no"],
 172     [ac_cv_assert="yes"])
 173   AC_MSG_RESULT([$ac_cv_assert])
 174 ])
 175 AX_HEADER_ASSERT
 176
 177
 178 AC_ARG_WITH([debug],
 179     [AS_HELP_STRING([--with-debug],
 180        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 181     [with_debug=$withval],
 182     [with_debug=no])
 183 if test "$with_debug" = "yes"
 184 then
 185   # Debugging. No optimization.
 186   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 187 else
 188   # Optimized version. No debug
 189   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 190 fi
 191
 192 AC_ARG_ENABLE([profiling],
 193     [AS_HELP_STRING([--enable-profiling],
 194        [Toggle profiling @<:@default=off@:>@])],
 195     [ac_profiling="$enableval"],
 196     [ac_profiling="no"])
 197
 198 AC_ARG_ENABLE([coverage],
 199     [AS_HELP_STRING([--enable-coverage],
 200        [Toggle coverage @<:@default=off@:>@])],
 201     [ac_coverage="$enableval"],
 202     [ac_coverage="no"])
 203
 204 dnl We can't do this warning, so turn off
 205 W_STRICT_ALIASING="-Wno-strict-aliasing"
 206
 207 if test "$GCC" = "yes"
 208 then
 209
 210
 211   AS_IF([test "$ac_profiling" = "yes"],
 212         [CC_PROFILING="-pg"])
 213
 214   AS_IF([test "$ac_coverage" = "yes"],
 215         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 216
 217   AS_IF([test "$building_from_bzr" = "yes"],
 218         [W_FAIL="-Werror"])
 219
 220   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef  -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} -fdiagnostics-show-option"
 221   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align -Wconversion"
 222   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long -Wconversion"
 223
 224   AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 225     [ac_cv_safe_to_use_Wconversion_],
 226     [save_CFLAGS="$CFLAGS"
 227      CFLAGS="${CC_WARNINGS} ${CFLAGS}"
 228      AC_COMPILE_IFELSE(
 229        [AC_LANG_PROGRAM(
 230          [[
 231 #include <netinet/in.h>
 232          ]],[[
 233 size_t source_port= 80;
 234 uint16_t x= htons((uint16_t)source_port);
 235          ]])],
 236        [ac_cv_safe_to_use_Wconversion_=yes],
 237        [ac_cv_safe_to_use_Wconversion_=no])
 238      CFLAGS="$save_CFLAGS"])
 239
 240   AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 241         [
 242           NO_CONVERSION="-Wno-conversion"
 243         ])
 244
 245
 246   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 247     [ac_cv_safe_to_use_Wlogical_op_],
 248     [save_CFLAGS="$CFLAGS"
 249      CFLAGS="-Wlogical-op"
 250      AC_COMPILE_IFELSE([
 251        AC_LANG_PROGRAM(
 252        [[
 253 #include <stdio>
 254        ]], [[]])
 255     ],
 256     [ac_cv_safe_to_use_Wlogical_op_=yes],
 257     [ac_cv_safe_to_use_Wlogical_op_=no])
 258   CFLAGS="$save_CFLAGS"])
 259   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 260         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 261
 262   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 263     [ac_cv_safe_to_use_Wredundant_decls_],
 264     [AC_LANG_PUSH(C++)
 265      save_CXXFLAGS="${CXXFLAGS}"
 266      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 267      AC_COMPILE_IFELSE(
 268        [AC_LANG_PROGRAM([
 269 template <typename E> struct C { void foo(); };
 270 template <typename E> void C<E>::foo() { }
 271 template <> void C<int>::foo();
 272           AC_INCLUDES_DEFAULT])],
 273         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 274         [ac_cv_safe_to_use_Wredundant_decls_=no])
 275       CXXFLAGS="${save_CXXFLAGS}"
 276       AC_LANG_POP()])
 277   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 278         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 279         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 280
 281   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 282 fi
 283 if test "$SUNCC" = "yes"
 284 then
 285
 286   AS_IF([test "$ac_profiling" = "yes"],
 287         [CC_PROFILING="-xinstrument=datarace"])
 288
 289   AS_IF([test "$building_from_bzr" = "yes"],
 290         [W_FAIL="-errwarn=%all"])
 291
 292   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 293     [ac_cv_paste_result],
 294     [
 295       save_CFLAGS="${CFLAGS}"
 296       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 297       AC_COMPILE_IFELSE(
 298         [AC_LANG_PROGRAM([
 299           AC_INCLUDES_DEFAULT
 300         ],[
 301           int x= 0;])],
 302         [ac_cv_paste_result=yes],
 303         [ac_cv_paste_result=no])
 304       CFLAGS="${save_CFLAGS}"
 305     ])
 306   AS_IF([test $ac_cv_paste_result = yes],
 307     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 308
 309
 310   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 311   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 312 fi
 313
 314 AC_SUBST(NO_CONVERSION)
 315 AC_SUBST(NO_REDUNDANT_DECLS)
 316
 317 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 318 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 319 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 320
 321 AC_SUBST([AM_CPPFLAGS])
 322 AC_SUBST([AM_CFLAGS])
 323 AC_SUBST([AM_CXXFLAGS])
 324
 325 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 326 CFLAGS=""
 327 CXXFLAGS=""
 328 CPPFLAGS=""
 329
 330 AC_CONFIG_FILES([
 331   Makefile
 332   clients/Makefile
 333   tests/Makefile
 334   docs/Makefile
 335   libmemcached/Makefile
 336   libmemcachedutil/Makefile
 337   support/Makefile
 338   support/libmemcached.pc
 339   support/libmemcached.spec
 340   support/libmemcached-fc.spec
 341   ])
 342 AC_OUTPUT
 343
 344 echo "---"
 345 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 346 echo ""
 347 echo "   * Installation prefix:       $prefix"
 348 echo "   * System type:               $host_vendor-$host_os"
 349 echo "   * Host CPU:                  $host_cpu"
 350 echo "   * C Compiler:                $CC_VERSION"
 351 echo "   * Assertions enabled:        $ac_cv_assert"
 352 echo "   * Debug enabled:             $with_debug"
 353 echo "   * Warnings as failure:       $building_from_bzr"
 354 echo ""
 355 echo "---"
 356