git.m6w6.name Git - m6w6/ext-psi/blob - src/parser_proc_grammar.y

   1 %code top {
   2 #include "php_psi_stdinc.h"
   3 }
   4
   5 %code {
   6 #include <assert.h>
   7 #include <stdarg.h>
   8
   9 #include "plist.h"
  10 #include "parser.h"
  11 #define YYDEBUG 1
  12
  13 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
  14 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
  15
  16 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
  17 {
  18         assert(strct);
  19         if (!P->structs) {
  20                 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
  21         }
  22         P->structs = psi_plist_add(P->structs, &strct);
  23 }
  24 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
  25 {
  26         assert(u);
  27         if (!P->unions) {
  28                 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
  29         }
  30         P->unions = psi_plist_add(P->unions, &u);
  31 }
  32 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
  33 {
  34         assert(e);
  35         if (!P->enums) {
  36                 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
  37         }
  38         P->enums = psi_plist_add(P->enums, &e);
  39 }
  40 static inline void psi_parser_proc_add_from_typedef(struct psi_parser *P, struct psi_decl_arg *def)
  41 {
  42         if (def->type->real.def) {
  43                 switch (def->type->type) {
  44                 case PSI_T_STRUCT:
  45                         psi_parser_proc_add_struct(P, def->type->real.strct);
  46                         break;
  47                 case PSI_T_UNION:
  48                         psi_parser_proc_add_union(P, def->type->real.unn);
  49                         break;
  50                 case PSI_T_ENUM:
  51                         psi_parser_proc_add_enum(P, def->type->real.enm);
  52                         break;
  53                 default:
  54                         break;
  55                 }
  56         }
  57 }
  58 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
  59 {
  60         assert(def);
  61         if (!P->types) {
  62                 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
  63         }
  64         P->types = psi_plist_add(P->types, &def);
  65         psi_parser_proc_add_from_typedef(P, def);
  66 }
  67 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
  68         assert(cnst);
  69         if (!P->consts) {
  70                 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
  71         }
  72         P->consts = psi_plist_add(P->consts, &cnst);
  73
  74 }
  75 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
  76         assert(decl);
  77         if (!P->decls) {
  78                 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
  79         }
  80         P->decls = psi_plist_add(P->decls, &decl);
  81 }
  82 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
  83         assert(impl);
  84         if (!P->impls) {
  85                 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
  86         }
  87         P->impls = psi_plist_add(P->impls, &impl);
  88 }
  89
  90 /* end code */
  91 }
  92
  93 %code requires {
  94 #include "plist.h"
  95 #include "types/layout.h"
  96
  97 struct psi_parser;
  98
  99 }
 100
 101 %require "3.0"
 102 %language "c"
 103 %name-prefix "psi_parser_proc_"
 104 %token-table
 105 %verbose
 106 %glr-parser
 107
 108 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
 109
 110 %define api.pure true
 111 %define api.token.prefix {PSI_T_}
 112 %define api.value.type union
 113
 114 %define parse.error verbose
 115 %define parse.trace true
 116
 117 %initial-action {
 118 }
 119
 120 %start file
 121
 122 %token <struct psi_token *> BOOL
 123 %token <struct psi_token *> CHAR
 124 %token <struct psi_token *> SHORT
 125 %token <struct psi_token *> INT
 126 %token <struct psi_token *> SIGNED
 127 %token <struct psi_token *> UNSIGNED
 128 %token <struct psi_token *> LONG
 129 %token <struct psi_token *> FLOAT
 130 %token <struct psi_token *> DOUBLE
 131 %token <struct psi_token *> STRING
 132 %token <struct psi_token *> MIXED
 133 %token <struct psi_token *> ARRAY
 134 %token <struct psi_token *> OBJECT
 135 %token <struct psi_token *> CALLABLE
 136 %token <struct psi_token *> VOID
 137 %token <struct psi_token *> ZVAL
 138 %token <struct psi_token *> INT8
 139 %token <struct psi_token *> UINT8
 140 %token <struct psi_token *> INT16
 141 %token <struct psi_token *> UINT16
 142 %token <struct psi_token *> INT32
 143 %token <struct psi_token *> UINT32
 144 %token <struct psi_token *> INT64
 145 %token <struct psi_token *> UINT64
 146 %token <struct psi_token *> NULL
 147 %token <struct psi_token *> TRUE
 148 %token <struct psi_token *> FALSE
 149 %token <struct psi_token *> NAME
 150 %token <struct psi_token *> NSNAME
 151 %token <struct psi_token *> DOLLAR_NAME
 152 %token <struct psi_token *> NUMBER
 153 %token <struct psi_token *> QUOTED_STRING
 154 %token <struct psi_token *> QUOTED_CHAR
 155
 156 %token <struct psi_token *> EOF 0               "end of file"
 157 %token <struct psi_token *> EOL                 "end of line"
 158 %token <struct psi_token *> EOS                 ";"
 159 %token <struct psi_token *> LPAREN              "("
 160 %token <struct psi_token *> RPAREN              ")"
 161 %token <struct psi_token *> COMMA               ","
 162 %token <struct psi_token *> COLON               ":"
 163 %token <struct psi_token *> LBRACE              "{"
 164 %token <struct psi_token *> RBRACE              "}"
 165 %token <struct psi_token *> LBRACKET    "["
 166 %token <struct psi_token *> RBRACKET    "]"
 167 %token <struct psi_token *> EQUALS              "="
 168 %token <struct psi_token *> HASH                "#"
 169 %token <struct psi_token *> PIPE                "|"
 170 %token <struct psi_token *> CARET               "^"
 171 %token <struct psi_token *> AMPERSAND   "&"
 172 %token <struct psi_token *> LSHIFT              "<<"
 173 %token <struct psi_token *> RSHIFT              ">>"
 174 %token <struct psi_token *> PLUS                "+"
 175 %token <struct psi_token *> MINUS               "-"
 176 %token <struct psi_token *> ASTERISK    "*"
 177 %token <struct psi_token *> SLASH               "/"
 178 %token <struct psi_token *> MODULO              "%"
 179 %token <struct psi_token *> LCHEVR              "<"
 180 %token <struct psi_token *> RCHEVR              ">"
 181 %token <struct psi_token *> CMP_GE              ">="
 182 %token <struct psi_token *> CMP_LE              "<="
 183 %token <struct psi_token *> OR                  "||"
 184 %token <struct psi_token *> AND                 "&&"
 185 %token <struct psi_token *> CMP_EQ              "=="
 186 %token <struct psi_token *> CMP_NE              "!="
 187 %token <struct psi_token *> TILDE               "~"
 188 %token <struct psi_token *> NOT                 "!"
 189 %token <struct psi_token *> PERIOD              "."
 190 %token <struct psi_token *> BACKSLASH   "\\"
 191 %token <struct psi_token *> ELLIPSIS    "..."
 192 %token <struct psi_token *> IIF                 "?"
 193
 194 %token <struct psi_token *> PRAGMA
 195 %token <struct psi_token *> PRAGMA_ONCE
 196 %token <struct psi_token *> LINE
 197 %token <struct psi_token *> ERROR
 198 %token <struct psi_token *> WARNING
 199 %token <struct psi_token *> IF
 200 %token <struct psi_token *> IFDEF
 201 %token <struct psi_token *> IFNDEF
 202 %token <struct psi_token *> ELSE
 203 %token <struct psi_token *> ELIF
 204 %token <struct psi_token *> ENDIF
 205 %token <struct psi_token *> DEFINE
 206 %token <struct psi_token *> DEFINED
 207 %token <struct psi_token *> UNDEF
 208 %token <struct psi_token *> IMPORT
 209 %token <struct psi_token *> INCLUDE
 210 %token <struct psi_token *> INCLUDE_NEXT
 211
 212 %token <struct psi_token *> TYPEDEF
 213 %token <struct psi_token *> STRUCT
 214 %token <struct psi_token *> UNION
 215 %token <struct psi_token *> ENUM
 216 %token <struct psi_token *> CONST
 217 %token <struct psi_token *> LIB
 218 %token <struct psi_token *> STATIC
 219 %token <struct psi_token *> CALLBACK
 220 %token <struct psi_token *> FUNCTION
 221 %token <struct psi_token *> LET
 222 %token <struct psi_token *> SET
 223 %token <struct psi_token *> TEMP
 224 %token <struct psi_token *> FREE
 225 %token <struct psi_token *> RETURN
 226 %token <struct psi_token *> PRE_ASSERT
 227 %token <struct psi_token *> POST_ASSERT
 228 %token <struct psi_token *> BOOLVAL
 229 %token <struct psi_token *> INTVAL
 230 %token <struct psi_token *> STRVAL
 231 %token <struct psi_token *> PATHVAL
 232 %token <struct psi_token *> STRLEN
 233 %token <struct psi_token *> FLOATVAL
 234 %token <struct psi_token *> ARRVAL
 235 %token <struct psi_token *> OBJVAL
 236 %token <struct psi_token *> COUNT
 237 %token <struct psi_token *> CALLOC
 238 %token <struct psi_token *> TO_BOOL
 239 %token <struct psi_token *> TO_INT
 240 %token <struct psi_token *> TO_STRING
 241 %token <struct psi_token *> TO_FLOAT
 242 %token <struct psi_token *> TO_ARRAY
 243 %token <struct psi_token *> TO_OBJECT
 244
 245 %token <struct psi_token *> COMMENT
 246 %token <struct psi_token *> WHITESPACE
 247 %token <struct psi_token *> NO_WHITESPACE
 248 %token <struct psi_token *> CPP_HEADER
 249 %token <struct psi_token *> CPP_ATTRIBUTE
 250 %token <struct psi_token *> CPP_EXTENSION
 251 %token <struct psi_token *> CPP_PASTE
 252 %token <struct psi_token *> CPP_RESTRICT
 253 %token <struct psi_token *> CPP_ASM
 254
 255 %precedence IIF COLON
 256 %precedence OR
 257 %precedence AND
 258 %precedence PIPE
 259 %precedence CARET
 260 %precedence AMPERSAND
 261 %precedence CMP_EQ CMP_NE
 262 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
 263 %precedence LSHIFT RSHIFT
 264 %precedence PLUS MINUS
 265 %precedence ASTERISK SLASH MODULO
 266 //%precedence NOT TILDE
 267 %precedence BINARY
 268 %precedence UNARY
 269
 270 %type           <struct psi_token *>                            lib optional_name enum_name struct_name union_name
 271 %destructor     {psi_token_free(&$$);}                          lib optional_name enum_name struct_name union_name
 272
 273 %type           <struct psi_token *>                            cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 274 %destructor     {}                                                                      cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 275
 276 %type           <struct psi_token *>                            name_token any_noeol_token binary_op_token unary_op_token
 277 %destructor     {}                                                                      name_token any_noeol_token binary_op_token unary_op_token
 278
 279 %type           <struct psi_token *>                            int_width int_width_types int_signed_types
 280 %destructor     {psi_token_free(&$$);}                          int_width int_width_types int_signed_types
 281
 282 %type           <struct psi_token *>                            signed_long_types signed_short_types int_signed
 283 %destructor     {}                                                                      signed_long_types signed_short_types int_signed
 284
 285 %type           <struct psi_cpp_exp *>                          cpp cpp_exp
 286 %destructor     {psi_cpp_exp_free(&$$);}                        cpp cpp_exp
 287 %type           <struct psi_cpp_macro_decl *>           cpp_macro_decl
 288 %destructor     {psi_cpp_macro_decl_free(&$$);}         cpp_macro_decl
 289 %type           <struct psi_plist *>                            cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 290 %destructor {psi_plist_free($$);}                               cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 291 %type           <struct psi_num_exp *>                          cpp_macro_exp
 292 %destructor     {psi_num_exp_free(&$$);}                        cpp_macro_exp
 293
 294 %type           <struct psi_token *>                            constant_type_token impl_def_val_token
 295 %destructor     {}                                                                      constant_type_token impl_def_val_token
 296
 297 %type           <struct psi_const *>                            constant
 298 %destructor     {psi_const_free(&$$);}                          constant
 299 %type           <struct psi_const_type *>                       constant_type
 300 %destructor     {psi_const_type_free(&$$);}                     constant_type
 301 %type           <struct psi_impl_def_val *>                     impl_def_val
 302 %destructor     {psi_impl_def_val_free(&$$);}           impl_def_val
 303
 304 %type           <struct psi_token *>                            decl_real_type decl_int_type decl_type_simple
 305 %destructor     {psi_token_free(&$$);}                          decl_real_type decl_int_type decl_type_simple
 306
 307 %type           <struct psi_token *>                            decl_stdint_type
 308 %destructor     {}                                                                      decl_stdint_type
 309
 310 %type           <struct psi_decl_type *>                        decl_type const_decl_type decl_type_complex
 311 %destructor     {psi_decl_type_free(&$$);}                      decl_type const_decl_type decl_type_complex
 312 %type           <struct psi_decl *>                                     decl_stmt decl decl_body decl_func_body decl_functor_body
 313 %destructor     {psi_decl_free(&$$);}                           decl_stmt decl decl_body decl_func_body decl_functor_body
 314 %type           <struct psi_decl_arg *>                         decl_typedef decl_func decl_functor decl_arg typedef
 315 %destructor     {psi_decl_arg_free(&$$);}                       decl_typedef decl_func decl_functor decl_arg typedef
 316 %type           <struct psi_decl_var *>                         decl_var
 317 %destructor     {psi_decl_var_free(&$$);}                       decl_var
 318 %type           <struct psi_decl_struct *>                      decl_struct
 319 %destructor     {psi_decl_struct_free(&$$);}            decl_struct
 320 %type           <struct psi_decl_union *>                       decl_union
 321 %destructor     {psi_decl_union_free(&$$);}                     decl_union
 322 %type           <struct psi_decl_enum *>                        decl_enum
 323 %destructor     {psi_decl_enum_free(&$$);}                      decl_enum
 324 %type           <struct psi_decl_enum_item *>           decl_enum_item
 325 %destructor     {psi_decl_enum_item_free(&$$);}         decl_enum_item
 326 %type           <struct psi_plist *>                            decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 327 %destructor     {psi_plist_free($$);}                           decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 328
 329 %type           <struct psi_layout>                                     align_and_size
 330 %destructor     {}                                                                      align_and_size
 331 %type           <struct psi_layout *>                           decl_layout
 332 %destructor     {psi_layout_free(&$$);}                         decl_layout
 333
 334 %type           <struct psi_impl *>                                     impl
 335 %destructor     {psi_impl_free(&$$);}                           impl
 336 %type           <struct psi_impl_func *>                        impl_func
 337 %destructor     {psi_impl_func_free(&$$);}                      impl_func
 338 %type           <struct psi_impl_arg *>                         impl_arg
 339 %destructor     {psi_impl_arg_free(&$$);}                       impl_arg
 340 %type           <struct psi_impl_type *>                        impl_type
 341 %destructor     {psi_impl_type_free(&$$);}                      impl_type
 342 %type           <struct psi_impl_var *>                         impl_var
 343 %destructor     {psi_impl_var_free(&$$);}                       impl_var
 344
 345 %type           <struct psi_let_stmt *>                         let_stmt
 346 %destructor     {psi_let_stmt_free(&$$);}                       let_stmt
 347 %type           <struct psi_let_exp *>                          let_exp let_exp_byref let_exp_assign
 348 %destructor     {psi_let_exp_free(&$$);}                        let_exp let_exp_byref let_exp_assign
 349 %type           <struct psi_let_calloc *>                       let_calloc
 350 %destructor     {psi_let_calloc_free(&$$);}                     let_calloc
 351 %type           <struct psi_let_callback *>                     let_callback
 352 %destructor     {psi_let_callback_free(&$$);}           let_callback
 353 %type           <struct psi_let_func *>                         let_func
 354 %destructor     {psi_let_func_free(&$$);}                       let_func
 355 %type           <struct psi_set_stmt *>                         set_stmt
 356 %destructor     {psi_set_stmt_free(&$$);}                       set_stmt
 357 %type           <struct psi_set_exp *>                          set_exp
 358 %destructor     {psi_set_exp_free(&$$);}                        set_exp
 359 %type           <struct psi_set_func *>                         set_func
 360 %destructor     {psi_set_func_free(&$$);}                       set_func
 361 %type           <struct psi_assert_stmt *>                      assert_stmt
 362 %destructor     {psi_assert_stmt_free(&$$);}            assert_stmt
 363 %type           <struct psi_return_stmt *>                      return_stmt
 364 %destructor     {psi_return_stmt_free(&$$);}            return_stmt
 365 %type           <struct psi_free_stmt *>                        free_stmt
 366 %destructor     {psi_free_stmt_free(&$$);}                      free_stmt
 367 %type           <struct psi_free_exp *>                         free_exp
 368 %destructor     {psi_free_exp_free(&$$);}                       free_exp
 369
 370 %type           <struct psi_token **>                           impl_stmt
 371 %destructor     {psi_impl_stmt_free(&$$);}                      impl_stmt
 372 %type           <struct psi_token *>                            impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 373 %destructor     {psi_token_free(&$$);}                          impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 374 %type           <struct psi_plist *>                            impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 375 %destructor     {psi_plist_free($$);}                           impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 376
 377 %type           <struct psi_num_exp *>                          num_exp
 378 %destructor     {psi_num_exp_free(&$$);}                        num_exp
 379 %type           <struct psi_number *>                           number
 380 %destructor     {psi_number_free(&$$);}                         number
 381
 382 %type           <size_t>                                                        indirection pointers asterisks array_size
 383 %destructor     {}                                                                      indirection pointers asterisks array_size
 384 %type           <bool>                                                          reference
 385 %destructor     {}                                                                      reference
 386
 387 %%
 388
 389 /* rules */
 390
 391
 392 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
 393 unary_op_token: TILDE | NOT | PLUS | MINUS ;
 394 name_token: NAME | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | let_func_token | set_func_token;
 395 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | INT8 | UINT8 | INT16 | UINT16 | INT32 | UINT32 | INT64 | UINT64 | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM;
 396
 397
 398 file:
 399         %empty
 400 |       blocks
 401 ;
 402 blocks:
 403         block
 404 |       blocks block
 405 ;
 406 block:
 407         EOS
 408 |       EOL
 409 |       COMMENT
 410 |       cpp {
 411         if ($cpp) {
 412                 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
 413                 psi_cpp_exp_free(&$cpp);
 414         }
 415 }
 416 |       lib {
 417         if (P->file.ln) {
 418                 P->error(PSI_DATA(P), $lib, PSI_WARNING,
 419                                 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
 420         } else {
 421                 P->file.ln = strndup($lib->text, $lib->size);
 422         }
 423 }
 424 |       constant {
 425         psi_parser_proc_add_const(P, $constant);
 426 }
 427 |       decl_stmt {
 428         psi_parser_proc_add_decl(P, $decl_stmt);
 429 }
 430 |       decl_ext_var_stmt
 431 |       decl_typedef[def] {
 432         psi_parser_proc_add_typedef(P, $def);
 433 }
 434 |       decl_struct[struct] {
 435         psi_parser_proc_add_struct(P, $struct);
 436 }
 437 |       decl_union[union] {
 438         psi_parser_proc_add_union(P, $union);
 439 }
 440 |       decl_enum[enum] {
 441         psi_parser_proc_add_enum(P, $enum);
 442 }
 443 |       impl {
 444         psi_parser_proc_add_impl(P, $impl);
 445 }
 446 ;
 447
 448 lib:
 449         LIB QUOTED_STRING EOS {
 450         $lib = $QUOTED_STRING;
 451 }
 452 ;
 453
 454 cpp:
 455         HASH EOL {
 456         $cpp = NULL;
 457 }
 458 |       HASH cpp_exp[exp] EOL {
 459         $cpp = $exp;
 460 }
 461 ;
 462
 463 cpp_exp[exp]:
 464         cpp_message_token cpp_macro_decl_tokens[tokens] {
 465         if ($tokens) {
 466                 struct psi_token *msg = NULL;
 467
 468                 if (psi_plist_get($tokens, 0, &msg)) {
 469                         size_t index = 1;
 470                         struct psi_token *next;
 471
 472                         msg = psi_token_copy(msg);
 473                         while (psi_plist_get($tokens, index++, &next)) {
 474                                 struct psi_token *old = msg;
 475                                 msg = psi_token_cat(" ", 2, msg, next);
 476                                 free(old);
 477                         }
 478                 }
 479                 psi_plist_free($tokens);
 480
 481                 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
 482         } else {
 483                 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
 484         }
 485         $exp->token = psi_token_copy($cpp_message_token);
 486 }
 487 |       cpp_include_token[INCLUDE] cpp_header_token {
 488         $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
 489         $exp->token = psi_token_copy($INCLUDE);
 490 }
 491 |       cpp_no_arg_token {
 492         $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
 493         $exp->token = psi_token_copy($cpp_no_arg_token);
 494 }
 495 |       cpp_name_arg_token cpp_special_name_token[name_token] {
 496         $name_token->type = PSI_T_NAME;
 497         $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
 498         $exp->token = psi_token_copy($cpp_name_arg_token);
 499 }
 500 |       DEFINE cpp_macro_decl {
 501         $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
 502         $exp->token = psi_token_copy($DEFINE);
 503 }
 504 |       cpp_exp_arg_token cpp_macro_exp {
 505         $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
 506         $exp->token = psi_token_copy($cpp_exp_arg_token);
 507 }
 508 |       PRAGMA_ONCE {
 509         $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
 510         $exp->token = psi_token_copy($PRAGMA_ONCE);
 511 }
 512 |       cpp_ignored_token cpp_macro_decl_tokens[tokens] {
 513         psi_plist_free($tokens);
 514         $exp = NULL;
 515 }
 516 ;
 517
 518 cpp_ignored_token:
 519         LINE
 520 |       PRAGMA
 521 ;
 522
 523 cpp_message_token:
 524         ERROR
 525 |       WARNING
 526 ;
 527
 528 cpp_include_token:
 529         IMPORT
 530 |       INCLUDE
 531 |       INCLUDE_NEXT
 532 ;
 533
 534 cpp_header_token:
 535         QUOTED_STRING
 536 |       CPP_HEADER
 537 ;
 538
 539 cpp_no_arg_token:
 540         ELSE
 541 |       ENDIF
 542 ;
 543
 544 cpp_name_arg_token:
 545         IFDEF
 546 |       IFNDEF
 547 |       UNDEF
 548 ;
 549
 550 cpp_exp_arg_token:
 551         IF
 552 |       ELIF
 553 ;
 554
 555 cpp_special_name_token:
 556         name_token
 557 |       NULL
 558 |       TRUE
 559 |       FALSE
 560 |       CPP_RESTRICT
 561 |       CPP_EXTENSION
 562 ;
 563
 564 cpp_macro_decl[macro]:
 565         name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
 566         $name_token->type = PSI_T_NAME;
 567         $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
 568         $macro->token = psi_token_copy($name_token);
 569 }
 570 |       cpp_special_name_token[name_token] cpp_macro_decl_tokens {
 571         $name_token->type = PSI_T_NAME;
 572         $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
 573         $macro->token = psi_token_copy($name_token);
 574 }
 575 ;
 576
 577 cpp_macro_sig[sig]:
 578         %empty {
 579         $sig = psi_plist_init(NULL);
 580 }
 581 |       cpp_macro_sig_args
 582 ;
 583
 584 cpp_macro_sig_args[args]:
 585         name_token {
 586         $name_token = psi_token_copy($name_token);
 587         $name_token->type = PSI_T_NAME;
 588         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
 589 }
 590 |       cpp_macro_sig_args[args_] COMMA name_token {
 591         $name_token = psi_token_copy($name_token);
 592         $name_token->type = PSI_T_NAME;
 593         $args = psi_plist_add($args_, &$name_token);
 594 }
 595 ;
 596
 597 cpp_macro_decl_tokens[tokens]:
 598         %empty {
 599         $tokens = NULL;
 600 }
 601 | cpp_macro_decl_token_list
 602 ;
 603
 604 cpp_macro_decl_token_list[tokens]:
 605         any_noeol_token[token] {
 606         $token = psi_token_copy($token);
 607         $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
 608 }
 609 |       cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
 610         $token = psi_token_copy($token);
 611         $tokens = psi_plist_add($tokens_, &$token);
 612 }
 613 ;
 614
 615 cpp_macro_exp[exp]:
 616         LPAREN cpp_macro_exp[exp_] RPAREN {
 617         $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
 618         $exp->token = psi_token_copy($LPAREN);
 619 }
 620 |       unary_op_token cpp_macro_exp[exp_] %prec UNARY {
 621         $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
 622         $exp->token = psi_token_copy($unary_op_token);
 623 }
 624 |       cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
 625         $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
 626         $exp->token = psi_token_copy($binary_op_token);
 627 }
 628 |       cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
 629         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
 630         $exp->token = psi_token_copy($IIF);
 631 }
 632
 633 |       DEFINED name_token {
 634         {
 635                 uint8_t exists;
 636
 637                 $name_token->type = PSI_T_NAME;
 638                 exists = psi_cpp_defined(P->preproc, $name_token);
 639                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 640                 $exp->token = psi_token_copy($name_token);
 641         }
 642 }
 643 |       DEFINED LPAREN name_token RPAREN {
 644         {
 645                 uint8_t exists;
 646
 647                 $name_token->type = PSI_T_NAME;
 648                 exists = psi_cpp_defined(P->preproc, $name_token);
 649                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 650                 $exp->token = psi_token_copy($name_token);
 651         }
 652 }
 653 |       NUMBER {
 654         $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
 655         $exp->token = psi_token_copy($NUMBER);
 656         $exp->data.n->token = psi_token_copy($NUMBER);
 657 }
 658 |       QUOTED_CHAR {
 659         $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
 660         $exp->token = psi_token_copy($QUOTED_CHAR);
 661         $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
 662 }
 663 |       name_token {
 664         $name_token->type = PSI_T_NAME;
 665         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
 666         $exp->token = psi_token_copy($name_token);
 667         $exp->data.n->token = psi_token_copy($name_token);
 668 }
 669 |       name_token LPAREN cpp_macro_call_args RPAREN {
 670         $name_token->type = PSI_T_NAME;
 671         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
 672                 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
 673         $exp->token = psi_token_copy($name_token);
 674 }
 675 ;
 676
 677 cpp_macro_call_args[args]:
 678         %empty {
 679         $args = NULL;
 680 }
 681 |       cpp_macro_call_arg_list
 682 ;
 683
 684 cpp_macro_call_arg_list[args]:
 685         cpp_macro_exp {
 686         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
 687                 &$cpp_macro_exp);
 688 }
 689 |       cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
 690         $args = psi_plist_add($args_, &$cpp_macro_exp);
 691 }
 692 ;
 693
 694 constant[const]:
 695         CONST constant_type NSNAME EQUALS impl_def_val EOS {
 696         $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
 697         $const->token = psi_token_copy($NSNAME);
 698 }
 699 ;
 700
 701 constant_type[type]:
 702         constant_type_token[token] {
 703         $type = psi_const_type_init($token->type, $token->text);
 704 }
 705 ;
 706
 707 constant_type_token:
 708         BOOL
 709 |       INT
 710 |       FLOAT
 711 |       STRING
 712 ;
 713
 714 impl_def_val[val]:
 715         %empty {
 716         $val = NULL;
 717 }
 718 |       impl_def_val_token[token] {
 719         $val = psi_impl_def_val_init($token->type, $token->text);
 720         $val->token = psi_token_copy($token);
 721 }
 722 ;
 723
 724 impl_def_val_token:
 725         NULL
 726 |       NUMBER
 727 |       TRUE
 728 |       FALSE
 729 |       QUOTED_STRING
 730 ;
 731
 732 decl_typedef[def]:
 733         TYPEDEF typedef[def_] EOS {
 734         $def = $def_;
 735 }
 736 ;
 737
 738 typedef[def]:
 739         decl_arg
 740 |       decl_func_body[decl] {
 741         $def = psi_decl_arg_init(
 742                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
 743                 psi_decl_var_copy($decl->func->var)
 744         );
 745         $def->type->token = psi_token_copy($decl->func->token);
 746         $def->type->real.func = $decl;
 747 }
 748 |       decl_enum[enum] name_token {
 749         $name_token->type = PSI_T_NAME;
 750         $def = psi_decl_arg_init(
 751                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 752                 psi_decl_var_init($name_token->text, 0, 0)
 753         );
 754         $def->var->token = psi_token_copy($name_token);
 755         $def->type->token = psi_token_copy($enum->token);
 756         $def->type->real.enm = $enum;
 757 }
 758 |       struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
 759         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
 760         $def->type->token = $struct;
 761         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 762         $def->type->real.strct->token = psi_token_copy($struct);
 763         $def->type->real.strct->align = $as.pos;
 764         $def->type->real.strct->size = $as.len;
 765 }
 766 |       union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
 767         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
 768         $def->type->token = $union;
 769         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 770         $def->type->real.unn->token = psi_token_copy($union);
 771         $def->type->real.unn->align = $as.pos;
 772         $def->type->real.unn->size = $as.len;
 773 }
 774 |       const_decl_type[type] decl_stdint_type[stdint] {
 775         $stdint->type = PSI_T_NAME;
 776         $def = psi_decl_arg_init($type, psi_decl_var_init($stdint->text, 0, 0));
 777         $def->var->token = psi_token_copy($stdint);
 778 }
 779 ;
 780
 781 const_decl_type[type]:
 782         CONST decl_type[type_] {
 783         $type = $type_;
 784 }
 785 |       decl_type
 786 ;
 787
 788 decl_type[type]:
 789         decl_type_simple[token] {
 790         $type = psi_decl_type_init($token->type, $token->text);
 791         $type->token = $token;
 792 }
 793 |       decl_type_complex
 794 ;
 795
 796 decl_type_complex[type]:
 797         STRUCT[token] name_token {
 798         $name_token->type = PSI_T_NAME;
 799         $type = psi_decl_type_init($token->type, $name_token->text);
 800         $type->token = psi_token_copy($name_token);
 801 }
 802 |       UNION[token] name_token {
 803         $name_token->type = PSI_T_NAME;
 804         $type = psi_decl_type_init($token->type, $name_token->text);
 805         $type->token = psi_token_copy($name_token);
 806 }
 807 |       ENUM[token] name_token {
 808         $name_token->type = PSI_T_NAME;
 809         $type = psi_decl_type_init($token->type, $name_token->text);
 810         $type->token = psi_token_copy($name_token);
 811 }
 812 ;
 813
 814 decl_type_simple[type]:
 815         decl_int_type
 816 |       decl_real_type
 817 |       decl_stdint_type[type_] {
 818         $type = psi_token_copy($type_);
 819 }
 820 |       NAME[type_] {
 821         $type = psi_token_copy($type_);
 822 }
 823 ;
 824
 825 decl_real_type[type]:
 826         FLOAT[type_] {
 827         $type = psi_token_copy($type_);
 828 }
 829 |       DOUBLE[type_] {
 830         $type = psi_token_copy($type_);
 831 }
 832 |       LONG DOUBLE {
 833         $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
 834 }
 835 ;
 836
 837 decl_stdint_type[type]:
 838         INT8
 839 |       UINT8
 840 |       INT16
 841 |       UINT16
 842 |       INT32
 843 |       UINT32
 844 |       INT64
 845 |       UINT64
 846 ;
 847
 848 int_signed[i]:
 849         SIGNED
 850 |       UNSIGNED
 851 ;
 852
 853 int_width[i]:
 854         SHORT {
 855         $i = psi_token_copy($SHORT);
 856 }
 857 |       LONG {
 858         $i = psi_token_copy($LONG);
 859 }
 860 |       LONG[l1] LONG[l2] {
 861         $i = psi_token_cat(" ", 2, $l1, $l2);
 862 }
 863 ;
 864
 865 decl_int_type[type]:
 866         CHAR {
 867         $type = psi_token_copy($CHAR);
 868 }
 869 |       INT {
 870         $type = psi_token_copy($INT);
 871 }
 872 |       int_signed int_signed_types {
 873         if ($2) {
 874                 $type = psi_token_cat(" ", 2, $1, $2);
 875                 free($2);
 876         } else {
 877                 $type = psi_token_copy($1);
 878         }
 879 }
 880 |       int_width int_width_types {
 881         if ($2) {
 882                 $type = psi_token_cat(" ", 2, $1, $2);
 883                 free($1);
 884                 free($2);
 885         } else {
 886                 $type = $1;
 887         }
 888 }
 889 ;
 890
 891 int_signed_types[type]:
 892         %empty {
 893         $type = NULL;
 894 }
 895 |       CHAR {
 896         $type = psi_token_copy($CHAR);
 897 }
 898 |       SHORT signed_short_types {
 899         if ($2) {
 900                 $type = psi_token_cat(" ", 2, $1, $2);
 901         } else {
 902                 $type = psi_token_copy($1);
 903         }
 904 }
 905 |       INT {
 906         $type = psi_token_copy($INT);
 907 }
 908 |       LONG signed_long_types {
 909         if ($2) {
 910                 $type = psi_token_cat(" ", 2, $1, $2);
 911         } else {
 912                 $type = psi_token_copy($1);
 913         }
 914 }
 915 ;
 916
 917 signed_short_types[type]:
 918         %empty {
 919         $type = NULL;
 920 }
 921 |       INT
 922 ;
 923 signed_long_types[type]:
 924         %empty {
 925         $type = NULL;
 926 }
 927 |       INT
 928 |       LONG
 929 ;
 930
 931 int_width_types[type]:
 932         %empty {
 933         $type = NULL;
 934 }
 935 |       INT {
 936         $type = psi_token_copy($INT);
 937 }
 938 |       int_signed int_signed_types {
 939         if ($2) {
 940                 $type = psi_token_cat(" ", 2, $1, $2);
 941                 free($2);
 942         } else {
 943                 $type = psi_token_copy($1);
 944         }
 945 }
 946 ;
 947
 948 decl_stmt:
 949         decl decl_asm EOS {
 950         $decl_stmt = $decl;
 951 }
 952 |       CPP_EXTENSION decl decl_asm EOS {
 953         $decl_stmt = $decl;
 954 }
 955 ;
 956
 957 decl_asm:
 958         %empty
 959 |       CPP_ASM LPAREN ignored_quoted_strings RPAREN
 960 ;
 961
 962 ignored_quoted_strings:
 963         QUOTED_STRING
 964 |       ignored_quoted_strings QUOTED_STRING
 965 ;
 966
 967 decl_ext_var_stmt:
 968         decl_ext_var EOS
 969 ;
 970
 971 decl_ext_var:
 972         NAME decl_arg decl_ext_var_list {
 973         psi_decl_arg_free(&$decl_arg);
 974 }
 975 ;
 976
 977 decl_ext_var_list:
 978         %empty
 979 |       COMMA decl_vars {
 980         psi_plist_free($decl_vars);
 981 }
 982 ;
 983
 984 decl_vars[vars]:
 985         decl_var[var] {
 986         $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
 987 }
 988 |       decl_vars[vars_] COMMA decl_var[var] {
 989         $vars = psi_plist_add($vars_, &$var);
 990 }
 991 ;
 992
 993 decl:
 994         decl_body
 995 |       NAME[abi] decl_body {
 996         $decl = $decl_body;
 997         $decl->abi = psi_decl_abi_init($abi->text);
 998 }
 999 ;
1000
1001 decl_body:
1002         decl_func_body
1003 |       decl_functor_body
1004 ;
1005
1006 decl_func_body[decl]:
1007         decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1008         $decl = psi_decl_init($func, $args);
1009         if ($as) {
1010                 $decl->func->var->pointer_level += 1;
1011                 $decl->func->var->array_size = $as;
1012         }
1013 }
1014 |       decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1015         $decl = psi_decl_init($func, $args);
1016         $decl->varargs = 1;
1017         if ($as) {
1018                 $decl->func->var->pointer_level += 1;
1019                 $decl->func->var->array_size = $as;
1020         }
1021 }
1022 ;
1023
1024 decl_functor_body[decl]:
1025         decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1026         $decl = psi_decl_init($func, $args);
1027         if ($as) {
1028                 $decl->func->var->pointer_level += 1;
1029                 $decl->func->var->array_size = $as;
1030         }
1031 }
1032 |       decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1033         $decl = psi_decl_init($func, $args);
1034         $decl->varargs = 1;
1035         if ($as) {
1036                 $decl->func->var->pointer_level += 1;
1037                 $decl->func->var->array_size = $as;
1038         }
1039 }
1040 ;
1041
1042 decl_functor[arg]:
1043         const_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1044         (void) $unused1;
1045         $NAME->type = PSI_T_NAME;
1046         $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1047         $arg->var->token = psi_token_copy($NAME);
1048         $arg->token = psi_token_copy($NAME);
1049 }
1050 |       CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1051         (void) $unused1;
1052         $NAME->type = PSI_T_NAME;
1053         $arg = psi_decl_arg_init(
1054                 psi_decl_type_init($VOID->type, $VOID->text),
1055                 psi_decl_var_init($NAME->text, $pointers, 0)
1056         );
1057         $arg->type->token = psi_token_copy($VOID);
1058         $arg->var->token = psi_token_copy($NAME);
1059         $arg->token = psi_token_copy($NAME);
1060 }
1061 |       VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1062         (void) $unused1;
1063         $NAME->type = PSI_T_NAME;
1064         $arg = psi_decl_arg_init(
1065                 psi_decl_type_init($VOID->type, $VOID->text),
1066                 psi_decl_var_init($NAME->text, $pointers, 0)
1067         );
1068         $arg->type->token = psi_token_copy($VOID);
1069         $arg->var->token = psi_token_copy($NAME);
1070         $arg->token = psi_token_copy($NAME);
1071 }
1072 |       VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1073         (void) $unused1;
1074         $NAME->type = PSI_T_NAME;
1075         $arg = psi_decl_arg_init(
1076                 psi_decl_type_init($VOID->type, $VOID->text),
1077                 psi_decl_var_init($NAME->text, 0, 0)
1078         );
1079         $arg->type->token = psi_token_copy($VOID);
1080         $arg->var->token = psi_token_copy($NAME);
1081         $arg->token = psi_token_copy($NAME);
1082 }
1083 ;
1084
1085 decl_func[func]:
1086         decl_arg
1087 |       VOID name_token[NAME] {
1088         $func = psi_decl_arg_init(
1089                 psi_decl_type_init($VOID->type, $VOID->text),
1090                 psi_decl_var_init($NAME->text, 0, 0)
1091         );
1092         $func->type->token = psi_token_copy($VOID);
1093         $func->var->token = psi_token_copy($NAME);
1094         $func->token = psi_token_copy($NAME);
1095 }
1096 ;
1097
1098 decl_args[args]:
1099         %empty {
1100         $args = NULL;
1101 }
1102 |       VOID {
1103         $args = NULL;
1104 }
1105 |       decl_arg[arg] {
1106         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1107 }
1108 |       decl_args[args_] COMMA decl_arg[arg] {
1109         $args = psi_plist_add($args_, &$arg);
1110 }
1111 ;
1112
1113 decl_arg[arg]:
1114         decl_functor_body[decl] {
1115         $arg = psi_decl_arg_init(
1116                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1117                 psi_decl_var_copy($decl->func->var)
1118         );
1119         $arg->type->token = psi_token_copy($decl->func->token);
1120         $arg->type->real.func = $decl;
1121 }
1122 |       const_decl_type[type] decl_var[var] {
1123         $arg = psi_decl_arg_init($type, $var);
1124 }
1125 |       CONST VOID pointers name_token[NAME] {
1126         $NAME->type = PSI_T_NAME;
1127         $arg = psi_decl_arg_init(
1128                 psi_decl_type_init($VOID->type, $VOID->text),
1129                 psi_decl_var_init($NAME->text, $pointers, 0)
1130         );
1131         $arg->type->token = psi_token_copy($VOID);
1132         $arg->var->token = psi_token_copy($NAME);
1133         $arg->token = psi_token_copy($NAME);
1134 }
1135 |       VOID pointers name_token[NAME] {
1136         $NAME->type = PSI_T_NAME;
1137         $arg = psi_decl_arg_init(
1138                 psi_decl_type_init($VOID->type, $VOID->text),
1139                 psi_decl_var_init($NAME->text, $pointers, 0)
1140         );
1141         $arg->type->token = psi_token_copy($VOID);
1142         $arg->var->token = psi_token_copy($NAME);
1143         $arg->token = psi_token_copy($NAME);
1144 }
1145 ;
1146
1147 decl_var[var]:
1148         pointers name_token array_size {
1149         $name_token->type = PSI_T_NAME;
1150         $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1151         $var->token = psi_token_copy($name_token);
1152 }
1153 |       name_token array_size {
1154         $name_token->type = PSI_T_NAME;
1155         $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1156         $var->token = psi_token_copy($name_token);
1157 }
1158 ;
1159
1160 decl_union[union]:
1161         UNION name_token align_and_size[as] decl_struct_args[args] {
1162         $name_token->type = PSI_T_NAME;
1163         $union = psi_decl_union_init($name_token->text, $args);
1164         $union->align = $as.pos;
1165         $union->size = $as.len;
1166         $union->token = psi_token_copy($name_token);
1167 }
1168 ;
1169
1170 decl_struct[struct]:
1171         STRUCT name_token align_and_size[as] decl_struct_args[args] {
1172         $name_token->type = PSI_T_NAME;
1173         $struct = psi_decl_struct_init($name_token->text, $args);
1174         $struct->align = $as.pos;
1175         $struct->size = $as.len;
1176         $struct->token = psi_token_copy($name_token);
1177 }
1178 ;
1179
1180 decl_struct_args[args]:
1181         EOS {
1182         $args = NULL;
1183 }
1184 |       struct_args_block
1185 ;
1186
1187 struct_args_block[args]:
1188         LBRACE struct_args RBRACE {
1189         $args = $struct_args;
1190 }
1191 ;
1192
1193 struct_args[args]:
1194         typedef[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1195         $arg->layout = $layout;
1196         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1197         if ($vars) {
1198                 size_t i = 0;
1199                 struct psi_decl_arg *arg;
1200
1201                 while (psi_plist_get($vars, i++, &arg)) {
1202                         arg->type = psi_decl_type_copy($arg->type);
1203                         $args = psi_plist_add($args, &arg);
1204                 }
1205                 free($vars);
1206         }
1207 }
1208 |       struct_args[args_] typedef[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1209         $arg->layout = $layout;
1210         $args = psi_plist_add($args_, &$arg);
1211         if ($vars) {
1212                 size_t i = 0;
1213                 struct psi_decl_arg *arg;
1214
1215                 while (psi_plist_get($vars, i++, &arg)) {
1216                         arg->type = psi_decl_type_copy($arg->type);
1217                         $args = psi_plist_add($args, &arg);
1218                 }
1219                 free($vars);
1220         }
1221 }
1222 ;
1223
1224 struct_arg_var_list[vars]:
1225         %empty {
1226         $vars = NULL;
1227 }
1228 |       COMMA decl_vars_with_layout[vars_] {
1229         $vars = $vars_;
1230 }
1231 ;
1232
1233 decl_vars_with_layout[vars]:
1234         decl_var[var] decl_layout[layout] {
1235         {
1236                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1237                 arg->layout = $layout;
1238                 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1239         }
1240 }
1241 |       decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1242         {
1243                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1244                 arg->layout = $layout;
1245                 $vars = psi_plist_add($vars_, &arg);
1246         }
1247 }
1248 ;
1249
1250 decl_enum[enum]:
1251         enum_name LBRACE decl_enum_items[list] RBRACE {
1252         $enum = psi_decl_enum_init($enum_name->text, $list);
1253         $enum->token = $enum_name;
1254 }
1255 ;
1256
1257 decl_enum_items[list]:
1258         decl_enum_item[i] {
1259         $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1260 }
1261 |       decl_enum_items[list_] COMMA decl_enum_item[i] {
1262         $list = psi_plist_add($list_, &$i);
1263 }
1264 ;
1265
1266 decl_enum_item[i]:
1267         name_token {
1268         $name_token->type = PSI_T_NAME;
1269         $i = psi_decl_enum_item_init($name_token->text, NULL);
1270         $i->token = psi_token_copy($name_token);
1271 }
1272 |       name_token EQUALS num_exp {
1273         $name_token->type = PSI_T_NAME;
1274         $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1275         $i->token = psi_token_copy($name_token);
1276 }
1277 ;
1278
1279 num_exp[exp]:
1280         number {
1281         $exp = psi_num_exp_init_num($number);
1282         $exp->token = psi_token_copy($number->token);
1283 }
1284 |       LPAREN const_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1285         $exp = psi_num_exp_init_cast($type, $exp_);
1286         $exp->token = psi_token_copy($type->token);
1287 }
1288 |       LPAREN num_exp[exp_] RPAREN {
1289         $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1290         $exp->token = psi_token_copy($LPAREN);
1291 }
1292 |       num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1293         $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1294         $exp->token = psi_token_copy($op);
1295 }
1296 |       unary_op_token[op] num_exp[exp_] %prec UNARY {
1297         $exp = psi_num_exp_init_unary($op->type, $exp_);
1298         $exp->token = psi_token_copy($op);
1299 }
1300 |       num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1301         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1302         $exp->token = psi_token_copy($IIF);
1303 }
1304 ;
1305
1306 number[num]:
1307         NUMBER[token] {
1308         $num = psi_number_init($token->type, $token->text, $token->flags);
1309         $num->token = psi_token_copy($token);
1310 }
1311 |       NSNAME[token] {
1312         $num = psi_number_init($token->type, $token->text, 0);
1313         $num->token = psi_token_copy($token);
1314 }
1315 |       QUOTED_CHAR[token] {
1316         $num = psi_number_init($token->type, $token->text, 0);
1317         $num->token = psi_token_copy($token);
1318 }
1319 |       decl_var {
1320         $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1321         $num->token = psi_token_copy($decl_var->token);
1322 }
1323 ;
1324
1325 enum_name[name]:
1326         ENUM optional_name[name_] {
1327         if ($name_) {
1328                 $name = psi_token_copy($name_);
1329         } else {
1330                 char digest[17];
1331
1332                 psi_token_hash($ENUM, digest);
1333                 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1334         }
1335 }
1336 ;
1337
1338 union_name[name]:
1339         UNION optional_name[name_] {
1340         if ($name_) {
1341                 $name = psi_token_copy($name_);
1342         } else {
1343                 char digest[17];
1344
1345                 psi_token_hash($UNION, digest);
1346                 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1347         }
1348 }
1349 ;
1350
1351 struct_name[name]:
1352         STRUCT optional_name[name_] {
1353         if ($name_) {
1354                 $name = psi_token_copy($name_);
1355         } else {
1356                 char digest[17];
1357
1358                 psi_token_hash($STRUCT, digest);
1359                 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1360         }
1361 }
1362 ;
1363
1364 optional_name[name]:
1365         %empty {
1366         $name = NULL;
1367 }
1368 |       name_token {
1369         $name = $name_token;
1370         $name->type = PSI_T_NAME;
1371 }
1372 ;
1373
1374 decl_layout[l]:
1375         %empty {
1376         $l = NULL;
1377 }
1378 |       COLON NUMBER[width] {
1379         $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1380 }
1381 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1382         $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1383 }
1384 |       COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1385         $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1386 }
1387 ;
1388
1389 align_and_size[as]:
1390         %empty {
1391         $as.pos = 0;
1392         $as.len = 0;
1393 }
1394 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1395         $as.pos = atol($align->text);
1396         $as.len = atol($size->text);
1397 }
1398 ;
1399
1400 array_size[as]:
1401         %empty {
1402         $as = 0;
1403 }
1404 |       LBRACKET NUMBER RBRACKET {
1405         $as = atol($NUMBER->text);
1406 }
1407 ;
1408
1409 indirection[i]:
1410         %empty {
1411         $i = 0;
1412 }
1413 |       pointers[p] %prec UNARY {
1414         $i = $p;
1415 }
1416 ;
1417
1418 pointers[p]:
1419         asterisks
1420 |       asterisks[a] CPP_RESTRICT {
1421         $p = $a;
1422 }
1423 ;
1424
1425 asterisks[a]:
1426         ASTERISK {
1427         $a = 1;
1428 }
1429 |       asterisks[a_] ASTERISK {
1430         $a = $a_ + 1;
1431 }
1432 ;
1433
1434 /*
1435  *
1436  * impl
1437  *
1438  */
1439
1440 impl:
1441         impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1442         $impl = psi_impl_init($func, $stmts);
1443 }
1444 |       STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1445         $impl = psi_impl_init($func, $stmts);
1446         $func->static_memory = 1;
1447 }
1448 ;
1449
1450 impl_func[func]:
1451         FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1452         $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1453         $func->token = psi_token_copy($NSNAME);
1454         $func->return_reference = $r;
1455 }
1456 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1457         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1458         $func->token = psi_token_copy($NSNAME);
1459         $func->return_reference = $r;
1460 }
1461 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1462         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1463         $func->token = psi_token_copy($NSNAME);
1464         $func->return_reference = $r;
1465         $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1466         $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1467 }
1468 ;
1469
1470 impl_args[args]:
1471         impl_arg[arg] {
1472         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1473 }
1474 |       impl_args[args_] COMMA impl_arg[arg] {
1475         $args = psi_plist_add($args_, &$arg);
1476 }
1477 ;
1478
1479 impl_arg[arg]:
1480         impl_type[type] impl_var[var] {
1481         $arg = psi_impl_arg_init($type, $var, NULL);
1482 }
1483 |       impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1484         $arg = psi_impl_arg_init($type, $var, $val);
1485 }
1486 ;
1487
1488 impl_var[var]:
1489         reference DOLLAR_NAME {
1490         $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1491         $var->token = psi_token_copy($DOLLAR_NAME);
1492 }
1493 ;
1494
1495 impl_type[type]:
1496         impl_type_token[token] {
1497         $type = psi_impl_type_init($token->type, $token->text);
1498         $type->token = psi_token_copy($token);
1499 }
1500 ;
1501
1502 impl_type_token:
1503         VOID
1504 |       MIXED
1505 |       BOOL
1506 |       INT
1507 |       FLOAT
1508 |       STRING
1509 |       ARRAY
1510 |       OBJECT
1511 |       CALLABLE
1512 ;
1513
1514 impl_stmts[stmts]:
1515         impl_stmt[stmt] {
1516         $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1517 }
1518 |       impl_stmts[stmts_] impl_stmt[stmt] {
1519         $stmts = psi_plist_add($stmts_, &$stmt);
1520 }
1521 ;
1522
1523 impl_stmt[stmt]:
1524         return_stmt[s] {
1525         $stmt = (struct psi_token **) $s;
1526 }
1527 |       let_stmt[s] {
1528         $stmt = (struct psi_token **) $s;
1529 }
1530 |       set_stmt[s] {
1531         $stmt = (struct psi_token **) $s;
1532 }
1533 |       assert_stmt[s] {
1534         $stmt = (struct psi_token **) $s;
1535 }
1536 |       free_stmt[s] {
1537         $stmt = (struct psi_token **) $s;
1538 }
1539 ;
1540
1541 let_stmt[let]:
1542         LET let_exp_assign[exp] EOS {
1543         $let = psi_let_stmt_init($exp);
1544         $let->token = psi_token_copy($LET);
1545 }
1546 |       TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1547         $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1548         $let->token = psi_token_copy($TEMP);
1549         $let->exp->is_reference = $reference;
1550 }
1551 ;
1552
1553 let_exp[exp]:
1554         let_exp_assign
1555 |       byref let_exp_byref[exp_] {
1556         $exp = $exp_;
1557         $exp->is_reference = true;
1558 }
1559 |       let_exp_byref[exp_] {
1560         $exp = $exp_;
1561         $exp->is_reference = false;
1562 }
1563 ;
1564
1565 let_exp_byref[exp]:
1566         NULL {
1567         $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1568 }
1569 |       let_calloc[calloc] {
1570         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1571 }
1572 |       let_callback[callback] {
1573         $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1574 }
1575 |       let_func[func] {
1576         $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1577 }
1578 |       num_exp[num] {
1579         $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1580 }
1581 ;
1582
1583 let_exp_assign[exp]:
1584         decl_var[var] EQUALS let_exp_byref[exp_] {
1585         $exp = $exp_;
1586         $exp->var = $var;
1587 }
1588 |       decl_var[var] EQUALS byref let_exp_byref[exp_] {
1589         $exp = $exp_;
1590         $exp->is_reference = 1;
1591         $exp->var = $var;
1592 }
1593 ;
1594
1595 let_calloc[calloc]:
1596         CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1597         $calloc = psi_let_calloc_init($nmemb, $size);
1598         $calloc->token = psi_token_copy($CALLOC);
1599 }
1600 ;
1601
1602 let_callback[callback]:
1603         CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1604         $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args);
1605         $callback->func->token = psi_token_copy($func);
1606         $callback->token = psi_token_copy($CALLBACK);
1607 }
1608 ;
1609
1610 let_func[func]:
1611         let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1612         $func = psi_let_func_init($token->type, $token->text, $var);
1613         $func->token = psi_token_copy($token);
1614         $func->inner = $exps;
1615 }
1616 ;
1617
1618 let_func_token:
1619         ZVAL
1620 |       OBJVAL
1621 |       ARRVAL
1622 |       PATHVAL
1623 |       STRLEN
1624 |       STRVAL
1625 |       FLOATVAL
1626 |       INTVAL
1627 |       BOOLVAL
1628 |       COUNT
1629 ;
1630
1631 let_func_exps[exps]:
1632         %empty {
1633         $exps = NULL;
1634 }
1635 |       COMMA let_exps[exps_] {
1636         $exps = $exps_;
1637 }
1638 ;
1639
1640 let_exps[exps]:
1641         let_exp[exp] {
1642         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1643 }
1644 |       let_exps[exps_] COMMA let_exp[exp] {
1645         $exps = psi_plist_add($exps_, &$exp);
1646 }
1647 ;
1648
1649 callback_rval[rval]:
1650         VOID
1651 |       let_func_token
1652 ;
1653
1654 callback_arg_list[list]:
1655         %empty {
1656         $list = NULL;
1657 }
1658 |       callback_args[args] {
1659         $list = $args;
1660 }
1661 ;
1662
1663 callback_args[args]:
1664         set_exp[exp] {
1665         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1666 }
1667 |       callback_args[args_] COMMA set_exp[exp] {
1668         $args = psi_plist_add($args_, &$exp);
1669 }
1670 ;
1671
1672 return_stmt[return]:
1673         RETURN set_func[func] EOS {
1674         $return = psi_return_stmt_init(psi_set_exp_init(PSI_SET_FUNC, $func));
1675         $return->token = psi_token_copy($RETURN);
1676 }
1677 ;
1678
1679 set_stmt[set]:
1680         SET set_exp[exp] EOS {
1681         $set = psi_set_stmt_init($exp);
1682         $set->token = psi_token_copy($SET);
1683 }
1684 ;
1685
1686 set_exp[exp]:
1687         set_func[func] {
1688         $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1689 }
1690 |       num_exp[num] {
1691         $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1692 }
1693 |       impl_var[var] EQUALS set_exp[exp_] {
1694         $exp = $exp_;
1695         $exp->var = $var;
1696 }
1697 ;
1698
1699 set_func[func]:
1700         set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1701         $func = psi_set_func_init($token->type, $token->text, $var);
1702         $func->token = psi_token_copy($token);
1703         $func->inner = $exps;
1704 }
1705 |       set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
1706         $func = psi_set_func_init($token->type, $token->text, $var);
1707         $func->token = psi_token_copy($token);
1708         $func->recursive = 1;
1709 }
1710 ;
1711
1712 set_func_token:
1713         TO_OBJECT
1714 |       TO_ARRAY
1715 |       TO_STRING
1716 |       TO_INT
1717 |       TO_FLOAT
1718 |       TO_BOOL
1719 |       ZVAL
1720 |       VOID
1721 ;
1722
1723 set_func_exps[exps]:
1724         %empty {
1725         $exps = NULL;
1726 }
1727 |       COMMA set_exps[exps_] {
1728         $exps = $exps_;
1729 }
1730 ;
1731
1732 set_exps[exps]:
1733         set_exp[exp] {
1734         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1735 }
1736 |       set_exps[exps_] COMMA set_exp[exp] {
1737         $exps = psi_plist_add($exps_, &$exp);
1738 }
1739 ;
1740
1741 assert_stmt[assert]:
1742         assert_stmt_token[token] num_exp[exp] EOS {
1743         $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
1744         $assert->token = psi_token_copy($token);
1745 }
1746 ;
1747
1748 assert_stmt_token:
1749         PRE_ASSERT
1750 |       POST_ASSERT
1751 ;
1752
1753 free_stmt[free]:
1754         FREE free_exps[exps] EOS {
1755         $free = psi_free_stmt_init($exps);
1756         $free->token = psi_token_copy($FREE);
1757 }
1758 ;
1759
1760 free_exps[exps]:
1761         free_exp[exp] {
1762         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
1763 }
1764 |       free_exps[exps_] COMMA free_exp[exp] {
1765         $exps = psi_plist_add($exps_, &$exp);
1766 }
1767 ;
1768
1769 free_exp[exp]:
1770         name_token[NAME] LPAREN decl_vars[vars] RPAREN {
1771         $NAME->type = PSI_T_NAME;
1772         $exp = psi_free_exp_init($NAME->text, $vars);
1773         $exp->token = psi_token_copy($NAME);
1774 }
1775 ;
1776
1777 reference:
1778         %empty {
1779         $reference = false;
1780 }
1781 |       byref {
1782         $reference = true;
1783 }
1784 ;
1785
1786 byref:
1787         AMPERSAND %prec UNARY
1788 ;
1789
1790 %%
1791
1792 /* epilogue */
1793
1794 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
1795 {
1796         struct psi_token *token;
1797
1798         if (psi_plist_get(tokens, (*index)++, &token)) {
1799                 if (P->flags & PSI_DEBUG) {
1800                         psi_token_dump(2, token);
1801                 }
1802
1803                 *((struct psi_token **)lvalp) = token;
1804                 return token->type;
1805         } else {
1806                 (*index)--;
1807                 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
1808         }
1809
1810         return PSI_T_EOF;
1811 }
1812
1813 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
1814 {
1815         struct psi_token *T = NULL;
1816         size_t last;
1817
1818         if (*index == 0) {
1819                 last = 0;
1820         } else {
1821                 last = --(*index);
1822         }
1823
1824         psi_plist_get(tokens, last, &T);
1825         if (T) {
1826                 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
1827         } else {
1828                 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
1829         }
1830         P->errors++;
1831 }
1832