projects / m6w6 / ext-psi / blob
? search:


c076abd0e5a630f1db8c78e2fd5fd5d10a144a8c
[m6w6/ext-psi] / src / parser_proc_grammar.y
1 %code top {
2 #include "php_psi_stdinc.h"
3 }
4
5 %code {
6 #include <assert.h>
7 #include <stdarg.h>
8
9 #include "plist.h"
10 #include "parser.h"
11
12 #define YYDEBUG 1
13 #define PSI_PARSER_PROC_DEBUG 1
14
15 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
16 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
17
18 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
19 {
20 assert(strct);
21 if (!P->structs) {
22 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
23 }
24 P->structs = psi_plist_add(P->structs, &strct);
25 }
26 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
27 {
28 assert(u);
29 if (!P->unions) {
30 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
31 }
32 P->unions = psi_plist_add(P->unions, &u);
33 }
34 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
35 {
36 assert(e);
37 if (!P->enums) {
38 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
39 }
40 P->enums = psi_plist_add(P->enums, &e);
41 }
42 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
43 {
44 assert(def);
45 if (!P->types) {
46 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
47 }
48 P->types = psi_plist_add(P->types, &def);
49 }
50 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
51 assert(cnst);
52 if (!P->consts) {
53 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
54 }
55 P->consts = psi_plist_add(P->consts, &cnst);
56
57 }
58 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
59 assert(decl);
60
61 if (psi_decl_is_blacklisted(decl->func->var->name->val)) {
62 psi_decl_free(&decl);
63 return;
64 }
65
66 if (!P->decls) {
67 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
68 }
69 P->decls = psi_plist_add(P->decls, &decl);
70 }
71 static inline void psi_parser_proc_add_decl_extvars(struct psi_parser *P, struct psi_plist *list) {
72 assert(list);
73 if (!P->vars) {
74 P->vars = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
75 }
76 P->vars = psi_plist_add_r(P->vars, psi_plist_count(list), psi_plist_eles(list));
77 free(list);
78 }
79 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
80 assert(impl);
81 if (!P->impls) {
82 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
83 }
84 P->impls = psi_plist_add(P->impls, &impl);
85 }
86
87 /* end code */
88 }
89
90 %code requires {
91 #include "plist.h"
92 #include "types/layout.h"
93
94 #define yytokentype psi_token_type
95
96 #define PSI_T_CAST PSI_T_EQUALS
97 #define PSI_T_POINTER PSI_T_ASTERISK
98
99 struct psi_parser;
100
101 }
102
103 %require "3.0"
104 %language "c"
105 %name-prefix "psi_parser_proc_"
106 %token-table
107 %verbose
108 %glr-parser
109
110 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
111
112 %define api.pure true
113 %define api.token.prefix {PSI_T_}
114 %define api.value.type union
115
116 %define parse.error verbose
117 %define parse.trace true
118
119 %initial-action {
120 }
121
122 %start file
123
124 %token <struct psi_token *> BOOL
125 %token <struct psi_token *> CHAR
126 %token <struct psi_token *> SHORT
127 %token <struct psi_token *> INT
128 %token <struct psi_token *> SIGNED
129 %token <struct psi_token *> UNSIGNED
130 %token <struct psi_token *> LONG
131 %token <struct psi_token *> FLOAT
132 %token <struct psi_token *> DOUBLE
133 %token <struct psi_token *> STRING
134 %token <struct psi_token *> MIXED
135 %token <struct psi_token *> ARRAY
136 %token <struct psi_token *> OBJECT
137 %token <struct psi_token *> CALLABLE
138 %token <struct psi_token *> VOID
139 %token <struct psi_token *> ZVAL
140 %token <struct psi_token *> NULL
141 %token <struct psi_token *> TRUE
142 %token <struct psi_token *> FALSE
143 %token <struct psi_token *> NAME
144 %token <struct psi_token *> NSNAME
145 %token <struct psi_token *> DOLLAR_NAME
146 %token <struct psi_token *> NUMBER
147 %token <struct psi_token *> QUOTED_STRING
148 %token <struct psi_token *> QUOTED_CHAR
149 %token <struct psi_token *> SIZEOF
150 %token <struct psi_token *> VOLATILE
151
152 %token <struct psi_token *> EOF 0 "end of file"
153 %token <struct psi_token *> EOL "end of line"
154 %token <struct psi_token *> EOS ";"
155 %token <struct psi_token *> LPAREN "("
156 %token <struct psi_token *> RPAREN ")"
157 %token <struct psi_token *> COMMA ","
158 %token <struct psi_token *> COLON ":"
159 %token <struct psi_token *> LBRACE "{"
160 %token <struct psi_token *> RBRACE "}"
161 %token <struct psi_token *> LBRACKET "["
162 %token <struct psi_token *> RBRACKET "]"
163 %token <struct psi_token *> EQUALS "="
164 %token <struct psi_token *> HASH "#"
165 %token <struct psi_token *> PIPE "|"
166 %token <struct psi_token *> CARET "^"
167 %token <struct psi_token *> AMPERSAND "&"
168 %token <struct psi_token *> LSHIFT "<<"
169 %token <struct psi_token *> RSHIFT ">>"
170 %token <struct psi_token *> PLUS "+"
171 %token <struct psi_token *> MINUS "-"
172 %token <struct psi_token *> ASTERISK "*"
173 %token <struct psi_token *> SLASH "/"
174 %token <struct psi_token *> MODULO "%"
175 %token <struct psi_token *> LCHEVR "<"
176 %token <struct psi_token *> RCHEVR ">"
177 %token <struct psi_token *> CMP_GE ">="
178 %token <struct psi_token *> CMP_LE "<="
179 %token <struct psi_token *> OR "||"
180 %token <struct psi_token *> AND "&&"
181 %token <struct psi_token *> CMP_EQ "=="
182 %token <struct psi_token *> CMP_NE "!="
183 %token <struct psi_token *> TILDE "~"
184 %token <struct psi_token *> NOT "!"
185 %token <struct psi_token *> PERIOD "."
186 %token <struct psi_token *> BACKSLASH "\\"
187 %token <struct psi_token *> ELLIPSIS "..."
188 %token <struct psi_token *> IIF "?"
189
190 %token <struct psi_token *> PRAGMA
191 %token <struct psi_token *> PRAGMA_ONCE
192 %token <struct psi_token *> LINE
193 %token <struct psi_token *> ERROR
194 %token <struct psi_token *> WARNING
195 %token <struct psi_token *> IF
196 %token <struct psi_token *> IFDEF
197 %token <struct psi_token *> IFNDEF
198 %token <struct psi_token *> ELSE
199 %token <struct psi_token *> ELIF
200 %token <struct psi_token *> ENDIF
201 %token <struct psi_token *> DEFINE
202 %token <struct psi_token *> DEFINED
203 %token <struct psi_token *> UNDEF
204 %token <struct psi_token *> IMPORT
205 %token <struct psi_token *> INCLUDE
206 %token <struct psi_token *> INCLUDE_NEXT
207
208 %token <struct psi_token *> TYPEDEF
209 %token <struct psi_token *> STRUCT
210 %token <struct psi_token *> UNION
211 %token <struct psi_token *> ENUM
212 %token <struct psi_token *> CONST
213 %token <struct psi_token *> LIB
214 %token <struct psi_token *> STATIC
215 %token <struct psi_token *> CALLBACK
216 %token <struct psi_token *> FUNCTION
217 %token <struct psi_token *> LET
218 %token <struct psi_token *> SET
219 %token <struct psi_token *> TEMP
220 %token <struct psi_token *> FREE
221 %token <struct psi_token *> RETURN
222 %token <struct psi_token *> AS
223 %token <struct psi_token *> PRE_ASSERT
224 %token <struct psi_token *> POST_ASSERT
225 %token <struct psi_token *> BOOLVAL
226 %token <struct psi_token *> INTVAL
227 %token <struct psi_token *> STRVAL
228 %token <struct psi_token *> PATHVAL
229 %token <struct psi_token *> STRLEN
230 %token <struct psi_token *> FLOATVAL
231 %token <struct psi_token *> ARRVAL
232 %token <struct psi_token *> OBJVAL
233 %token <struct psi_token *> COUNT
234 %token <struct psi_token *> CALLOC
235 %token <struct psi_token *> TO_BOOL
236 %token <struct psi_token *> TO_INT
237 %token <struct psi_token *> TO_STRING
238 %token <struct psi_token *> TO_FLOAT
239 %token <struct psi_token *> TO_ARRAY
240 %token <struct psi_token *> TO_OBJECT
241
242 %token <struct psi_token *> COMMENT
243 %token <struct psi_token *> WHITESPACE
244 %token <struct psi_token *> NO_WHITESPACE
245 %token <struct psi_token *> CPP_HEADER
246 %token <struct psi_token *> CPP_ATTRIBUTE
247 %token <struct psi_token *> CPP_EXTENSION
248 %token <struct psi_token *> CPP_PASTE
249 %token <struct psi_token *> CPP_INLINE
250 %token <struct psi_token *> CPP_RESTRICT
251 %token <struct psi_token *> CPP_ASM
252
253 /* virtual tokens */
254 %token <struct psi_token *> BSLASH
255 %token <struct psi_token *> LONG_DOUBLE
256 %token <struct psi_token *> INT8
257 %token <struct psi_token *> UINT8
258 %token <struct psi_token *> INT16
259 %token <struct psi_token *> UINT16
260 %token <struct psi_token *> INT32
261 %token <struct psi_token *> UINT32
262 %token <struct psi_token *> INT64
263 %token <struct psi_token *> UINT64
264 %token <struct psi_token *> INT128
265 %token <struct psi_token *> UINT128
266
267
268 %precedence IIF COLON
269 %precedence OR
270 %precedence AND
271 %precedence PIPE
272 %precedence CARET
273 %precedence AMPERSAND
274 %precedence CMP_EQ CMP_NE
275 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
276 %precedence LSHIFT RSHIFT
277 %precedence PLUS MINUS
278 %precedence ASTERISK SLASH MODULO
279 //%precedence NOT TILDE
280 %precedence BINARY
281 %precedence UNARY
282
283 %type <struct psi_token *> lib optional_name enum_name struct_name union_name
284 %destructor {psi_token_free(&$$);} lib optional_name enum_name struct_name union_name
285
286 %type <struct psi_token *> cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token
287 %destructor {} cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token
288
289 %type <struct psi_token *> name_token any_noeol_token binary_op_token unary_op_token
290 %destructor {} name_token any_noeol_token binary_op_token unary_op_token
291
292 %type <struct psi_token *> int_width int_width_types int_signed_types
293 %destructor {psi_token_free(&$$);} int_width int_width_types int_signed_types
294
295 %type <struct psi_token *> signed_long_types signed_short_types int_signed
296 %destructor {} signed_long_types signed_short_types int_signed
297
298 %type <struct psi_cpp_exp *> cpp cpp_exp
299 %destructor {psi_cpp_exp_free(&$$);} cpp cpp_exp
300 %type <struct psi_cpp_macro_decl *> cpp_macro_decl
301 %destructor {psi_cpp_macro_decl_free(&$$);} cpp_macro_decl
302 %type <struct psi_plist *> cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
303 %destructor {psi_plist_free($$);} cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
304 %type <struct psi_num_exp *> cpp_macro_exp
305 %destructor {psi_num_exp_free(&$$);} cpp_macro_exp
306
307 %type <struct psi_token *> impl_def_val_token
308 %destructor {} impl_def_val_token
309
310 %type <struct psi_const *> constant
311 %destructor {psi_const_free(&$$);} constant
312 %type <struct psi_impl_def_val *> impl_def_val
313 %destructor {psi_impl_def_val_free(&$$);} impl_def_val
314
315 %type <struct psi_token *> decl_real_type decl_int_type decl_type_simple
316 %destructor {psi_token_free(&$$);} decl_real_type decl_int_type decl_type_simple
317
318 %type <struct psi_token *> decl_asm quoted_strings
319 %destructor {psi_token_free(&$$);} decl_asm quoted_strings
320
321 %type <struct psi_decl_type *> decl_type qualified_decl_type decl_type_complex
322 %destructor {psi_decl_type_free(&$$);} decl_type qualified_decl_type decl_type_complex
323 %type <struct psi_decl *> decl_stmt decl decl_body decl_func_body decl_functor_body decl_anon_functor_body ignored_decl
324 %destructor {psi_decl_free(&$$);} decl_stmt decl decl_body decl_func_body decl_functor_body decl_anon_functor_body ignored_decl
325 %type <struct psi_decl_arg *> decl_typedef decl_func decl_functor decl_anon_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
326 %destructor {psi_decl_arg_free(&$$);} decl_typedef decl_func decl_functor decl_anon_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
327 %type <struct psi_decl_var *> decl_var
328 %destructor {psi_decl_var_free(&$$);} decl_var
329 %type <struct psi_decl_struct *> decl_struct
330 %destructor {psi_decl_struct_free(&$$);} decl_struct
331 %type <struct psi_decl_union *> decl_union
332 %destructor {psi_decl_union_free(&$$);} decl_union
333 %type <struct psi_decl_enum *> decl_enum
334 %destructor {psi_decl_enum_free(&$$);} decl_enum
335 %type <struct psi_decl_enum_item *> decl_enum_item
336 %destructor {psi_decl_enum_item_free(&$$);} decl_enum_item
337 %type <struct psi_plist *> decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
338 %destructor {psi_plist_free($$);} decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
339
340 %type <struct psi_layout> align_and_size
341 %destructor {} align_and_size
342 %type <struct psi_layout *> decl_layout
343 %destructor {psi_layout_free(&$$);} decl_layout
344
345 %type <struct psi_number *> sizeof sizeof_body sizeof_body_notypes
346 %destructor {psi_number_free(&$$);} sizeof sizeof_body sizeof_body_notypes
347
348 %type <struct psi_impl *> impl
349 %destructor {psi_impl_free(&$$);} impl
350 %type <struct psi_impl_func *> impl_func
351 %destructor {psi_impl_func_free(&$$);} impl_func
352 %type <struct psi_impl_arg *> impl_arg
353 %destructor {psi_impl_arg_free(&$$);} impl_arg
354 %type <struct psi_impl_type *> impl_type impl_type_restricted
355 %destructor {psi_impl_type_free(&$$);} impl_type impl_type_restricted
356 %type <struct psi_impl_var *> impl_var
357 %destructor {psi_impl_var_free(&$$);} impl_var
358
359 %type <struct psi_let_stmt *> let_stmt
360 %destructor {psi_let_stmt_free(&$$);} let_stmt
361 %type <struct psi_let_exp *> let_exp let_exp_byref let_exp_assign
362 %destructor {psi_let_exp_free(&$$);} let_exp let_exp_byref let_exp_assign
363 %type <struct psi_let_calloc *> let_calloc
364 %destructor {psi_let_calloc_free(&$$);} let_calloc
365 %type <struct psi_let_callback *> let_callback
366 %destructor {psi_let_callback_free(&$$);} let_callback
367 %type <struct psi_let_func *> let_func
368 %destructor {psi_let_func_free(&$$);} let_func
369 %type <struct psi_set_stmt *> set_stmt
370 %destructor {psi_set_stmt_free(&$$);} set_stmt
371 %type <struct psi_set_exp *> set_exp
372 %destructor {psi_set_exp_free(&$$);} set_exp
373 %type <struct psi_set_func *> set_func
374 %destructor {psi_set_func_free(&$$);} set_func
375 %type <struct psi_assert_stmt *> assert_stmt
376 %destructor {psi_assert_stmt_free(&$$);} assert_stmt
377 %type <struct psi_return_stmt *> return_stmt
378 %destructor {psi_return_stmt_free(&$$);} return_stmt
379 %type <struct psi_return_exp *> return_exp
380 %destructor {psi_return_exp_free(&$$);} return_exp
381 %type <struct psi_free_stmt *> free_stmt
382 %destructor {psi_free_stmt_free(&$$);} free_stmt
383 %type <struct psi_free_exp *> free_exp
384 %destructor {psi_free_exp_free(&$$);} free_exp
385
386 %type <struct psi_token **> impl_stmt
387 %destructor {psi_impl_stmt_free(&$$);} impl_stmt
388 %type <struct psi_token *> impl_type_token impl_type_restricted_token impl_type_extended_token callback_rval let_func_token set_func_token assert_stmt_token
389 %destructor {psi_token_free(&$$);} impl_type_token impl_type_restricted_token impl_type_extended_token callback_rval let_func_token set_func_token assert_stmt_token
390 %type <struct psi_plist *> impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
391 %destructor {psi_plist_free($$);} impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
392
393 %type <struct psi_num_exp *> num_exp
394 %destructor {psi_num_exp_free(&$$);} num_exp
395 %type <struct psi_number *> number
396 %destructor {psi_number_free(&$$);} number
397
398 %type <size_t> indirection pointers asterisks array_size
399 %destructor {} indirection pointers asterisks array_size
400 %type <bool> reference
401 %destructor {} reference
402
403 %%
404
405 /* rules */
406
407
408 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
409 unary_op_token: TILDE | NOT | PLUS | MINUS ;
410 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | MIXED | ARRAY | OBJECT | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | AS | let_func_token | set_func_token;
411 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
412 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
413
414
415 file:
416 %empty
417 | blocks
418 ;
419 blocks:
420 block
421 | blocks block
422 ;
423 block:
424 EOS
425 | EOL
426 | COMMENT
427 | cpp {
428 if ($cpp) {
429 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
430 psi_cpp_exp_free(&$cpp);
431 }
432 }
433 | lib {
434 char *libname = strdup($lib->text->val);
435 P->file.libnames = psi_plist_add(P->file.libnames, &libname);
436 }
437 | constant {
438 psi_parser_proc_add_const(P, $constant);
439 }
440 | decl_stmt {
441 psi_parser_proc_add_decl(P, $decl_stmt);
442 }
443 | decl_extvar_stmt[list] {
444 psi_parser_proc_add_decl_extvars(P, $list);
445 }
446 | ignored_decl {
447 if (P->flags & PSI_DEBUG) {
448 P->error(PSI_DATA(P), $ignored_decl->func->token, PSI_NOTICE, "Ignored decl: %s", $ignored_decl->func->var->name->val);
449 }
450 psi_decl_free(&$ignored_decl);
451 }
452 | decl_typedef[def] {
453 psi_parser_proc_add_typedef(P, $def);
454 }
455 | decl_struct[struct] {
456 psi_parser_proc_add_struct(P, $struct);
457 }
458 | decl_union[union] {
459 psi_parser_proc_add_union(P, $union);
460 }
461 | decl_enum[enum] {
462 psi_parser_proc_add_enum(P, $enum);
463 }
464 | impl {
465 psi_parser_proc_add_impl(P, $impl);
466 }
467 ;
468
469 lib:
470 LIB QUOTED_STRING EOS {
471 $lib = $QUOTED_STRING;
472 }
473 ;
474
475 cpp:
476 HASH EOL {
477 $cpp = NULL;
478 }
479 | HASH cpp_exp[exp] EOL {
480 $cpp = $exp;
481 }
482 ;
483
484 cpp_exp[exp]:
485 cpp_message_token cpp_macro_decl_tokens[tokens] {
486 if ($tokens) {
487 struct psi_token *msg = NULL;
488
489 if (psi_plist_get($tokens, 0, &msg)) {
490 size_t index = 1;
491 struct psi_token *next;
492
493 msg = psi_token_copy(msg);
494 while (psi_plist_get($tokens, index++, &next)) {
495 struct psi_token *old = msg;
496 msg = psi_token_cat(" ", 2, msg, next);
497 psi_token_free(&old);
498 }
499 }
500 psi_plist_free($tokens);
501
502 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
503 } else {
504 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
505 }
506 $exp->token = psi_token_copy($cpp_message_token);
507 }
508 | cpp_include_token[INCLUDE] cpp_header_token {
509 $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
510 $exp->token = psi_token_copy($INCLUDE);
511 }
512 | cpp_no_arg_token {
513 $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
514 $exp->token = psi_token_copy($cpp_no_arg_token);
515 }
516 | cpp_name_arg_token any_noeol_token[name_token] {
517 $name_token->type = PSI_T_NAME;
518 $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
519 $exp->token = psi_token_copy($cpp_name_arg_token);
520 }
521 | DEFINE cpp_macro_decl {
522 $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
523 $exp->token = psi_token_copy($DEFINE);
524 }
525 | cpp_exp_arg_token cpp_macro_exp {
526 $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
527 $exp->token = psi_token_copy($cpp_exp_arg_token);
528 }
529 | PRAGMA_ONCE {
530 $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
531 $exp->token = psi_token_copy($PRAGMA_ONCE);
532 }
533 | cpp_ignored_token cpp_macro_decl_tokens[tokens] {
534 psi_plist_free($tokens);
535 $exp = NULL;
536 }
537 ;
538
539 cpp_ignored_token:
540 LINE
541 | PRAGMA
542 ;
543
544 cpp_message_token:
545 ERROR
546 | WARNING
547 ;
548
549 cpp_include_token:
550 IMPORT
551 | INCLUDE
552 | INCLUDE_NEXT
553 ;
554
555 cpp_header_token:
556 QUOTED_STRING
557 | CPP_HEADER
558 ;
559
560 cpp_no_arg_token:
561 ELSE
562 | ENDIF
563 ;
564
565 cpp_name_arg_token:
566 IFDEF
567 | IFNDEF
568 | UNDEF
569 ;
570
571 cpp_exp_arg_token:
572 IF
573 | ELIF
574 ;
575
576 cpp_macro_decl[macro]:
577 any_noeol_token[name_token] cpp_macro_decl_tokens %dprec 1 {
578 $name_token->type = PSI_T_NAME;
579 $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
580 $macro->token = psi_token_copy($name_token);
581 }
582 | name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens %dprec 2 {
583 $name_token->type = PSI_T_NAME;
584 $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
585 $macro->token = psi_token_copy($name_token);
586 }
587 | name_token cpp_macro_exp[num_exp] %dprec 2 {
588 $name_token->type = PSI_T_NAME;
589 $macro = psi_cpp_macro_decl_init(NULL, psi_num_exp_tokens($num_exp, NULL), $num_exp);
590 $macro->token = psi_token_copy($name_token);
591 }
592 | name_token quoted_strings[strings] %dprec 2 {
593 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_token_free);
594 $name_token->type = PSI_T_NAME;
595 $macro = psi_cpp_macro_decl_init(NULL, psi_plist_add(list, &$strings), NULL);
596 $macro->token = psi_token_copy($name_token);
597 }
598 ;
599
600 cpp_macro_sig[sig]:
601 %empty {
602 $sig = psi_plist_init(NULL);
603 }
604 | ELLIPSIS {
605 $sig = psi_plist_init(NULL); /* FIXME */
606 }
607 | cpp_macro_sig_args
608 | cpp_macro_sig_args[args] COMMA ELLIPSIS {
609 $sig = $args;
610 }
611 ;
612
613 cpp_macro_sig_args[args]:
614 name_token {
615 $name_token = psi_token_copy($name_token);
616 $name_token->type = PSI_T_NAME;
617 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
618 }
619 | cpp_macro_sig_args[args_] COMMA name_token {
620 $name_token = psi_token_copy($name_token);
621 $name_token->type = PSI_T_NAME;
622 $args = psi_plist_add($args_, &$name_token);
623 }
624 ;
625
626 cpp_macro_decl_tokens[tokens]:
627 %empty {
628 $tokens = NULL;
629 }
630 | cpp_macro_decl_token_list
631 ;
632
633 cpp_macro_decl_token_list[tokens]:
634 any_noeol_token[token] {
635 $token = psi_token_copy($token);
636 $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
637 }
638 | cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
639 $token = psi_token_copy($token);
640 $tokens = psi_plist_add($tokens_, &$token);
641 }
642 ;
643
644 cpp_macro_exp[exp]:
645 LPAREN cpp_macro_exp[exp_] RPAREN {
646 $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
647 $exp->token = psi_token_copy($LPAREN);
648 }
649 | unary_op_token cpp_macro_exp[exp_] %prec UNARY {
650 $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
651 $exp->token = psi_token_copy($unary_op_token);
652 }
653 | cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
654 $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
655 $exp->token = psi_token_copy($binary_op_token);
656 }
657 | cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
658 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
659 $exp->token = psi_token_copy($IIF);
660 }
661
662 | DEFINED name_token {
663 {
664 uint8_t exists;
665
666 $name_token->type = PSI_T_NAME;
667 exists = psi_cpp_defined(P->preproc, $name_token);
668 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINED, &exists, 0));
669 $exp->token = psi_token_copy($DEFINED);
670 $exp->data.n->token = psi_token_copy($name_token);
671 }
672 }
673 | DEFINED LPAREN name_token RPAREN {
674 {
675 uint8_t exists;
676
677 $name_token->type = PSI_T_NAME;
678 exists = psi_cpp_defined(P->preproc, $name_token);
679 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINED, &exists, 0));
680 $exp->token = psi_token_copy($DEFINED);
681 $exp->data.n->token = psi_token_copy($name_token);
682 }
683 }
684 | NUMBER {
685 $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
686 $exp->token = psi_token_copy($NUMBER);
687 $exp->data.n->token = psi_token_copy($NUMBER);
688 }
689 | QUOTED_CHAR {
690 $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
691 $exp->token = psi_token_copy($QUOTED_CHAR);
692 $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
693 }
694 | sizeof {
695 $exp = psi_num_exp_init_num($sizeof);
696 $exp->token = psi_token_copy($sizeof->token);
697 }
698 | name_token {
699 $name_token->type = PSI_T_NAME;
700 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
701 $exp->token = psi_token_copy($name_token);
702 $exp->data.n->token = psi_token_copy($name_token);
703 }
704 | name_token LPAREN cpp_macro_call_args RPAREN {
705 $name_token->type = PSI_T_NAME;
706 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
707 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
708 $exp->token = psi_token_copy($name_token);
709 $exp->data.n->token = psi_token_copy($name_token);
710 $exp->data.n->data.call->token = psi_token_copy($name_token);
711 }
712 ;
713
714 cpp_macro_call_args[args]:
715 %empty {
716 $args = NULL;
717 }
718 | cpp_macro_call_arg_list
719 ;
720
721 cpp_macro_call_arg_list[args]:
722 CPP_HEADER {
723 /* TODO: clang include test macros */
724 uint8_t no = 1;
725 struct psi_num_exp *exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &no, 0));
726 exp->token = psi_token_copy($CPP_HEADER);
727 exp->data.n->token = psi_token_copy($CPP_HEADER);
728 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free), &exp);
729 }
730 | cpp_macro_exp {
731 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
732 &$cpp_macro_exp);
733 }
734 | cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
735 $args = psi_plist_add($args_, &$cpp_macro_exp);
736 }
737 ;
738
739 constant[const]:
740 CONST impl_type_restricted[type] NSNAME EQUALS impl_def_val EOS {
741 $const = psi_const_init($type, $NSNAME->text, $impl_def_val);
742 $const->token = psi_token_copy($NSNAME);
743 }
744 | CONST NSNAME EQUALS impl_def_val EOS {
745 $const = psi_const_init(NULL, $NSNAME->text, $impl_def_val);
746 $const->token = psi_token_copy($NSNAME);
747 }
748 ;
749
750 impl_def_val[val]:
751 impl_def_val_token[token] %dprec 2 {
752 $val = psi_impl_def_val_init($token->type, $token->text);
753 $val->token = psi_token_copy($token);
754 }
755 | num_exp[num] %dprec 1 {
756 $val = psi_impl_def_val_init(PSI_T_NUMBER, $num);
757 $val->token = psi_token_copy($num->token);
758 }
759 | quoted_strings[token] {
760 $val = psi_impl_def_val_init($token->type, $token->text);
761 $val->token = $token;
762 }
763 ;
764
765 impl_def_val_token:
766 NULL
767 | TRUE
768 | FALSE
769 ;
770
771 decl_typedef[def]:
772 TYPEDEF typedef[def_] EOS {
773 $def = $def_;
774 }
775 /*
776 | TYPEDEF VOID name_token EOS {
777 $def = psi_decl_arg_init(
778 psi_decl_type_init(PSI_T_VOID, $VOID->text),
779 psi_decl_var_init($name_token->text, 0, 0)
780 );
781 $def->token = psi_token_copy($VOID);
782 $def->type->token = psi_token_copy($VOID);
783 $def->var->token = psi_token_copy($name_token);
784 }
785 */
786 | CPP_EXTENSION TYPEDEF typedef[def_] EOS {
787 $def = $def_;
788 }
789 ;
790
791 typedef[def]:
792 typedef_decl {
793 $def = $typedef_decl;
794 }
795 | CPP_EXTENSION typedef_decl {
796 $def = $typedef_decl;
797 }
798 ;
799
800 typedef_anon[def]:
801 typedef_anon_decl {
802 $def = $typedef_anon_decl;
803 }
804 | CPP_EXTENSION typedef_anon_decl {
805 $def = $typedef_anon_decl;
806 }
807 ;
808
809 typedef_decl[def]:
810 decl_arg
811 | decl_func_body[decl] {
812 $def = psi_decl_arg_init(
813 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
814 psi_decl_var_copy($decl->func->var)
815 );
816 $def->type->token = psi_token_copy($decl->func->token);
817 $def->type->real.func = $decl;
818 }
819 | decl_enum[enum] name_token {
820 $name_token->type = PSI_T_NAME;
821 $def = psi_decl_arg_init(
822 psi_decl_type_init(PSI_T_ENUM, $enum->name),
823 psi_decl_var_init($name_token->text, 0, 0)
824 );
825 $def->var->token = psi_token_copy($name_token);
826 $def->type->token = psi_token_copy($enum->token);
827 $def->type->real.enm = $enum;
828 psi_parser_proc_add_enum(P, $enum);
829 }
830 | struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
831 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
832 $def->type->token = $struct;
833 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
834 $def->type->real.strct->token = psi_token_copy($struct);
835 $def->type->real.strct->align = $as.pos;
836 $def->type->real.strct->size = $as.len;
837 psi_parser_proc_add_struct(P, $def->type->real.strct);
838 }
839 | union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
840 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
841 $def->type->token = $union;
842 $def->type->real.unn = psi_decl_union_init($union->text, $args);
843 $def->type->real.unn->token = psi_token_copy($union);
844 $def->type->real.unn->align = $as.pos;
845 $def->type->real.unn->size = $as.len;
846 psi_parser_proc_add_union(P, $def->type->real.unn);
847 }
848 ;
849
850 typedef_anon_decl[def]:
851 typedef_decl %dprec 2
852 | qualified_decl_type[type] %dprec 1 {
853 $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
854 $def->var->token = psi_token_copy($type->token);
855 }
856 | decl_enum[enum] {
857 $def = psi_decl_arg_init(
858 psi_decl_type_init(PSI_T_ENUM, $enum->name),
859 psi_decl_var_init(NULL, 0, 0)
860 );
861 $def->var->token = psi_token_copy($enum->token);
862 $def->type->token = psi_token_copy($enum->token);
863 $def->type->real.enm = $enum;
864 psi_parser_proc_add_enum(P, $enum);
865 }
866 | struct_name[struct] align_and_size[as] struct_args_block[args] {
867 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
868 $def->type->token = $struct;
869 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
870 $def->type->real.strct->token = psi_token_copy($struct);
871 $def->type->real.strct->align = $as.pos;
872 $def->type->real.strct->size = $as.len;
873 psi_parser_proc_add_struct(P, $def->type->real.strct);
874 }
875 | union_name[union] align_and_size[as] struct_args_block[args] {
876 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
877 $def->type->token = $union;
878 $def->type->real.unn = psi_decl_union_init($union->text, $args);
879 $def->type->real.unn->token = psi_token_copy($union);
880 $def->type->real.unn->align = $as.pos;
881 $def->type->real.unn->size = $as.len;
882 psi_parser_proc_add_union(P, $def->type->real.unn);
883 }
884 ;
885
886 qualified_decl_type[type]:
887 decl_type
888 | decl_type_qualifier_token decl_type[type_] {
889 $type = $type_;
890 }
891 | qualified_decl_type[type_] decl_type_qualifier_token {
892 $type = $type_;
893 }
894 ;
895
896 decl_type_qualifier_token:
897 CONST
898 | VOLATILE
899 ;
900
901 decl_type[type]:
902 decl_type_simple[token] {
903 $type = psi_decl_type_init($token->type, $token->text);
904 $type->token = $token;
905 }
906 | decl_type_complex
907 ;
908
909 decl_type_complex[type]:
910 STRUCT[token] name_token {
911 $name_token->type = PSI_T_NAME;
912 $type = psi_decl_type_init($token->type, $name_token->text);
913 $type->token = psi_token_copy($name_token);
914 }
915 | UNION[token] name_token {
916 $name_token->type = PSI_T_NAME;
917 $type = psi_decl_type_init($token->type, $name_token->text);
918 $type->token = psi_token_copy($name_token);
919 }
920 | ENUM[token] name_token {
921 $name_token->type = PSI_T_NAME;
922 $type = psi_decl_type_init($token->type, $name_token->text);
923 $type->token = psi_token_copy($name_token);
924 }
925 ;
926
927 decl_type_simple[type]:
928 decl_int_type
929 | decl_real_type
930 | NAME[type_] {
931 $type = psi_token_copy($type_);
932 }
933 | VOID[type_] {
934 $type = psi_token_copy($type_);
935 }
936 ;
937
938 decl_real_type[type]: /* allocated, so free, if set */
939 FLOAT[type_] {
940 $type = psi_token_copy($type_);
941 }
942 | DOUBLE[type_] {
943 $type = psi_token_copy($type_);
944 }
945 | LONG DOUBLE {
946 $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
947 }
948 ;
949
950 int_signed[i]:
951 SIGNED
952 | UNSIGNED
953 ;
954
955 int_width[i]: /* allocated, so free, if set */
956 SHORT {
957 $i = psi_token_copy($SHORT);
958 }
959 | LONG {
960 $i = psi_token_copy($LONG);
961 }
962 | LONG[l1] LONG[l2] {
963 $i = psi_token_cat(" ", 2, $l1, $l2);
964 }
965 ;
966
967 decl_int_type[type]: /* allocated, so free, if set */
968 CHAR {
969 $type = psi_token_copy($CHAR);
970 }
971 | INT {
972 $type = psi_token_copy($INT);
973 }
974 | int_signed int_signed_types {
975 if ($2) {
976 $type = psi_token_cat(" ", 2, $1, $2);
977 psi_token_free(&$2);
978 } else {
979 $type = psi_token_copy($1);
980 }
981 }
982 | int_width int_width_types {
983 if ($2) {
984 $type = psi_token_cat(" ", 2, $1, $2);
985 psi_token_free(&$1);
986 psi_token_free(&$2);
987 } else {
988 $type = $1;
989 }
990 }
991 ;
992
993 int_signed_types[type]: /* allocated, so free, if set */
994 %empty {
995 $type = NULL;
996 }
997 | NAME {
998 $type = psi_token_copy($NAME);
999 }
1000 | CHAR {
1001 $type = psi_token_copy($CHAR);
1002 }
1003 | SHORT signed_short_types {
1004 if ($2) {
1005 $type = psi_token_cat(" ", 2, $1, $2);
1006 } else {
1007 $type = psi_token_copy($1);
1008 }
1009 }
1010 | INT {
1011 $type = psi_token_copy($INT);
1012 }
1013 | LONG signed_long_types {
1014 if ($2) {
1015 $type = psi_token_cat(" ", 2, $1, $2);
1016 } else {
1017 $type = psi_token_copy($1);
1018 }
1019 }
1020 ;
1021
1022 signed_short_types[type]:
1023 %empty {
1024 $type = NULL;
1025 }
1026 | INT
1027 ;
1028 signed_long_types[type]:
1029 %empty {
1030 $type = NULL;
1031 }
1032 | INT
1033 | LONG
1034 | LONG INT
1035 ;
1036
1037 int_width_types[type]: /* allocated, so free, if set */
1038 %empty {
1039 $type = NULL;
1040 }
1041 | INT {
1042 $type = psi_token_copy($INT);
1043 }
1044 | int_signed int_signed_types {
1045 if ($2) {
1046 $type = psi_token_cat(" ", 2, $1, $2);
1047 psi_token_free(&$2);
1048 } else {
1049 $type = psi_token_copy($1);
1050 }
1051 }
1052 ;
1053
1054 decl_stmt:
1055 decl decl_asm EOS {
1056 $decl_stmt = $decl;
1057 if ($decl_asm) {
1058 $decl->redir = zend_string_copy($decl_asm->text);
1059 psi_token_free(&$decl_asm);
1060 }
1061 }
1062 | CPP_EXTENSION decl decl_asm EOS {
1063 $decl_stmt = $decl;
1064 if ($decl_asm) {
1065 $decl->redir = zend_string_copy($decl_asm->text);
1066 psi_token_free(&$decl_asm);
1067 }
1068 }
1069 ;
1070
1071 decl_asm:
1072 %empty {
1073 $decl_asm = NULL;
1074 }
1075 | CPP_ASM LPAREN quoted_strings RPAREN {
1076 $decl_asm = $quoted_strings;
1077 }
1078 ;
1079
1080 quoted_strings[strings]:
1081 QUOTED_STRING {
1082 $strings = psi_token_copy($QUOTED_STRING);
1083 }
1084 | quoted_strings[strings_] QUOTED_STRING {
1085 $strings = psi_token_cat("", 2, $strings_, $QUOTED_STRING);
1086 psi_token_free(&$strings_);
1087 }
1088 ;
1089
1090 decl_extvar_stmt[list]:
1091 NAME decl_arg decl_extvar_list[vars] decl_asm EOS {
1092 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
1093
1094 if ($vars) {
1095 size_t i = 0;
1096 struct psi_decl_var *var;
1097
1098 while (psi_plist_get($vars, i++, &var)) {
1099 if (psi_decl_extvar_is_blacklisted(var->name->val)) {
1100 psi_decl_var_free(&var);
1101 } else {
1102 struct psi_decl_extvar *evar = psi_decl_extvar_init(
1103 psi_decl_arg_init(psi_decl_type_copy($decl_arg->type), var));
1104 list = psi_plist_add(list, &evar);
1105 }
1106 }
1107 free($vars);
1108 }
1109
1110 if (psi_decl_extvar_is_blacklisted($decl_arg->var->name->val)) {
1111 psi_decl_arg_free(&$decl_arg);
1112 } else {
1113 struct psi_decl_extvar *evar = psi_decl_extvar_init($decl_arg);
1114
1115 if ($decl_asm) {
1116 evar->redir = zend_string_copy($decl_asm->text);
1117 psi_token_free(&$decl_asm);
1118 }
1119 list = psi_plist_add(list, &evar);
1120 }
1121
1122 $list = list;
1123 }
1124 ;
1125
1126 decl_extvar_list[list]:
1127 %empty {
1128 $list = NULL;
1129 }
1130 | COMMA decl_vars {
1131 $list = $decl_vars;
1132 }
1133 ;
1134
1135 decl_vars[vars]:
1136 decl_var[var] {
1137 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1138 }
1139 | decl_vars[vars_] COMMA decl_var[var] {
1140 $vars = psi_plist_add($vars_, &$var);
1141 }
1142 ;
1143
1144 ignored_decl:
1145 ignored_decl_qualifiers decl_body ignored_decl_body {
1146 $ignored_decl = $decl_body;
1147 }
1148 ;
1149
1150 ignored_decl_qualifiers:
1151 STATIC
1152 | STATIC CPP_INLINE
1153 | CPP_EXTENSION CPP_INLINE
1154 | CPP_EXTENSION STATIC CPP_INLINE
1155 | CPP_INLINE
1156 | NAME CPP_INLINE
1157 ;
1158
1159 ignored_decl_body:
1160 LBRACE ignored_decl_body_stmts RBRACE
1161 ;
1162
1163 ignored_decl_body_stmts:
1164 ignored_decl_body_stmt
1165 | ignored_decl_body_stmts ignored_decl_body_stmt
1166 ;
1167
1168 ignored_decl_body_stmt:
1169 any_nobrace_token
1170 | ignored_decl_body
1171 ;
1172
1173 decl:
1174 decl_body
1175 | NAME[abi] decl_body {
1176 $decl = $decl_body;
1177 $decl->abi = psi_decl_abi_init($abi->text);
1178 }
1179 ;
1180
1181 decl_body:
1182 decl_func_body
1183 | decl_functor_body
1184 ;
1185
1186 decl_func_body[decl]:
1187 decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1188 $decl = psi_decl_init($func, $args);
1189 if ($as) {
1190 $decl->func->var->pointer_level += 1;
1191 $decl->func->var->array_size = $as;
1192 }
1193 }
1194 | decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1195 $decl = psi_decl_init($func, $args);
1196 $decl->varargs = 1;
1197 if ($as) {
1198 $decl->func->var->pointer_level += 1;
1199 $decl->func->var->array_size = $as;
1200 }
1201 }
1202 ;
1203
1204 decl_functor_body[decl]:
1205 decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1206 $decl = psi_decl_init($func, $args);
1207 if ($as) {
1208 $decl->func->var->pointer_level += 1;
1209 $decl->func->var->array_size = $as;
1210 }
1211 }
1212 | decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1213 $decl = psi_decl_init($func, $args);
1214 $decl->varargs = 1;
1215 if ($as) {
1216 $decl->func->var->pointer_level += 1;
1217 $decl->func->var->array_size = $as;
1218 }
1219 }
1220 | qualified_decl_type[rval_type] indirection[i] LPAREN indirection[unused1] name_token[NAME] LPAREN decl_args[args] RPAREN RPAREN LPAREN decl_args[rval_args] RPAREN array_size[as] {
1221 (void) $unused1;
1222 $NAME->type = PSI_T_NAME;
1223
1224 struct psi_token *type_token = psi_token_append("@", psi_token_copy($NAME), 1, "rval");
1225 struct psi_decl_arg *rval_func = psi_decl_arg_init($rval_type, psi_decl_var_init(type_token->text, $i, 0));
1226 struct psi_decl *rval_decl = psi_decl_init(rval_func, $rval_args);
1227
1228 rval_func->var->token = psi_token_copy(type_token);
1229 rval_func->token = psi_token_copy(type_token);
1230 if ($as) {
1231 rval_func->var->pointer_level += 1;
1232 rval_func->var->array_size = $as;
1233 }
1234
1235 struct psi_decl_type *type = psi_decl_type_init(PSI_T_FUNCTION, type_token->text);
1236 struct psi_decl_arg *func = psi_decl_arg_init(type, psi_decl_var_init($NAME->text, 1, 0));
1237
1238 type->real.func = rval_decl;
1239 func->var->token = psi_token_copy($NAME);
1240 func->token = psi_token_copy($NAME);
1241
1242 $decl = psi_decl_init(func, $args);
1243 }
1244 | qualified_decl_type[rval_type] indirection[i] LPAREN indirection[unused1] LPAREN indirection[unused2] name_token[NAME] RPAREN LPAREN decl_args[args] RPAREN RPAREN LPAREN decl_args[rval_args] RPAREN array_size[as] {
1245 (void) $unused1;
1246 (void) $unused2;
1247 $NAME->type = PSI_T_NAME;
1248
1249 struct psi_token *type_token = psi_token_append("@", psi_token_copy($NAME), 1, "rval");
1250 struct psi_decl_arg *rval_func = psi_decl_arg_init($rval_type, psi_decl_var_init(type_token->text, $i, 0));
1251 struct psi_decl *rval_decl = psi_decl_init(rval_func, $rval_args);
1252
1253 rval_func->var->token = psi_token_copy(type_token);
1254 rval_func->token = psi_token_copy(type_token);
1255 if ($as) {
1256 rval_func->var->pointer_level += 1;
1257 rval_func->var->array_size = $as;
1258 }
1259
1260 struct psi_decl_type *type = psi_decl_type_init(PSI_T_FUNCTION, type_token->text);
1261 struct psi_decl_arg *func = psi_decl_arg_init(type, psi_decl_var_init($NAME->text, 1, 0));
1262
1263 type->real.func = rval_decl;
1264 func->var->token = psi_token_copy($NAME);
1265 func->token = psi_token_copy($NAME);
1266 type->token = type_token;
1267
1268 $decl = psi_decl_init(func, $args);
1269 }
1270 ;
1271
1272 decl_anon_functor_body[decl]:
1273 decl_anon_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1274 $decl = psi_decl_init($func, $args);
1275 if ($as) {
1276 $decl->func->var->pointer_level += 1;
1277 $decl->func->var->array_size = $as;
1278 }
1279 }
1280 | decl_anon_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1281 $decl = psi_decl_init($func, $args);
1282 $decl->varargs = 1;
1283 if ($as) {
1284 $decl->func->var->pointer_level += 1;
1285 $decl->func->var->array_size = $as;
1286 }
1287 }
1288 ;
1289
1290 decl_functor[arg]:
1291 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1292 (void) $unused1;
1293 $NAME->type = PSI_T_NAME;
1294 $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1295 $arg->var->token = psi_token_copy($NAME);
1296 $arg->token = psi_token_copy($NAME);
1297 }
1298
1299 /*
1300 | CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1301 (void) $unused1;
1302 $NAME->type = PSI_T_NAME;
1303 $arg = psi_decl_arg_init(
1304 psi_decl_type_init($VOID->type, $VOID->text),
1305 psi_decl_var_init($NAME->text, $pointers, 0)
1306 );
1307 $arg->type->token = psi_token_copy($VOID);
1308 $arg->var->token = psi_token_copy($NAME);
1309 $arg->token = psi_token_copy($NAME);
1310 }
1311 | VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1312 (void) $unused1;
1313 $NAME->type = PSI_T_NAME;
1314 $arg = psi_decl_arg_init(
1315 psi_decl_type_init($VOID->type, $VOID->text),
1316 psi_decl_var_init($NAME->text, $pointers, 0)
1317 );
1318 $arg->type->token = psi_token_copy($VOID);
1319 $arg->var->token = psi_token_copy($NAME);
1320 $arg->token = psi_token_copy($NAME);
1321 }
1322 | VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1323 (void) $unused1;
1324 $NAME->type = PSI_T_NAME;
1325 $arg = psi_decl_arg_init(
1326 psi_decl_type_init($VOID->type, $VOID->text),
1327 psi_decl_var_init($NAME->text, 0, 0)
1328 );
1329 $arg->type->token = psi_token_copy($VOID);
1330 $arg->var->token = psi_token_copy($NAME);
1331 $arg->token = psi_token_copy($NAME);
1332 }
1333 */
1334 ;
1335
1336 decl_anon_functor[arg]:
1337 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] RPAREN {
1338 (void) $unused1;
1339 $arg = psi_decl_arg_init($type, psi_decl_var_init(NULL, $i, 0));
1340 $arg->var->token = psi_token_copy($LPAREN);
1341 $arg->token = psi_token_copy($LPAREN);
1342 }
1343 /*
1344 | CONST VOID pointers LPAREN indirection[unused1] RPAREN {
1345 (void) $unused1;
1346 $arg = psi_decl_arg_init(
1347 psi_decl_type_init($VOID->type, $VOID->text),
1348 psi_decl_var_init(NULL, $pointers, 0)
1349 );
1350 $arg->type->token = psi_token_copy($VOID);
1351 $arg->var->token = psi_token_copy($VOID);
1352 $arg->token = psi_token_copy($VOID);
1353 }
1354 | VOID pointers LPAREN indirection[unused1] RPAREN {
1355 (void) $unused1;
1356 $arg = psi_decl_arg_init(
1357 psi_decl_type_init($VOID->type, $VOID->text),
1358 psi_decl_var_init(NULL, $pointers, 0)
1359 );
1360 $arg->type->token = psi_token_copy($VOID);
1361 $arg->var->token = psi_token_copy($VOID);
1362 $arg->token = psi_token_copy($VOID);
1363 }
1364 | VOID LPAREN indirection[unused1] RPAREN {
1365 (void) $unused1;
1366 $arg = psi_decl_arg_init(
1367 psi_decl_type_init($VOID->type, $VOID->text),
1368 psi_decl_var_init(NULL, 0, 0)
1369 );
1370 $arg->type->token = psi_token_copy($VOID);
1371 $arg->var->token = psi_token_copy($VOID);
1372 $arg->token = psi_token_copy($VOID);
1373 }
1374 */
1375 ;
1376
1377 decl_func[func]:
1378 decl_arg
1379 /*
1380 | VOID name_token[NAME] {
1381 $func = psi_decl_arg_init(
1382 psi_decl_type_init($VOID->type, $VOID->text),
1383 psi_decl_var_init($NAME->text, 0, 0)
1384 );
1385 $func->type->token = psi_token_copy($VOID);
1386 $func->var->token = psi_token_copy($NAME);
1387 $func->token = psi_token_copy($NAME);
1388 }
1389 */
1390 ;
1391
1392 decl_args[args]:
1393 %empty {
1394 $args = NULL;
1395 }
1396 | VOID %dprec 2 {
1397 $args = NULL;
1398 }
1399 | decl_arg_list[args_] %dprec 1 {
1400 $args = $args_;
1401 }
1402 ;
1403
1404 decl_arg_list[args]:
1405 decl_anon_arg[arg] {
1406 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1407 }
1408 | decl_arg_list[args_] COMMA decl_anon_arg[arg] {
1409 $args = psi_plist_add($args_, &$arg);
1410 }
1411 ;
1412
1413 decl_anon_arg[arg]:
1414 decl_anon_functor_body[decl] {
1415 char digest[17];
1416 struct psi_token *name;
1417
1418 psi_token_hash($decl->func->token, digest);
1419 name = psi_token_append("@", psi_token_copy($decl->func->token), 2, "funct", digest);
1420
1421 $arg = psi_decl_arg_init(
1422 psi_decl_type_init(PSI_T_FUNCTION, name->text),
1423 psi_decl_var_copy($decl->func->var)
1424 );
1425 $arg->token = name;
1426 $arg->type->token = psi_token_copy($decl->func->token);
1427 $arg->type->real.func = $decl;
1428 }
1429 | decl_arg %dprec 2 {
1430 $arg = $decl_arg;
1431 }
1432 | qualified_decl_type[type] indirection array_size[as] %dprec 1 {
1433 $arg = psi_decl_arg_init(
1434 $type,
1435 psi_decl_var_init(NULL, $indirection, $as)
1436 );
1437 }
1438 /*
1439 | CONST VOID pointers {
1440 $arg = psi_decl_arg_init(
1441 psi_decl_type_init($VOID->type, $VOID->text),
1442 psi_decl_var_init(NULL, $pointers, 0)
1443 );
1444 $arg->type->token = psi_token_copy($VOID);
1445 $arg->var->token = psi_token_copy($VOID);
1446 $arg->token = psi_token_copy($VOID);
1447 }
1448 | VOID pointers {
1449 $arg = psi_decl_arg_init(
1450 psi_decl_type_init($VOID->type, $VOID->text),
1451 psi_decl_var_init(NULL, $pointers, 0)
1452 );
1453 $arg->type->token = psi_token_copy($VOID);
1454 $arg->var->token = psi_token_copy($VOID);
1455 $arg->token = psi_token_copy($VOID);
1456 }
1457 */
1458 ;
1459
1460 decl_arg[arg]:
1461 decl_functor_body[decl] {
1462 $arg = psi_decl_arg_init(
1463 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1464 psi_decl_var_copy($decl->func->var)
1465 );
1466 $arg->type->token = psi_token_copy($decl->func->token);
1467 $arg->type->real.func = $decl;
1468 }
1469 | qualified_decl_type[type] decl_var[var] {
1470 $arg = psi_decl_arg_init($type, $var);
1471 }
1472 /*
1473 | CONST VOID pointers name_token[NAME] {
1474 $NAME->type = PSI_T_NAME;
1475 $arg = psi_decl_arg_init(
1476 psi_decl_type_init($VOID->type, $VOID->text),
1477 psi_decl_var_init($NAME->text, $pointers, 0)
1478 );
1479 $arg->type->token = psi_token_copy($VOID);
1480 $arg->var->token = psi_token_copy($NAME);
1481 $arg->token = psi_token_copy($NAME);
1482 }
1483 | VOID pointers name_token[NAME] {
1484 $NAME->type = PSI_T_NAME;
1485 $arg = psi_decl_arg_init(
1486 psi_decl_type_init($VOID->type, $VOID->text),
1487 psi_decl_var_init($NAME->text, $pointers, 0)
1488 );
1489 $arg->type->token = psi_token_copy($VOID);
1490 $arg->var->token = psi_token_copy($NAME);
1491 $arg->token = psi_token_copy($NAME);
1492 }
1493 */
1494 ;
1495
1496 decl_var[var]:
1497 pointers name_token array_size {
1498 $name_token->type = PSI_T_NAME;
1499 $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1500 $var->token = psi_token_copy($name_token);
1501 }
1502 | name_token array_size {
1503 $name_token->type = PSI_T_NAME;
1504 $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1505 $var->token = psi_token_copy($name_token);
1506 }
1507 ;
1508
1509 decl_union[union]:
1510 UNION name_token align_and_size[as] decl_struct_args[args] {
1511 $name_token->type = PSI_T_NAME;
1512 $union = psi_decl_union_init($name_token->text, $args);
1513 $union->align = $as.pos;
1514 $union->size = $as.len;
1515 $union->token = psi_token_copy($name_token);
1516 }
1517 ;
1518
1519 decl_struct[struct]:
1520 STRUCT name_token align_and_size[as] decl_struct_args[args] {
1521 $name_token->type = PSI_T_NAME;
1522 $struct = psi_decl_struct_init($name_token->text, $args);
1523 $struct->align = $as.pos;
1524 $struct->size = $as.len;
1525 $struct->token = psi_token_copy($name_token);
1526 }
1527 ;
1528
1529 decl_struct_args[args]:
1530 EOS {
1531 $args = NULL;
1532 }
1533 | struct_args_block
1534 ;
1535
1536 struct_args_block[args]:
1537 LBRACE struct_args RBRACE {
1538 $args = $struct_args;
1539 }
1540 ;
1541
1542 struct_args[args]:
1543 typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1544 $arg->layout = $layout;
1545 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1546 if ($vars) {
1547 size_t i = 0;
1548 struct psi_decl_arg *arg;
1549
1550 while (psi_plist_get($vars, i++, &arg)) {
1551 arg->type = psi_decl_type_copy($arg->type);
1552 $args = psi_plist_add($args, &arg);
1553 }
1554 free($vars);
1555 }
1556 }
1557 | struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1558 $arg->layout = $layout;
1559 $args = psi_plist_add($args_, &$arg);
1560 if ($vars) {
1561 size_t i = 0;
1562 struct psi_decl_arg *arg;
1563
1564 while (psi_plist_get($vars, i++, &arg)) {
1565 arg->type = psi_decl_type_copy($arg->type);
1566 $args = psi_plist_add($args, &arg);
1567 }
1568 free($vars);
1569 }
1570 }
1571 ;
1572
1573 struct_arg_var_list[vars]:
1574 %empty {
1575 $vars = NULL;
1576 }
1577 | COMMA decl_vars_with_layout[vars_] {
1578 $vars = $vars_;
1579 }
1580 ;
1581
1582 decl_vars_with_layout[vars]:
1583 decl_var[var] decl_layout[layout] {
1584 {
1585 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1586 arg->layout = $layout;
1587 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1588 }
1589 }
1590 | decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1591 {
1592 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1593 arg->layout = $layout;
1594 $vars = psi_plist_add($vars_, &arg);
1595 }
1596 }
1597 | decl_layout[layout] {
1598 {
1599 struct psi_decl_var *var = psi_decl_var_init(NULL, 0, 0);
1600 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, var);
1601 arg->layout = $layout;
1602 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1603 }
1604 }
1605 | decl_vars_with_layout[vars_] COMMA decl_layout[layout] {
1606 {
1607 struct psi_decl_var *var = psi_decl_var_init(NULL, 0, 0);
1608 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, var);
1609 arg->layout = $layout;
1610 $vars = psi_plist_add($vars_, &arg);
1611 }
1612 }
1613 ;
1614
1615 decl_enum[enum]:
1616 enum_name LBRACE decl_enum_items[list] optional_comma RBRACE {
1617 $enum = psi_decl_enum_init($enum_name->text, $list);
1618 $enum->token = $enum_name;
1619 }
1620 ;
1621
1622 decl_enum_items[list]:
1623 decl_enum_item[i] {
1624 $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1625 }
1626 | decl_enum_items[list_] COMMA decl_enum_item[i] {
1627 $list = psi_plist_add($list_, &$i);
1628 }
1629 ;
1630
1631 decl_enum_item[i]:
1632 name_token {
1633 $name_token->type = PSI_T_NAME;
1634 $i = psi_decl_enum_item_init($name_token->text, NULL);
1635 $i->token = psi_token_copy($name_token);
1636 }
1637 | name_token EQUALS num_exp {
1638 $name_token->type = PSI_T_NAME;
1639 $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1640 $i->token = psi_token_copy($name_token);
1641 }
1642 ;
1643
1644 num_exp[exp]:
1645 number {
1646 $exp = psi_num_exp_init_num($number);
1647 $exp->token = psi_token_copy($number->token);
1648 }
1649 | LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1650 $exp = psi_num_exp_init_cast($type, $exp_);
1651 $exp->token = psi_token_copy($type->token);
1652 }
1653 | LPAREN num_exp[exp_] RPAREN {
1654 $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1655 $exp->token = psi_token_copy($LPAREN);
1656 }
1657 | num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1658 $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1659 $exp->token = psi_token_copy($op);
1660 }
1661 | unary_op_token[op] num_exp[exp_] %prec UNARY {
1662 $exp = psi_num_exp_init_unary($op->type, $exp_);
1663 $exp->token = psi_token_copy($op);
1664 }
1665 | num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1666 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1667 $exp->token = psi_token_copy($IIF);
1668 }
1669 ;
1670
1671 number[num]:
1672 NUMBER[token] {
1673 $num = psi_number_init($token->type, $token->text, $token->flags);
1674 $num->token = psi_token_copy($token);
1675 }
1676 | NSNAME[token] {
1677 $num = psi_number_init($token->type, $token->text, 0);
1678 $num->token = psi_token_copy($token);
1679 }
1680 | QUOTED_CHAR[token] {
1681 $num = psi_number_init($token->type, $token->text, 0);
1682 $num->token = psi_token_copy($token);
1683 }
1684 | NULL[token] {
1685 $num = psi_number_init($token->type, $token->text, 0);
1686 $num->token = psi_token_copy($token);
1687 }
1688 | decl_var {
1689 $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1690 $num->token = psi_token_copy($decl_var->token);
1691 }
1692 | sizeof {
1693 $num = $sizeof;
1694 }
1695 ;
1696
1697 sizeof:
1698 SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1699 $sizeof = $sizeof_;
1700 $sizeof->token = psi_token_copy($SIZEOF);
1701 }
1702 | SIZEOF sizeof_body_notypes[sizeof_] {
1703 $sizeof = $sizeof_;
1704 $sizeof->token = psi_token_copy($SIZEOF);
1705 }
1706 ;
1707
1708 sizeof_body[sizeof]:
1709 sizeof_body_notypes[sizeof_] {
1710 $sizeof = $sizeof_;
1711 }
1712 | decl_type indirection {
1713 if ($indirection) {
1714 int8_t sizeof_void_p = sizeof(void *);
1715 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1716 psi_decl_type_free(&$decl_type);
1717 } else {
1718 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1719 }
1720 }
1721 ;
1722
1723 sizeof_body_notypes[sizeof]:
1724 AMPERSAND NAME {
1725 int8_t sizeof_void_p = sizeof(void *);
1726 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1727 }
1728 | QUOTED_CHAR {
1729 int8_t sizeof_a = sizeof('a');
1730 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1731 }
1732 | QUOTED_STRING {
1733 uint64_t len = $QUOTED_STRING->text->len + 1;
1734 $sizeof = psi_number_init(PSI_T_UINT64, &len, 0);
1735 }
1736 ;
1737
1738 enum_name[name]:
1739 ENUM optional_name[name_] {
1740 if ($name_) {
1741 $name = psi_token_copy($name_);
1742 } else {
1743 char digest[17];
1744
1745 psi_token_hash($ENUM, digest);
1746 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1747 }
1748 }
1749 ;
1750
1751 union_name[name]:
1752 UNION optional_name[name_] {
1753 if ($name_) {
1754 $name = psi_token_copy($name_);
1755 } else {
1756 char digest[17];
1757
1758 psi_token_hash($UNION, digest);
1759 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1760 }
1761 }
1762 ;
1763
1764 struct_name[name]:
1765 STRUCT optional_name[name_] {
1766 if ($name_) {
1767 $name = psi_token_copy($name_);
1768 } else {
1769 char digest[17];
1770
1771 psi_token_hash($STRUCT, digest);
1772 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1773 }
1774 }
1775 ;
1776
1777 optional_name[name]:
1778 %empty {
1779 $name = NULL;
1780 }
1781 | name_token {
1782 $name = $name_token;
1783 $name->type = PSI_T_NAME;
1784 }
1785 ;
1786
1787 optional_comma:
1788 %empty
1789 | COMMA
1790 ;
1791
1792 decl_layout[l]:
1793 %empty {
1794 $l = NULL;
1795 }
1796 | COLON NUMBER[width] {
1797 $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text->val), NULL));
1798 }
1799 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1800 $l = psi_layout_init(atol($align->text->val), atol($size->text->val), NULL);
1801 }
1802 | COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1803 $l = psi_layout_init(atol($align->text->val), atol($size->text->val), psi_layout_init(0, atol($width->text->val), NULL));
1804 }
1805 ;
1806
1807 align_and_size[as]:
1808 %empty {
1809 $as.pos = 0;
1810 $as.len = 0;
1811 }
1812 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1813 $as.pos = atol($align->text->val);
1814 $as.len = atol($size->text->val);
1815 }
1816 ;
1817
1818 array_size[as]:
1819 %empty {
1820 $as = 0;
1821 }
1822 | LBRACKET array_qualifier_token RBRACKET {
1823 $as = 0;
1824 }
1825 | LBRACKET num_exp RBRACKET {
1826 struct psi_validate_scope scope = {0};
1827 psi_validate_scope_ctor(&scope);
1828 scope.cpp = P->preproc;
1829 if (psi_num_exp_validate(PSI_DATA(P), $num_exp, &scope)) {
1830 $as = psi_num_exp_get_long($num_exp, NULL, P->preproc);
1831 } else {
1832 $as = 0;
1833 }
1834 psi_num_exp_free(&$num_exp);
1835 psi_validate_scope_dtor(&scope);
1836 }
1837 ;
1838
1839 array_qualifier_token:
1840 %empty
1841 | CPP_RESTRICT
1842 | VOLATILE
1843 | CONST
1844 ;
1845
1846 indirection[i]:
1847 %empty {
1848 $i = 0;
1849 }
1850 | pointers[p] %prec UNARY {
1851 $i = $p;
1852 }
1853 ;
1854
1855 pointers[p]:
1856 asterisks
1857 | asterisks[a] CPP_RESTRICT {
1858 $p = $a;
1859 }
1860 ;
1861
1862 asterisks[a]:
1863 asterisk {
1864 $a = 1;
1865 }
1866 | asterisks[a_] asterisk {
1867 $a = $a_ + 1;
1868 }
1869 ;
1870
1871 asterisk:
1872 ASTERISK
1873 | ASTERISK pointer_qualifier_token
1874 ;
1875
1876 pointer_qualifier_token:
1877 CONST
1878 | VOLATILE
1879 ;
1880
1881 /*
1882 *
1883 * impl
1884 *
1885 */
1886
1887 impl:
1888 impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1889 $impl = psi_impl_init($func, $stmts);
1890 }
1891 | STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1892 $impl = psi_impl_init($func, $stmts);
1893 $func->static_memory = 1;
1894 }
1895 ;
1896
1897 impl_func[func]:
1898 FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1899 $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1900 $func->token = psi_token_copy($NSNAME);
1901 $func->return_reference = $r;
1902 }
1903 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1904 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1905 $func->token = psi_token_copy($NSNAME);
1906 $func->return_reference = $r;
1907 }
1908 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1909 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1910 $func->token = psi_token_copy($NSNAME);
1911 $func->return_reference = $r;
1912 $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1913 $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1914 }
1915 ;
1916
1917 impl_args[args]:
1918 impl_arg[arg] {
1919 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1920 }
1921 | impl_args[args_] COMMA impl_arg[arg] {
1922 $args = psi_plist_add($args_, &$arg);
1923 }
1924 ;
1925
1926 impl_arg[arg]:
1927 impl_type[type] impl_var[var] {
1928 $arg = psi_impl_arg_init($type, $var, NULL);
1929 }
1930 | impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1931 $arg = psi_impl_arg_init($type, $var, $val);
1932 }
1933 ;
1934
1935 impl_var[var]:
1936 reference DOLLAR_NAME {
1937 $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1938 $var->token = psi_token_copy($DOLLAR_NAME);
1939 }
1940 ;
1941
1942 impl_type[type]:
1943 impl_type_token[token] {
1944 $type = psi_impl_type_init($token->type, $token->text);
1945 $type->token = psi_token_copy($token);
1946 }
1947 ;
1948
1949 impl_type_restricted[type]:
1950 impl_type_restricted_token[token] {
1951 $type = psi_impl_type_init($token->type, $token->text);
1952 $type->token = psi_token_copy($token);
1953 }
1954 ;
1955
1956 impl_type_token:
1957 impl_type_restricted_token
1958 | impl_type_extended_token
1959 ;
1960
1961 impl_type_restricted_token:
1962 BOOL
1963 | INT
1964 | FLOAT
1965 | STRING
1966 | MIXED
1967 ;
1968
1969 impl_type_extended_token:
1970 VOID
1971 | ARRAY
1972 | OBJECT
1973 | CALLABLE
1974 ;
1975
1976 impl_stmts[stmts]:
1977 impl_stmt[stmt] {
1978 $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1979 }
1980 | impl_stmts[stmts_] impl_stmt[stmt] {
1981 $stmts = psi_plist_add($stmts_, &$stmt);
1982 }
1983 ;
1984
1985 impl_stmt[stmt]:
1986 return_stmt[s] {
1987 $stmt = (struct psi_token **) $s;
1988 }
1989 | let_stmt[s] {
1990 $stmt = (struct psi_token **) $s;
1991 }
1992 | set_stmt[s] {
1993 $stmt = (struct psi_token **) $s;
1994 }
1995 | assert_stmt[s] {
1996 $stmt = (struct psi_token **) $s;
1997 }
1998 | free_stmt[s] {
1999 $stmt = (struct psi_token **) $s;
2000 }
2001 ;
2002
2003 let_stmt[let]:
2004 LET let_exp_assign[exp] EOS {
2005 $let = psi_let_stmt_init($exp);
2006 $let->token = psi_token_copy($LET);
2007 }
2008 | TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
2009 $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
2010 $let->token = psi_token_copy($TEMP);
2011 $let->exp->is_reference = $reference;
2012 }
2013 ;
2014
2015 let_exp[exp]:
2016 let_exp_assign
2017 | byref let_exp_byref[exp_] {
2018 $exp = $exp_;
2019 $exp->is_reference = true;
2020 }
2021 | let_exp_byref[exp_] {
2022 $exp = $exp_;
2023 $exp->is_reference = false;
2024 }
2025 ;
2026
2027 let_exp_byref[exp]:
2028 NULL %dprec 2 {
2029 $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
2030 }
2031 | num_exp[num] %dprec 1 {
2032 $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
2033 }
2034 | let_calloc[calloc] {
2035 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
2036 }
2037 | STATIC let_calloc[calloc] {
2038 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
2039 $calloc->static_memory = 1;
2040 }
2041 | let_callback[callback] {
2042 $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
2043 }
2044 | let_func[func] {
2045 $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
2046 }
2047 ;
2048
2049 let_exp_assign[exp]:
2050 decl_var[var] EQUALS let_exp_byref[exp_] {
2051 $exp = $exp_;
2052 $exp->var = $var;
2053 }
2054 | decl_var[var] EQUALS byref let_exp_byref[exp_] {
2055 $exp = $exp_;
2056 $exp->is_reference = 1;
2057 $exp->var = $var;
2058 }
2059 ;
2060
2061 let_calloc[calloc]:
2062 CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
2063 $calloc = psi_let_calloc_init($nmemb, $size);
2064 $calloc->token = psi_token_copy($CALLOC);
2065 }
2066 ;
2067
2068 let_callback[callback]:
2069 CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
2070 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, NULL);
2071 $callback->func->token = psi_token_copy($func);
2072 $callback->token = psi_token_copy($CALLBACK);
2073 }
2074 | CALLBACK LPAREN call_decl_vars[cb_args] RPAREN AS callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
2075 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, $cb_args);
2076 $callback->func->token = psi_token_copy($func);
2077 $callback->token = psi_token_copy($CALLBACK);
2078 }
2079 ;
2080
2081 let_func[func]:
2082 let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
2083 $func = psi_let_func_init($token->type, $token->text, $var);
2084 $func->token = psi_token_copy($token);
2085 $func->inner = $exps;
2086 }
2087 ;
2088
2089 let_func_token:
2090 ZVAL
2091 | OBJVAL
2092 | ARRVAL
2093 | PATHVAL
2094 | STRLEN
2095 | STRVAL
2096 | FLOATVAL
2097 | INTVAL
2098 | BOOLVAL
2099 | COUNT
2100 ;
2101
2102 let_func_exps[exps]:
2103 %empty {
2104 $exps = NULL;
2105 }
2106 | COMMA let_exps[exps_] {
2107 $exps = $exps_;
2108 }
2109 ;
2110
2111 let_exps[exps]:
2112 let_exp[exp] {
2113 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
2114 }
2115 | let_exps[exps_] COMMA let_exp[exp] {
2116 $exps = psi_plist_add($exps_, &$exp);
2117 }
2118 ;
2119
2120 callback_rval[rval]:
2121 VOID
2122 | let_func_token
2123 ;
2124
2125 callback_arg_list[list]:
2126 %empty {
2127 $list = NULL;
2128 }
2129 | callback_args[args] {
2130 $list = $args;
2131 }
2132 ;
2133
2134 callback_args[args]:
2135 set_exp[exp] {
2136 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2137 }
2138 | callback_args[args_] COMMA set_exp[exp] {
2139 $args = psi_plist_add($args_, &$exp);
2140 }
2141 ;
2142
2143 return_stmt[return]:
2144 RETURN return_exp EOS {
2145 $return = psi_return_stmt_init($return_exp);
2146 $return->token = psi_token_copy($RETURN);
2147 }
2148 ;
2149
2150 return_exp:
2151 decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
2152 $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
2153 $return_exp->token = psi_token_copy($func->token);
2154 }
2155 | set_func {
2156 $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
2157 $return_exp->token = psi_token_copy($set_func->token);
2158 }
2159 ;
2160
2161 call_decl_vars[args]:
2162 %empty {
2163 $args = NULL;
2164 }
2165 | VOID {
2166 $args = NULL;
2167 }
2168 | decl_vars[vars] {
2169 $args = $vars;
2170 }
2171 ;
2172
2173 set_stmt[set]:
2174 SET set_exp[exp] EOS {
2175 $set = psi_set_stmt_init($exp);
2176 $set->token = psi_token_copy($SET);
2177 }
2178 ;
2179
2180 set_exp[exp]:
2181 set_func[func] {
2182 $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
2183 }
2184 | num_exp[num] {
2185 $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
2186 }
2187 | impl_var[var] EQUALS set_exp[exp_] {
2188 $exp = $exp_;
2189 $exp->var = $var;
2190 }
2191 ;
2192
2193 set_func[func]:
2194 set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
2195 $func = psi_set_func_init($token->type, $token->text, $var);
2196 $func->token = psi_token_copy($token);
2197 $func->inner = $exps;
2198 }
2199 | set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
2200 $func = psi_set_func_init($token->type, $token->text, $var);
2201 $func->token = psi_token_copy($token);
2202 $func->recursive = 1;
2203 }
2204 ;
2205
2206 set_func_token:
2207 TO_OBJECT
2208 | TO_ARRAY
2209 | TO_STRING
2210 | TO_INT
2211 | TO_FLOAT
2212 | TO_BOOL
2213 | ZVAL
2214 | VOID
2215 ;
2216
2217 set_func_exps[exps]:
2218 %empty {
2219 $exps = NULL;
2220 }
2221 | COMMA set_exps[exps_] {
2222 $exps = $exps_;
2223 }
2224 ;
2225
2226 set_exps[exps]:
2227 set_exp[exp] {
2228 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2229 }
2230 | set_exps[exps_] COMMA set_exp[exp] {
2231 $exps = psi_plist_add($exps_, &$exp);
2232 }
2233 ;
2234
2235 assert_stmt[assert]:
2236 assert_stmt_token[token] num_exp[exp] EOS {
2237 $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
2238 $assert->token = psi_token_copy($token);
2239 }
2240 ;
2241
2242 assert_stmt_token:
2243 PRE_ASSERT
2244 | POST_ASSERT
2245 ;
2246
2247 free_stmt[free]:
2248 FREE free_exps[exps] EOS {
2249 $free = psi_free_stmt_init($exps);
2250 $free->token = psi_token_copy($FREE);
2251 }
2252 ;
2253
2254 free_exps[exps]:
2255 free_exp[exp] {
2256 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
2257 }
2258 | free_exps[exps_] COMMA free_exp[exp] {
2259 $exps = psi_plist_add($exps_, &$exp);
2260 }
2261 ;
2262
2263 free_exp[exp]:
2264 name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2265 $NAME->type = PSI_T_NAME;
2266 $exp = psi_free_exp_init($NAME->text, $vars);
2267 $exp->token = psi_token_copy($NAME);
2268 }
2269 ;
2270
2271 reference:
2272 %empty {
2273 $reference = false;
2274 }
2275 | byref {
2276 $reference = true;
2277 }
2278 ;
2279
2280 byref:
2281 AMPERSAND %prec UNARY
2282 ;
2283
2284 %%
2285
2286 /* epilogue */
2287
2288 #define PSI_DEBUG_LEX 0
2289 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2290 {
2291 struct psi_token *token;
2292 #if PSI_DEBUG_LEX
2293 PSI_DEBUG_PRINT(P, "PSI: LEX index %4zu ", *index);
2294 #endif
2295 if (psi_plist_get(tokens, (*index)++, &token)) {
2296 #if PSI_DEBUG_LEX
2297 PSI_DEBUG_DUMP(P, psi_token_dump, token);
2298 #endif
2299 *((struct psi_token **)lvalp) = token;
2300 return token->type;
2301 } else {
2302 #if PSI_DEBUG_LEX
2303 PSI_DEBUG_PRINT(P, "EOF\n");
2304 #endif
2305 (*index)--;
2306 }
2307
2308 return PSI_T_EOF;
2309 }
2310
2311 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2312 {
2313 struct psi_token *T = NULL;
2314 size_t last;
2315
2316 if (*index == 0) {
2317 last = 0;
2318 } else {
2319 last = --(*index);
2320 }
2321
2322 psi_plist_get(tokens, last, &T);
2323 if (T) {
2324 int i = (last >= 5) ? last - 5 : 0;
2325
2326 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2327 while (i <= last || T->type != PSI_T_EOS) {
2328 if (!psi_plist_get(tokens, i++, &T)) {
2329 break;
2330 }
2331 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s token '%s' at col %u",
2332 i<last+1?"preceding":i>last+1?"following":"offending", T->text->val, T->col);
2333 }
2334 } else {
2335 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2336 }
2337 P->errors++;
2338 }
2339
PHP System Interface / POSIX Standard Interface