git.m6w6.name Git - m6w6/libmemcached/blob - CMake/_Include.cmake

   1
   2 # globals
   3 if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   4     include(CTest)
   5 endif()
   6 include(GNUInstallDirs)
   7 include(CMakePackageConfigHelpers)
   8
   9 if(CMAKE_HOST_SYSTEM_NAME STREQUAL "FreeBSD")
  10     find_program(PKGCONF pkgconf)
  11     if(PKGCONF)
  12         set(PKG_CONFIG_EXECUTABLE ${PKGCONF})
  13     endif()
  14 endif()
  15 find_package(PkgConfig)
  16 set(THREADS_PREFER_PTHREAD_FLAG ON)
  17 find_package(Threads REQUIRED)
  18
  19 # locals
  20 include(InstallPublicHeaders)
  21 include(SafeString)
  22 include(CheckDebug)
  23 include(CheckDecl)
  24 include(CheckDependency)
  25 include(CheckHeader)
  26 include(CheckCompiles)
  27 include(CheckType)
  28 include(CheckStdatomic)
  29 include(TestBigEndian)
  30 include(CheckByteswap)
  31
  32 # configuration
  33
  34 ## debug
  35 check_debug()
  36
  37 ## memaslap
  38 if(ENABLE_MEMASLAP)
  39     check_stdatomic()
  40     check_dependency(LIBEVENT event event.h)
  41     check_decl(getline stdio.h)
  42 endif()
  43
  44 ## dtrace
  45 include(EnableDtrace)
  46 if(ENABLE_DTRACE)
  47     find_package(DTrace)
  48     if(DTRACE_EXECUTABLE)
  49         set(HAVE_DTRACE 1)
  50     else()
  51         message(WARNING "The dtrace command is required to enable dtrace/systemtap support.")
  52     endif()
  53 endif()
  54
  55 ## uuid
  56 if(BUILD_TESTING)
  57     check_dependency(LIBUUID uuid uuid/uuid.h)
  58 endif()
  59
  60 ## sasl
  61 if(ENABLE_SASL)
  62     check_dependency(LIBSASL sasl2 sasl/sasl.h)
  63     if(LIBSASL)
  64         set(LIBMEMCACHED_WITH_SASL_SUPPORT 1)
  65     endif()
  66 endif()
  67
  68 ## hashes
  69 if(ENABLE_HASH_FNV64)
  70     set(HAVE_FNV64_HASH 1)
  71 endif()
  72 if(ENABLE_HASH_MURMUR)
  73     set(HAVE_MURMUR_HASH 1)
  74 endif()
  75 if(ENABLE_HASH_HSIEH)
  76     set(HAVE_HSIEH_HASH 1)
  77 endif()
  78
  79 # system checks
  80
  81 test_big_endian(WORDS_BIGENDIAN)
  82 check_byteswap()
  83
  84 check_header(alloca.h)
  85 check_header(arpa/inet.h)
  86 check_header(dlfcn.h)
  87 check_header(errno.h)
  88 check_header(fcntl.h)
  89 check_header(io.h)
  90 check_header(limits.h)
  91 check_header(netdb.h)
  92 check_header(poll.h)
  93 check_header(stddef.h)
  94 check_header(stdlib.h)
  95 check_header(strings.h)
  96 check_header(sys/socket.h)
  97 check_header(sys/time.h)
  98 check_header(sys/types.h)
  99 check_header(sys/un.h)
 100 check_header(sys/wait.h)
 101 check_header(time.h)
 102 check_header(umem.h)
 103 check_header(unistd.h)
 104 check_header(winsock2.h)
 105 check_header(ws2tcpip.h)
 106
 107 check_decl(fcntl fcntl.h)
 108 check_decl(htonll arpa/inet.h)
 109 check_decl(MSG_DONTWAIT sys/socket.h)
 110 check_decl(MSG_MORE sys/socket.h)
 111 check_decl(MSG_NOSIGNAL sys/socket.h)
 112 check_decl(rcvtimeo sys/socket.h)
 113 check_decl(sndtimeo sys/socket.h)
 114 check_decl(setenv stdlib.h)
 115 check_decl(strerror string.h)
 116 check_decl(strerror_r string.h)
 117
 118 check_compiles(HAVE_STRERROR_R_CHAR_P "char x, y = *strerror_r(0,&x,1);" string.h)
 119
 120 check_decl(abi::__cxa_demangle cxxabi.h)
 121
 122 find_package(Backtrace)
 123 if(Backtrace_FOUND)
 124     set(HAVE_BACKTRACE 1)
 125 endif()
 126
 127 check_type(in_port_t netinet/in.h)
 128
 129 check_header(cstdint)
 130 check_header(cinttypes)