projects / m6w6 / ext-psi / blob
? search:
summary | shortlog | log | commit | commitdiff | tree | github
history | raw | HEAD
parser: extern var support
[m6w6/ext-psi] / src / parser_proc_grammar.y
1 %code top {
2 #include "php_psi_stdinc.h"
3 }
4
5 %code {
6 #include <assert.h>
7 #include <stdarg.h>
8
9 #include "plist.h"
10 #include "parser.h"
11
12 #define YYDEBUG 1
13 #define PSI_PARSER_PROC_DEBUG 1
14
15 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
16 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
17
18 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
19 {
20 assert(strct);
21 if (!P->structs) {
22 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
23 }
24 P->structs = psi_plist_add(P->structs, &strct);
25 }
26 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
27 {
28 assert(u);
29 if (!P->unions) {
30 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
31 }
32 P->unions = psi_plist_add(P->unions, &u);
33 }
34 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
35 {
36 assert(e);
37 if (!P->enums) {
38 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
39 }
40 P->enums = psi_plist_add(P->enums, &e);
41 }
42 static inline void psi_parser_proc_deanon_typedef(struct psi_decl_arg *def)
43 {
44 switch (def->type->type) {
45 case PSI_T_STRUCT:
46 if (!psi_decl_type_is_anon(def->type->name, "struct")) {
47 return;
48 }
49 break;
50 case PSI_T_UNION:
51 if (!psi_decl_type_is_anon(def->type->name, "union")) {
52 return;
53 }
54 break;
55 case PSI_T_ENUM:
56 if (!psi_decl_type_is_anon(def->type->name, "enum")) {
57 return;
58 }
59 break;
60 default:
61 return;
62 }
63 free(def->type->name);
64 def->type->name = strdup(def->var->name);
65 }
66 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
67 {
68 assert(def);
69 if (!P->types) {
70 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
71 }
72 psi_parser_proc_deanon_typedef(def);
73 P->types = psi_plist_add(P->types, &def);
74 }
75 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
76 assert(cnst);
77 if (!P->consts) {
78 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
79 }
80 P->consts = psi_plist_add(P->consts, &cnst);
81
82 }
83 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
84 assert(decl);
85
86 if (psi_decl_is_blacklisted(decl->func->var->name)) {
87 psi_decl_free(&decl);
88 return;
89 }
90
91 if (!P->decls) {
92 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
93 }
94 P->decls = psi_plist_add(P->decls, &decl);
95 }
96 static inline void psi_parser_proc_add_decl_extvars(struct psi_parser *P, struct psi_plist *list) {
97 assert(list);
98 if (!P->vars) {
99 P->vars = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
100 }
101 P->vars = psi_plist_add_r(P->vars, psi_plist_count(list), psi_plist_eles(list));
102 free(list);
103 }
104 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
105 assert(impl);
106 if (!P->impls) {
107 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
108 }
109 P->impls = psi_plist_add(P->impls, &impl);
110 }
111
112 /* end code */
113 }
114
115 %code requires {
116 #include "plist.h"
117 #include "types/layout.h"
118
119 #define yytokentype psi_token_type
120
121 #define PSI_T_CAST PSI_T_EQUALS
122 #define PSI_T_POINTER PSI_T_ASTERISK
123
124 struct psi_parser;
125
126 }
127
128 %require "3.0"
129 %language "c"
130 %name-prefix "psi_parser_proc_"
131 %token-table
132 %verbose
133 %glr-parser
134
135 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
136
137 %define api.pure true
138 %define api.token.prefix {PSI_T_}
139 %define api.value.type union
140
141 %define parse.error verbose
142 %define parse.trace true
143
144 %initial-action {
145 }
146
147 %start file
148
149 %token <struct psi_token *> BOOL
150 %token <struct psi_token *> CHAR
151 %token <struct psi_token *> SHORT
152 %token <struct psi_token *> INT
153 %token <struct psi_token *> SIGNED
154 %token <struct psi_token *> UNSIGNED
155 %token <struct psi_token *> LONG
156 %token <struct psi_token *> FLOAT
157 %token <struct psi_token *> DOUBLE
158 %token <struct psi_token *> STRING
159 %token <struct psi_token *> MIXED
160 %token <struct psi_token *> ARRAY
161 %token <struct psi_token *> OBJECT
162 %token <struct psi_token *> CALLABLE
163 %token <struct psi_token *> VOID
164 %token <struct psi_token *> ZVAL
165 %token <struct psi_token *> NULL
166 %token <struct psi_token *> TRUE
167 %token <struct psi_token *> FALSE
168 %token <struct psi_token *> NAME
169 %token <struct psi_token *> NSNAME
170 %token <struct psi_token *> DOLLAR_NAME
171 %token <struct psi_token *> NUMBER
172 %token <struct psi_token *> QUOTED_STRING
173 %token <struct psi_token *> QUOTED_CHAR
174 %token <struct psi_token *> SIZEOF
175 %token <struct psi_token *> VOLATILE
176
177 %token <struct psi_token *> EOF 0 "end of file"
178 %token <struct psi_token *> EOL "end of line"
179 %token <struct psi_token *> EOS ";"
180 %token <struct psi_token *> LPAREN "("
181 %token <struct psi_token *> RPAREN ")"
182 %token <struct psi_token *> COMMA ","
183 %token <struct psi_token *> COLON ":"
184 %token <struct psi_token *> LBRACE "{"
185 %token <struct psi_token *> RBRACE "}"
186 %token <struct psi_token *> LBRACKET "["
187 %token <struct psi_token *> RBRACKET "]"
188 %token <struct psi_token *> EQUALS "="
189 %token <struct psi_token *> HASH "#"
190 %token <struct psi_token *> PIPE "|"
191 %token <struct psi_token *> CARET "^"
192 %token <struct psi_token *> AMPERSAND "&"
193 %token <struct psi_token *> LSHIFT "<<"
194 %token <struct psi_token *> RSHIFT ">>"
195 %token <struct psi_token *> PLUS "+"
196 %token <struct psi_token *> MINUS "-"
197 %token <struct psi_token *> ASTERISK "*"
198 %token <struct psi_token *> SLASH "/"
199 %token <struct psi_token *> MODULO "%"
200 %token <struct psi_token *> LCHEVR "<"
201 %token <struct psi_token *> RCHEVR ">"
202 %token <struct psi_token *> CMP_GE ">="
203 %token <struct psi_token *> CMP_LE "<="
204 %token <struct psi_token *> OR "||"
205 %token <struct psi_token *> AND "&&"
206 %token <struct psi_token *> CMP_EQ "=="
207 %token <struct psi_token *> CMP_NE "!="
208 %token <struct psi_token *> TILDE "~"
209 %token <struct psi_token *> NOT "!"
210 %token <struct psi_token *> PERIOD "."
211 %token <struct psi_token *> BACKSLASH "\\"
212 %token <struct psi_token *> ELLIPSIS "..."
213 %token <struct psi_token *> IIF "?"
214
215 %token <struct psi_token *> PRAGMA
216 %token <struct psi_token *> PRAGMA_ONCE
217 %token <struct psi_token *> LINE
218 %token <struct psi_token *> ERROR
219 %token <struct psi_token *> WARNING
220 %token <struct psi_token *> IF
221 %token <struct psi_token *> IFDEF
222 %token <struct psi_token *> IFNDEF
223 %token <struct psi_token *> ELSE
224 %token <struct psi_token *> ELIF
225 %token <struct psi_token *> ENDIF
226 %token <struct psi_token *> DEFINE
227 %token <struct psi_token *> DEFINED
228 %token <struct psi_token *> UNDEF
229 %token <struct psi_token *> IMPORT
230 %token <struct psi_token *> INCLUDE
231 %token <struct psi_token *> INCLUDE_NEXT
232
233 %token <struct psi_token *> TYPEDEF
234 %token <struct psi_token *> STRUCT
235 %token <struct psi_token *> UNION
236 %token <struct psi_token *> ENUM
237 %token <struct psi_token *> CONST
238 %token <struct psi_token *> LIB
239 %token <struct psi_token *> STATIC
240 %token <struct psi_token *> CALLBACK
241 %token <struct psi_token *> FUNCTION
242 %token <struct psi_token *> LET
243 %token <struct psi_token *> SET
244 %token <struct psi_token *> TEMP
245 %token <struct psi_token *> FREE
246 %token <struct psi_token *> RETURN
247 %token <struct psi_token *> AS
248 %token <struct psi_token *> PRE_ASSERT
249 %token <struct psi_token *> POST_ASSERT
250 %token <struct psi_token *> BOOLVAL
251 %token <struct psi_token *> INTVAL
252 %token <struct psi_token *> STRVAL
253 %token <struct psi_token *> PATHVAL
254 %token <struct psi_token *> STRLEN
255 %token <struct psi_token *> FLOATVAL
256 %token <struct psi_token *> ARRVAL
257 %token <struct psi_token *> OBJVAL
258 %token <struct psi_token *> COUNT
259 %token <struct psi_token *> CALLOC
260 %token <struct psi_token *> TO_BOOL
261 %token <struct psi_token *> TO_INT
262 %token <struct psi_token *> TO_STRING
263 %token <struct psi_token *> TO_FLOAT
264 %token <struct psi_token *> TO_ARRAY
265 %token <struct psi_token *> TO_OBJECT
266
267 %token <struct psi_token *> COMMENT
268 %token <struct psi_token *> WHITESPACE
269 %token <struct psi_token *> NO_WHITESPACE
270 %token <struct psi_token *> CPP_HEADER
271 %token <struct psi_token *> CPP_ATTRIBUTE
272 %token <struct psi_token *> CPP_EXTENSION
273 %token <struct psi_token *> CPP_PASTE
274 %token <struct psi_token *> CPP_INLINE
275 %token <struct psi_token *> CPP_RESTRICT
276 %token <struct psi_token *> CPP_ASM
277
278 /* virtual tokens */
279 %token <struct psi_token *> BSLASH
280 %token <struct psi_token *> LONG_DOUBLE
281 %token <struct psi_token *> INT8
282 %token <struct psi_token *> UINT8
283 %token <struct psi_token *> INT16
284 %token <struct psi_token *> UINT16
285 %token <struct psi_token *> INT32
286 %token <struct psi_token *> UINT32
287 %token <struct psi_token *> INT64
288 %token <struct psi_token *> UINT64
289 %token <struct psi_token *> INT128
290 %token <struct psi_token *> UINT128
291
292
293 %precedence IIF COLON
294 %precedence OR
295 %precedence AND
296 %precedence PIPE
297 %precedence CARET
298 %precedence AMPERSAND
299 %precedence CMP_EQ CMP_NE
300 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
301 %precedence LSHIFT RSHIFT
302 %precedence PLUS MINUS
303 %precedence ASTERISK SLASH MODULO
304 //%precedence NOT TILDE
305 %precedence BINARY
306 %precedence UNARY
307
308 %type <struct psi_token *> lib optional_name enum_name struct_name union_name
309 %destructor {psi_token_free(&$$);} lib optional_name enum_name struct_name union_name
310
311 %type <struct psi_token *> cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
312 %destructor {} cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
313
314 %type <struct psi_token *> name_token any_noeol_token binary_op_token unary_op_token
315 %destructor {} name_token any_noeol_token binary_op_token unary_op_token
316
317 %type <struct psi_token *> int_width int_width_types int_signed_types
318 %destructor {psi_token_free(&$$);} int_width int_width_types int_signed_types
319
320 %type <struct psi_token *> signed_long_types signed_short_types int_signed
321 %destructor {} signed_long_types signed_short_types int_signed
322
323 %type <struct psi_cpp_exp *> cpp cpp_exp
324 %destructor {psi_cpp_exp_free(&$$);} cpp cpp_exp
325 %type <struct psi_cpp_macro_decl *> cpp_macro_decl
326 %destructor {psi_cpp_macro_decl_free(&$$);} cpp_macro_decl
327 %type <struct psi_plist *> cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
328 %destructor {psi_plist_free($$);} cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
329 %type <struct psi_num_exp *> cpp_macro_exp
330 %destructor {psi_num_exp_free(&$$);} cpp_macro_exp
331
332 %type <struct psi_token *> constant_type_token impl_def_val_token
333 %destructor {} constant_type_token impl_def_val_token
334
335 %type <struct psi_const *> constant
336 %destructor {psi_const_free(&$$);} constant
337 %type <struct psi_const_type *> constant_type
338 %destructor {psi_const_type_free(&$$);} constant_type
339 %type <struct psi_impl_def_val *> impl_def_val
340 %destructor {psi_impl_def_val_free(&$$);} impl_def_val
341
342 %type <struct psi_token *> decl_real_type decl_int_type decl_type_simple
343 %destructor {psi_token_free(&$$);} decl_real_type decl_int_type decl_type_simple
344
345 %type <struct psi_decl_type *> decl_type qualified_decl_type decl_type_complex
346 %destructor {psi_decl_type_free(&$$);} decl_type qualified_decl_type decl_type_complex
347 %type <struct psi_decl *> decl_stmt decl decl_body decl_func_body decl_functor_body
348 %destructor {psi_decl_free(&$$);} decl_stmt decl decl_body decl_func_body decl_functor_body
349 %type <struct psi_decl_arg *> decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
350 %destructor {psi_decl_arg_free(&$$);} decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
351 %type <struct psi_decl_var *> decl_var
352 %destructor {psi_decl_var_free(&$$);} decl_var
353 %type <struct psi_decl_struct *> decl_struct
354 %destructor {psi_decl_struct_free(&$$);} decl_struct
355 %type <struct psi_decl_union *> decl_union
356 %destructor {psi_decl_union_free(&$$);} decl_union
357 %type <struct psi_decl_enum *> decl_enum
358 %destructor {psi_decl_enum_free(&$$);} decl_enum
359 %type <struct psi_decl_enum_item *> decl_enum_item
360 %destructor {psi_decl_enum_item_free(&$$);} decl_enum_item
361 %type <struct psi_plist *> decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
362 %destructor {psi_plist_free($$);} decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
363
364 %type <struct psi_layout> align_and_size
365 %destructor {} align_and_size
366 %type <struct psi_layout *> decl_layout
367 %destructor {psi_layout_free(&$$);} decl_layout
368
369 %type <struct psi_number *> sizeof sizeof_body sizeof_body_notypes
370 %destructor {psi_number_free(&$$);} sizeof sizeof_body sizeof_body_notypes
371
372 %type <struct psi_impl *> impl
373 %destructor {psi_impl_free(&$$);} impl
374 %type <struct psi_impl_func *> impl_func
375 %destructor {psi_impl_func_free(&$$);} impl_func
376 %type <struct psi_impl_arg *> impl_arg
377 %destructor {psi_impl_arg_free(&$$);} impl_arg
378 %type <struct psi_impl_type *> impl_type
379 %destructor {psi_impl_type_free(&$$);} impl_type
380 %type <struct psi_impl_var *> impl_var
381 %destructor {psi_impl_var_free(&$$);} impl_var
382
383 %type <struct psi_let_stmt *> let_stmt
384 %destructor {psi_let_stmt_free(&$$);} let_stmt
385 %type <struct psi_let_exp *> let_exp let_exp_byref let_exp_assign
386 %destructor {psi_let_exp_free(&$$);} let_exp let_exp_byref let_exp_assign
387 %type <struct psi_let_calloc *> let_calloc
388 %destructor {psi_let_calloc_free(&$$);} let_calloc
389 %type <struct psi_let_callback *> let_callback
390 %destructor {psi_let_callback_free(&$$);} let_callback
391 %type <struct psi_let_func *> let_func
392 %destructor {psi_let_func_free(&$$);} let_func
393 %type <struct psi_set_stmt *> set_stmt
394 %destructor {psi_set_stmt_free(&$$);} set_stmt
395 %type <struct psi_set_exp *> set_exp
396 %destructor {psi_set_exp_free(&$$);} set_exp
397 %type <struct psi_set_func *> set_func
398 %destructor {psi_set_func_free(&$$);} set_func
399 %type <struct psi_assert_stmt *> assert_stmt
400 %destructor {psi_assert_stmt_free(&$$);} assert_stmt
401 %type <struct psi_return_stmt *> return_stmt
402 %destructor {psi_return_stmt_free(&$$);} return_stmt
403 %type <struct psi_return_exp *> return_exp
404 %destructor {psi_return_exp_free(&$$);} return_exp
405 %type <struct psi_free_stmt *> free_stmt
406 %destructor {psi_free_stmt_free(&$$);} free_stmt
407 %type <struct psi_free_exp *> free_exp
408 %destructor {psi_free_exp_free(&$$);} free_exp
409
410 %type <struct psi_token **> impl_stmt
411 %destructor {psi_impl_stmt_free(&$$);} impl_stmt
412 %type <struct psi_token *> impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
413 %destructor {psi_token_free(&$$);} impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
414 %type <struct psi_plist *> impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
415 %destructor {psi_plist_free($$);} impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
416
417 %type <struct psi_num_exp *> num_exp
418 %destructor {psi_num_exp_free(&$$);} num_exp
419 %type <struct psi_number *> number
420 %destructor {psi_number_free(&$$);} number
421
422 %type <size_t> indirection pointers asterisks array_size
423 %destructor {} indirection pointers asterisks array_size
424 %type <bool> reference
425 %destructor {} reference
426
427 %%
428
429 /* rules */
430
431
432 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
433 unary_op_token: TILDE | NOT | PLUS | MINUS ;
434 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | AS | let_func_token | set_func_token;
435 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
436 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
437
438
439 file:
440 %empty
441 | blocks
442 ;
443 blocks:
444 block
445 | blocks block
446 ;
447 block:
448 EOS
449 | EOL
450 | COMMENT
451 | cpp {
452 if ($cpp) {
453 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
454 psi_cpp_exp_free(&$cpp);
455 }
456 }
457 | lib {
458 if (P->file.ln) {
459 P->error(PSI_DATA(P), $lib, PSI_WARNING,
460 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
461 } else {
462 P->file.ln = strndup($lib->text, $lib->size);
463 }
464 }
465 | constant {
466 psi_parser_proc_add_const(P, $constant);
467 }
468 | decl_stmt {
469 psi_parser_proc_add_decl(P, $decl_stmt);
470 }
471 | decl_extvar_stmt[list] {
472 psi_parser_proc_add_decl_extvars(P, $list);
473 }
474 | ignored_decl
475 | decl_typedef[def] {
476 psi_parser_proc_add_typedef(P, $def);
477 }
478 | decl_struct[struct] {
479 psi_parser_proc_add_struct(P, $struct);
480 }
481 | decl_union[union] {
482 psi_parser_proc_add_union(P, $union);
483 }
484 | decl_enum[enum] {
485 psi_parser_proc_add_enum(P, $enum);
486 }
487 | impl {
488 psi_parser_proc_add_impl(P, $impl);
489 }
490 ;
491
492 lib:
493 LIB QUOTED_STRING EOS {
494 $lib = $QUOTED_STRING;
495 }
496 ;
497
498 cpp:
499 HASH EOL {
500 $cpp = NULL;
501 }
502 | HASH cpp_exp[exp] EOL {
503 $cpp = $exp;
504 }
505 ;
506
507 cpp_exp[exp]:
508 cpp_message_token cpp_macro_decl_tokens[tokens] {
509 if ($tokens) {
510 struct psi_token *msg = NULL;
511
512 if (psi_plist_get($tokens, 0, &msg)) {
513 size_t index = 1;
514 struct psi_token *next;
515
516 msg = psi_token_copy(msg);
517 while (psi_plist_get($tokens, index++, &next)) {
518 struct psi_token *old = msg;
519 msg = psi_token_cat(" ", 2, msg, next);
520 free(old);
521 }
522 }
523 psi_plist_free($tokens);
524
525 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
526 } else {
527 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
528 }
529 $exp->token = psi_token_copy($cpp_message_token);
530 }
531 | cpp_include_token[INCLUDE] cpp_header_token {
532 $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
533 $exp->token = psi_token_copy($INCLUDE);
534 }
535 | cpp_no_arg_token {
536 $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
537 $exp->token = psi_token_copy($cpp_no_arg_token);
538 }
539 | cpp_name_arg_token cpp_special_name_token[name_token] {
540 $name_token->type = PSI_T_NAME;
541 $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
542 $exp->token = psi_token_copy($cpp_name_arg_token);
543 }
544 | DEFINE cpp_macro_decl {
545 $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
546 $exp->token = psi_token_copy($DEFINE);
547 }
548 | cpp_exp_arg_token cpp_macro_exp {
549 $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
550 $exp->token = psi_token_copy($cpp_exp_arg_token);
551 }
552 | PRAGMA_ONCE {
553 $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
554 $exp->token = psi_token_copy($PRAGMA_ONCE);
555 }
556 | cpp_ignored_token cpp_macro_decl_tokens[tokens] {
557 psi_plist_free($tokens);
558 $exp = NULL;
559 }
560 ;
561
562 cpp_ignored_token:
563 LINE
564 | PRAGMA
565 ;
566
567 cpp_message_token:
568 ERROR
569 | WARNING
570 ;
571
572 cpp_include_token:
573 IMPORT
574 | INCLUDE
575 | INCLUDE_NEXT
576 ;
577
578 cpp_header_token:
579 QUOTED_STRING
580 | CPP_HEADER
581 ;
582
583 cpp_no_arg_token:
584 ELSE
585 | ENDIF
586 ;
587
588 cpp_name_arg_token:
589 IFDEF
590 | IFNDEF
591 | UNDEF
592 ;
593
594 cpp_exp_arg_token:
595 IF
596 | ELIF
597 ;
598
599 cpp_special_name_token:
600 name_token
601 | NULL
602 | TRUE
603 | FALSE
604 | CPP_RESTRICT
605 | CPP_EXTENSION
606 | CPP_INLINE
607 ;
608
609 cpp_macro_decl[macro]:
610 name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
611 $name_token->type = PSI_T_NAME;
612 $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
613 $macro->token = psi_token_copy($name_token);
614 }
615 | cpp_special_name_token[name_token] cpp_macro_decl_tokens {
616 $name_token->type = PSI_T_NAME;
617 $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
618 $macro->token = psi_token_copy($name_token);
619 }
620 ;
621
622 cpp_macro_sig[sig]:
623 %empty {
624 $sig = psi_plist_init(NULL);
625 }
626 | ELLIPSIS {
627 $sig = psi_plist_init(NULL); /* FIXME */
628 }
629 | cpp_macro_sig_args
630 | cpp_macro_sig_args[args] COMMA ELLIPSIS {
631 $sig = $args;
632 }
633 ;
634
635 cpp_macro_sig_args[args]:
636 name_token {
637 $name_token = psi_token_copy($name_token);
638 $name_token->type = PSI_T_NAME;
639 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
640 }
641 | cpp_macro_sig_args[args_] COMMA name_token {
642 $name_token = psi_token_copy($name_token);
643 $name_token->type = PSI_T_NAME;
644 $args = psi_plist_add($args_, &$name_token);
645 }
646 ;
647
648 cpp_macro_decl_tokens[tokens]:
649 %empty {
650 $tokens = NULL;
651 }
652 | cpp_macro_decl_token_list
653 ;
654
655 cpp_macro_decl_token_list[tokens]:
656 any_noeol_token[token] {
657 $token = psi_token_copy($token);
658 $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
659 }
660 | cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
661 $token = psi_token_copy($token);
662 $tokens = psi_plist_add($tokens_, &$token);
663 }
664 ;
665
666 cpp_macro_exp[exp]:
667 LPAREN cpp_macro_exp[exp_] RPAREN {
668 $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
669 $exp->token = psi_token_copy($LPAREN);
670 }
671 | unary_op_token cpp_macro_exp[exp_] %prec UNARY {
672 $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
673 $exp->token = psi_token_copy($unary_op_token);
674 }
675 | cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
676 $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
677 $exp->token = psi_token_copy($binary_op_token);
678 }
679 | cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
680 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
681 $exp->token = psi_token_copy($IIF);
682 }
683
684 | DEFINED name_token {
685 {
686 uint8_t exists;
687
688 $name_token->type = PSI_T_NAME;
689 exists = psi_cpp_defined(P->preproc, $name_token);
690 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
691 $exp->token = psi_token_copy($name_token);
692 }
693 }
694 | DEFINED LPAREN name_token RPAREN {
695 {
696 uint8_t exists;
697
698 $name_token->type = PSI_T_NAME;
699 exists = psi_cpp_defined(P->preproc, $name_token);
700 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
701 $exp->token = psi_token_copy($name_token);
702 }
703 }
704 | NUMBER {
705 $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
706 $exp->token = psi_token_copy($NUMBER);
707 $exp->data.n->token = psi_token_copy($NUMBER);
708 }
709 | QUOTED_CHAR {
710 $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
711 $exp->token = psi_token_copy($QUOTED_CHAR);
712 $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
713 }
714 | sizeof {
715 $exp = psi_num_exp_init_num($sizeof);
716 $exp->token = psi_token_copy($sizeof->token);
717 }
718 | name_token {
719 $name_token->type = PSI_T_NAME;
720 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
721 $exp->token = psi_token_copy($name_token);
722 $exp->data.n->token = psi_token_copy($name_token);
723 }
724 | name_token LPAREN cpp_macro_call_args RPAREN {
725 $name_token->type = PSI_T_NAME;
726 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
727 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
728 $exp->token = psi_token_copy($name_token);
729 }
730 ;
731
732 cpp_macro_call_args[args]:
733 %empty {
734 $args = NULL;
735 }
736 | cpp_macro_call_arg_list
737 ;
738
739 cpp_macro_call_arg_list[args]:
740 cpp_macro_exp {
741 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
742 &$cpp_macro_exp);
743 }
744 | cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
745 $args = psi_plist_add($args_, &$cpp_macro_exp);
746 }
747 ;
748
749 constant[const]:
750 CONST constant_type NSNAME EQUALS impl_def_val EOS {
751 $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
752 $const->token = psi_token_copy($NSNAME);
753 }
754 ;
755
756 constant_type[type]:
757 constant_type_token[token] {
758 $type = psi_const_type_init($token->type, $token->text);
759 }
760 ;
761
762 constant_type_token:
763 BOOL
764 | INT
765 | FLOAT
766 | STRING
767 ;
768
769 impl_def_val[val]:
770 %empty {
771 $val = NULL;
772 }
773 | num_exp[num] %dprec 1 {
774 /* FIXME */
775 if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
776 impl_val res = {0};
777 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
778
779 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
780 $val = psi_impl_def_val_init(type, NULL);
781 } else {
782 $val = psi_impl_def_val_init(PSI_T_INT, NULL);
783 }
784
785 switch (type) {
786 case PSI_T_UINT8: $val->ival.zend.lval = res.u8; break;
787 case PSI_T_UINT16: $val->ival.zend.lval = res.u16; break;
788 case PSI_T_UINT32: $val->ival.zend.lval = res.u32; break;
789 case PSI_T_UINT64: $val->ival.zend.lval = res.u64; break; /* FIXME */
790 case PSI_T_INT8: $val->ival.zend.lval = res.i8; break;
791 case PSI_T_INT16: $val->ival.zend.lval = res.i16; break;
792 case PSI_T_INT32: $val->ival.zend.lval = res.i32; break;
793 case PSI_T_INT64: $val->ival.zend.lval = res.i64; break;
794 case PSI_T_FLOAT: $val->ival.dval = res.fval; break;
795 case PSI_T_DOUBLE: $val->ival.dval = res.dval; break;
796 default:
797 assert(0);
798
799 }
800 } else {
801 $val = NULL;
802 }
803 psi_num_exp_free(&$num);
804 }
805 | impl_def_val_token[token] %dprec 2 {
806 $val = psi_impl_def_val_init($token->type, $token->text);
807 $val->token = psi_token_copy($token);
808 }
809 ;
810
811 impl_def_val_token:
812 NULL
813 | TRUE
814 | FALSE
815 | QUOTED_STRING
816 ;
817
818 decl_typedef[def]:
819 TYPEDEF typedef[def_] EOS {
820 $def = $def_;
821 }
822 | TYPEDEF VOID name_token EOS {
823 $def = psi_decl_arg_init(
824 psi_decl_type_init(PSI_T_VOID, $VOID->text),
825 psi_decl_var_init($name_token->text, 0, 0)
826 );
827 $def->token = psi_token_copy($VOID);
828 $def->type->token = psi_token_copy($VOID);
829 $def->var->token = psi_token_copy($name_token);
830 }
831 | CPP_EXTENSION TYPEDEF typedef[def_] EOS {
832 $def = $def_;
833 }
834 ;
835
836 typedef[def]:
837 typedef_decl {
838 $def = $typedef_decl;
839 }
840 | CPP_EXTENSION typedef_decl {
841 $def = $typedef_decl;
842 }
843 ;
844
845 typedef_anon[def]:
846 typedef_anon_decl {
847 $def = $typedef_anon_decl;
848 }
849 | CPP_EXTENSION typedef_anon_decl {
850 $def = $typedef_anon_decl;
851 }
852 ;
853
854 typedef_decl[def]:
855 decl_arg
856 | decl_func_body[decl] {
857 $def = psi_decl_arg_init(
858 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
859 psi_decl_var_copy($decl->func->var)
860 );
861 $def->type->token = psi_token_copy($decl->func->token);
862 $def->type->real.func = $decl;
863 }
864 | decl_enum[enum] name_token {
865 $name_token->type = PSI_T_NAME;
866 $def = psi_decl_arg_init(
867 psi_decl_type_init(PSI_T_ENUM, $enum->name),
868 psi_decl_var_init($name_token->text, 0, 0)
869 );
870 $def->var->token = psi_token_copy($name_token);
871 $def->type->token = psi_token_copy($enum->token);
872 $def->type->real.enm = $enum;
873 psi_parser_proc_add_enum(P, $enum);
874 }
875 | struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
876 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
877 $def->type->token = $struct;
878 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
879 $def->type->real.strct->token = psi_token_copy($struct);
880 $def->type->real.strct->align = $as.pos;
881 $def->type->real.strct->size = $as.len;
882 psi_parser_proc_add_struct(P, $def->type->real.strct);
883 }
884 | union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
885 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
886 $def->type->token = $union;
887 $def->type->real.unn = psi_decl_union_init($union->text, $args);
888 $def->type->real.unn->token = psi_token_copy($union);
889 $def->type->real.unn->align = $as.pos;
890 $def->type->real.unn->size = $as.len;
891 psi_parser_proc_add_union(P, $def->type->real.unn);
892 }
893 ;
894
895 typedef_anon_decl[def]:
896 typedef_decl %dprec 2
897 | qualified_decl_type[type] %dprec 1 {
898 $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
899 $def->var->token = psi_token_copy($type->token);
900 }
901 | decl_enum[enum] {
902 $def = psi_decl_arg_init(
903 psi_decl_type_init(PSI_T_ENUM, $enum->name),
904 psi_decl_var_init(NULL, 0, 0)
905 );
906 $def->var->token = psi_token_copy($enum->token);
907 $def->type->token = psi_token_copy($enum->token);
908 $def->type->real.enm = $enum;
909 psi_parser_proc_add_enum(P, $enum);
910 }
911 | struct_name[struct] align_and_size[as] struct_args_block[args] {
912 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
913 $def->type->token = $struct;
914 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
915 $def->type->real.strct->token = psi_token_copy($struct);
916 $def->type->real.strct->align = $as.pos;
917 $def->type->real.strct->size = $as.len;
918 psi_parser_proc_add_struct(P, $def->type->real.strct);
919 }
920 | union_name[union] align_and_size[as] struct_args_block[args] {
921 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
922 $def->type->token = $union;
923 $def->type->real.unn = psi_decl_union_init($union->text, $args);
924 $def->type->real.unn->token = psi_token_copy($union);
925 $def->type->real.unn->align = $as.pos;
926 $def->type->real.unn->size = $as.len;
927 psi_parser_proc_add_union(P, $def->type->real.unn);
928 }
929 ;
930
931 qualified_decl_type[type]:
932 CONST decl_type[type_] {
933 $type = $type_;
934 }
935 | VOLATILE decl_type[type_] {
936 $type = $type_;
937 }
938 | decl_type
939 ;
940
941 decl_type[type]:
942 decl_type_simple[token] {
943 $type = psi_decl_type_init($token->type, $token->text);
944 $type->token = $token;
945 }
946 | decl_type_complex
947 ;
948
949 decl_type_complex[type]:
950 STRUCT[token] name_token {
951 $name_token->type = PSI_T_NAME;
952 $type = psi_decl_type_init($token->type, $name_token->text);
953 $type->token = psi_token_copy($name_token);
954 }
955 | UNION[token] name_token {
956 $name_token->type = PSI_T_NAME;
957 $type = psi_decl_type_init($token->type, $name_token->text);
958 $type->token = psi_token_copy($name_token);
959 }
960 | ENUM[token] name_token {
961 $name_token->type = PSI_T_NAME;
962 $type = psi_decl_type_init($token->type, $name_token->text);
963 $type->token = psi_token_copy($name_token);
964 }
965 ;
966
967 decl_type_simple[type]:
968 decl_int_type
969 | decl_real_type
970 | NAME[type_] {
971 $type = psi_token_copy($type_);
972 }
973 ;
974
975 decl_real_type[type]:
976 FLOAT[type_] {
977 $type = psi_token_copy($type_);
978 }
979 | DOUBLE[type_] {
980 $type = psi_token_copy($type_);
981 }
982 | LONG DOUBLE {
983 $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
984 }
985 ;
986
987 int_signed[i]:
988 SIGNED
989 | UNSIGNED
990 ;
991
992 int_width[i]:
993 SHORT {
994 $i = psi_token_copy($SHORT);
995 }
996 | LONG {
997 $i = psi_token_copy($LONG);
998 }
999 | LONG[l1] LONG[l2] {
1000 $i = psi_token_cat(" ", 2, $l1, $l2);
1001 }
1002 ;
1003
1004 decl_int_type[type]:
1005 CHAR {
1006 $type = psi_token_copy($CHAR);
1007 }
1008 | INT {
1009 $type = psi_token_copy($INT);
1010 }
1011 | int_signed int_signed_types {
1012 if ($2) {
1013 $type = psi_token_cat(" ", 2, $1, $2);
1014 free($2);
1015 } else {
1016 $type = psi_token_copy($1);
1017 }
1018 }
1019 | int_width int_width_types {
1020 if ($2) {
1021 $type = psi_token_cat(" ", 2, $1, $2);
1022 free($1);
1023 free($2);
1024 } else {
1025 $type = $1;
1026 }
1027 }
1028 ;
1029
1030 int_signed_types[type]:
1031 %empty {
1032 $type = NULL;
1033 }
1034 | NAME {
1035 $type = psi_token_copy($NAME);
1036 }
1037 | CHAR {
1038 $type = psi_token_copy($CHAR);
1039 }
1040 | SHORT signed_short_types {
1041 if ($2) {
1042 $type = psi_token_cat(" ", 2, $1, $2);
1043 } else {
1044 $type = psi_token_copy($1);
1045 }
1046 }
1047 | INT {
1048 $type = psi_token_copy($INT);
1049 }
1050 | LONG signed_long_types {
1051 if ($2) {
1052 $type = psi_token_cat(" ", 2, $1, $2);
1053 } else {
1054 $type = psi_token_copy($1);
1055 }
1056 }
1057 ;
1058
1059 signed_short_types[type]:
1060 %empty {
1061 $type = NULL;
1062 }
1063 | INT
1064 ;
1065 signed_long_types[type]:
1066 %empty {
1067 $type = NULL;
1068 }
1069 | INT
1070 | LONG
1071 | LONG INT
1072 ;
1073
1074 int_width_types[type]:
1075 %empty {
1076 $type = NULL;
1077 }
1078 | INT {
1079 $type = psi_token_copy($INT);
1080 }
1081 | int_signed int_signed_types {
1082 if ($2) {
1083 $type = psi_token_cat(" ", 2, $1, $2);
1084 free($2);
1085 } else {
1086 $type = psi_token_copy($1);
1087 }
1088 }
1089 ;
1090
1091 decl_stmt:
1092 decl decl_asm EOS {
1093 $decl_stmt = $decl;
1094 }
1095 | CPP_EXTENSION decl decl_asm EOS {
1096 $decl_stmt = $decl;
1097 }
1098 ;
1099
1100 decl_asm:
1101 %empty
1102 | CPP_ASM LPAREN ignored_quoted_strings RPAREN
1103 ;
1104
1105 ignored_quoted_strings:
1106 QUOTED_STRING
1107 | ignored_quoted_strings QUOTED_STRING
1108 ;
1109
1110 decl_extvar_stmt[list]:
1111 NAME decl_arg decl_extvar_list[vars] EOS {
1112 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
1113
1114 if ($vars) {
1115 size_t i = 0;
1116 struct psi_decl_var *var;
1117
1118 while (psi_plist_get($vars, i++, &var)) {
1119 if (psi_decl_extvar_is_blacklisted(var->name)) {
1120 psi_decl_var_free(&var);
1121 } else {
1122 list = psi_plist_add(list, psi_decl_extvar_init(
1123 psi_decl_arg_init(psi_decl_type_copy($decl_arg->type), var)));
1124 }
1125 }
1126 free($vars);
1127 }
1128
1129 if (psi_decl_extvar_is_blacklisted($decl_arg->var->name)) {
1130 psi_decl_arg_free(&$decl_arg);
1131 } else {
1132 struct psi_decl_extvar *evar = psi_decl_extvar_init($decl_arg);
1133 list = psi_plist_add(list, &evar);
1134 }
1135
1136 $list = list;
1137 }
1138 ;
1139
1140 decl_extvar_list[list]:
1141 %empty {
1142 $list = NULL;
1143 }
1144 | COMMA decl_vars {
1145 $list = $decl_vars;
1146 }
1147 ;
1148
1149 decl_vars[vars]:
1150 decl_var[var] {
1151 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1152 }
1153 | decl_vars[vars_] COMMA decl_var[var] {
1154 $vars = psi_plist_add($vars_, &$var);
1155 }
1156 ;
1157
1158 ignored_decl:
1159 STATIC decl_body ignored_decl_body {
1160 psi_decl_free(&$decl_body);
1161 }
1162 | CPP_INLINE decl_body ignored_decl_body {
1163 psi_decl_free(&$decl_body);
1164 }
1165 | STATIC CPP_INLINE decl_body ignored_decl_body {
1166 psi_decl_free(&$decl_body);
1167 }
1168 ;
1169
1170 ignored_decl_body:
1171 LBRACE ignored_decl_body_stmts RBRACE
1172 ;
1173
1174 ignored_decl_body_stmts:
1175 ignored_decl_body_stmt
1176 | ignored_decl_body_stmts ignored_decl_body_stmt
1177 ;
1178
1179 ignored_decl_body_stmt:
1180 any_nobrace_token
1181 | ignored_decl_body
1182 ;
1183
1184 decl:
1185 decl_body
1186 | NAME[abi] decl_body {
1187 $decl = $decl_body;
1188 $decl->abi = psi_decl_abi_init($abi->text);
1189 }
1190 ;
1191
1192 decl_body:
1193 decl_func_body
1194 | decl_functor_body
1195 ;
1196
1197 decl_func_body[decl]:
1198 decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1199 $decl = psi_decl_init($func, $args);
1200 if ($as) {
1201 $decl->func->var->pointer_level += 1;
1202 $decl->func->var->array_size = $as;
1203 }
1204 }
1205 | decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1206 $decl = psi_decl_init($func, $args);
1207 $decl->varargs = 1;
1208 if ($as) {
1209 $decl->func->var->pointer_level += 1;
1210 $decl->func->var->array_size = $as;
1211 }
1212 }
1213 ;
1214
1215 decl_functor_body[decl]:
1216 decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1217 $decl = psi_decl_init($func, $args);
1218 if ($as) {
1219 $decl->func->var->pointer_level += 1;
1220 $decl->func->var->array_size = $as;
1221 }
1222 }
1223 | decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1224 $decl = psi_decl_init($func, $args);
1225 $decl->varargs = 1;
1226 if ($as) {
1227 $decl->func->var->pointer_level += 1;
1228 $decl->func->var->array_size = $as;
1229 }
1230 }
1231 ;
1232
1233 decl_functor[arg]:
1234 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1235 (void) $unused1;
1236 $NAME->type = PSI_T_NAME;
1237 $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1238 $arg->var->token = psi_token_copy($NAME);
1239 $arg->token = psi_token_copy($NAME);
1240 }
1241 | CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1242 (void) $unused1;
1243 $NAME->type = PSI_T_NAME;
1244 $arg = psi_decl_arg_init(
1245 psi_decl_type_init($VOID->type, $VOID->text),
1246 psi_decl_var_init($NAME->text, $pointers, 0)
1247 );
1248 $arg->type->token = psi_token_copy($VOID);
1249 $arg->var->token = psi_token_copy($NAME);
1250 $arg->token = psi_token_copy($NAME);
1251 }
1252 | VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1253 (void) $unused1;
1254 $NAME->type = PSI_T_NAME;
1255 $arg = psi_decl_arg_init(
1256 psi_decl_type_init($VOID->type, $VOID->text),
1257 psi_decl_var_init($NAME->text, $pointers, 0)
1258 );
1259 $arg->type->token = psi_token_copy($VOID);
1260 $arg->var->token = psi_token_copy($NAME);
1261 $arg->token = psi_token_copy($NAME);
1262 }
1263 | VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1264 (void) $unused1;
1265 $NAME->type = PSI_T_NAME;
1266 $arg = psi_decl_arg_init(
1267 psi_decl_type_init($VOID->type, $VOID->text),
1268 psi_decl_var_init($NAME->text, 0, 0)
1269 );
1270 $arg->type->token = psi_token_copy($VOID);
1271 $arg->var->token = psi_token_copy($NAME);
1272 $arg->token = psi_token_copy($NAME);
1273 }
1274 ;
1275
1276 decl_func[func]:
1277 decl_arg
1278 | VOID name_token[NAME] {
1279 $func = psi_decl_arg_init(
1280 psi_decl_type_init($VOID->type, $VOID->text),
1281 psi_decl_var_init($NAME->text, 0, 0)
1282 );
1283 $func->type->token = psi_token_copy($VOID);
1284 $func->var->token = psi_token_copy($NAME);
1285 $func->token = psi_token_copy($NAME);
1286 }
1287 ;
1288
1289 decl_args[args]:
1290 %empty {
1291 $args = NULL;
1292 }
1293 | VOID {
1294 $args = NULL;
1295 }
1296 | decl_arg_list[args_] {
1297 $args = $args_;
1298 }
1299 ;
1300
1301 decl_arg_list[args]:
1302 decl_anon_arg[arg] {
1303 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1304 }
1305 | decl_arg_list[args_] COMMA decl_anon_arg[arg] {
1306 $args = psi_plist_add($args_, &$arg);
1307 }
1308 ;
1309
1310 decl_anon_arg[arg]:
1311 /* FIXME decl_functor_body_anon */
1312 decl_arg %dprec 2 {
1313 $arg = $decl_arg;
1314 }
1315 | qualified_decl_type[type] indirection %dprec 1 {
1316 $arg = psi_decl_arg_init(
1317 $type,
1318 psi_decl_var_init(NULL, $indirection, 0)
1319 );
1320 }
1321 | CONST VOID pointers {
1322 $arg = psi_decl_arg_init(
1323 psi_decl_type_init($VOID->type, $VOID->text),
1324 psi_decl_var_init(NULL, $pointers, 0)
1325 );
1326 $arg->type->token = psi_token_copy($VOID);
1327 $arg->var->token = psi_token_copy($VOID);
1328 $arg->token = psi_token_copy($VOID);
1329 }
1330 | VOID pointers {
1331 $arg = psi_decl_arg_init(
1332 psi_decl_type_init($VOID->type, $VOID->text),
1333 psi_decl_var_init(NULL, $pointers, 0)
1334 );
1335 $arg->type->token = psi_token_copy($VOID);
1336 $arg->var->token = psi_token_copy($VOID);
1337 $arg->token = psi_token_copy($VOID);
1338 }
1339 ;
1340
1341 decl_arg[arg]:
1342 decl_functor_body[decl] {
1343 $arg = psi_decl_arg_init(
1344 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1345 psi_decl_var_copy($decl->func->var)
1346 );
1347 $arg->type->token = psi_token_copy($decl->func->token);
1348 $arg->type->real.func = $decl;
1349 }
1350 | qualified_decl_type[type] decl_var[var] {
1351 $arg = psi_decl_arg_init($type, $var);
1352 }
1353 | CONST VOID pointers name_token[NAME] {
1354 $NAME->type = PSI_T_NAME;
1355 $arg = psi_decl_arg_init(
1356 psi_decl_type_init($VOID->type, $VOID->text),
1357 psi_decl_var_init($NAME->text, $pointers, 0)
1358 );
1359 $arg->type->token = psi_token_copy($VOID);
1360 $arg->var->token = psi_token_copy($NAME);
1361 $arg->token = psi_token_copy($NAME);
1362 }
1363 | VOID pointers name_token[NAME] {
1364 $NAME->type = PSI_T_NAME;
1365 $arg = psi_decl_arg_init(
1366 psi_decl_type_init($VOID->type, $VOID->text),
1367 psi_decl_var_init($NAME->text, $pointers, 0)
1368 );
1369 $arg->type->token = psi_token_copy($VOID);
1370 $arg->var->token = psi_token_copy($NAME);
1371 $arg->token = psi_token_copy($NAME);
1372 }
1373 ;
1374
1375 decl_var[var]:
1376 pointers name_token array_size {
1377 $name_token->type = PSI_T_NAME;
1378 $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1379 $var->token = psi_token_copy($name_token);
1380 }
1381 | name_token array_size {
1382 $name_token->type = PSI_T_NAME;
1383 $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1384 $var->token = psi_token_copy($name_token);
1385 }
1386 ;
1387
1388 decl_union[union]:
1389 UNION name_token align_and_size[as] decl_struct_args[args] {
1390 $name_token->type = PSI_T_NAME;
1391 $union = psi_decl_union_init($name_token->text, $args);
1392 $union->align = $as.pos;
1393 $union->size = $as.len;
1394 $union->token = psi_token_copy($name_token);
1395 }
1396 ;
1397
1398 decl_struct[struct]:
1399 STRUCT name_token align_and_size[as] decl_struct_args[args] {
1400 $name_token->type = PSI_T_NAME;
1401 $struct = psi_decl_struct_init($name_token->text, $args);
1402 $struct->align = $as.pos;
1403 $struct->size = $as.len;
1404 $struct->token = psi_token_copy($name_token);
1405 }
1406 ;
1407
1408 decl_struct_args[args]:
1409 EOS {
1410 $args = NULL;
1411 }
1412 | struct_args_block
1413 ;
1414
1415 struct_args_block[args]:
1416 LBRACE struct_args RBRACE {
1417 $args = $struct_args;
1418 }
1419 ;
1420
1421 struct_args[args]:
1422 typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1423 $arg->layout = $layout;
1424 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1425 if ($vars) {
1426 size_t i = 0;
1427 struct psi_decl_arg *arg;
1428
1429 while (psi_plist_get($vars, i++, &arg)) {
1430 arg->type = psi_decl_type_copy($arg->type);
1431 $args = psi_plist_add($args, &arg);
1432 }
1433 free($vars);
1434 }
1435 }
1436 | struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1437 $arg->layout = $layout;
1438 $args = psi_plist_add($args_, &$arg);
1439 if ($vars) {
1440 size_t i = 0;
1441 struct psi_decl_arg *arg;
1442
1443 while (psi_plist_get($vars, i++, &arg)) {
1444 arg->type = psi_decl_type_copy($arg->type);
1445 $args = psi_plist_add($args, &arg);
1446 }
1447 free($vars);
1448 }
1449 }
1450 ;
1451
1452 struct_arg_var_list[vars]:
1453 %empty {
1454 $vars = NULL;
1455 }
1456 | COMMA decl_vars_with_layout[vars_] {
1457 $vars = $vars_;
1458 }
1459 ;
1460
1461 decl_vars_with_layout[vars]:
1462 decl_var[var] decl_layout[layout] {
1463 {
1464 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1465 arg->layout = $layout;
1466 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1467 }
1468 }
1469 | decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1470 {
1471 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1472 arg->layout = $layout;
1473 $vars = psi_plist_add($vars_, &arg);
1474 }
1475 }
1476 ;
1477
1478 decl_enum[enum]:
1479 enum_name LBRACE decl_enum_items[list] optional_comma RBRACE {
1480 $enum = psi_decl_enum_init($enum_name->text, $list);
1481 $enum->token = $enum_name;
1482 }
1483 ;
1484
1485 decl_enum_items[list]:
1486 decl_enum_item[i] {
1487 $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1488 }
1489 | decl_enum_items[list_] COMMA decl_enum_item[i] {
1490 $list = psi_plist_add($list_, &$i);
1491 }
1492 ;
1493
1494 decl_enum_item[i]:
1495 name_token {
1496 $name_token->type = PSI_T_NAME;
1497 $i = psi_decl_enum_item_init($name_token->text, NULL);
1498 $i->token = psi_token_copy($name_token);
1499 }
1500 | name_token EQUALS num_exp {
1501 $name_token->type = PSI_T_NAME;
1502 $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1503 $i->token = psi_token_copy($name_token);
1504 }
1505 ;
1506
1507 num_exp[exp]:
1508 number {
1509 $exp = psi_num_exp_init_num($number);
1510 $exp->token = psi_token_copy($number->token);
1511 }
1512 | LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1513 $exp = psi_num_exp_init_cast($type, $exp_);
1514 $exp->token = psi_token_copy($type->token);
1515 }
1516 | LPAREN num_exp[exp_] RPAREN {
1517 $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1518 $exp->token = psi_token_copy($LPAREN);
1519 }
1520 | num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1521 $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1522 $exp->token = psi_token_copy($op);
1523 }
1524 | unary_op_token[op] num_exp[exp_] %prec UNARY {
1525 $exp = psi_num_exp_init_unary($op->type, $exp_);
1526 $exp->token = psi_token_copy($op);
1527 }
1528 | num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1529 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1530 $exp->token = psi_token_copy($IIF);
1531 }
1532 ;
1533
1534 number[num]:
1535 NUMBER[token] {
1536 $num = psi_number_init($token->type, $token->text, $token->flags);
1537 $num->token = psi_token_copy($token);
1538 }
1539 | NSNAME[token] {
1540 $num = psi_number_init($token->type, $token->text, 0);
1541 $num->token = psi_token_copy($token);
1542 }
1543 | QUOTED_CHAR[token] {
1544 $num = psi_number_init($token->type, $token->text, 0);
1545 $num->token = psi_token_copy($token);
1546 }
1547 | NULL[token] {
1548 $num = psi_number_init($token->type, $token->text, 0);
1549 $num->token = psi_token_copy($token);
1550 }
1551 | decl_var {
1552 $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1553 $num->token = psi_token_copy($decl_var->token);
1554 }
1555 | sizeof {
1556 $num = $sizeof;
1557 }
1558 ;
1559
1560 sizeof:
1561 SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1562 $sizeof = $sizeof_;
1563 $sizeof->token = psi_token_copy($SIZEOF);
1564 }
1565 | SIZEOF sizeof_body_notypes[sizeof_] {
1566 $sizeof = $sizeof_;
1567 $sizeof->token = psi_token_copy($SIZEOF);
1568 }
1569 ;
1570
1571 sizeof_body[sizeof]:
1572 sizeof_body_notypes[sizeof_] {
1573 $sizeof = $sizeof_;
1574 }
1575 | decl_type indirection {
1576 if ($indirection) {
1577 int8_t sizeof_void_p = sizeof(void *);
1578 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1579 psi_decl_type_free(&$decl_type);
1580 } else {
1581 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1582 }
1583 }
1584 ;
1585
1586 sizeof_body_notypes[sizeof]:
1587 AMPERSAND NAME {
1588 int8_t sizeof_void_p = sizeof(void *);
1589 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1590 }
1591 | QUOTED_CHAR {
1592 int8_t sizeof_a = sizeof('a');
1593 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1594 }
1595 | QUOTED_STRING {
1596 $sizeof = psi_number_init(PSI_T_INT64, &$QUOTED_STRING->size, 0);
1597 }
1598 ;
1599
1600 enum_name[name]:
1601 ENUM optional_name[name_] {
1602 if ($name_) {
1603 $name = psi_token_copy($name_);
1604 } else {
1605 char digest[17];
1606
1607 psi_token_hash($ENUM, digest);
1608 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1609 }
1610 }
1611 ;
1612
1613 union_name[name]:
1614 UNION optional_name[name_] {
1615 if ($name_) {
1616 $name = psi_token_copy($name_);
1617 } else {
1618 char digest[17];
1619
1620 psi_token_hash($UNION, digest);
1621 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1622 }
1623 }
1624 ;
1625
1626 struct_name[name]:
1627 STRUCT optional_name[name_] {
1628 if ($name_) {
1629 $name = psi_token_copy($name_);
1630 } else {
1631 char digest[17];
1632
1633 psi_token_hash($STRUCT, digest);
1634 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1635 }
1636 }
1637 ;
1638
1639 optional_name[name]:
1640 %empty {
1641 $name = NULL;
1642 }
1643 | name_token {
1644 $name = $name_token;
1645 $name->type = PSI_T_NAME;
1646 }
1647 ;
1648
1649 optional_comma:
1650 %empty
1651 | COMMA
1652 ;
1653
1654 decl_layout[l]:
1655 %empty {
1656 $l = NULL;
1657 }
1658 | COLON NUMBER[width] {
1659 $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1660 }
1661 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1662 $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1663 }
1664 | COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1665 $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1666 }
1667 ;
1668
1669 align_and_size[as]:
1670 %empty {
1671 $as.pos = 0;
1672 $as.len = 0;
1673 }
1674 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1675 $as.pos = atol($align->text);
1676 $as.len = atol($size->text);
1677 }
1678 ;
1679
1680 array_size[as]:
1681 %empty {
1682 $as = 0;
1683 }
1684 | LBRACKET RBRACKET {
1685 $as = 0;
1686 }
1687 | LBRACKET CPP_RESTRICT RBRACKET {
1688 $as = 0;
1689 }
1690 | LBRACKET num_exp RBRACKET {
1691 if (psi_num_exp_validate(PSI_DATA(P), $num_exp, NULL, NULL, NULL, NULL, NULL)) {
1692 $as = psi_long_num_exp($num_exp, NULL, &P->preproc->defs);
1693 } else {
1694 $as = 0;
1695 }
1696 psi_num_exp_free(&$num_exp);
1697 }
1698 ;
1699
1700 indirection[i]:
1701 %empty {
1702 $i = 0;
1703 }
1704 | pointers[p] %prec UNARY {
1705 $i = $p;
1706 }
1707 ;
1708
1709 pointers[p]:
1710 asterisks
1711 | asterisks[a] CPP_RESTRICT {
1712 $p = $a;
1713 }
1714 ;
1715
1716 asterisks[a]:
1717 asterisk {
1718 $a = 1;
1719 }
1720 | asterisks[a_] asterisk {
1721 $a = $a_ + 1;
1722 }
1723 ;
1724
1725 asterisk:
1726 ASTERISK
1727 | ASTERISK CONST
1728 ;
1729
1730 /*
1731 *
1732 * impl
1733 *
1734 */
1735
1736 impl:
1737 impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1738 $impl = psi_impl_init($func, $stmts);
1739 }
1740 | STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1741 $impl = psi_impl_init($func, $stmts);
1742 $func->static_memory = 1;
1743 }
1744 ;
1745
1746 impl_func[func]:
1747 FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1748 $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1749 $func->token = psi_token_copy($NSNAME);
1750 $func->return_reference = $r;
1751 }
1752 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1753 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1754 $func->token = psi_token_copy($NSNAME);
1755 $func->return_reference = $r;
1756 }
1757 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1758 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1759 $func->token = psi_token_copy($NSNAME);
1760 $func->return_reference = $r;
1761 $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1762 $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1763 }
1764 ;
1765
1766 impl_args[args]:
1767 impl_arg[arg] {
1768 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1769 }
1770 | impl_args[args_] COMMA impl_arg[arg] {
1771 $args = psi_plist_add($args_, &$arg);
1772 }
1773 ;
1774
1775 impl_arg[arg]:
1776 impl_type[type] impl_var[var] {
1777 $arg = psi_impl_arg_init($type, $var, NULL);
1778 }
1779 | impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1780 $arg = psi_impl_arg_init($type, $var, $val);
1781 }
1782 ;
1783
1784 impl_var[var]:
1785 reference DOLLAR_NAME {
1786 $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1787 $var->token = psi_token_copy($DOLLAR_NAME);
1788 }
1789 ;
1790
1791 impl_type[type]:
1792 impl_type_token[token] {
1793 $type = psi_impl_type_init($token->type, $token->text);
1794 $type->token = psi_token_copy($token);
1795 }
1796 ;
1797
1798 impl_type_token:
1799 VOID
1800 | MIXED
1801 | BOOL
1802 | INT
1803 | FLOAT
1804 | STRING
1805 | ARRAY
1806 | OBJECT
1807 | CALLABLE
1808 ;
1809
1810 impl_stmts[stmts]:
1811 impl_stmt[stmt] {
1812 $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1813 }
1814 | impl_stmts[stmts_] impl_stmt[stmt] {
1815 $stmts = psi_plist_add($stmts_, &$stmt);
1816 }
1817 ;
1818
1819 impl_stmt[stmt]:
1820 return_stmt[s] {
1821 $stmt = (struct psi_token **) $s;
1822 }
1823 | let_stmt[s] {
1824 $stmt = (struct psi_token **) $s;
1825 }
1826 | set_stmt[s] {
1827 $stmt = (struct psi_token **) $s;
1828 }
1829 | assert_stmt[s] {
1830 $stmt = (struct psi_token **) $s;
1831 }
1832 | free_stmt[s] {
1833 $stmt = (struct psi_token **) $s;
1834 }
1835 ;
1836
1837 let_stmt[let]:
1838 LET let_exp_assign[exp] EOS {
1839 $let = psi_let_stmt_init($exp);
1840 $let->token = psi_token_copy($LET);
1841 }
1842 | TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1843 $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1844 $let->token = psi_token_copy($TEMP);
1845 $let->exp->is_reference = $reference;
1846 }
1847 ;
1848
1849 let_exp[exp]:
1850 let_exp_assign
1851 | byref let_exp_byref[exp_] {
1852 $exp = $exp_;
1853 $exp->is_reference = true;
1854 }
1855 | let_exp_byref[exp_] {
1856 $exp = $exp_;
1857 $exp->is_reference = false;
1858 }
1859 ;
1860
1861 let_exp_byref[exp]:
1862 NULL %dprec 2 {
1863 $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1864 }
1865 | num_exp[num] %dprec 1 {
1866 $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1867 }
1868 | let_calloc[calloc] {
1869 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1870 }
1871 | STATIC let_calloc[calloc] {
1872 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1873 $calloc->static_memory = 1;
1874 }
1875 | let_callback[callback] {
1876 $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1877 }
1878 | let_func[func] {
1879 $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1880 }
1881 ;
1882
1883 let_exp_assign[exp]:
1884 decl_var[var] EQUALS let_exp_byref[exp_] {
1885 $exp = $exp_;
1886 $exp->var = $var;
1887 }
1888 | decl_var[var] EQUALS byref let_exp_byref[exp_] {
1889 $exp = $exp_;
1890 $exp->is_reference = 1;
1891 $exp->var = $var;
1892 }
1893 ;
1894
1895 let_calloc[calloc]:
1896 CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1897 $calloc = psi_let_calloc_init($nmemb, $size);
1898 $calloc->token = psi_token_copy($CALLOC);
1899 }
1900 ;
1901
1902 let_callback[callback]:
1903 CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1904 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, NULL);
1905 $callback->func->token = psi_token_copy($func);
1906 $callback->token = psi_token_copy($CALLBACK);
1907 }
1908 | CALLBACK LPAREN call_decl_vars[cb_args] RPAREN AS callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1909 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, $cb_args);
1910 $callback->func->token = psi_token_copy($func);
1911 $callback->token = psi_token_copy($CALLBACK);
1912 }
1913 ;
1914
1915 let_func[func]:
1916 let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1917 $func = psi_let_func_init($token->type, $token->text, $var);
1918 $func->token = psi_token_copy($token);
1919 $func->inner = $exps;
1920 }
1921 ;
1922
1923 let_func_token:
1924 ZVAL
1925 | OBJVAL
1926 | ARRVAL
1927 | PATHVAL
1928 | STRLEN
1929 | STRVAL
1930 | FLOATVAL
1931 | INTVAL
1932 | BOOLVAL
1933 | COUNT
1934 ;
1935
1936 let_func_exps[exps]:
1937 %empty {
1938 $exps = NULL;
1939 }
1940 | COMMA let_exps[exps_] {
1941 $exps = $exps_;
1942 }
1943 ;
1944
1945 let_exps[exps]:
1946 let_exp[exp] {
1947 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1948 }
1949 | let_exps[exps_] COMMA let_exp[exp] {
1950 $exps = psi_plist_add($exps_, &$exp);
1951 }
1952 ;
1953
1954 callback_rval[rval]:
1955 VOID
1956 | let_func_token
1957 ;
1958
1959 callback_arg_list[list]:
1960 %empty {
1961 $list = NULL;
1962 }
1963 | callback_args[args] {
1964 $list = $args;
1965 }
1966 ;
1967
1968 callback_args[args]:
1969 set_exp[exp] {
1970 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1971 }
1972 | callback_args[args_] COMMA set_exp[exp] {
1973 $args = psi_plist_add($args_, &$exp);
1974 }
1975 ;
1976
1977 return_stmt[return]:
1978 RETURN return_exp EOS {
1979 $return = psi_return_stmt_init($return_exp);
1980 $return->token = psi_token_copy($RETURN);
1981 }
1982 ;
1983
1984 return_exp:
1985 decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
1986 $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1987 $return_exp->token = psi_token_copy($func->token);
1988 }
1989 | set_func {
1990 $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1991 $return_exp->token = psi_token_copy($set_func->token);
1992 }
1993 ;
1994
1995 call_decl_vars[args]:
1996 %empty {
1997 $args = NULL;
1998 }
1999 | VOID {
2000 $args = NULL;
2001 }
2002 | decl_vars[vars] {
2003 $args = $vars;
2004 }
2005 ;
2006
2007 set_stmt[set]:
2008 SET set_exp[exp] EOS {
2009 $set = psi_set_stmt_init($exp);
2010 $set->token = psi_token_copy($SET);
2011 }
2012 ;
2013
2014 set_exp[exp]:
2015 set_func[func] {
2016 $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
2017 }
2018 | num_exp[num] {
2019 $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
2020 }
2021 | impl_var[var] EQUALS set_exp[exp_] {
2022 $exp = $exp_;
2023 $exp->var = $var;
2024 }
2025 ;
2026
2027 set_func[func]:
2028 set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
2029 $func = psi_set_func_init($token->type, $token->text, $var);
2030 $func->token = psi_token_copy($token);
2031 $func->inner = $exps;
2032 }
2033 | set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
2034 $func = psi_set_func_init($token->type, $token->text, $var);
2035 $func->token = psi_token_copy($token);
2036 $func->recursive = 1;
2037 }
2038 ;
2039
2040 set_func_token:
2041 TO_OBJECT
2042 | TO_ARRAY
2043 | TO_STRING
2044 | TO_INT
2045 | TO_FLOAT
2046 | TO_BOOL
2047 | ZVAL
2048 | VOID
2049 ;
2050
2051 set_func_exps[exps]:
2052 %empty {
2053 $exps = NULL;
2054 }
2055 | COMMA set_exps[exps_] {
2056 $exps = $exps_;
2057 }
2058 ;
2059
2060 set_exps[exps]:
2061 set_exp[exp] {
2062 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2063 }
2064 | set_exps[exps_] COMMA set_exp[exp] {
2065 $exps = psi_plist_add($exps_, &$exp);
2066 }
2067 ;
2068
2069 assert_stmt[assert]:
2070 assert_stmt_token[token] num_exp[exp] EOS {
2071 $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
2072 $assert->token = psi_token_copy($token);
2073 }
2074 ;
2075
2076 assert_stmt_token:
2077 PRE_ASSERT
2078 | POST_ASSERT
2079 ;
2080
2081 free_stmt[free]:
2082 FREE free_exps[exps] EOS {
2083 $free = psi_free_stmt_init($exps);
2084 $free->token = psi_token_copy($FREE);
2085 }
2086 ;
2087
2088 free_exps[exps]:
2089 free_exp[exp] {
2090 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
2091 }
2092 | free_exps[exps_] COMMA free_exp[exp] {
2093 $exps = psi_plist_add($exps_, &$exp);
2094 }
2095 ;
2096
2097 free_exp[exp]:
2098 name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2099 $NAME->type = PSI_T_NAME;
2100 $exp = psi_free_exp_init($NAME->text, $vars);
2101 $exp->token = psi_token_copy($NAME);
2102 }
2103 ;
2104
2105 reference:
2106 %empty {
2107 $reference = false;
2108 }
2109 | byref {
2110 $reference = true;
2111 }
2112 ;
2113
2114 byref:
2115 AMPERSAND %prec UNARY
2116 ;
2117
2118 %%
2119
2120 /* epilogue */
2121
2122 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2123 {
2124 struct psi_token *token;
2125
2126 if (psi_plist_get(tokens, (*index)++, &token)) {
2127 if (P->flags & PSI_DEBUG) {
2128 psi_token_dump(2, token);
2129 }
2130
2131 *((struct psi_token **)lvalp) = token;
2132 return token->type;
2133 } else {
2134 (*index)--;
2135 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
2136 }
2137
2138 return PSI_T_EOF;
2139 }
2140
2141 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2142 {
2143 struct psi_token *T = NULL;
2144 size_t last;
2145
2146 if (*index == 0) {
2147 last = 0;
2148 } else {
2149 last = --(*index);
2150 }
2151
2152 psi_plist_get(tokens, last, &T);
2153 if (T) {
2154 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2155 } else {
2156 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2157 }
2158 P->errors++;
2159 }
2160
PHP System Interface / POSIX Standard Interface