git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # Gearman server and library
   2 # Copyright (C) 2008 Brian Aker
   3 # All rights reserved.
   4 #
   5 # Use and distribution licensed under the BSD license.  See
   6 # the COPYING file in this directory for full text.
   7
   8 AC_PREREQ(2.59)
   9 AC_INIT([libmemcached],[0.30],[http://tangent.org/552/libmemcached.html])
  10 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  11 AC_CONFIG_AUX_DIR(config)
  12 AM_CONFIG_HEADER(libmemcached/libmemcached_config.h)
  13
  14 #shared library versioning
  15 MEMCACHED_LIBRARY_VERSION=2:0:0
  16 #                         | | |
  17 #                  +------+ | +---+
  18 #                  |        |     |
  19 #                 current:revision:age
  20 #                  |        |     |
  21 #                  |        |     +- increment if interfaces have been added
  22 #                  |        |        set to zero if interfaces have been removed or changed
  23 #                  |        +- increment if source code has changed
  24 #                  |           set to zero if current is incremented
  25 #                  +- increment if interfaces have been added, removed or changed
  26 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  27 MEMCACHEDUTIL_LIBRARY_VERSION=0:0:0
  28 AC_SUBST(MEMCACHEDUTIL_LIBRARY_VERSION)
  29
  30 # Setting CFLAGS here prevents AC_CANONICAL_TARGET from injecting them
  31 SAVE_CFLAGS=${CFLAGS}
  32 SAVE_CXXFLAGS=${CXXFLAGS}
  33 CFLAGS=
  34 CXXFLAGS=
  35
  36 AC_CANONICAL_TARGET
  37
  38 CFLAGS=${SAVE_CFLAGS}
  39 CXXFLAGS=${SAVE_CXXFLAGS}
  40
  41 AM_INIT_AUTOMAKE([-Wall -Werror nostdinc subdir-objects])
  42
  43 if test "x${enable_dependency_tracking}" = "x"
  44 then
  45   enable_dependency_tracking=yes
  46 fi
  47
  48 if test -d "${srcdir}/.bzr"
  49 then
  50   building_from_bzr=yes
  51 else
  52   building_from_bzr=no
  53 fi
  54
  55 AC_PROG_CC
  56 AC_PROG_CC_C99
  57 AM_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 ACX_USE_SYSTEM_EXTENSIONS
  61
  62 AC_PROG_CPP
  63 AM_PROG_CC_C_O
  64
  65 AC_C_BIGENDIAN
  66 AC_C_CONST
  67 AC_HEADER_TIME
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_FUNC_MALLOC
  71 AC_FUNC_REALLOC
  72
  73 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  74
  75 # We use libtool
  76 AC_PROG_LIBTOOL
  77
  78 AC_MSG_CHECKING("C Compiler version")
  79 if test "$GCC" = "yes"
  80 then
  81   CC_VERSION=`$CC --version | sed 1q`
  82 elif test "$SUNCC" = "yes"
  83 then
  84   CC_VERSION=`$CC -V 2>&1 | sed 1q`
  85 else
  86   CC_VERSION=""
  87 fi
  88 AC_MSG_RESULT("$CC_VERSION")
  89 AC_SUBST(CC_VERSION)
  90
  91 # libmemcached versioning when linked with GNU ld.
  92 if test "$lt_cv_prog_gnu_ld" = "yes"
  93 then
  94     LD_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcached/libmemcached.ver"
  95     LD_UTIL_VERSION_SCRIPT="-Wl,--version-script=\$(top_srcdir)/libmemcachedutil/libmemcachedutil.ver"
  96 fi
  97 AC_SUBST(LD_VERSION_SCRIPT)
  98 AC_SUBST(LD_UTIL_VERSION_SCRIPT)
  99
 100 # Use the C99 enabling flag found earlier
 101 AS_IF([test "$ac_cv_prog_cc_c99" != "no"],
 102       [CFLAGS="$ac_cv_prog_cc_c99 ${CFLAGS}"])
 103
 104 # Build optimized or debug version ?
 105 # First check for gcc and g++
 106 if test "$GCC" = "yes"
 107 then
 108   CFLAGS="-ggdb3 ${CFLAGS}"
 109   CXXFLAGS="-ggdb3 ${CXXFLAGS}"
 110
 111   DEBUG_CFLAGS="-O0"
 112   DEBUG_CXXFLAGS="-O0"
 113
 114   OPTIMIZE_CFLAGS="-O3"
 115   OPTIMIZE_CXXFLAGS="-O3"
 116 fi
 117 if test "x$SUNCC" = "xyes"
 118 then
 119   CFLAGS="-g -mt ${CFLAGS}"
 120   CXXFLAGS="-g -mt -xlang=c99 ${CXXFLAGS}"
 121
 122   OPTIMIZE_FLAGS="-xO4 -xlibmil -xdepend -xbuiltin -lmopt"
 123   OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS} -Xa -xstrconst"
 124   OPTIMIZE_CXXFLAGS="${OPTIMIZE_FLAGS}"
 125
 126 fi
 127
 128 ENABLE_64BIT
 129
 130 #--------------------------------------------------------------------
 131 # Check for libpthread
 132 #--------------------------------------------------------------------
 133
 134 ACX_PTHREAD(,AC_MSG_ERROR(could not find libpthread))
 135 LIBS="${PTHREAD_LIBS} ${LIBS}"
 136 CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
 137 CC="$PTHREAD_CC"
 138
 139
 140 AC_SEARCH_LIBS(getopt_long, gnugetopt)
 141 AC_SEARCH_LIBS(socket, socket)
 142 AC_SEARCH_LIBS(gethostbyname, nsl)
 143
 144 save_LIBS="$LIBS"
 145 LIBS="$LIBS -lm"
 146 AC_LINK_IFELSE(
 147   [AC_LANG_PROGRAM(
 148     [[
 149 #include <stdlib.h>
 150     ]],[[
 151       float f= floorf((float) 1.0);
 152     ]],
 153     [LIBM="-lm"],[LIBM=""])])
 154
 155 AC_SUBST(LIBM)
 156 LIBS="$save_LIBS"
 157
 158 AC_SEARCH_LIBS(floorf, m)
 159
 160 dnl Specialty checks
 161 DETECT_BYTEORDER
 162 ENABLE_UTILLIB
 163 ENABLE_DTRACE
 164 SETSOCKOPT_SANITY
 165 ENABLE_HSIEH_HASH
 166 REQUIRE_POD2MAN
 167 PROTOCOL_BINARY_TEST
 168 WITH_MEMCACHED
 169
 170 dnl TODO: Remove this define once we are using 2.61 across the board.
 171 # AX_HEADER_ASSERT
 172 # ----------------
 173 # Check whether to enable assertions.
 174 AC_DEFUN([AX_HEADER_ASSERT],
 175 [
 176   AC_MSG_CHECKING([whether to enable assertions])
 177   AC_ARG_ENABLE([assert],
 178     [AS_HELP_STRING([--disable-assert],
 179        [Turn off assertions])],
 180     [ac_cv_assert="no"],
 181     [ac_cv_assert="yes"])
 182   AC_MSG_RESULT([$ac_cv_assert])
 183 ])
 184 AX_HEADER_ASSERT
 185
 186
 187 AC_ARG_WITH([debug],
 188     [AS_HELP_STRING([--with-debug],
 189        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
 190     [with_debug=$withval],
 191     [with_debug=no])
 192 if test "$with_debug" = "yes"
 193 then
 194   # Debugging. No optimization.
 195   CFLAGS="${DEBUG_CFLAGS} -DDEBUG ${CFLAGS}"
 196 else
 197   # Optimized version. No debug
 198   CFLAGS="${OPTIMIZE_CFLAGS} ${CFLAGS}"
 199 fi
 200
 201 AC_ARG_ENABLE([profiling],
 202     [AS_HELP_STRING([--enable-profiling],
 203        [Toggle profiling @<:@default=off@:>@])],
 204     [ac_profiling="$enableval"],
 205     [ac_profiling="no"])
 206
 207 AC_ARG_ENABLE([coverage],
 208     [AS_HELP_STRING([--enable-coverage],
 209        [Toggle coverage @<:@default=off@:>@])],
 210     [ac_coverage="$enableval"],
 211     [ac_coverage="no"])
 212
 213 dnl We can't do this warning, so turn off
 214 W_STRICT_ALIASING="-Wno-strict-aliasing"
 215
 216 if test "$GCC" = "yes"
 217 then
 218
 219   AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
 220     [ac_cv_safe_to_use_fdiagnostics_show_option_],
 221     [save_CFLAGS="$CFLAGS"
 222      CFLAGS="-fdiagnostics-show-option ${CFLAGS}"
 223      AC_COMPILE_IFELSE(
 224        [AC_LANG_PROGRAM([],[])],
 225        [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
 226        [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
 227      CFLAGS="$save_CFLAGS"])
 228
 229   AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
 230         [
 231           F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
 232         ])
 233
 234
 235   AC_CACHE_CHECK([whether it is safe to use -Wconversion],
 236     [ac_cv_safe_to_use_wconversion_],
 237     [save_CFLAGS="$CFLAGS"
 238      CFLAGS="-Werror -Wconversion ${CFLAGS}"
 239      AC_COMPILE_IFELSE(
 240        [AC_LANG_PROGRAM([[
 241 #include <stdbool.h>
 242 void foo(bool a)
 243 {
 244   (void)a;
 245 }
 246        ]],[[
 247 foo(0);
 248        ]])],
 249        [ac_cv_safe_to_use_wconversion_=yes],
 250        [ac_cv_safe_to_use_wconversion_=no])
 251      CFLAGS="$save_CFLAGS"])
 252   AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 253     [W_CONVERSION="-Wconversion"
 254     AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 255       [ac_cv_safe_to_use_Wconversion_],
 256       [save_CFLAGS="$CFLAGS"
 257        CFLAGS="-Werror -Wconversion ${CFLAGS}"
 258        AC_COMPILE_IFELSE(
 259          [AC_LANG_PROGRAM(
 260            [[
 261 #include <netinet/in.h>
 262            ]],[[
 263 uint16_t x= htons(80);
 264            ]])],
 265          [ac_cv_safe_to_use_Wconversion_=yes],
 266          [ac_cv_safe_to_use_Wconversion_=no])
 267        CFLAGS="$save_CFLAGS"])
 268
 269     AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 270           [
 271             NO_CONVERSION="-Wno-conversion"
 272           ])
 273     ])
 274
 275   W_STRICT_ALIASING="-Wno-strict-aliasing"
 276
 277   AS_IF([test "$ac_profiling" = "yes"],
 278         [CC_PROFILING="-pg"])
 279
 280   AS_IF([test "$ac_coverage" = "yes"],
 281         [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
 282
 283   AS_IF([test "$building_from_bzr" = "yes"],
 284         [W_FAIL="-Werror"])
 285
 286   BASE_WARNINGS="-pedantic -W -Wall -Wextra ${W_FAIL} -Wundef -Wshadow -Wmissing-declarations ${W_STRICT_ALIASING} ${F_DIAGNOSTICS_SHOW_OPTION} ${W_CONVERSION}"
 287   CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wswitch-default -Wswitch-enum -Wcast-align -Wconversion"
 288   CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual  -Wnon-virtual-dtor -Wctor-dtor-privacy  -Wold-style-cast -Weffc++ -Wno-long-long -Wconversion"
 289
 290
 291   AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 292     [ac_cv_safe_to_use_Wlogical_op_],
 293     [save_CFLAGS="$CFLAGS"
 294      CFLAGS="-Wlogical-op"
 295      AC_COMPILE_IFELSE([
 296        AC_LANG_PROGRAM(
 297        [[
 298 #include <stdio>
 299        ]], [[]])
 300     ],
 301     [ac_cv_safe_to_use_Wlogical_op_=yes],
 302     [ac_cv_safe_to_use_Wlogical_op_=no])
 303   CFLAGS="$save_CFLAGS"])
 304   AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 305         [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 306
 307   AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 308     [ac_cv_safe_to_use_Wredundant_decls_],
 309     [AC_LANG_PUSH(C++)
 310      save_CXXFLAGS="${CXXFLAGS}"
 311      CXXFLAGS="${CXXFLAGS} ${W_FAIL} -Wredundant-decls"
 312      AC_COMPILE_IFELSE(
 313        [AC_LANG_PROGRAM([
 314 template <typename E> struct C { void foo(); };
 315 template <typename E> void C<E>::foo() { }
 316 template <> void C<int>::foo();
 317           AC_INCLUDES_DEFAULT])],
 318         [ac_cv_safe_to_use_Wredundant_decls_=yes],
 319         [ac_cv_safe_to_use_Wredundant_decls_=no])
 320       CXXFLAGS="${save_CXXFLAGS}"
 321       AC_LANG_POP()])
 322   AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 323         [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 324         [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 325
 326   NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 327 fi
 328 if test "$SUNCC" = "yes"
 329 then
 330
 331   AS_IF([test "$ac_profiling" = "yes"],
 332         [CC_PROFILING="-xinstrument=datarace"])
 333
 334   AS_IF([test "$building_from_bzr" = "yes"],
 335         [W_FAIL="-errwarn=%all"])
 336
 337   AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 338     [ac_cv_paste_result],
 339     [
 340       save_CFLAGS="${CFLAGS}"
 341       CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 342       AC_COMPILE_IFELSE(
 343         [AC_LANG_PROGRAM([
 344           AC_INCLUDES_DEFAULT
 345         ],[
 346           int x= 0;])],
 347         [ac_cv_paste_result=yes],
 348         [ac_cv_paste_result=no])
 349       CFLAGS="${save_CFLAGS}"
 350     ])
 351   AS_IF([test $ac_cv_paste_result = yes],
 352     [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 353
 354
 355   CC_WARNINGS="-v -errtags=yes ${W_FAIL} -erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 356   CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${W_FAIL}"
 357 fi
 358
 359 AC_SUBST(NO_CONVERSION)
 360 AC_SUBST(NO_REDUNDANT_DECLS)
 361
 362 AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${CPPFLAGS}"
 363 AM_CFLAGS="${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE} ${CFLAGS}"
 364 AM_CXXFLAGS="${CXX_WARNING} ${CC_PROFILING} ${CC_COVERAGE} ${CXXFLAGS}"
 365
 366 AC_SUBST([AM_CPPFLAGS])
 367 AC_SUBST([AM_CFLAGS])
 368 AC_SUBST([AM_CXXFLAGS])
 369
 370 dnl We've collected the flags in AM_*FLAGS now, so blank these.
 371 CFLAGS=""
 372 CXXFLAGS=""
 373 CPPFLAGS=""
 374
 375 AC_CONFIG_FILES([
 376   Makefile
 377   clients/Makefile
 378   tests/Makefile
 379   docs/Makefile
 380   libmemcached/Makefile
 381   libmemcachedutil/Makefile
 382   support/Makefile
 383   support/libmemcached.pc
 384   support/libmemcached.spec
 385   support/libmemcached-fc.spec
 386   ])
 387 AC_OUTPUT
 388
 389 echo "---"
 390 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 391 echo ""
 392 echo "   * Installation prefix:       $prefix"
 393 echo "   * System type:               $host_vendor-$host_os"
 394 echo "   * Host CPU:                  $host_cpu"
 395 echo "   * C Compiler:                $CC_VERSION"
 396 echo "   * Assertions enabled:        $ac_cv_assert"
 397 echo "   * Debug enabled:             $with_debug"
 398 echo "   * Warnings as failure:       $building_from_bzr"
 399 echo ""
 400 echo "---"
 401