git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # libmemcached
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 #shared library versioning
  16 MEMCACHED_LIBRARY_VERSION=2:0:0
  17 #                         | | |
  18 #                  +------+ | +---+
  19 #                  |        |     |
  20 #                 current:revision:age
  21 #                  |        |     |
  22 #                  |        |     +- increment if interfaces have been added
  23 #                  |        |        set to zero if interfaces have been removed or changed
  24 #                  |        +- increment if source code has changed
  25 #                  |           set to zero if current is incremented
  26 #                  +- increment if interfaces have been added, removed or changed
  27 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  28 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  29 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  30
  31 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  32 SAVE_CFLAGS=${CFLAGS}
  33 SAVE_CXXFLAGS=${CXXFLAGS}
  34 CFLAGS=
  35 CXXFLAGS=
  36
  37 AC_CANONICAL_TARGET
  38
  39 CFLAGS=${SAVE_CFLAGS}
  40 CXXFLAGS=${SAVE_CXXFLAGS}
  41
  42 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  43
  44 if test "x${enable_dependency_tracking}" = "x"
  45 then
  46   enable_dependency_tracking=yes
  47 fi
  48
  49 if test -d "${srcdir}/.bzr"
  50 then
  51   building_from_bzr=yes
  52 else
  53   building_from_bzr=no
  54 fi
  55
  56 AC_PROG_CXX
  57
  58 ACX_USE_SYSTEM_EXTENSIONS
  59
  60 AC_PROG_CPP
  61 AM_PROG_CC_C_O
  62
  63 FORCE_MAC_GCC42
  64 dnl Once we can use a modern autoconf, we can use this
  65 dnl AC_PROG_CC_C99
  66
  67 AC_C_BIGENDIAN
  68 AC_C_CONST
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_FUNC_MALLOC
  72 AC_FUNC_REALLOC
  73
  74 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  75
  76 # We use libtool
  77 AC_PROG_LIBTOOL
  78
  79 AC_MSG_CHECKING("C Compiler version")
  80 if test "$GCC" = "yes"
  81 then
  82   CC_VERSION=`$CC --version | sed 1q`
  83 elif test "$SUNCC" = "yes"
  84 then
  85   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  86 else
  87   CC_VERSION=""
  88 fi
  89 AC_MSG_RESULT("$CC_VERSION")
  90 AC_SUBST(CC_VERSION)
  91
  92 # libmemcached versioning when linked with GNU ld.
  93 if test "$lt_cv_prog_gnu_ld" = "yes"
  94 then
  95     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  96     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  97 fi
  98 AC_SUBST(LD_VERSION_SCRIPT)
  99 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
 100
 101 # Use the C99 enabling flag found earlier
 102 AS_IF([test "$ac_cv_prog_cc_c99" != "no"],
 103       [CFLAGS="$ac_cv_prog_cc_c99 ${CFLAGS}"])
 104
 105 # Build optimized or debug version ?
 106 # First check for gcc and g++
 107 if test "$GCC" = "yes"
 108 then
 109
 110   dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
 111   dnl with using AC_CC_STD_C99 above
 112   CC="${CC} -std=gnu99"
 113
 114   CFLAGS="-ggdb3 ${CFLAGS}"
 115   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 116
 117   DEBUG_CFLAGS="-O0"
 118   DEBUG_CXXFLAGS="-O0"
 119
 120   OPTIMIZE_CFLAGS="-O3"
 121   OPTIMIZE_CXXFLAGS="-O3"
 122 fi
 123 if test "x$SUNCC" = "xyes"
 124 then
 125   dnl Once we can use a modern autoconf, we can replace the -xc99=all here
 126   dnl with using AC_CC_STD_C99 above
 127   CC="${CC} -xc99=all"
 128
 129   CFLAGS="-g -mt ${CFLAGS}"
 130   CXXFLAGS="-xlang=c99 -g -mt -compat=5 -library=stlport4 -template=no%extdef ${CXXFLAGS}"
 131
 132   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin"
 133   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 134   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 135
 136 fi
 137
 138 ENABLE_64BIT
 139
 140 #--------------------------------------------------------------------
 141 # Check for libpthread
 142 #--------------------------------------------------------------------
 143
 144 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 145 LIBS="${PTHREAD_LIBS} ${LIBS}"
 146 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 147 CC="$PTHREAD_CC"
 148
 149
 150 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 151 AC_SEARCH_LIBS(socket, socket)
 152 AC_SEARCH_LIBS(gethostbyname, nsl)
 153
 154 save_LIBS="$LIBS"
 155 LIBS="$LIBS -lm"
 156 AC_LINK_IFELSE(
 157   [AC_LANG_PROGRAM(
 158     [[
 159 #include <stdlib.h>
 160     ]],[[
 161       float f= floorf((float) 1.0);
 162     ]],
 163     [LIBM="-lm"],[LIBM=""])])
 164
 165 AC_SUBST(LIBM)
 166 LIBS="$save_LIBS"
 167
 168 AC_SEARCH_LIBS(floorf, m)
 169
 170 dnl Specialty checks
 171 DETECT_BYTEORDER
 172 ENABLE_UTILLIB
 173 ENABLE_DTRACE
 174 SETSOCKOPT_SANITY
 175 ENABLE_HSIEH_HASH
 176 REQUIRE_POD2MAN
 177 PROTOCOL_BINARY_TEST
 178 WITH_MEMCACHED
 179
 180 dnl TODO: Remove this define once we are using 2.61 across the board.
 181 # AX_HEADER_ASSERT
 182 # ----------------
 183 # Check whether to enable assertions.
 184 AC_DEFUN([AX_HEADER_ASSERT],
 185 [
 186   AC_MSG_CHECKING([whether to enable assertions])
 187   AC_ARG_ENABLE([assert],
 188     [AS_HELP_STRING([--disable-assert],
 189        [Turn off assertions])],
 190     [ac_cv_assert="no"],
 191     [ac_cv_assert="yes"])
 192   AC_MSG_RESULT([$ac_cv_assert])
 193 ])
 194 AX_HEADER_ASSERT
 195
 196
 197 AC_ARG_WITH([debug],
 198     [AS_HELP_STRING([--with-debug],
 199        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 200     [with_debug=$withval],
 201     [with_debug=no])
 202 if test "$with_debug" = "yes"
 203 then
 204   # Debugging. No optimization.
 205   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 206   CXXFLAGS="${DEBUG_CXXFLAGS} -DDEBUG ${CXXFLAGS}"
 207 else
 208   # Optimized version. No debug
 209   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 210   CXXFLAGS="${OPTIMIZE_CXXFLAGS} ${CXXFLAGS}"
 211 fi
 212
 213 AC_ARG_ENABLE([profiling],
 214     [AS_HELP_STRING([--enable-profiling],
 215        [Toggle profiling @<:@default=off@:>@])],
 216     [ac_profiling="$enableval"],
 217     [ac_profiling="no"])
 218
 219 AC_ARG_ENABLE([coverage],
 220     [AS_HELP_STRING([--enable-coverage],
 221        [Toggle coverage @<:@default=off@:>@])],
 222     [ac_coverage="$enableval"],
 223     [ac_coverage="no"])
 224
 225 if test "$GCC" = "yes"
 226 then
 227
 228   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 229     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 230     [save_CFLAGS="$CFLAGS"
 231      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 232      AC_COMPILE_IFELSE(
 233        [AC_LANG_PROGRAM([],[])],
 234        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 235        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 236      CFLAGS="$save_CFLAGS"])
 237
 238   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 239         [
 240           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 241         ])
 242
 243   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 244     [ac_cv_safe_to_use_wconversion_],
 245     [save_CFLAGS="$CFLAGS"
 246      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 247      AC_COMPILE_IFELSE(
 248        [AC_LANG_PROGRAM([[
 249 #include <stdbool.h>
 250 void foo(bool a)
 251 {
 252   (void)a;
 253 }
 254        ]],[[
 255 foo(0);
 256        ]])],
 257        [ac_cv_safe_to_use_wconversion_=yes],
 258        [ac_cv_safe_to_use_wconversion_=no])
 259      CFLAGS="$save_CFLAGS"])
 260
 261   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 262     [W_CONVERSION="-Wconversion"
 263     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 264       [ac_cv_safe_to_use_Wconversion_],
 265       [save_CFLAGS="$CFLAGS"
 266        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 267        AC_COMPILE_IFELSE(
 268          [AC_LANG_PROGRAM(
 269            [[
 270 #include <netinet/in.h>
 271            ]],[[
 272 uint16_t x= htons(80);
 273            ]])],
 274          [ac_cv_safe_to_use_Wconversion_=yes],
 275          [ac_cv_safe_to_use_Wconversion_=no])
 276        CFLAGS="$save_CFLAGS"])
 277
 278     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 279           [
 280             NO_CONVERSION="-Wno-conversion"
 281           ])
 282     ])
 283
 284   W_STRICT_ALIASING="-Wno-strict-aliasing"
 285
 286   AS_IF([test "$ac_profiling" = "yes"],
 287         [CC_PROFILING="-pg"])
 288
 289   AS_IF([test "$ac_coverage" = "yes"],
 290         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 291
 292   AS_IF([test "$building_from_bzr" = "yes"],
 293         [W_FAIL="-Werror"])
 294
 295   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 296   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align"
 297   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wold-style-cast -Weffc++ -Wno-long-long"
 298
 299   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 300     [ac_cv_safe_to_use_Wlogical_op_],
 301     [save_CFLAGS="$CFLAGS"
 302      CFLAGS="-Wlogical-op"
 303      AC_COMPILE_IFELSE([
 304        AC_LANG_PROGRAM(
 305        [[
 306 #include <stdio>
 307        ]], [[]])
 308     ],
 309     [ac_cv_safe_to_use_Wlogical_op_=yes],
 310     [ac_cv_safe_to_use_Wlogical_op_=no])
 311   CFLAGS="$save_CFLAGS"])
 312   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 313         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 314
 315   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 316     [ac_cv_safe_to_use_Wredundant_decls_],
 317     [AC_LANG_PUSH(C++)
 318      save_CXXFLAGS="${CXXFLAGS}"
 319      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 320      AC_COMPILE_IFELSE(
 321        [AC_LANG_PROGRAM([
 322 template <typename E> struct C { void foo(); };
 323 template <typename E> void C<E>::foo() { }
 324 template <> void C<int>::foo();
 325           AC_INCLUDES_DEFAULT])],
 326         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 327         [ac_cv_safe_to_use_Wredundant_decls_=no])
 328       CXXFLAGS="${save_CXXFLAGS}"
 329       AC_LANG_POP()])
 330   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 331         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 332         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 333
 334   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 335 fi
 336 if test "$SUNCC" = "yes"
 337 then
 338
 339   AS_IF([test "$ac_profiling" = "yes"],
 340         [CC_PROFILING="-xinstrument=datarace"])
 341
 342   AS_IF([test "$building_from_bzr" = "yes"],
 343         [W_FAIL="-errwarn=%all"])
 344
 345   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 346     [ac_cv_paste_result],
 347     [
 348       save_CFLAGS="${CFLAGS}"
 349       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 350       AC_COMPILE_IFELSE(
 351         [AC_LANG_PROGRAM([
 352           AC_INCLUDES_DEFAULT
 353         ],[
 354           int x= 0;])],
 355         [ac_cv_paste_result=yes],
 356         [ac_cv_paste_result=no])
 357       CFLAGS="${save_CFLAGS}"
 358     ])
 359   AS_IF([test $ac_cv_paste_result = yes],
 360     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 361
 362
 363   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 364   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 365 fi
 366
 367 AC_SUBST(NO_CONVERSION)
 368 AC_SUBST(NO_REDUNDANT_DECLS)
 369
 370 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 371 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 372 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 373
 374 AC_SUBST([AM_CPPFLAGS])
 375 AC_SUBST([AM_CFLAGS])
 376 AC_SUBST([AM_CXXFLAGS])
 377
 378 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 379 CFLAGS=""
 380 CXXFLAGS=""
 381 CPPFLAGS=""
 382
 383 AC_CONFIG_FILES([
 384   Makefile
 385   clients/Makefile
 386   tests/Makefile
 387   docs/Makefile
 388   libmemcached/Makefile
 389   libmemcachedutil/Makefile
 390   support/Makefile
 391   support/libmemcached.pc
 392   support/libmemcached.spec
 393   support/libmemcached-fc.spec
 394   ])
 395 AC_OUTPUT
 396
 397 echo "---"
 398 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 399 echo ""
 400 echo "   * Installation prefix:       $prefix"
 401 echo "   * System type:               $host_vendor-$host_os"
 402 echo "   * Host CPU:                  $host_cpu"
 403 echo "   * C Compiler:                $CC_VERSION"
 404 echo "   * Assertions enabled:        $ac_cv_assert"
 405 echo "   * Debug enabled:             $with_debug"
 406 echo "   * Warnings as failure:       $building_from_bzr"
 407 echo ""
 408 echo "---"
 409