projects / m6w6 / ext-psi / blob
? search:


becbe77aac39958cc8eebbb47b7112d419aab7ad
[m6w6/ext-psi] / src / parser_proc_grammar.y
1 %code top {
2 #include "php_psi_stdinc.h"
3 }
4
5 %code {
6 #include <assert.h>
7 #include <stdarg.h>
8
9 #include "plist.h"
10 #include "parser.h"
11
12 #define YYDEBUG 1
13 #define PSI_PARSER_PROC_DEBUG 1
14
15 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
16 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
17
18 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
19 {
20 assert(strct);
21 if (!P->structs) {
22 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
23 }
24 P->structs = psi_plist_add(P->structs, &strct);
25 }
26 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
27 {
28 assert(u);
29 if (!P->unions) {
30 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
31 }
32 P->unions = psi_plist_add(P->unions, &u);
33 }
34 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
35 {
36 assert(e);
37 if (!P->enums) {
38 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
39 }
40 P->enums = psi_plist_add(P->enums, &e);
41 }
42 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
43 {
44 assert(def);
45 if (!P->types) {
46 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
47 }
48 P->types = psi_plist_add(P->types, &def);
49 }
50 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
51 assert(cnst);
52 if (!P->consts) {
53 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
54 }
55 P->consts = psi_plist_add(P->consts, &cnst);
56
57 }
58 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
59 assert(decl);
60
61 if (psi_decl_is_blacklisted(decl->func->var->name)) {
62 psi_decl_free(&decl);
63 return;
64 }
65
66 if (!P->decls) {
67 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
68 }
69 P->decls = psi_plist_add(P->decls, &decl);
70 }
71 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
72 assert(impl);
73 if (!P->impls) {
74 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
75 }
76 P->impls = psi_plist_add(P->impls, &impl);
77 }
78
79 /* end code */
80 }
81
82 %code requires {
83 #include "plist.h"
84 #include "types/layout.h"
85
86 #define yytokentype psi_token_type
87
88 #define PSI_T_CAST PSI_T_EQUALS
89 #define PSI_T_POINTER PSI_T_ASTERISK
90
91 struct psi_parser;
92
93 }
94
95 %require "3.0"
96 %language "c"
97 %name-prefix "psi_parser_proc_"
98 %token-table
99 %verbose
100 %glr-parser
101
102 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
103
104 %define api.pure true
105 %define api.token.prefix {PSI_T_}
106 %define api.value.type union
107
108 %define parse.error verbose
109 %define parse.trace true
110
111 %initial-action {
112 }
113
114 %start file
115
116 %token <struct psi_token *> BOOL
117 %token <struct psi_token *> CHAR
118 %token <struct psi_token *> SHORT
119 %token <struct psi_token *> INT
120 %token <struct psi_token *> SIGNED
121 %token <struct psi_token *> UNSIGNED
122 %token <struct psi_token *> LONG
123 %token <struct psi_token *> FLOAT
124 %token <struct psi_token *> DOUBLE
125 %token <struct psi_token *> STRING
126 %token <struct psi_token *> MIXED
127 %token <struct psi_token *> ARRAY
128 %token <struct psi_token *> OBJECT
129 %token <struct psi_token *> CALLABLE
130 %token <struct psi_token *> VOID
131 %token <struct psi_token *> ZVAL
132 %token <struct psi_token *> NULL
133 %token <struct psi_token *> TRUE
134 %token <struct psi_token *> FALSE
135 %token <struct psi_token *> NAME
136 %token <struct psi_token *> NSNAME
137 %token <struct psi_token *> DOLLAR_NAME
138 %token <struct psi_token *> NUMBER
139 %token <struct psi_token *> QUOTED_STRING
140 %token <struct psi_token *> QUOTED_CHAR
141 %token <struct psi_token *> SIZEOF
142 %token <struct psi_token *> VOLATILE
143
144 %token <struct psi_token *> EOF 0 "end of file"
145 %token <struct psi_token *> EOL "end of line"
146 %token <struct psi_token *> EOS ";"
147 %token <struct psi_token *> LPAREN "("
148 %token <struct psi_token *> RPAREN ")"
149 %token <struct psi_token *> COMMA ","
150 %token <struct psi_token *> COLON ":"
151 %token <struct psi_token *> LBRACE "{"
152 %token <struct psi_token *> RBRACE "}"
153 %token <struct psi_token *> LBRACKET "["
154 %token <struct psi_token *> RBRACKET "]"
155 %token <struct psi_token *> EQUALS "="
156 %token <struct psi_token *> HASH "#"
157 %token <struct psi_token *> PIPE "|"
158 %token <struct psi_token *> CARET "^"
159 %token <struct psi_token *> AMPERSAND "&"
160 %token <struct psi_token *> LSHIFT "<<"
161 %token <struct psi_token *> RSHIFT ">>"
162 %token <struct psi_token *> PLUS "+"
163 %token <struct psi_token *> MINUS "-"
164 %token <struct psi_token *> ASTERISK "*"
165 %token <struct psi_token *> SLASH "/"
166 %token <struct psi_token *> MODULO "%"
167 %token <struct psi_token *> LCHEVR "<"
168 %token <struct psi_token *> RCHEVR ">"
169 %token <struct psi_token *> CMP_GE ">="
170 %token <struct psi_token *> CMP_LE "<="
171 %token <struct psi_token *> OR "||"
172 %token <struct psi_token *> AND "&&"
173 %token <struct psi_token *> CMP_EQ "=="
174 %token <struct psi_token *> CMP_NE "!="
175 %token <struct psi_token *> TILDE "~"
176 %token <struct psi_token *> NOT "!"
177 %token <struct psi_token *> PERIOD "."
178 %token <struct psi_token *> BACKSLASH "\\"
179 %token <struct psi_token *> ELLIPSIS "..."
180 %token <struct psi_token *> IIF "?"
181
182 %token <struct psi_token *> PRAGMA
183 %token <struct psi_token *> PRAGMA_ONCE
184 %token <struct psi_token *> LINE
185 %token <struct psi_token *> ERROR
186 %token <struct psi_token *> WARNING
187 %token <struct psi_token *> IF
188 %token <struct psi_token *> IFDEF
189 %token <struct psi_token *> IFNDEF
190 %token <struct psi_token *> ELSE
191 %token <struct psi_token *> ELIF
192 %token <struct psi_token *> ENDIF
193 %token <struct psi_token *> DEFINE
194 %token <struct psi_token *> DEFINED
195 %token <struct psi_token *> UNDEF
196 %token <struct psi_token *> IMPORT
197 %token <struct psi_token *> INCLUDE
198 %token <struct psi_token *> INCLUDE_NEXT
199
200 %token <struct psi_token *> TYPEDEF
201 %token <struct psi_token *> STRUCT
202 %token <struct psi_token *> UNION
203 %token <struct psi_token *> ENUM
204 %token <struct psi_token *> CONST
205 %token <struct psi_token *> LIB
206 %token <struct psi_token *> STATIC
207 %token <struct psi_token *> CALLBACK
208 %token <struct psi_token *> FUNCTION
209 %token <struct psi_token *> LET
210 %token <struct psi_token *> SET
211 %token <struct psi_token *> TEMP
212 %token <struct psi_token *> FREE
213 %token <struct psi_token *> RETURN
214 %token <struct psi_token *> AS
215 %token <struct psi_token *> PRE_ASSERT
216 %token <struct psi_token *> POST_ASSERT
217 %token <struct psi_token *> BOOLVAL
218 %token <struct psi_token *> INTVAL
219 %token <struct psi_token *> STRVAL
220 %token <struct psi_token *> PATHVAL
221 %token <struct psi_token *> STRLEN
222 %token <struct psi_token *> FLOATVAL
223 %token <struct psi_token *> ARRVAL
224 %token <struct psi_token *> OBJVAL
225 %token <struct psi_token *> COUNT
226 %token <struct psi_token *> CALLOC
227 %token <struct psi_token *> TO_BOOL
228 %token <struct psi_token *> TO_INT
229 %token <struct psi_token *> TO_STRING
230 %token <struct psi_token *> TO_FLOAT
231 %token <struct psi_token *> TO_ARRAY
232 %token <struct psi_token *> TO_OBJECT
233
234 %token <struct psi_token *> COMMENT
235 %token <struct psi_token *> WHITESPACE
236 %token <struct psi_token *> NO_WHITESPACE
237 %token <struct psi_token *> CPP_HEADER
238 %token <struct psi_token *> CPP_ATTRIBUTE
239 %token <struct psi_token *> CPP_EXTENSION
240 %token <struct psi_token *> CPP_PASTE
241 %token <struct psi_token *> CPP_INLINE
242 %token <struct psi_token *> CPP_RESTRICT
243 %token <struct psi_token *> CPP_ASM
244
245 /* virtual tokens */
246 %token <struct psi_token *> BSLASH
247 %token <struct psi_token *> LONG_DOUBLE
248 %token <struct psi_token *> INT8
249 %token <struct psi_token *> UINT8
250 %token <struct psi_token *> INT16
251 %token <struct psi_token *> UINT16
252 %token <struct psi_token *> INT32
253 %token <struct psi_token *> UINT32
254 %token <struct psi_token *> INT64
255 %token <struct psi_token *> UINT64
256 %token <struct psi_token *> INT128
257 %token <struct psi_token *> UINT128
258
259
260 %precedence IIF COLON
261 %precedence OR
262 %precedence AND
263 %precedence PIPE
264 %precedence CARET
265 %precedence AMPERSAND
266 %precedence CMP_EQ CMP_NE
267 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
268 %precedence LSHIFT RSHIFT
269 %precedence PLUS MINUS
270 %precedence ASTERISK SLASH MODULO
271 //%precedence NOT TILDE
272 %precedence BINARY
273 %precedence UNARY
274
275 %type <struct psi_token *> lib optional_name enum_name struct_name union_name
276 %destructor {psi_token_free(&$$);} lib optional_name enum_name struct_name union_name
277
278 %type <struct psi_token *> cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
279 %destructor {} cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
280
281 %type <struct psi_token *> name_token any_noeol_token binary_op_token unary_op_token
282 %destructor {} name_token any_noeol_token binary_op_token unary_op_token
283
284 %type <struct psi_token *> int_width int_width_types int_signed_types
285 %destructor {psi_token_free(&$$);} int_width int_width_types int_signed_types
286
287 %type <struct psi_token *> signed_long_types signed_short_types int_signed
288 %destructor {} signed_long_types signed_short_types int_signed
289
290 %type <struct psi_cpp_exp *> cpp cpp_exp
291 %destructor {psi_cpp_exp_free(&$$);} cpp cpp_exp
292 %type <struct psi_cpp_macro_decl *> cpp_macro_decl
293 %destructor {psi_cpp_macro_decl_free(&$$);} cpp_macro_decl
294 %type <struct psi_plist *> cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
295 %destructor {psi_plist_free($$);} cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
296 %type <struct psi_num_exp *> cpp_macro_exp
297 %destructor {psi_num_exp_free(&$$);} cpp_macro_exp
298
299 %type <struct psi_token *> constant_type_token impl_def_val_token
300 %destructor {} constant_type_token impl_def_val_token
301
302 %type <struct psi_const *> constant
303 %destructor {psi_const_free(&$$);} constant
304 %type <struct psi_const_type *> constant_type
305 %destructor {psi_const_type_free(&$$);} constant_type
306 %type <struct psi_impl_def_val *> impl_def_val
307 %destructor {psi_impl_def_val_free(&$$);} impl_def_val
308
309 %type <struct psi_token *> decl_real_type decl_int_type decl_type_simple
310 %destructor {psi_token_free(&$$);} decl_real_type decl_int_type decl_type_simple
311
312 %type <struct psi_decl_type *> decl_type qualified_decl_type decl_type_complex
313 %destructor {psi_decl_type_free(&$$);} decl_type qualified_decl_type decl_type_complex
314 %type <struct psi_decl *> decl_stmt decl decl_body decl_func_body decl_functor_body
315 %destructor {psi_decl_free(&$$);} decl_stmt decl decl_body decl_func_body decl_functor_body
316 %type <struct psi_decl_arg *> decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
317 %destructor {psi_decl_arg_free(&$$);} decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
318 %type <struct psi_decl_var *> decl_var
319 %destructor {psi_decl_var_free(&$$);} decl_var
320 %type <struct psi_decl_struct *> decl_struct
321 %destructor {psi_decl_struct_free(&$$);} decl_struct
322 %type <struct psi_decl_union *> decl_union
323 %destructor {psi_decl_union_free(&$$);} decl_union
324 %type <struct psi_decl_enum *> decl_enum
325 %destructor {psi_decl_enum_free(&$$);} decl_enum
326 %type <struct psi_decl_enum_item *> decl_enum_item
327 %destructor {psi_decl_enum_item_free(&$$);} decl_enum_item
328 %type <struct psi_plist *> decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars
329 %destructor {psi_plist_free($$);} decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars
330
331 %type <struct psi_layout> align_and_size
332 %destructor {} align_and_size
333 %type <struct psi_layout *> decl_layout
334 %destructor {psi_layout_free(&$$);} decl_layout
335
336 %type <struct psi_number *> sizeof sizeof_body sizeof_body_notypes
337 %destructor {psi_number_free(&$$);} sizeof sizeof_body sizeof_body_notypes
338
339 %type <struct psi_impl *> impl
340 %destructor {psi_impl_free(&$$);} impl
341 %type <struct psi_impl_func *> impl_func
342 %destructor {psi_impl_func_free(&$$);} impl_func
343 %type <struct psi_impl_arg *> impl_arg
344 %destructor {psi_impl_arg_free(&$$);} impl_arg
345 %type <struct psi_impl_type *> impl_type
346 %destructor {psi_impl_type_free(&$$);} impl_type
347 %type <struct psi_impl_var *> impl_var
348 %destructor {psi_impl_var_free(&$$);} impl_var
349
350 %type <struct psi_let_stmt *> let_stmt
351 %destructor {psi_let_stmt_free(&$$);} let_stmt
352 %type <struct psi_let_exp *> let_exp let_exp_byref let_exp_assign
353 %destructor {psi_let_exp_free(&$$);} let_exp let_exp_byref let_exp_assign
354 %type <struct psi_let_calloc *> let_calloc
355 %destructor {psi_let_calloc_free(&$$);} let_calloc
356 %type <struct psi_let_callback *> let_callback
357 %destructor {psi_let_callback_free(&$$);} let_callback
358 %type <struct psi_let_func *> let_func
359 %destructor {psi_let_func_free(&$$);} let_func
360 %type <struct psi_set_stmt *> set_stmt
361 %destructor {psi_set_stmt_free(&$$);} set_stmt
362 %type <struct psi_set_exp *> set_exp
363 %destructor {psi_set_exp_free(&$$);} set_exp
364 %type <struct psi_set_func *> set_func
365 %destructor {psi_set_func_free(&$$);} set_func
366 %type <struct psi_assert_stmt *> assert_stmt
367 %destructor {psi_assert_stmt_free(&$$);} assert_stmt
368 %type <struct psi_return_stmt *> return_stmt
369 %destructor {psi_return_stmt_free(&$$);} return_stmt
370 %type <struct psi_return_exp *> return_exp
371 %destructor {psi_return_exp_free(&$$);} return_exp
372 %type <struct psi_free_stmt *> free_stmt
373 %destructor {psi_free_stmt_free(&$$);} free_stmt
374 %type <struct psi_free_exp *> free_exp
375 %destructor {psi_free_exp_free(&$$);} free_exp
376
377 %type <struct psi_token **> impl_stmt
378 %destructor {psi_impl_stmt_free(&$$);} impl_stmt
379 %type <struct psi_token *> impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
380 %destructor {psi_token_free(&$$);} impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
381 %type <struct psi_plist *> impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
382 %destructor {psi_plist_free($$);} impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
383
384 %type <struct psi_num_exp *> num_exp
385 %destructor {psi_num_exp_free(&$$);} num_exp
386 %type <struct psi_number *> number
387 %destructor {psi_number_free(&$$);} number
388
389 %type <size_t> indirection pointers asterisks array_size
390 %destructor {} indirection pointers asterisks array_size
391 %type <bool> reference
392 %destructor {} reference
393
394 %%
395
396 /* rules */
397
398
399 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
400 unary_op_token: TILDE | NOT | PLUS | MINUS ;
401 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | AS | let_func_token | set_func_token;
402 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
403 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
404
405
406 file:
407 %empty
408 | blocks
409 ;
410 blocks:
411 block
412 | blocks block
413 ;
414 block:
415 EOS
416 | EOL
417 | COMMENT
418 | cpp {
419 if ($cpp) {
420 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
421 psi_cpp_exp_free(&$cpp);
422 }
423 }
424 | lib {
425 if (P->file.ln) {
426 P->error(PSI_DATA(P), $lib, PSI_WARNING,
427 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
428 } else {
429 P->file.ln = strndup($lib->text, $lib->size);
430 }
431 }
432 | constant {
433 psi_parser_proc_add_const(P, $constant);
434 }
435 | decl_stmt {
436 psi_parser_proc_add_decl(P, $decl_stmt);
437 }
438 | ignored_decl
439 | decl_ext_var_stmt
440 | decl_typedef[def] {
441 psi_parser_proc_add_typedef(P, $def);
442 }
443 | decl_struct[struct] {
444 psi_parser_proc_add_struct(P, $struct);
445 }
446 | decl_union[union] {
447 psi_parser_proc_add_union(P, $union);
448 }
449 | decl_enum[enum] {
450 psi_parser_proc_add_enum(P, $enum);
451 }
452 | impl {
453 psi_parser_proc_add_impl(P, $impl);
454 }
455 ;
456
457 lib:
458 LIB QUOTED_STRING EOS {
459 $lib = $QUOTED_STRING;
460 }
461 ;
462
463 cpp:
464 HASH EOL {
465 $cpp = NULL;
466 }
467 | HASH cpp_exp[exp] EOL {
468 $cpp = $exp;
469 }
470 ;
471
472 cpp_exp[exp]:
473 cpp_message_token cpp_macro_decl_tokens[tokens] {
474 if ($tokens) {
475 struct psi_token *msg = NULL;
476
477 if (psi_plist_get($tokens, 0, &msg)) {
478 size_t index = 1;
479 struct psi_token *next;
480
481 msg = psi_token_copy(msg);
482 while (psi_plist_get($tokens, index++, &next)) {
483 struct psi_token *old = msg;
484 msg = psi_token_cat(" ", 2, msg, next);
485 free(old);
486 }
487 }
488 psi_plist_free($tokens);
489
490 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
491 } else {
492 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
493 }
494 $exp->token = psi_token_copy($cpp_message_token);
495 }
496 | cpp_include_token[INCLUDE] cpp_header_token {
497 $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
498 $exp->token = psi_token_copy($INCLUDE);
499 }
500 | cpp_no_arg_token {
501 $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
502 $exp->token = psi_token_copy($cpp_no_arg_token);
503 }
504 | cpp_name_arg_token cpp_special_name_token[name_token] {
505 $name_token->type = PSI_T_NAME;
506 $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
507 $exp->token = psi_token_copy($cpp_name_arg_token);
508 }
509 | DEFINE cpp_macro_decl {
510 $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
511 $exp->token = psi_token_copy($DEFINE);
512 }
513 | cpp_exp_arg_token cpp_macro_exp {
514 $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
515 $exp->token = psi_token_copy($cpp_exp_arg_token);
516 }
517 | PRAGMA_ONCE {
518 $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
519 $exp->token = psi_token_copy($PRAGMA_ONCE);
520 }
521 | cpp_ignored_token cpp_macro_decl_tokens[tokens] {
522 psi_plist_free($tokens);
523 $exp = NULL;
524 }
525 ;
526
527 cpp_ignored_token:
528 LINE
529 | PRAGMA
530 ;
531
532 cpp_message_token:
533 ERROR
534 | WARNING
535 ;
536
537 cpp_include_token:
538 IMPORT
539 | INCLUDE
540 | INCLUDE_NEXT
541 ;
542
543 cpp_header_token:
544 QUOTED_STRING
545 | CPP_HEADER
546 ;
547
548 cpp_no_arg_token:
549 ELSE
550 | ENDIF
551 ;
552
553 cpp_name_arg_token:
554 IFDEF
555 | IFNDEF
556 | UNDEF
557 ;
558
559 cpp_exp_arg_token:
560 IF
561 | ELIF
562 ;
563
564 cpp_special_name_token:
565 name_token
566 | NULL
567 | TRUE
568 | FALSE
569 | CPP_RESTRICT
570 | CPP_EXTENSION
571 | CPP_INLINE
572 ;
573
574 cpp_macro_decl[macro]:
575 name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
576 $name_token->type = PSI_T_NAME;
577 $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
578 $macro->token = psi_token_copy($name_token);
579 }
580 | cpp_special_name_token[name_token] cpp_macro_decl_tokens {
581 $name_token->type = PSI_T_NAME;
582 $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
583 $macro->token = psi_token_copy($name_token);
584 }
585 ;
586
587 cpp_macro_sig[sig]:
588 %empty {
589 $sig = psi_plist_init(NULL);
590 }
591 | ELLIPSIS {
592 $sig = psi_plist_init(NULL); /* FIXME */
593 }
594 | cpp_macro_sig_args
595 | cpp_macro_sig_args[args] COMMA ELLIPSIS {
596 $sig = $args;
597 }
598 ;
599
600 cpp_macro_sig_args[args]:
601 name_token {
602 $name_token = psi_token_copy($name_token);
603 $name_token->type = PSI_T_NAME;
604 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
605 }
606 | cpp_macro_sig_args[args_] COMMA name_token {
607 $name_token = psi_token_copy($name_token);
608 $name_token->type = PSI_T_NAME;
609 $args = psi_plist_add($args_, &$name_token);
610 }
611 ;
612
613 cpp_macro_decl_tokens[tokens]:
614 %empty {
615 $tokens = NULL;
616 }
617 | cpp_macro_decl_token_list
618 ;
619
620 cpp_macro_decl_token_list[tokens]:
621 any_noeol_token[token] {
622 $token = psi_token_copy($token);
623 $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
624 }
625 | cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
626 $token = psi_token_copy($token);
627 $tokens = psi_plist_add($tokens_, &$token);
628 }
629 ;
630
631 cpp_macro_exp[exp]:
632 LPAREN cpp_macro_exp[exp_] RPAREN {
633 $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
634 $exp->token = psi_token_copy($LPAREN);
635 }
636 | unary_op_token cpp_macro_exp[exp_] %prec UNARY {
637 $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
638 $exp->token = psi_token_copy($unary_op_token);
639 }
640 | cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
641 $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
642 $exp->token = psi_token_copy($binary_op_token);
643 }
644 | cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
645 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
646 $exp->token = psi_token_copy($IIF);
647 }
648
649 | DEFINED name_token {
650 {
651 uint8_t exists;
652
653 $name_token->type = PSI_T_NAME;
654 exists = psi_cpp_defined(P->preproc, $name_token);
655 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
656 $exp->token = psi_token_copy($name_token);
657 }
658 }
659 | DEFINED LPAREN name_token RPAREN {
660 {
661 uint8_t exists;
662
663 $name_token->type = PSI_T_NAME;
664 exists = psi_cpp_defined(P->preproc, $name_token);
665 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
666 $exp->token = psi_token_copy($name_token);
667 }
668 }
669 | NUMBER {
670 $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
671 $exp->token = psi_token_copy($NUMBER);
672 $exp->data.n->token = psi_token_copy($NUMBER);
673 }
674 | QUOTED_CHAR {
675 $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
676 $exp->token = psi_token_copy($QUOTED_CHAR);
677 $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
678 }
679 | sizeof {
680 $exp = psi_num_exp_init_num($sizeof);
681 $exp->token = psi_token_copy($sizeof->token);
682 }
683 | name_token {
684 $name_token->type = PSI_T_NAME;
685 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
686 $exp->token = psi_token_copy($name_token);
687 $exp->data.n->token = psi_token_copy($name_token);
688 }
689 | name_token LPAREN cpp_macro_call_args RPAREN {
690 $name_token->type = PSI_T_NAME;
691 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
692 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
693 $exp->token = psi_token_copy($name_token);
694 }
695 ;
696
697 cpp_macro_call_args[args]:
698 %empty {
699 $args = NULL;
700 }
701 | cpp_macro_call_arg_list
702 ;
703
704 cpp_macro_call_arg_list[args]:
705 cpp_macro_exp {
706 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
707 &$cpp_macro_exp);
708 }
709 | cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
710 $args = psi_plist_add($args_, &$cpp_macro_exp);
711 }
712 ;
713
714 constant[const]:
715 CONST constant_type NSNAME EQUALS impl_def_val EOS {
716 $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
717 $const->token = psi_token_copy($NSNAME);
718 }
719 ;
720
721 constant_type[type]:
722 constant_type_token[token] {
723 $type = psi_const_type_init($token->type, $token->text);
724 }
725 ;
726
727 constant_type_token:
728 BOOL
729 | INT
730 | FLOAT
731 | STRING
732 ;
733
734 impl_def_val[val]:
735 %empty {
736 $val = NULL;
737 }
738 | num_exp[num] %dprec 1 {
739 if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
740 impl_val res = {0};
741 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
742
743 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
744 $val = psi_impl_def_val_init(type, NULL);
745 } else {
746 $val = psi_impl_def_val_init(PSI_T_INT, NULL);
747 }
748
749 switch (type) {
750 case PSI_T_UINT8: $val->ival.zend.lval = res.u8; break;
751 case PSI_T_UINT16: $val->ival.zend.lval = res.u16; break;
752 case PSI_T_UINT32: $val->ival.zend.lval = res.u32; break;
753 case PSI_T_UINT64: $val->ival.zend.lval = res.u64; break; /* FIXME */
754 case PSI_T_INT8: $val->ival.zend.lval = res.i8; break;
755 case PSI_T_INT16: $val->ival.zend.lval = res.i16; break;
756 case PSI_T_INT32: $val->ival.zend.lval = res.i32; break;
757 case PSI_T_INT64: $val->ival.zend.lval = res.i64; break;
758 case PSI_T_FLOAT: $val->ival.dval = res.fval; break;
759 case PSI_T_DOUBLE: $val->ival.dval = res.dval; break;
760 default:
761 assert(0);
762
763 }
764 } else {
765 $val = NULL;
766 }
767 psi_num_exp_free(&$num);
768 }
769 | impl_def_val_token[token] %dprec 2 {
770 $val = psi_impl_def_val_init($token->type, $token->text);
771 $val->token = psi_token_copy($token);
772 }
773 ;
774
775 impl_def_val_token:
776 NULL
777 | TRUE
778 | FALSE
779 | QUOTED_STRING
780 ;
781
782 decl_typedef[def]:
783 TYPEDEF typedef[def_] EOS {
784 $def = $def_;
785 }
786 | TYPEDEF VOID name_token EOS {
787 $def = psi_decl_arg_init(
788 psi_decl_type_init(PSI_T_VOID, $VOID->text),
789 psi_decl_var_init($name_token->text, 0, 0)
790 );
791 $def->token = psi_token_copy($VOID);
792 $def->type->token = psi_token_copy($VOID);
793 $def->var->token = psi_token_copy($name_token);
794 }
795 | CPP_EXTENSION TYPEDEF typedef[def_] EOS {
796 $def = $def_;
797 }
798 ;
799
800 typedef[def]:
801 typedef_decl {
802 $def = $typedef_decl;
803 }
804 | CPP_EXTENSION typedef_decl {
805 $def = $typedef_decl;
806 }
807 ;
808
809 typedef_anon[def]:
810 typedef_anon_decl {
811 $def = $typedef_anon_decl;
812 }
813 | CPP_EXTENSION typedef_anon_decl {
814 $def = $typedef_anon_decl;
815 }
816 ;
817
818 typedef_decl[def]:
819 decl_arg
820 | decl_func_body[decl] {
821 $def = psi_decl_arg_init(
822 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
823 psi_decl_var_copy($decl->func->var)
824 );
825 $def->type->token = psi_token_copy($decl->func->token);
826 $def->type->real.func = $decl;
827 }
828 | decl_enum[enum] name_token {
829 $name_token->type = PSI_T_NAME;
830 $def = psi_decl_arg_init(
831 psi_decl_type_init(PSI_T_ENUM, $enum->name),
832 psi_decl_var_init($name_token->text, 0, 0)
833 );
834 $def->var->token = psi_token_copy($name_token);
835 $def->type->token = psi_token_copy($enum->token);
836 $def->type->real.enm = $enum;
837 psi_parser_proc_add_enum(P, $enum);
838 }
839 | struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
840 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
841 $def->type->token = $struct;
842 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
843 $def->type->real.strct->token = psi_token_copy($struct);
844 $def->type->real.strct->align = $as.pos;
845 $def->type->real.strct->size = $as.len;
846 psi_parser_proc_add_struct(P, $def->type->real.strct);
847 }
848 | union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
849 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
850 $def->type->token = $union;
851 $def->type->real.unn = psi_decl_union_init($union->text, $args);
852 $def->type->real.unn->token = psi_token_copy($union);
853 $def->type->real.unn->align = $as.pos;
854 $def->type->real.unn->size = $as.len;
855 psi_parser_proc_add_union(P, $def->type->real.unn);
856 }
857 ;
858
859 typedef_anon_decl[def]:
860 typedef_decl %dprec 2
861 | qualified_decl_type[type] %dprec 1 {
862 $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
863 $def->var->token = psi_token_copy($type->token);
864 }
865 | decl_enum[enum] {
866 $def = psi_decl_arg_init(
867 psi_decl_type_init(PSI_T_ENUM, $enum->name),
868 psi_decl_var_init(NULL, 0, 0)
869 );
870 $def->var->token = psi_token_copy($enum->token);
871 $def->type->token = psi_token_copy($enum->token);
872 $def->type->real.enm = $enum;
873 psi_parser_proc_add_enum(P, $enum);
874 }
875 | struct_name[struct] align_and_size[as] struct_args_block[args] {
876 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
877 $def->type->token = $struct;
878 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
879 $def->type->real.strct->token = psi_token_copy($struct);
880 $def->type->real.strct->align = $as.pos;
881 $def->type->real.strct->size = $as.len;
882 psi_parser_proc_add_struct(P, $def->type->real.strct);
883 }
884 | union_name[union] align_and_size[as] struct_args_block[args] {
885 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
886 $def->type->token = $union;
887 $def->type->real.unn = psi_decl_union_init($union->text, $args);
888 $def->type->real.unn->token = psi_token_copy($union);
889 $def->type->real.unn->align = $as.pos;
890 $def->type->real.unn->size = $as.len;
891 psi_parser_proc_add_union(P, $def->type->real.unn);
892 }
893 ;
894
895 qualified_decl_type[type]:
896 CONST decl_type[type_] {
897 $type = $type_;
898 }
899 | VOLATILE decl_type[type_] {
900 $type = $type_;
901 }
902 | decl_type
903 ;
904
905 decl_type[type]:
906 decl_type_simple[token] {
907 $type = psi_decl_type_init($token->type, $token->text);
908 $type->token = $token;
909 }
910 | decl_type_complex
911 ;
912
913 decl_type_complex[type]:
914 STRUCT[token] name_token {
915 $name_token->type = PSI_T_NAME;
916 $type = psi_decl_type_init($token->type, $name_token->text);
917 $type->token = psi_token_copy($name_token);
918 }
919 | UNION[token] name_token {
920 $name_token->type = PSI_T_NAME;
921 $type = psi_decl_type_init($token->type, $name_token->text);
922 $type->token = psi_token_copy($name_token);
923 }
924 | ENUM[token] name_token {
925 $name_token->type = PSI_T_NAME;
926 $type = psi_decl_type_init($token->type, $name_token->text);
927 $type->token = psi_token_copy($name_token);
928 }
929 ;
930
931 decl_type_simple[type]:
932 decl_int_type
933 | decl_real_type
934 | NAME[type_] {
935 $type = psi_token_copy($type_);
936 }
937 ;
938
939 decl_real_type[type]:
940 FLOAT[type_] {
941 $type = psi_token_copy($type_);
942 }
943 | DOUBLE[type_] {
944 $type = psi_token_copy($type_);
945 }
946 | LONG DOUBLE {
947 $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
948 }
949 ;
950
951 int_signed[i]:
952 SIGNED
953 | UNSIGNED
954 ;
955
956 int_width[i]:
957 SHORT {
958 $i = psi_token_copy($SHORT);
959 }
960 | LONG {
961 $i = psi_token_copy($LONG);
962 }
963 | LONG[l1] LONG[l2] {
964 $i = psi_token_cat(" ", 2, $l1, $l2);
965 }
966 ;
967
968 decl_int_type[type]:
969 CHAR {
970 $type = psi_token_copy($CHAR);
971 }
972 | INT {
973 $type = psi_token_copy($INT);
974 }
975 | int_signed int_signed_types {
976 if ($2) {
977 $type = psi_token_cat(" ", 2, $1, $2);
978 free($2);
979 } else {
980 $type = psi_token_copy($1);
981 }
982 }
983 | int_width int_width_types {
984 if ($2) {
985 $type = psi_token_cat(" ", 2, $1, $2);
986 free($1);
987 free($2);
988 } else {
989 $type = $1;
990 }
991 }
992 ;
993
994 int_signed_types[type]:
995 %empty {
996 $type = NULL;
997 }
998 | NAME {
999 $type = psi_token_copy($NAME);
1000 }
1001 | CHAR {
1002 $type = psi_token_copy($CHAR);
1003 }
1004 | SHORT signed_short_types {
1005 if ($2) {
1006 $type = psi_token_cat(" ", 2, $1, $2);
1007 } else {
1008 $type = psi_token_copy($1);
1009 }
1010 }
1011 | INT {
1012 $type = psi_token_copy($INT);
1013 }
1014 | LONG signed_long_types {
1015 if ($2) {
1016 $type = psi_token_cat(" ", 2, $1, $2);
1017 } else {
1018 $type = psi_token_copy($1);
1019 }
1020 }
1021 ;
1022
1023 signed_short_types[type]:
1024 %empty {
1025 $type = NULL;
1026 }
1027 | INT
1028 ;
1029 signed_long_types[type]:
1030 %empty {
1031 $type = NULL;
1032 }
1033 | INT
1034 | LONG
1035 | LONG INT
1036 ;
1037
1038 int_width_types[type]:
1039 %empty {
1040 $type = NULL;
1041 }
1042 | INT {
1043 $type = psi_token_copy($INT);
1044 }
1045 | int_signed int_signed_types {
1046 if ($2) {
1047 $type = psi_token_cat(" ", 2, $1, $2);
1048 free($2);
1049 } else {
1050 $type = psi_token_copy($1);
1051 }
1052 }
1053 ;
1054
1055 decl_stmt:
1056 decl decl_asm EOS {
1057 $decl_stmt = $decl;
1058 }
1059 | CPP_EXTENSION decl decl_asm EOS {
1060 $decl_stmt = $decl;
1061 }
1062 ;
1063
1064 decl_asm:
1065 %empty
1066 | CPP_ASM LPAREN ignored_quoted_strings RPAREN
1067 ;
1068
1069 ignored_quoted_strings:
1070 QUOTED_STRING
1071 | ignored_quoted_strings QUOTED_STRING
1072 ;
1073
1074 decl_ext_var_stmt:
1075 decl_ext_var EOS
1076 ;
1077
1078 decl_ext_var:
1079 NAME decl_arg decl_ext_var_list {
1080 psi_decl_arg_free(&$decl_arg);
1081 }
1082 ;
1083
1084 decl_ext_var_list:
1085 %empty
1086 | COMMA decl_vars {
1087 psi_plist_free($decl_vars);
1088 }
1089 ;
1090
1091 decl_vars[vars]:
1092 decl_var[var] {
1093 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1094 }
1095 | decl_vars[vars_] COMMA decl_var[var] {
1096 $vars = psi_plist_add($vars_, &$var);
1097 }
1098 ;
1099
1100 ignored_decl:
1101 STATIC decl_body ignored_decl_body {
1102 psi_decl_free(&$decl_body);
1103 }
1104 | CPP_INLINE decl_body ignored_decl_body {
1105 psi_decl_free(&$decl_body);
1106 }
1107 | STATIC CPP_INLINE decl_body ignored_decl_body {
1108 psi_decl_free(&$decl_body);
1109 }
1110 ;
1111
1112 ignored_decl_body:
1113 LBRACE ignored_decl_body_stmts RBRACE
1114 ;
1115
1116 ignored_decl_body_stmts:
1117 ignored_decl_body_stmt
1118 | ignored_decl_body_stmts ignored_decl_body_stmt
1119 ;
1120
1121 ignored_decl_body_stmt:
1122 any_nobrace_token
1123 | ignored_decl_body
1124 ;
1125
1126 decl:
1127 decl_body
1128 | NAME[abi] decl_body {
1129 $decl = $decl_body;
1130 $decl->abi = psi_decl_abi_init($abi->text);
1131 }
1132 ;
1133
1134 decl_body:
1135 decl_func_body
1136 | decl_functor_body
1137 ;
1138
1139 decl_func_body[decl]:
1140 decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1141 $decl = psi_decl_init($func, $args);
1142 if ($as) {
1143 $decl->func->var->pointer_level += 1;
1144 $decl->func->var->array_size = $as;
1145 }
1146 }
1147 | decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1148 $decl = psi_decl_init($func, $args);
1149 $decl->varargs = 1;
1150 if ($as) {
1151 $decl->func->var->pointer_level += 1;
1152 $decl->func->var->array_size = $as;
1153 }
1154 }
1155 ;
1156
1157 decl_functor_body[decl]:
1158 decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1159 $decl = psi_decl_init($func, $args);
1160 if ($as) {
1161 $decl->func->var->pointer_level += 1;
1162 $decl->func->var->array_size = $as;
1163 }
1164 }
1165 | decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1166 $decl = psi_decl_init($func, $args);
1167 $decl->varargs = 1;
1168 if ($as) {
1169 $decl->func->var->pointer_level += 1;
1170 $decl->func->var->array_size = $as;
1171 }
1172 }
1173 ;
1174
1175 decl_functor[arg]:
1176 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1177 (void) $unused1;
1178 $NAME->type = PSI_T_NAME;
1179 $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1180 $arg->var->token = psi_token_copy($NAME);
1181 $arg->token = psi_token_copy($NAME);
1182 }
1183 | CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1184 (void) $unused1;
1185 $NAME->type = PSI_T_NAME;
1186 $arg = psi_decl_arg_init(
1187 psi_decl_type_init($VOID->type, $VOID->text),
1188 psi_decl_var_init($NAME->text, $pointers, 0)
1189 );
1190 $arg->type->token = psi_token_copy($VOID);
1191 $arg->var->token = psi_token_copy($NAME);
1192 $arg->token = psi_token_copy($NAME);
1193 }
1194 | VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1195 (void) $unused1;
1196 $NAME->type = PSI_T_NAME;
1197 $arg = psi_decl_arg_init(
1198 psi_decl_type_init($VOID->type, $VOID->text),
1199 psi_decl_var_init($NAME->text, $pointers, 0)
1200 );
1201 $arg->type->token = psi_token_copy($VOID);
1202 $arg->var->token = psi_token_copy($NAME);
1203 $arg->token = psi_token_copy($NAME);
1204 }
1205 | VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1206 (void) $unused1;
1207 $NAME->type = PSI_T_NAME;
1208 $arg = psi_decl_arg_init(
1209 psi_decl_type_init($VOID->type, $VOID->text),
1210 psi_decl_var_init($NAME->text, 0, 0)
1211 );
1212 $arg->type->token = psi_token_copy($VOID);
1213 $arg->var->token = psi_token_copy($NAME);
1214 $arg->token = psi_token_copy($NAME);
1215 }
1216 ;
1217
1218 decl_func[func]:
1219 decl_arg
1220 | VOID name_token[NAME] {
1221 $func = psi_decl_arg_init(
1222 psi_decl_type_init($VOID->type, $VOID->text),
1223 psi_decl_var_init($NAME->text, 0, 0)
1224 );
1225 $func->type->token = psi_token_copy($VOID);
1226 $func->var->token = psi_token_copy($NAME);
1227 $func->token = psi_token_copy($NAME);
1228 }
1229 ;
1230
1231 decl_args[args]:
1232 %empty {
1233 $args = NULL;
1234 }
1235 | VOID {
1236 $args = NULL;
1237 }
1238 | decl_arg_list[args_] {
1239 $args = $args_;
1240 }
1241 ;
1242
1243 decl_arg_list[args]:
1244 decl_anon_arg[arg] {
1245 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1246 }
1247 | decl_arg_list[args_] COMMA decl_anon_arg[arg] {
1248 $args = psi_plist_add($args_, &$arg);
1249 }
1250 ;
1251
1252 decl_anon_arg[arg]:
1253 /* FIXME decl_functor_body_anon */
1254 decl_arg %dprec 2 {
1255 $arg = $decl_arg;
1256 }
1257 | qualified_decl_type[type] indirection %dprec 1 {
1258 $arg = psi_decl_arg_init(
1259 $type,
1260 psi_decl_var_init(NULL, $indirection, 0)
1261 );
1262 }
1263 | CONST VOID pointers {
1264 $arg = psi_decl_arg_init(
1265 psi_decl_type_init($VOID->type, $VOID->text),
1266 psi_decl_var_init(NULL, $pointers, 0)
1267 );
1268 $arg->type->token = psi_token_copy($VOID);
1269 $arg->var->token = psi_token_copy($VOID);
1270 $arg->token = psi_token_copy($VOID);
1271 }
1272 | VOID pointers {
1273 $arg = psi_decl_arg_init(
1274 psi_decl_type_init($VOID->type, $VOID->text),
1275 psi_decl_var_init(NULL, $pointers, 0)
1276 );
1277 $arg->type->token = psi_token_copy($VOID);
1278 $arg->var->token = psi_token_copy($VOID);
1279 $arg->token = psi_token_copy($VOID);
1280 }
1281 ;
1282
1283 decl_arg[arg]:
1284 decl_functor_body[decl] {
1285 $arg = psi_decl_arg_init(
1286 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1287 psi_decl_var_copy($decl->func->var)
1288 );
1289 $arg->type->token = psi_token_copy($decl->func->token);
1290 $arg->type->real.func = $decl;
1291 }
1292 | qualified_decl_type[type] decl_var[var] {
1293 $arg = psi_decl_arg_init($type, $var);
1294 }
1295 | CONST VOID pointers name_token[NAME] {
1296 $NAME->type = PSI_T_NAME;
1297 $arg = psi_decl_arg_init(
1298 psi_decl_type_init($VOID->type, $VOID->text),
1299 psi_decl_var_init($NAME->text, $pointers, 0)
1300 );
1301 $arg->type->token = psi_token_copy($VOID);
1302 $arg->var->token = psi_token_copy($NAME);
1303 $arg->token = psi_token_copy($NAME);
1304 }
1305 | VOID pointers name_token[NAME] {
1306 $NAME->type = PSI_T_NAME;
1307 $arg = psi_decl_arg_init(
1308 psi_decl_type_init($VOID->type, $VOID->text),
1309 psi_decl_var_init($NAME->text, $pointers, 0)
1310 );
1311 $arg->type->token = psi_token_copy($VOID);
1312 $arg->var->token = psi_token_copy($NAME);
1313 $arg->token = psi_token_copy($NAME);
1314 }
1315 ;
1316
1317 decl_var[var]:
1318 pointers name_token array_size {
1319 $name_token->type = PSI_T_NAME;
1320 $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1321 $var->token = psi_token_copy($name_token);
1322 }
1323 | name_token array_size {
1324 $name_token->type = PSI_T_NAME;
1325 $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1326 $var->token = psi_token_copy($name_token);
1327 }
1328 ;
1329
1330 decl_union[union]:
1331 UNION name_token align_and_size[as] decl_struct_args[args] {
1332 $name_token->type = PSI_T_NAME;
1333 $union = psi_decl_union_init($name_token->text, $args);
1334 $union->align = $as.pos;
1335 $union->size = $as.len;
1336 $union->token = psi_token_copy($name_token);
1337 }
1338 ;
1339
1340 decl_struct[struct]:
1341 STRUCT name_token align_and_size[as] decl_struct_args[args] {
1342 $name_token->type = PSI_T_NAME;
1343 $struct = psi_decl_struct_init($name_token->text, $args);
1344 $struct->align = $as.pos;
1345 $struct->size = $as.len;
1346 $struct->token = psi_token_copy($name_token);
1347 }
1348 ;
1349
1350 decl_struct_args[args]:
1351 EOS {
1352 $args = NULL;
1353 }
1354 | struct_args_block
1355 ;
1356
1357 struct_args_block[args]:
1358 LBRACE struct_args RBRACE {
1359 $args = $struct_args;
1360 }
1361 ;
1362
1363 struct_args[args]:
1364 typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1365 $arg->layout = $layout;
1366 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1367 if ($vars) {
1368 size_t i = 0;
1369 struct psi_decl_arg *arg;
1370
1371 while (psi_plist_get($vars, i++, &arg)) {
1372 arg->type = psi_decl_type_copy($arg->type);
1373 $args = psi_plist_add($args, &arg);
1374 }
1375 free($vars);
1376 }
1377 }
1378 | struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1379 $arg->layout = $layout;
1380 $args = psi_plist_add($args_, &$arg);
1381 if ($vars) {
1382 size_t i = 0;
1383 struct psi_decl_arg *arg;
1384
1385 while (psi_plist_get($vars, i++, &arg)) {
1386 arg->type = psi_decl_type_copy($arg->type);
1387 $args = psi_plist_add($args, &arg);
1388 }
1389 free($vars);
1390 }
1391 }
1392 ;
1393
1394 struct_arg_var_list[vars]:
1395 %empty {
1396 $vars = NULL;
1397 }
1398 | COMMA decl_vars_with_layout[vars_] {
1399 $vars = $vars_;
1400 }
1401 ;
1402
1403 decl_vars_with_layout[vars]:
1404 decl_var[var] decl_layout[layout] {
1405 {
1406 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1407 arg->layout = $layout;
1408 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1409 }
1410 }
1411 | decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1412 {
1413 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1414 arg->layout = $layout;
1415 $vars = psi_plist_add($vars_, &arg);
1416 }
1417 }
1418 ;
1419
1420 decl_enum[enum]:
1421 enum_name LBRACE decl_enum_items[list] optional_comma RBRACE {
1422 $enum = psi_decl_enum_init($enum_name->text, $list);
1423 $enum->token = $enum_name;
1424 }
1425 ;
1426
1427 decl_enum_items[list]:
1428 decl_enum_item[i] {
1429 $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1430 }
1431 | decl_enum_items[list_] COMMA decl_enum_item[i] {
1432 $list = psi_plist_add($list_, &$i);
1433 }
1434 ;
1435
1436 decl_enum_item[i]:
1437 name_token {
1438 $name_token->type = PSI_T_NAME;
1439 $i = psi_decl_enum_item_init($name_token->text, NULL);
1440 $i->token = psi_token_copy($name_token);
1441 }
1442 | name_token EQUALS num_exp {
1443 $name_token->type = PSI_T_NAME;
1444 $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1445 $i->token = psi_token_copy($name_token);
1446 }
1447 ;
1448
1449 num_exp[exp]:
1450 number {
1451 $exp = psi_num_exp_init_num($number);
1452 $exp->token = psi_token_copy($number->token);
1453 }
1454 | LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1455 $exp = psi_num_exp_init_cast($type, $exp_);
1456 $exp->token = psi_token_copy($type->token);
1457 }
1458 | LPAREN num_exp[exp_] RPAREN {
1459 $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1460 $exp->token = psi_token_copy($LPAREN);
1461 }
1462 | num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1463 $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1464 $exp->token = psi_token_copy($op);
1465 }
1466 | unary_op_token[op] num_exp[exp_] %prec UNARY {
1467 $exp = psi_num_exp_init_unary($op->type, $exp_);
1468 $exp->token = psi_token_copy($op);
1469 }
1470 | num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1471 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1472 $exp->token = psi_token_copy($IIF);
1473 }
1474 ;
1475
1476 number[num]:
1477 NUMBER[token] {
1478 $num = psi_number_init($token->type, $token->text, $token->flags);
1479 $num->token = psi_token_copy($token);
1480 }
1481 | NSNAME[token] {
1482 $num = psi_number_init($token->type, $token->text, 0);
1483 $num->token = psi_token_copy($token);
1484 }
1485 | QUOTED_CHAR[token] {
1486 $num = psi_number_init($token->type, $token->text, 0);
1487 $num->token = psi_token_copy($token);
1488 }
1489 | NULL[token] {
1490 $num = psi_number_init($token->type, $token->text, 0);
1491 $num->token = psi_token_copy($token);
1492 }
1493 | decl_var {
1494 $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1495 $num->token = psi_token_copy($decl_var->token);
1496 }
1497 | sizeof {
1498 $num = $sizeof;
1499 }
1500 ;
1501
1502 sizeof:
1503 SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1504 $sizeof = $sizeof_;
1505 $sizeof->token = psi_token_copy($SIZEOF);
1506 }
1507 | SIZEOF sizeof_body_notypes[sizeof_] {
1508 $sizeof = $sizeof_;
1509 $sizeof->token = psi_token_copy($SIZEOF);
1510 }
1511 ;
1512
1513 sizeof_body[sizeof]:
1514 sizeof_body_notypes[sizeof_] {
1515 $sizeof = $sizeof_;
1516 }
1517 | decl_type indirection {
1518 if ($indirection) {
1519 int8_t sizeof_void_p = sizeof(void *);
1520 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1521 } else {
1522 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1523 }
1524 }
1525 ;
1526
1527 sizeof_body_notypes[sizeof]:
1528 AMPERSAND NAME {
1529 int8_t sizeof_void_p = sizeof(void *);
1530 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1531 }
1532 | QUOTED_CHAR {
1533 int8_t sizeof_a = sizeof('a');
1534 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1535 }
1536 | QUOTED_STRING {
1537 $sizeof = psi_number_init(PSI_T_INT64, &$QUOTED_STRING->size, 0);
1538 }
1539 ;
1540
1541 enum_name[name]:
1542 ENUM optional_name[name_] {
1543 if ($name_) {
1544 $name = psi_token_copy($name_);
1545 } else {
1546 char digest[17];
1547
1548 psi_token_hash($ENUM, digest);
1549 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1550 }
1551 }
1552 ;
1553
1554 union_name[name]:
1555 UNION optional_name[name_] {
1556 if ($name_) {
1557 $name = psi_token_copy($name_);
1558 } else {
1559 char digest[17];
1560
1561 psi_token_hash($UNION, digest);
1562 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1563 }
1564 }
1565 ;
1566
1567 struct_name[name]:
1568 STRUCT optional_name[name_] {
1569 if ($name_) {
1570 $name = psi_token_copy($name_);
1571 } else {
1572 char digest[17];
1573
1574 psi_token_hash($STRUCT, digest);
1575 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1576 }
1577 }
1578 ;
1579
1580 optional_name[name]:
1581 %empty {
1582 $name = NULL;
1583 }
1584 | name_token {
1585 $name = $name_token;
1586 $name->type = PSI_T_NAME;
1587 }
1588 ;
1589
1590 optional_comma:
1591 %empty
1592 | COMMA
1593 ;
1594
1595 decl_layout[l]:
1596 %empty {
1597 $l = NULL;
1598 }
1599 | COLON NUMBER[width] {
1600 $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1601 }
1602 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1603 $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1604 }
1605 | COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1606 $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1607 }
1608 ;
1609
1610 align_and_size[as]:
1611 %empty {
1612 $as.pos = 0;
1613 $as.len = 0;
1614 }
1615 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1616 $as.pos = atol($align->text);
1617 $as.len = atol($size->text);
1618 }
1619 ;
1620
1621 array_size[as]:
1622 %empty {
1623 $as = 0;
1624 }
1625 | LBRACKET RBRACKET {
1626 $as = 0;
1627 }
1628 | LBRACKET CPP_RESTRICT RBRACKET {
1629 $as = 0;
1630 }
1631 | LBRACKET num_exp RBRACKET {
1632 if (psi_num_exp_validate(PSI_DATA(P), $num_exp, NULL, NULL, NULL, NULL, NULL)) {
1633 $as = psi_long_num_exp($num_exp, NULL, &P->preproc->defs);
1634 } else {
1635 $as = 0;
1636 }
1637 }
1638 ;
1639
1640 indirection[i]:
1641 %empty {
1642 $i = 0;
1643 }
1644 | pointers[p] %prec UNARY {
1645 $i = $p;
1646 }
1647 ;
1648
1649 pointers[p]:
1650 asterisks
1651 | asterisks[a] CPP_RESTRICT {
1652 $p = $a;
1653 }
1654 ;
1655
1656 asterisks[a]:
1657 asterisk {
1658 $a = 1;
1659 }
1660 | asterisks[a_] asterisk {
1661 $a = $a_ + 1;
1662 }
1663 ;
1664
1665 asterisk:
1666 ASTERISK
1667 | ASTERISK CONST
1668 ;
1669
1670 /*
1671 *
1672 * impl
1673 *
1674 */
1675
1676 impl:
1677 impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1678 $impl = psi_impl_init($func, $stmts);
1679 }
1680 | STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1681 $impl = psi_impl_init($func, $stmts);
1682 $func->static_memory = 1;
1683 }
1684 ;
1685
1686 impl_func[func]:
1687 FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1688 $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1689 $func->token = psi_token_copy($NSNAME);
1690 $func->return_reference = $r;
1691 }
1692 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1693 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1694 $func->token = psi_token_copy($NSNAME);
1695 $func->return_reference = $r;
1696 }
1697 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1698 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1699 $func->token = psi_token_copy($NSNAME);
1700 $func->return_reference = $r;
1701 $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1702 $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1703 }
1704 ;
1705
1706 impl_args[args]:
1707 impl_arg[arg] {
1708 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1709 }
1710 | impl_args[args_] COMMA impl_arg[arg] {
1711 $args = psi_plist_add($args_, &$arg);
1712 }
1713 ;
1714
1715 impl_arg[arg]:
1716 impl_type[type] impl_var[var] {
1717 $arg = psi_impl_arg_init($type, $var, NULL);
1718 }
1719 | impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1720 $arg = psi_impl_arg_init($type, $var, $val);
1721 }
1722 ;
1723
1724 impl_var[var]:
1725 reference DOLLAR_NAME {
1726 $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1727 $var->token = psi_token_copy($DOLLAR_NAME);
1728 }
1729 ;
1730
1731 impl_type[type]:
1732 impl_type_token[token] {
1733 $type = psi_impl_type_init($token->type, $token->text);
1734 $type->token = psi_token_copy($token);
1735 }
1736 ;
1737
1738 impl_type_token:
1739 VOID
1740 | MIXED
1741 | BOOL
1742 | INT
1743 | FLOAT
1744 | STRING
1745 | ARRAY
1746 | OBJECT
1747 | CALLABLE
1748 ;
1749
1750 impl_stmts[stmts]:
1751 impl_stmt[stmt] {
1752 $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1753 }
1754 | impl_stmts[stmts_] impl_stmt[stmt] {
1755 $stmts = psi_plist_add($stmts_, &$stmt);
1756 }
1757 ;
1758
1759 impl_stmt[stmt]:
1760 return_stmt[s] {
1761 $stmt = (struct psi_token **) $s;
1762 }
1763 | let_stmt[s] {
1764 $stmt = (struct psi_token **) $s;
1765 }
1766 | set_stmt[s] {
1767 $stmt = (struct psi_token **) $s;
1768 }
1769 | assert_stmt[s] {
1770 $stmt = (struct psi_token **) $s;
1771 }
1772 | free_stmt[s] {
1773 $stmt = (struct psi_token **) $s;
1774 }
1775 ;
1776
1777 let_stmt[let]:
1778 LET let_exp_assign[exp] EOS {
1779 $let = psi_let_stmt_init($exp);
1780 $let->token = psi_token_copy($LET);
1781 }
1782 | TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1783 $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1784 $let->token = psi_token_copy($TEMP);
1785 $let->exp->is_reference = $reference;
1786 }
1787 ;
1788
1789 let_exp[exp]:
1790 let_exp_assign
1791 | byref let_exp_byref[exp_] {
1792 $exp = $exp_;
1793 $exp->is_reference = true;
1794 }
1795 | let_exp_byref[exp_] {
1796 $exp = $exp_;
1797 $exp->is_reference = false;
1798 }
1799 ;
1800
1801 let_exp_byref[exp]:
1802 NULL %dprec 2 {
1803 $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1804 }
1805 | num_exp[num] %dprec 1 {
1806 $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1807 }
1808 | let_calloc[calloc] {
1809 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1810 }
1811 | STATIC let_calloc[calloc] {
1812 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1813 $calloc->static_memory = 1;
1814 }
1815 | let_callback[callback] {
1816 $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1817 }
1818 | let_func[func] {
1819 $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1820 }
1821 ;
1822
1823 let_exp_assign[exp]:
1824 decl_var[var] EQUALS let_exp_byref[exp_] {
1825 $exp = $exp_;
1826 $exp->var = $var;
1827 }
1828 | decl_var[var] EQUALS byref let_exp_byref[exp_] {
1829 $exp = $exp_;
1830 $exp->is_reference = 1;
1831 $exp->var = $var;
1832 }
1833 ;
1834
1835 let_calloc[calloc]:
1836 CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1837 $calloc = psi_let_calloc_init($nmemb, $size);
1838 $calloc->token = psi_token_copy($CALLOC);
1839 }
1840 ;
1841
1842 let_callback[callback]:
1843 CALLBACK LPAREN call_decl_vars[cb_args] RPAREN AS callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1844 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, $cb_args);
1845 $callback->func->token = psi_token_copy($func);
1846 $callback->token = psi_token_copy($CALLBACK);
1847 }
1848 ;
1849
1850 let_func[func]:
1851 let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1852 $func = psi_let_func_init($token->type, $token->text, $var);
1853 $func->token = psi_token_copy($token);
1854 $func->inner = $exps;
1855 }
1856 ;
1857
1858 let_func_token:
1859 ZVAL
1860 | OBJVAL
1861 | ARRVAL
1862 | PATHVAL
1863 | STRLEN
1864 | STRVAL
1865 | FLOATVAL
1866 | INTVAL
1867 | BOOLVAL
1868 | COUNT
1869 ;
1870
1871 let_func_exps[exps]:
1872 %empty {
1873 $exps = NULL;
1874 }
1875 | COMMA let_exps[exps_] {
1876 $exps = $exps_;
1877 }
1878 ;
1879
1880 let_exps[exps]:
1881 let_exp[exp] {
1882 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1883 }
1884 | let_exps[exps_] COMMA let_exp[exp] {
1885 $exps = psi_plist_add($exps_, &$exp);
1886 }
1887 ;
1888
1889 callback_rval[rval]:
1890 VOID
1891 | let_func_token
1892 ;
1893
1894 callback_arg_list[list]:
1895 %empty {
1896 $list = NULL;
1897 }
1898 | callback_args[args] {
1899 $list = $args;
1900 }
1901 ;
1902
1903 callback_args[args]:
1904 set_exp[exp] {
1905 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1906 }
1907 | callback_args[args_] COMMA set_exp[exp] {
1908 $args = psi_plist_add($args_, &$exp);
1909 }
1910 ;
1911
1912 return_stmt[return]:
1913 RETURN return_exp EOS {
1914 $return = psi_return_stmt_init($return_exp);
1915 $return->token = psi_token_copy($RETURN);
1916 }
1917 ;
1918
1919 return_exp:
1920 decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
1921 $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1922 $return_exp->token = psi_token_copy($func->token);
1923 }
1924 | set_func {
1925 $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1926 $return_exp->token = psi_token_copy($set_func->token);
1927 }
1928 ;
1929
1930 call_decl_vars[args]:
1931 %empty {
1932 $args = NULL;
1933 }
1934 | VOID {
1935 $args = NULL;
1936 }
1937 | decl_vars[vars] {
1938 $args = $vars;
1939 }
1940 ;
1941
1942 set_stmt[set]:
1943 SET set_exp[exp] EOS {
1944 $set = psi_set_stmt_init($exp);
1945 $set->token = psi_token_copy($SET);
1946 }
1947 ;
1948
1949 set_exp[exp]:
1950 set_func[func] {
1951 $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1952 }
1953 | num_exp[num] {
1954 $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1955 }
1956 | impl_var[var] EQUALS set_exp[exp_] {
1957 $exp = $exp_;
1958 $exp->var = $var;
1959 }
1960 ;
1961
1962 set_func[func]:
1963 set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1964 $func = psi_set_func_init($token->type, $token->text, $var);
1965 $func->token = psi_token_copy($token);
1966 $func->inner = $exps;
1967 }
1968 | set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
1969 $func = psi_set_func_init($token->type, $token->text, $var);
1970 $func->token = psi_token_copy($token);
1971 $func->recursive = 1;
1972 }
1973 ;
1974
1975 set_func_token:
1976 TO_OBJECT
1977 | TO_ARRAY
1978 | TO_STRING
1979 | TO_INT
1980 | TO_FLOAT
1981 | TO_BOOL
1982 | ZVAL
1983 | VOID
1984 ;
1985
1986 set_func_exps[exps]:
1987 %empty {
1988 $exps = NULL;
1989 }
1990 | COMMA set_exps[exps_] {
1991 $exps = $exps_;
1992 }
1993 ;
1994
1995 set_exps[exps]:
1996 set_exp[exp] {
1997 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1998 }
1999 | set_exps[exps_] COMMA set_exp[exp] {
2000 $exps = psi_plist_add($exps_, &$exp);
2001 }
2002 ;
2003
2004 assert_stmt[assert]:
2005 assert_stmt_token[token] num_exp[exp] EOS {
2006 $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
2007 $assert->token = psi_token_copy($token);
2008 }
2009 ;
2010
2011 assert_stmt_token:
2012 PRE_ASSERT
2013 | POST_ASSERT
2014 ;
2015
2016 free_stmt[free]:
2017 FREE free_exps[exps] EOS {
2018 $free = psi_free_stmt_init($exps);
2019 $free->token = psi_token_copy($FREE);
2020 }
2021 ;
2022
2023 free_exps[exps]:
2024 free_exp[exp] {
2025 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
2026 }
2027 | free_exps[exps_] COMMA free_exp[exp] {
2028 $exps = psi_plist_add($exps_, &$exp);
2029 }
2030 ;
2031
2032 free_exp[exp]:
2033 name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2034 $NAME->type = PSI_T_NAME;
2035 $exp = psi_free_exp_init($NAME->text, $vars);
2036 $exp->token = psi_token_copy($NAME);
2037 }
2038 ;
2039
2040 reference:
2041 %empty {
2042 $reference = false;
2043 }
2044 | byref {
2045 $reference = true;
2046 }
2047 ;
2048
2049 byref:
2050 AMPERSAND %prec UNARY
2051 ;
2052
2053 %%
2054
2055 /* epilogue */
2056
2057 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2058 {
2059 struct psi_token *token;
2060
2061 if (psi_plist_get(tokens, (*index)++, &token)) {
2062 if (P->flags & PSI_DEBUG) {
2063 psi_token_dump(2, token);
2064 }
2065
2066 *((struct psi_token **)lvalp) = token;
2067 return token->type;
2068 } else {
2069 (*index)--;
2070 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
2071 }
2072
2073 return PSI_T_EOF;
2074 }
2075
2076 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2077 {
2078 struct psi_token *T = NULL;
2079 size_t last;
2080
2081 if (*index == 0) {
2082 last = 0;
2083 } else {
2084 last = --(*index);
2085 }
2086
2087 psi_plist_get(tokens, last, &T);
2088 if (T) {
2089 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2090 } else {
2091 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2092 }
2093 P->errors++;
2094 }
2095
PHP System Interface / POSIX Standard Interface