git.m6w6.name Git - m6w6/ext-psi/blob - src/parser_proc_grammar.y

   1 %code top {
   2 #include "php_psi_stdinc.h"
   3 }
   4
   5 %code {
   6 #include <assert.h>
   7 #include <stdarg.h>
   8
   9 #include "plist.h"
  10 #include "parser.h"
  11 #define YYDEBUG 1
  12
  13 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
  14 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
  15
  16 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
  17 {
  18         assert(strct);
  19         if (!P->structs) {
  20                 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
  21         }
  22         P->structs = psi_plist_add(P->structs, &strct);
  23 }
  24 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
  25 {
  26         assert(u);
  27         if (!P->unions) {
  28                 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
  29         }
  30         P->unions = psi_plist_add(P->unions, &u);
  31 }
  32 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
  33 {
  34         assert(e);
  35         if (!P->enums) {
  36                 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
  37         }
  38         P->enums = psi_plist_add(P->enums, &e);
  39 }
  40 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
  41 {
  42         assert(def);
  43         if (!P->types) {
  44                 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
  45         }
  46         P->types = psi_plist_add(P->types, &def);
  47 }
  48 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
  49         assert(cnst);
  50         if (!P->consts) {
  51                 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
  52         }
  53         P->consts = psi_plist_add(P->consts, &cnst);
  54
  55 }
  56 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
  57         assert(decl);
  58         if (!P->decls) {
  59                 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
  60         }
  61         P->decls = psi_plist_add(P->decls, &decl);
  62 }
  63 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
  64         assert(impl);
  65         if (!P->impls) {
  66                 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
  67         }
  68         P->impls = psi_plist_add(P->impls, &impl);
  69 }
  70
  71 /* end code */
  72 }
  73
  74 %code requires {
  75 #include "plist.h"
  76 #include "types/layout.h"
  77
  78 struct psi_parser;
  79
  80 }
  81
  82 %require "3.0"
  83 %language "c"
  84 %name-prefix "psi_parser_proc_"
  85 %token-table
  86 %verbose
  87 %glr-parser
  88
  89 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
  90
  91 %define api.pure true
  92 %define api.token.prefix {PSI_T_}
  93 %define api.value.type union
  94
  95 %define parse.error verbose
  96 %define parse.trace true
  97
  98 %initial-action {
  99 }
 100
 101 %start file
 102
 103 %token <struct psi_token *> BOOL
 104 %token <struct psi_token *> CHAR
 105 %token <struct psi_token *> SHORT
 106 %token <struct psi_token *> INT
 107 %token <struct psi_token *> SIGNED
 108 %token <struct psi_token *> UNSIGNED
 109 %token <struct psi_token *> LONG
 110 %token <struct psi_token *> FLOAT
 111 %token <struct psi_token *> DOUBLE
 112 %token <struct psi_token *> STRING
 113 %token <struct psi_token *> MIXED
 114 %token <struct psi_token *> ARRAY
 115 %token <struct psi_token *> OBJECT
 116 %token <struct psi_token *> CALLABLE
 117 %token <struct psi_token *> VOID
 118 %token <struct psi_token *> ZVAL
 119 %token <struct psi_token *> INT8
 120 %token <struct psi_token *> UINT8
 121 %token <struct psi_token *> INT16
 122 %token <struct psi_token *> UINT16
 123 %token <struct psi_token *> INT32
 124 %token <struct psi_token *> UINT32
 125 %token <struct psi_token *> INT64
 126 %token <struct psi_token *> UINT64
 127 %token <struct psi_token *> NULL
 128 %token <struct psi_token *> TRUE
 129 %token <struct psi_token *> FALSE
 130 %token <struct psi_token *> NAME
 131 %token <struct psi_token *> NSNAME
 132 %token <struct psi_token *> DOLLAR_NAME
 133 %token <struct psi_token *> NUMBER
 134 %token <struct psi_token *> QUOTED_STRING
 135 %token <struct psi_token *> QUOTED_CHAR
 136
 137 %token <struct psi_token *> EOF 0               "end of file"
 138 %token <struct psi_token *> EOL                 "end of line"
 139 %token <struct psi_token *> EOS                 ";"
 140 %token <struct psi_token *> LPAREN              "("
 141 %token <struct psi_token *> RPAREN              ")"
 142 %token <struct psi_token *> COMMA               ","
 143 %token <struct psi_token *> COLON               ":"
 144 %token <struct psi_token *> LBRACE              "{"
 145 %token <struct psi_token *> RBRACE              "}"
 146 %token <struct psi_token *> LBRACKET    "["
 147 %token <struct psi_token *> RBRACKET    "]"
 148 %token <struct psi_token *> EQUALS              "="
 149 %token <struct psi_token *> HASH                "#"
 150 %token <struct psi_token *> PIPE                "|"
 151 %token <struct psi_token *> CARET               "^"
 152 %token <struct psi_token *> AMPERSAND   "&"
 153 %token <struct psi_token *> LSHIFT              "<<"
 154 %token <struct psi_token *> RSHIFT              ">>"
 155 %token <struct psi_token *> PLUS                "+"
 156 %token <struct psi_token *> MINUS               "-"
 157 %token <struct psi_token *> ASTERISK    "*"
 158 %token <struct psi_token *> SLASH               "/"
 159 %token <struct psi_token *> MODULO              "%"
 160 %token <struct psi_token *> LCHEVR              "<"
 161 %token <struct psi_token *> RCHEVR              ">"
 162 %token <struct psi_token *> CMP_GE              ">="
 163 %token <struct psi_token *> CMP_LE              "<="
 164 %token <struct psi_token *> OR                  "||"
 165 %token <struct psi_token *> AND                 "&&"
 166 %token <struct psi_token *> CMP_EQ              "=="
 167 %token <struct psi_token *> CMP_NE              "!="
 168 %token <struct psi_token *> TILDE               "~"
 169 %token <struct psi_token *> NOT                 "!"
 170 %token <struct psi_token *> PERIOD              "."
 171 %token <struct psi_token *> BACKSLASH   "\\"
 172 %token <struct psi_token *> ELLIPSIS    "..."
 173 %token <struct psi_token *> IIF                 "?"
 174
 175 %token <struct psi_token *> PRAGMA
 176 %token <struct psi_token *> PRAGMA_ONCE
 177 %token <struct psi_token *> LINE
 178 %token <struct psi_token *> ERROR
 179 %token <struct psi_token *> WARNING
 180 %token <struct psi_token *> IF
 181 %token <struct psi_token *> IFDEF
 182 %token <struct psi_token *> IFNDEF
 183 %token <struct psi_token *> ELSE
 184 %token <struct psi_token *> ELIF
 185 %token <struct psi_token *> ENDIF
 186 %token <struct psi_token *> DEFINE
 187 %token <struct psi_token *> DEFINED
 188 %token <struct psi_token *> UNDEF
 189 %token <struct psi_token *> IMPORT
 190 %token <struct psi_token *> INCLUDE
 191 %token <struct psi_token *> INCLUDE_NEXT
 192
 193 %token <struct psi_token *> TYPEDEF
 194 %token <struct psi_token *> STRUCT
 195 %token <struct psi_token *> UNION
 196 %token <struct psi_token *> ENUM
 197 %token <struct psi_token *> CONST
 198 %token <struct psi_token *> LIB
 199 %token <struct psi_token *> STATIC
 200 %token <struct psi_token *> CALLBACK
 201 %token <struct psi_token *> FUNCTION
 202 %token <struct psi_token *> LET
 203 %token <struct psi_token *> SET
 204 %token <struct psi_token *> TEMP
 205 %token <struct psi_token *> FREE
 206 %token <struct psi_token *> RETURN
 207 %token <struct psi_token *> PRE_ASSERT
 208 %token <struct psi_token *> POST_ASSERT
 209 %token <struct psi_token *> BOOLVAL
 210 %token <struct psi_token *> INTVAL
 211 %token <struct psi_token *> STRVAL
 212 %token <struct psi_token *> PATHVAL
 213 %token <struct psi_token *> STRLEN
 214 %token <struct psi_token *> FLOATVAL
 215 %token <struct psi_token *> ARRVAL
 216 %token <struct psi_token *> OBJVAL
 217 %token <struct psi_token *> COUNT
 218 %token <struct psi_token *> CALLOC
 219 %token <struct psi_token *> TO_BOOL
 220 %token <struct psi_token *> TO_INT
 221 %token <struct psi_token *> TO_STRING
 222 %token <struct psi_token *> TO_FLOAT
 223 %token <struct psi_token *> TO_ARRAY
 224 %token <struct psi_token *> TO_OBJECT
 225
 226 %token <struct psi_token *> COMMENT
 227 %token <struct psi_token *> WHITESPACE
 228 %token <struct psi_token *> NO_WHITESPACE
 229 %token <struct psi_token *> CPP_HEADER
 230 %token <struct psi_token *> CPP_ATTRIBUTE
 231 %token <struct psi_token *> CPP_EXTENSION
 232 %token <struct psi_token *> CPP_PASTE
 233 %token <struct psi_token *> CPP_RESTRICT
 234 %token <struct psi_token *> CPP_ASM
 235
 236 %precedence IIF COLON
 237 %precedence OR
 238 %precedence AND
 239 %precedence PIPE
 240 %precedence CARET
 241 %precedence AMPERSAND
 242 %precedence CMP_EQ CMP_NE
 243 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
 244 %precedence LSHIFT RSHIFT
 245 %precedence PLUS MINUS
 246 %precedence ASTERISK SLASH MODULO
 247 //%precedence NOT TILDE
 248 %precedence BINARY
 249 %precedence UNARY
 250
 251 %type           <struct psi_token *>                            lib optional_name enum_name struct_name union_name
 252 %destructor     {psi_token_free(&$$);}                          lib optional_name enum_name struct_name union_name
 253
 254 %type           <struct psi_token *>                            cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 255 %destructor     {}                                                                      cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 256
 257 %type           <struct psi_token *>                            name_token any_noeol_token binary_op_token unary_op_token
 258 %destructor     {}                                                                      name_token any_noeol_token binary_op_token unary_op_token
 259
 260 %type           <struct psi_token *>                            int_width int_width_types int_signed_types
 261 %destructor     {psi_token_free(&$$);}                          int_width int_width_types int_signed_types
 262
 263 %type           <struct psi_token *>                            signed_long_types signed_short_types int_signed
 264 %destructor     {}                                                                      signed_long_types signed_short_types int_signed
 265
 266 %type           <struct psi_cpp_exp *>                          cpp cpp_exp
 267 %destructor     {psi_cpp_exp_free(&$$);}                        cpp cpp_exp
 268 %type           <struct psi_cpp_macro_decl *>           cpp_macro_decl
 269 %destructor     {psi_cpp_macro_decl_free(&$$);}         cpp_macro_decl
 270 %type           <struct psi_plist *>                            cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 271 %destructor {psi_plist_free($$);}                               cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 272 %type           <struct psi_num_exp *>                          cpp_macro_exp
 273 %destructor     {psi_num_exp_free(&$$);}                        cpp_macro_exp
 274
 275 %type           <struct psi_token *>                            constant_type_token impl_def_val_token
 276 %destructor     {}                                                                      constant_type_token impl_def_val_token
 277
 278 %type           <struct psi_const *>                            constant
 279 %destructor     {psi_const_free(&$$);}                          constant
 280 %type           <struct psi_const_type *>                       constant_type
 281 %destructor     {psi_const_type_free(&$$);}                     constant_type
 282 %type           <struct psi_impl_def_val *>                     impl_def_val
 283 %destructor     {psi_impl_def_val_free(&$$);}           impl_def_val
 284
 285 %type           <struct psi_token *>                            decl_real_type decl_int_type decl_type_simple
 286 %destructor     {psi_token_free(&$$);}                          decl_real_type decl_int_type decl_type_simple
 287
 288 %type           <struct psi_token *>                            decl_stdint_type
 289 %destructor     {}                                                                      decl_stdint_type
 290
 291 %type           <struct psi_decl_type *>                        decl_type const_decl_type decl_type_complex
 292 %destructor     {psi_decl_type_free(&$$);}                      decl_type const_decl_type decl_type_complex
 293 %type           <struct psi_decl *>                                     decl_stmt decl decl_body decl_func_body decl_functor_body
 294 %destructor     {psi_decl_free(&$$);}                           decl_stmt decl decl_body decl_func_body decl_functor_body
 295 %type           <struct psi_decl_arg *>                         decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef
 296 %destructor     {psi_decl_arg_free(&$$);}                       decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef
 297 %type           <struct psi_decl_var *>                         decl_var
 298 %destructor     {psi_decl_var_free(&$$);}                       decl_var
 299 %type           <struct psi_decl_struct *>                      decl_struct
 300 %destructor     {psi_decl_struct_free(&$$);}            decl_struct
 301 %type           <struct psi_decl_union *>                       decl_union
 302 %destructor     {psi_decl_union_free(&$$);}                     decl_union
 303 %type           <struct psi_decl_enum *>                        decl_enum
 304 %destructor     {psi_decl_enum_free(&$$);}                      decl_enum
 305 %type           <struct psi_decl_enum_item *>           decl_enum_item
 306 %destructor     {psi_decl_enum_item_free(&$$);}         decl_enum_item
 307 %type           <struct psi_plist *>                            decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 308 %destructor     {psi_plist_free($$);}                           decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 309
 310 %type           <struct psi_layout>                                     align_and_size
 311 %destructor     {}                                                                      align_and_size
 312 %type           <struct psi_layout *>                           decl_layout
 313 %destructor     {psi_layout_free(&$$);}                         decl_layout
 314
 315 %type           <struct psi_impl *>                                     impl
 316 %destructor     {psi_impl_free(&$$);}                           impl
 317 %type           <struct psi_impl_func *>                        impl_func
 318 %destructor     {psi_impl_func_free(&$$);}                      impl_func
 319 %type           <struct psi_impl_arg *>                         impl_arg
 320 %destructor     {psi_impl_arg_free(&$$);}                       impl_arg
 321 %type           <struct psi_impl_type *>                        impl_type
 322 %destructor     {psi_impl_type_free(&$$);}                      impl_type
 323 %type           <struct psi_impl_var *>                         impl_var
 324 %destructor     {psi_impl_var_free(&$$);}                       impl_var
 325
 326 %type           <struct psi_let_stmt *>                         let_stmt
 327 %destructor     {psi_let_stmt_free(&$$);}                       let_stmt
 328 %type           <struct psi_let_exp *>                          let_exp let_exp_byref let_exp_assign
 329 %destructor     {psi_let_exp_free(&$$);}                        let_exp let_exp_byref let_exp_assign
 330 %type           <struct psi_let_calloc *>                       let_calloc
 331 %destructor     {psi_let_calloc_free(&$$);}                     let_calloc
 332 %type           <struct psi_let_callback *>                     let_callback
 333 %destructor     {psi_let_callback_free(&$$);}           let_callback
 334 %type           <struct psi_let_func *>                         let_func
 335 %destructor     {psi_let_func_free(&$$);}                       let_func
 336 %type           <struct psi_set_stmt *>                         set_stmt
 337 %destructor     {psi_set_stmt_free(&$$);}                       set_stmt
 338 %type           <struct psi_set_exp *>                          set_exp
 339 %destructor     {psi_set_exp_free(&$$);}                        set_exp
 340 %type           <struct psi_set_func *>                         set_func
 341 %destructor     {psi_set_func_free(&$$);}                       set_func
 342 %type           <struct psi_assert_stmt *>                      assert_stmt
 343 %destructor     {psi_assert_stmt_free(&$$);}            assert_stmt
 344 %type           <struct psi_return_stmt *>                      return_stmt
 345 %destructor     {psi_return_stmt_free(&$$);}            return_stmt
 346 %type           <struct psi_free_stmt *>                        free_stmt
 347 %destructor     {psi_free_stmt_free(&$$);}                      free_stmt
 348 %type           <struct psi_free_exp *>                         free_exp
 349 %destructor     {psi_free_exp_free(&$$);}                       free_exp
 350
 351 %type           <struct psi_token **>                           impl_stmt
 352 %destructor     {psi_impl_stmt_free(&$$);}                      impl_stmt
 353 %type           <struct psi_token *>                            impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 354 %destructor     {psi_token_free(&$$);}                          impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 355 %type           <struct psi_plist *>                            impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 356 %destructor     {psi_plist_free($$);}                           impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 357
 358 %type           <struct psi_num_exp *>                          num_exp
 359 %destructor     {psi_num_exp_free(&$$);}                        num_exp
 360 %type           <struct psi_number *>                           number
 361 %destructor     {psi_number_free(&$$);}                         number
 362
 363 %type           <size_t>                                                        indirection pointers asterisks array_size
 364 %destructor     {}                                                                      indirection pointers asterisks array_size
 365 %type           <bool>                                                          reference
 366 %destructor     {}                                                                      reference
 367
 368 %%
 369
 370 /* rules */
 371
 372
 373 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
 374 unary_op_token: TILDE | NOT | PLUS | MINUS ;
 375 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | let_func_token | set_func_token;
 376 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | INT8 | UINT8 | INT16 | UINT16 | INT32 | UINT32 | INT64 | UINT64 | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM;
 377
 378
 379 file:
 380         %empty
 381 |       blocks
 382 ;
 383 blocks:
 384         block
 385 |       blocks block
 386 ;
 387 block:
 388         EOS
 389 |       EOL
 390 |       COMMENT
 391 |       cpp {
 392         if ($cpp) {
 393                 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
 394                 psi_cpp_exp_free(&$cpp);
 395         }
 396 }
 397 |       lib {
 398         if (P->file.ln) {
 399                 P->error(PSI_DATA(P), $lib, PSI_WARNING,
 400                                 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
 401         } else {
 402                 P->file.ln = strndup($lib->text, $lib->size);
 403         }
 404 }
 405 |       constant {
 406         psi_parser_proc_add_const(P, $constant);
 407 }
 408 |       decl_stmt {
 409         psi_parser_proc_add_decl(P, $decl_stmt);
 410 }
 411 |       decl_ext_var_stmt
 412 |       decl_typedef[def] {
 413         psi_parser_proc_add_typedef(P, $def);
 414 }
 415 |       decl_struct[struct] {
 416         psi_parser_proc_add_struct(P, $struct);
 417 }
 418 |       decl_union[union] {
 419         psi_parser_proc_add_union(P, $union);
 420 }
 421 |       decl_enum[enum] {
 422         psi_parser_proc_add_enum(P, $enum);
 423 }
 424 |       impl {
 425         psi_parser_proc_add_impl(P, $impl);
 426 }
 427 ;
 428
 429 lib:
 430         LIB QUOTED_STRING EOS {
 431         $lib = $QUOTED_STRING;
 432 }
 433 ;
 434
 435 cpp:
 436         HASH EOL {
 437         $cpp = NULL;
 438 }
 439 |       HASH cpp_exp[exp] EOL {
 440         $cpp = $exp;
 441 }
 442 ;
 443
 444 cpp_exp[exp]:
 445         cpp_message_token cpp_macro_decl_tokens[tokens] {
 446         if ($tokens) {
 447                 struct psi_token *msg = NULL;
 448
 449                 if (psi_plist_get($tokens, 0, &msg)) {
 450                         size_t index = 1;
 451                         struct psi_token *next;
 452
 453                         msg = psi_token_copy(msg);
 454                         while (psi_plist_get($tokens, index++, &next)) {
 455                                 struct psi_token *old = msg;
 456                                 msg = psi_token_cat(" ", 2, msg, next);
 457                                 free(old);
 458                         }
 459                 }
 460                 psi_plist_free($tokens);
 461
 462                 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
 463         } else {
 464                 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
 465         }
 466         $exp->token = psi_token_copy($cpp_message_token);
 467 }
 468 |       cpp_include_token[INCLUDE] cpp_header_token {
 469         $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
 470         $exp->token = psi_token_copy($INCLUDE);
 471 }
 472 |       cpp_no_arg_token {
 473         $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
 474         $exp->token = psi_token_copy($cpp_no_arg_token);
 475 }
 476 |       cpp_name_arg_token cpp_special_name_token[name_token] {
 477         $name_token->type = PSI_T_NAME;
 478         $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
 479         $exp->token = psi_token_copy($cpp_name_arg_token);
 480 }
 481 |       DEFINE cpp_macro_decl {
 482         $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
 483         $exp->token = psi_token_copy($DEFINE);
 484 }
 485 |       cpp_exp_arg_token cpp_macro_exp {
 486         $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
 487         $exp->token = psi_token_copy($cpp_exp_arg_token);
 488 }
 489 |       PRAGMA_ONCE {
 490         $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
 491         $exp->token = psi_token_copy($PRAGMA_ONCE);
 492 }
 493 |       cpp_ignored_token cpp_macro_decl_tokens[tokens] {
 494         psi_plist_free($tokens);
 495         $exp = NULL;
 496 }
 497 ;
 498
 499 cpp_ignored_token:
 500         LINE
 501 |       PRAGMA
 502 ;
 503
 504 cpp_message_token:
 505         ERROR
 506 |       WARNING
 507 ;
 508
 509 cpp_include_token:
 510         IMPORT
 511 |       INCLUDE
 512 |       INCLUDE_NEXT
 513 ;
 514
 515 cpp_header_token:
 516         QUOTED_STRING
 517 |       CPP_HEADER
 518 ;
 519
 520 cpp_no_arg_token:
 521         ELSE
 522 |       ENDIF
 523 ;
 524
 525 cpp_name_arg_token:
 526         IFDEF
 527 |       IFNDEF
 528 |       UNDEF
 529 ;
 530
 531 cpp_exp_arg_token:
 532         IF
 533 |       ELIF
 534 ;
 535
 536 cpp_special_name_token:
 537         name_token
 538 |       NULL
 539 |       TRUE
 540 |       FALSE
 541 |       CPP_RESTRICT
 542 |       CPP_EXTENSION
 543 ;
 544
 545 cpp_macro_decl[macro]:
 546         name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
 547         $name_token->type = PSI_T_NAME;
 548         $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
 549         $macro->token = psi_token_copy($name_token);
 550 }
 551 |       cpp_special_name_token[name_token] cpp_macro_decl_tokens {
 552         $name_token->type = PSI_T_NAME;
 553         $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
 554         $macro->token = psi_token_copy($name_token);
 555 }
 556 ;
 557
 558 cpp_macro_sig[sig]:
 559         %empty {
 560         $sig = psi_plist_init(NULL);
 561 }
 562 |       cpp_macro_sig_args
 563 ;
 564
 565 cpp_macro_sig_args[args]:
 566         name_token {
 567         $name_token = psi_token_copy($name_token);
 568         $name_token->type = PSI_T_NAME;
 569         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
 570 }
 571 |       cpp_macro_sig_args[args_] COMMA name_token {
 572         $name_token = psi_token_copy($name_token);
 573         $name_token->type = PSI_T_NAME;
 574         $args = psi_plist_add($args_, &$name_token);
 575 }
 576 ;
 577
 578 cpp_macro_decl_tokens[tokens]:
 579         %empty {
 580         $tokens = NULL;
 581 }
 582 | cpp_macro_decl_token_list
 583 ;
 584
 585 cpp_macro_decl_token_list[tokens]:
 586         any_noeol_token[token] {
 587         $token = psi_token_copy($token);
 588         $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
 589 }
 590 |       cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
 591         $token = psi_token_copy($token);
 592         $tokens = psi_plist_add($tokens_, &$token);
 593 }
 594 ;
 595
 596 cpp_macro_exp[exp]:
 597         LPAREN cpp_macro_exp[exp_] RPAREN {
 598         $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
 599         $exp->token = psi_token_copy($LPAREN);
 600 }
 601 |       unary_op_token cpp_macro_exp[exp_] %prec UNARY {
 602         $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
 603         $exp->token = psi_token_copy($unary_op_token);
 604 }
 605 |       cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
 606         $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
 607         $exp->token = psi_token_copy($binary_op_token);
 608 }
 609 |       cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
 610         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
 611         $exp->token = psi_token_copy($IIF);
 612 }
 613
 614 |       DEFINED name_token {
 615         {
 616                 uint8_t exists;
 617
 618                 $name_token->type = PSI_T_NAME;
 619                 exists = psi_cpp_defined(P->preproc, $name_token);
 620                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 621                 $exp->token = psi_token_copy($name_token);
 622         }
 623 }
 624 |       DEFINED LPAREN name_token RPAREN {
 625         {
 626                 uint8_t exists;
 627
 628                 $name_token->type = PSI_T_NAME;
 629                 exists = psi_cpp_defined(P->preproc, $name_token);
 630                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 631                 $exp->token = psi_token_copy($name_token);
 632         }
 633 }
 634 |       NUMBER {
 635         $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
 636         $exp->token = psi_token_copy($NUMBER);
 637         $exp->data.n->token = psi_token_copy($NUMBER);
 638 }
 639 |       QUOTED_CHAR {
 640         $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
 641         $exp->token = psi_token_copy($QUOTED_CHAR);
 642         $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
 643 }
 644 |       name_token {
 645         $name_token->type = PSI_T_NAME;
 646         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
 647         $exp->token = psi_token_copy($name_token);
 648         $exp->data.n->token = psi_token_copy($name_token);
 649 }
 650 |       name_token LPAREN cpp_macro_call_args RPAREN {
 651         $name_token->type = PSI_T_NAME;
 652         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
 653                 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
 654         $exp->token = psi_token_copy($name_token);
 655 }
 656 ;
 657
 658 cpp_macro_call_args[args]:
 659         %empty {
 660         $args = NULL;
 661 }
 662 |       cpp_macro_call_arg_list
 663 ;
 664
 665 cpp_macro_call_arg_list[args]:
 666         cpp_macro_exp {
 667         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
 668                 &$cpp_macro_exp);
 669 }
 670 |       cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
 671         $args = psi_plist_add($args_, &$cpp_macro_exp);
 672 }
 673 ;
 674
 675 constant[const]:
 676         CONST constant_type NSNAME EQUALS impl_def_val EOS {
 677         $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
 678         $const->token = psi_token_copy($NSNAME);
 679 }
 680 ;
 681
 682 constant_type[type]:
 683         constant_type_token[token] {
 684         $type = psi_const_type_init($token->type, $token->text);
 685 }
 686 ;
 687
 688 constant_type_token:
 689         BOOL
 690 |       INT
 691 |       FLOAT
 692 |       STRING
 693 ;
 694
 695 impl_def_val[val]:
 696         %empty {
 697         $val = NULL;
 698 }
 699 |       num_exp[num] {
 700         if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
 701                 impl_val res = {0};
 702                 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
 703
 704                 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
 705                         $val = psi_impl_def_val_init(type, NULL);
 706                 } else {
 707                         $val = psi_impl_def_val_init(PSI_T_INT, NULL);
 708                 }
 709
 710                 switch (type) {
 711                 case PSI_T_UINT8:       $val->ival.zend.lval = res.u8;  break;
 712                 case PSI_T_UINT16:      $val->ival.zend.lval = res.u16; break;
 713                 case PSI_T_UINT32:      $val->ival.zend.lval = res.u32; break;
 714                 case PSI_T_UINT64:      $val->ival.zend.lval = res.u64; break; /* FIXME */
 715                 case PSI_T_INT8:        $val->ival.zend.lval = res.i8;  break;
 716                 case PSI_T_INT16:       $val->ival.zend.lval = res.i16; break;
 717                 case PSI_T_INT32:       $val->ival.zend.lval = res.i32; break;
 718                 case PSI_T_INT64:       $val->ival.zend.lval = res.i64; break;
 719                 case PSI_T_FLOAT:       $val->ival.dval = res.fval;             break;
 720                 case PSI_T_DOUBLE:      $val->ival.dval = res.dval;             break;
 721                 default:
 722                         assert(0);
 723
 724                 }
 725         } else {
 726                 $val = NULL;
 727         }
 728         psi_num_exp_free(&$num);
 729 }
 730 |       impl_def_val_token[token] {
 731         $val = psi_impl_def_val_init($token->type, $token->text);
 732         $val->token = psi_token_copy($token);
 733 }
 734 ;
 735
 736 impl_def_val_token:
 737         NULL
 738 |       TRUE
 739 |       FALSE
 740 |       QUOTED_STRING
 741 ;
 742
 743 decl_typedef[def]:
 744         TYPEDEF typedef[def_] EOS {
 745         $def = $def_;
 746 }
 747 |       TYPEDEF VOID name_token EOS {
 748         $def = psi_decl_arg_init(
 749                 psi_decl_type_init(PSI_T_VOID, $VOID->text),
 750                 psi_decl_var_init($name_token->text, 0, 0)
 751         );
 752         $def->token = psi_token_copy($VOID);
 753         $def->type->token = psi_token_copy($VOID);
 754         $def->var->token = psi_token_copy($name_token);
 755 }
 756 |       CPP_EXTENSION TYPEDEF typedef[def_] EOS {
 757         $def = $def_;
 758 }
 759 ;
 760
 761 typedef[def]:
 762         decl_arg
 763 |       decl_func_body[decl] {
 764         $def = psi_decl_arg_init(
 765                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
 766                 psi_decl_var_copy($decl->func->var)
 767         );
 768         $def->type->token = psi_token_copy($decl->func->token);
 769         $def->type->real.func = $decl;
 770 }
 771 |       decl_enum[enum] name_token {
 772         $name_token->type = PSI_T_NAME;
 773         $def = psi_decl_arg_init(
 774                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 775                 psi_decl_var_init($name_token->text, 0, 0)
 776         );
 777         $def->var->token = psi_token_copy($name_token);
 778         $def->type->token = psi_token_copy($enum->token);
 779         $def->type->real.enm = $enum;
 780         psi_parser_proc_add_enum(P, $enum);
 781 }
 782 |       struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
 783         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
 784         $def->type->token = $struct;
 785         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 786         $def->type->real.strct->token = psi_token_copy($struct);
 787         $def->type->real.strct->align = $as.pos;
 788         $def->type->real.strct->size = $as.len;
 789         psi_parser_proc_add_struct(P, $def->type->real.strct);
 790 }
 791 |       union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
 792         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
 793         $def->type->token = $union;
 794         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 795         $def->type->real.unn->token = psi_token_copy($union);
 796         $def->type->real.unn->align = $as.pos;
 797         $def->type->real.unn->size = $as.len;
 798         psi_parser_proc_add_union(P, $def->type->real.unn);
 799 }
 800 |       const_decl_type[type] decl_stdint_type[stdint] {
 801         $stdint->type = PSI_T_NAME;
 802         $def = psi_decl_arg_init($type, psi_decl_var_init($stdint->text, 0, 0));
 803         $def->var->token = psi_token_copy($stdint);
 804 }
 805 ;
 806
 807 const_decl_type[type]:
 808         CONST decl_type[type_] {
 809         $type = $type_;
 810 }
 811 |       decl_type
 812 ;
 813
 814 decl_type[type]:
 815         decl_type_simple[token] {
 816         $type = psi_decl_type_init($token->type, $token->text);
 817         $type->token = $token;
 818 }
 819 |       decl_type_complex
 820 ;
 821
 822 decl_type_complex[type]:
 823         STRUCT[token] name_token {
 824         $name_token->type = PSI_T_NAME;
 825         $type = psi_decl_type_init($token->type, $name_token->text);
 826         $type->token = psi_token_copy($name_token);
 827 }
 828 |       UNION[token] name_token {
 829         $name_token->type = PSI_T_NAME;
 830         $type = psi_decl_type_init($token->type, $name_token->text);
 831         $type->token = psi_token_copy($name_token);
 832 }
 833 |       ENUM[token] name_token {
 834         $name_token->type = PSI_T_NAME;
 835         $type = psi_decl_type_init($token->type, $name_token->text);
 836         $type->token = psi_token_copy($name_token);
 837 }
 838 ;
 839
 840 decl_type_simple[type]:
 841         decl_int_type
 842 |       decl_real_type
 843 |       decl_stdint_type[type_] {
 844         $type = psi_token_copy($type_);
 845 }
 846 |       NAME[type_] {
 847         $type = psi_token_copy($type_);
 848 }
 849 ;
 850
 851 decl_real_type[type]:
 852         FLOAT[type_] {
 853         $type = psi_token_copy($type_);
 854 }
 855 |       DOUBLE[type_] {
 856         $type = psi_token_copy($type_);
 857 }
 858 |       LONG DOUBLE {
 859         $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
 860 }
 861 ;
 862
 863 decl_stdint_type[type]:
 864         INT8
 865 |       UINT8
 866 |       INT16
 867 |       UINT16
 868 |       INT32
 869 |       UINT32
 870 |       INT64
 871 |       UINT64
 872 ;
 873
 874 int_signed[i]:
 875         SIGNED
 876 |       UNSIGNED
 877 ;
 878
 879 int_width[i]:
 880         SHORT {
 881         $i = psi_token_copy($SHORT);
 882 }
 883 |       LONG {
 884         $i = psi_token_copy($LONG);
 885 }
 886 |       LONG[l1] LONG[l2] {
 887         $i = psi_token_cat(" ", 2, $l1, $l2);
 888 }
 889 ;
 890
 891 decl_int_type[type]:
 892         CHAR {
 893         $type = psi_token_copy($CHAR);
 894 }
 895 |       INT {
 896         $type = psi_token_copy($INT);
 897 }
 898 |       int_signed int_signed_types {
 899         if ($2) {
 900                 $type = psi_token_cat(" ", 2, $1, $2);
 901                 free($2);
 902         } else {
 903                 $type = psi_token_copy($1);
 904         }
 905 }
 906 |       int_width int_width_types {
 907         if ($2) {
 908                 $type = psi_token_cat(" ", 2, $1, $2);
 909                 free($1);
 910                 free($2);
 911         } else {
 912                 $type = $1;
 913         }
 914 }
 915 ;
 916
 917 int_signed_types[type]:
 918         %empty {
 919         $type = NULL;
 920 }
 921 |       CHAR {
 922         $type = psi_token_copy($CHAR);
 923 }
 924 |       SHORT signed_short_types {
 925         if ($2) {
 926                 $type = psi_token_cat(" ", 2, $1, $2);
 927         } else {
 928                 $type = psi_token_copy($1);
 929         }
 930 }
 931 |       INT {
 932         $type = psi_token_copy($INT);
 933 }
 934 |       LONG signed_long_types {
 935         if ($2) {
 936                 $type = psi_token_cat(" ", 2, $1, $2);
 937         } else {
 938                 $type = psi_token_copy($1);
 939         }
 940 }
 941 ;
 942
 943 signed_short_types[type]:
 944         %empty {
 945         $type = NULL;
 946 }
 947 |       INT
 948 ;
 949 signed_long_types[type]:
 950         %empty {
 951         $type = NULL;
 952 }
 953 |       INT
 954 |       LONG
 955 ;
 956
 957 int_width_types[type]:
 958         %empty {
 959         $type = NULL;
 960 }
 961 |       INT {
 962         $type = psi_token_copy($INT);
 963 }
 964 |       int_signed int_signed_types {
 965         if ($2) {
 966                 $type = psi_token_cat(" ", 2, $1, $2);
 967                 free($2);
 968         } else {
 969                 $type = psi_token_copy($1);
 970         }
 971 }
 972 ;
 973
 974 decl_stmt:
 975         decl decl_asm EOS {
 976         $decl_stmt = $decl;
 977 }
 978 |       CPP_EXTENSION decl decl_asm EOS {
 979         $decl_stmt = $decl;
 980 }
 981 ;
 982
 983 decl_asm:
 984         %empty
 985 |       CPP_ASM LPAREN ignored_quoted_strings RPAREN
 986 ;
 987
 988 ignored_quoted_strings:
 989         QUOTED_STRING
 990 |       ignored_quoted_strings QUOTED_STRING
 991 ;
 992
 993 decl_ext_var_stmt:
 994         decl_ext_var EOS
 995 ;
 996
 997 decl_ext_var:
 998         NAME decl_arg decl_ext_var_list {
 999         psi_decl_arg_free(&$decl_arg);
1000 }
1001 ;
1002
1003 decl_ext_var_list:
1004         %empty
1005 |       COMMA decl_vars {
1006         psi_plist_free($decl_vars);
1007 }
1008 ;
1009
1010 decl_vars[vars]:
1011         decl_var[var] {
1012         $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1013 }
1014 |       decl_vars[vars_] COMMA decl_var[var] {
1015         $vars = psi_plist_add($vars_, &$var);
1016 }
1017 ;
1018
1019 decl:
1020         decl_body
1021 |       NAME[abi] decl_body {
1022         $decl = $decl_body;
1023         $decl->abi = psi_decl_abi_init($abi->text);
1024 }
1025 ;
1026
1027 decl_body:
1028         decl_func_body
1029 |       decl_functor_body
1030 ;
1031
1032 decl_func_body[decl]:
1033         decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1034         $decl = psi_decl_init($func, $args);
1035         if ($as) {
1036                 $decl->func->var->pointer_level += 1;
1037                 $decl->func->var->array_size = $as;
1038         }
1039 }
1040 |       decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1041         $decl = psi_decl_init($func, $args);
1042         $decl->varargs = 1;
1043         if ($as) {
1044                 $decl->func->var->pointer_level += 1;
1045                 $decl->func->var->array_size = $as;
1046         }
1047 }
1048 ;
1049
1050 decl_functor_body[decl]:
1051         decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1052         $decl = psi_decl_init($func, $args);
1053         if ($as) {
1054                 $decl->func->var->pointer_level += 1;
1055                 $decl->func->var->array_size = $as;
1056         }
1057 }
1058 |       decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1059         $decl = psi_decl_init($func, $args);
1060         $decl->varargs = 1;
1061         if ($as) {
1062                 $decl->func->var->pointer_level += 1;
1063                 $decl->func->var->array_size = $as;
1064         }
1065 }
1066 ;
1067
1068 decl_functor[arg]:
1069         const_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1070         (void) $unused1;
1071         $NAME->type = PSI_T_NAME;
1072         $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1073         $arg->var->token = psi_token_copy($NAME);
1074         $arg->token = psi_token_copy($NAME);
1075 }
1076 |       CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1077         (void) $unused1;
1078         $NAME->type = PSI_T_NAME;
1079         $arg = psi_decl_arg_init(
1080                 psi_decl_type_init($VOID->type, $VOID->text),
1081                 psi_decl_var_init($NAME->text, $pointers, 0)
1082         );
1083         $arg->type->token = psi_token_copy($VOID);
1084         $arg->var->token = psi_token_copy($NAME);
1085         $arg->token = psi_token_copy($NAME);
1086 }
1087 |       VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1088         (void) $unused1;
1089         $NAME->type = PSI_T_NAME;
1090         $arg = psi_decl_arg_init(
1091                 psi_decl_type_init($VOID->type, $VOID->text),
1092                 psi_decl_var_init($NAME->text, $pointers, 0)
1093         );
1094         $arg->type->token = psi_token_copy($VOID);
1095         $arg->var->token = psi_token_copy($NAME);
1096         $arg->token = psi_token_copy($NAME);
1097 }
1098 |       VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1099         (void) $unused1;
1100         $NAME->type = PSI_T_NAME;
1101         $arg = psi_decl_arg_init(
1102                 psi_decl_type_init($VOID->type, $VOID->text),
1103                 psi_decl_var_init($NAME->text, 0, 0)
1104         );
1105         $arg->type->token = psi_token_copy($VOID);
1106         $arg->var->token = psi_token_copy($NAME);
1107         $arg->token = psi_token_copy($NAME);
1108 }
1109 ;
1110
1111 decl_func[func]:
1112         decl_arg
1113 |       VOID name_token[NAME] {
1114         $func = psi_decl_arg_init(
1115                 psi_decl_type_init($VOID->type, $VOID->text),
1116                 psi_decl_var_init($NAME->text, 0, 0)
1117         );
1118         $func->type->token = psi_token_copy($VOID);
1119         $func->var->token = psi_token_copy($NAME);
1120         $func->token = psi_token_copy($NAME);
1121 }
1122 ;
1123
1124 decl_args[args]:
1125         %empty {
1126         $args = NULL;
1127 }
1128 |       VOID {
1129         $args = NULL;
1130 }
1131 |       decl_anon_arg[arg] {
1132         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1133 }
1134 |       decl_args[args_] COMMA decl_anon_arg[arg] {
1135         $args = psi_plist_add($args_, &$arg);
1136 }
1137 ;
1138
1139 decl_anon_arg[arg]:
1140 /* FIXME decl_functor_body_anon */
1141         decl_arg {
1142         $arg = $decl_arg;
1143 }
1144 |       const_decl_type[type] indirection {
1145         $arg = psi_decl_arg_init(
1146                 $type,
1147                 psi_decl_var_init(NULL, $indirection, 0)
1148         );
1149 }
1150 |       CONST VOID pointers {
1151         $arg = psi_decl_arg_init(
1152                 psi_decl_type_init($VOID->type, $VOID->text),
1153                 psi_decl_var_init(NULL, $pointers, 0)
1154         );
1155         $arg->type->token = psi_token_copy($VOID);
1156         $arg->var->token = psi_token_copy($VOID);
1157         $arg->token = psi_token_copy($VOID);
1158 }
1159 |       VOID pointers {
1160         $arg = psi_decl_arg_init(
1161                 psi_decl_type_init($VOID->type, $VOID->text),
1162                 psi_decl_var_init(NULL, $pointers, 0)
1163         );
1164         $arg->type->token = psi_token_copy($VOID);
1165         $arg->var->token = psi_token_copy($VOID);
1166         $arg->token = psi_token_copy($VOID);
1167 }
1168 ;
1169
1170 decl_arg[arg]:
1171         decl_functor_body[decl] {
1172         $arg = psi_decl_arg_init(
1173                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1174                 psi_decl_var_copy($decl->func->var)
1175         );
1176         $arg->type->token = psi_token_copy($decl->func->token);
1177         $arg->type->real.func = $decl;
1178 }
1179 |       const_decl_type[type] decl_var[var] {
1180         $arg = psi_decl_arg_init($type, $var);
1181 }
1182 |       CONST VOID pointers name_token[NAME] {
1183         $NAME->type = PSI_T_NAME;
1184         $arg = psi_decl_arg_init(
1185                 psi_decl_type_init($VOID->type, $VOID->text),
1186                 psi_decl_var_init($NAME->text, $pointers, 0)
1187         );
1188         $arg->type->token = psi_token_copy($VOID);
1189         $arg->var->token = psi_token_copy($NAME);
1190         $arg->token = psi_token_copy($NAME);
1191 }
1192 |       VOID pointers name_token[NAME] {
1193         $NAME->type = PSI_T_NAME;
1194         $arg = psi_decl_arg_init(
1195                 psi_decl_type_init($VOID->type, $VOID->text),
1196                 psi_decl_var_init($NAME->text, $pointers, 0)
1197         );
1198         $arg->type->token = psi_token_copy($VOID);
1199         $arg->var->token = psi_token_copy($NAME);
1200         $arg->token = psi_token_copy($NAME);
1201 }
1202 ;
1203
1204 decl_var[var]:
1205         pointers name_token array_size {
1206         $name_token->type = PSI_T_NAME;
1207         $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1208         $var->token = psi_token_copy($name_token);
1209 }
1210 |       name_token array_size {
1211         $name_token->type = PSI_T_NAME;
1212         $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1213         $var->token = psi_token_copy($name_token);
1214 }
1215 ;
1216
1217 decl_union[union]:
1218         UNION name_token align_and_size[as] decl_struct_args[args] {
1219         $name_token->type = PSI_T_NAME;
1220         $union = psi_decl_union_init($name_token->text, $args);
1221         $union->align = $as.pos;
1222         $union->size = $as.len;
1223         $union->token = psi_token_copy($name_token);
1224 }
1225 ;
1226
1227 decl_struct[struct]:
1228         STRUCT name_token align_and_size[as] decl_struct_args[args] {
1229         $name_token->type = PSI_T_NAME;
1230         $struct = psi_decl_struct_init($name_token->text, $args);
1231         $struct->align = $as.pos;
1232         $struct->size = $as.len;
1233         $struct->token = psi_token_copy($name_token);
1234 }
1235 ;
1236
1237 decl_struct_args[args]:
1238         EOS {
1239         $args = NULL;
1240 }
1241 |       struct_args_block
1242 ;
1243
1244 struct_args_block[args]:
1245         LBRACE struct_args RBRACE {
1246         $args = $struct_args;
1247 }
1248 ;
1249
1250 struct_args[args]:
1251         typedef[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1252         $arg->layout = $layout;
1253         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1254         if ($vars) {
1255                 size_t i = 0;
1256                 struct psi_decl_arg *arg;
1257
1258                 while (psi_plist_get($vars, i++, &arg)) {
1259                         arg->type = psi_decl_type_copy($arg->type);
1260                         $args = psi_plist_add($args, &arg);
1261                 }
1262                 free($vars);
1263         }
1264 }
1265 |       struct_args[args_] typedef[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1266         $arg->layout = $layout;
1267         $args = psi_plist_add($args_, &$arg);
1268         if ($vars) {
1269                 size_t i = 0;
1270                 struct psi_decl_arg *arg;
1271
1272                 while (psi_plist_get($vars, i++, &arg)) {
1273                         arg->type = psi_decl_type_copy($arg->type);
1274                         $args = psi_plist_add($args, &arg);
1275                 }
1276                 free($vars);
1277         }
1278 }
1279 ;
1280
1281 struct_arg_var_list[vars]:
1282         %empty {
1283         $vars = NULL;
1284 }
1285 |       COMMA decl_vars_with_layout[vars_] {
1286         $vars = $vars_;
1287 }
1288 ;
1289
1290 decl_vars_with_layout[vars]:
1291         decl_var[var] decl_layout[layout] {
1292         {
1293                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1294                 arg->layout = $layout;
1295                 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1296         }
1297 }
1298 |       decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1299         {
1300                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1301                 arg->layout = $layout;
1302                 $vars = psi_plist_add($vars_, &arg);
1303         }
1304 }
1305 ;
1306
1307 decl_enum[enum]:
1308         enum_name LBRACE decl_enum_items[list] RBRACE {
1309         $enum = psi_decl_enum_init($enum_name->text, $list);
1310         $enum->token = $enum_name;
1311 }
1312 ;
1313
1314 decl_enum_items[list]:
1315         decl_enum_item[i] {
1316         $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1317 }
1318 |       decl_enum_items[list_] COMMA decl_enum_item[i] {
1319         $list = psi_plist_add($list_, &$i);
1320 }
1321 ;
1322
1323 decl_enum_item[i]:
1324         name_token {
1325         $name_token->type = PSI_T_NAME;
1326         $i = psi_decl_enum_item_init($name_token->text, NULL);
1327         $i->token = psi_token_copy($name_token);
1328 }
1329 |       name_token EQUALS num_exp {
1330         $name_token->type = PSI_T_NAME;
1331         $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1332         $i->token = psi_token_copy($name_token);
1333 }
1334 ;
1335
1336 num_exp[exp]:
1337         number {
1338         $exp = psi_num_exp_init_num($number);
1339         $exp->token = psi_token_copy($number->token);
1340 }
1341 |       LPAREN const_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1342         $exp = psi_num_exp_init_cast($type, $exp_);
1343         $exp->token = psi_token_copy($type->token);
1344 }
1345 |       LPAREN num_exp[exp_] RPAREN {
1346         $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1347         $exp->token = psi_token_copy($LPAREN);
1348 }
1349 |       num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1350         $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1351         $exp->token = psi_token_copy($op);
1352 }
1353 |       unary_op_token[op] num_exp[exp_] %prec UNARY {
1354         $exp = psi_num_exp_init_unary($op->type, $exp_);
1355         $exp->token = psi_token_copy($op);
1356 }
1357 |       num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1358         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1359         $exp->token = psi_token_copy($IIF);
1360 }
1361 ;
1362
1363 number[num]:
1364         NUMBER[token] {
1365         $num = psi_number_init($token->type, $token->text, $token->flags);
1366         $num->token = psi_token_copy($token);
1367 }
1368 |       NSNAME[token] {
1369         $num = psi_number_init($token->type, $token->text, 0);
1370         $num->token = psi_token_copy($token);
1371 }
1372 |       QUOTED_CHAR[token] {
1373         $num = psi_number_init($token->type, $token->text, 0);
1374         $num->token = psi_token_copy($token);
1375 }
1376 |       decl_var {
1377         $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1378         $num->token = psi_token_copy($decl_var->token);
1379 }
1380 ;
1381
1382 enum_name[name]:
1383         ENUM optional_name[name_] {
1384         if ($name_) {
1385                 $name = psi_token_copy($name_);
1386         } else {
1387                 char digest[17];
1388
1389                 psi_token_hash($ENUM, digest);
1390                 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1391         }
1392 }
1393 ;
1394
1395 union_name[name]:
1396         UNION optional_name[name_] {
1397         if ($name_) {
1398                 $name = psi_token_copy($name_);
1399         } else {
1400                 char digest[17];
1401
1402                 psi_token_hash($UNION, digest);
1403                 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1404         }
1405 }
1406 ;
1407
1408 struct_name[name]:
1409         STRUCT optional_name[name_] {
1410         if ($name_) {
1411                 $name = psi_token_copy($name_);
1412         } else {
1413                 char digest[17];
1414
1415                 psi_token_hash($STRUCT, digest);
1416                 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1417         }
1418 }
1419 ;
1420
1421 optional_name[name]:
1422         %empty {
1423         $name = NULL;
1424 }
1425 |       name_token {
1426         $name = $name_token;
1427         $name->type = PSI_T_NAME;
1428 }
1429 ;
1430
1431 decl_layout[l]:
1432         %empty {
1433         $l = NULL;
1434 }
1435 |       COLON NUMBER[width] {
1436         $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1437 }
1438 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1439         $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1440 }
1441 |       COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1442         $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1443 }
1444 ;
1445
1446 align_and_size[as]:
1447         %empty {
1448         $as.pos = 0;
1449         $as.len = 0;
1450 }
1451 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1452         $as.pos = atol($align->text);
1453         $as.len = atol($size->text);
1454 }
1455 ;
1456
1457 array_size[as]:
1458         %empty {
1459         $as = 0;
1460 }
1461 |       LBRACKET NUMBER RBRACKET {
1462         $as = atol($NUMBER->text);
1463 }
1464 ;
1465
1466 indirection[i]:
1467         %empty {
1468         $i = 0;
1469 }
1470 |       pointers[p] %prec UNARY {
1471         $i = $p;
1472 }
1473 ;
1474
1475 pointers[p]:
1476         asterisks
1477 |       asterisks[a] CPP_RESTRICT {
1478         $p = $a;
1479 }
1480 ;
1481
1482 asterisks[a]:
1483         ASTERISK {
1484         $a = 1;
1485 }
1486 |       asterisks[a_] ASTERISK {
1487         $a = $a_ + 1;
1488 }
1489 ;
1490
1491 /*
1492  *
1493  * impl
1494  *
1495  */
1496
1497 impl:
1498         impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1499         $impl = psi_impl_init($func, $stmts);
1500 }
1501 |       STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1502         $impl = psi_impl_init($func, $stmts);
1503         $func->static_memory = 1;
1504 }
1505 ;
1506
1507 impl_func[func]:
1508         FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1509         $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1510         $func->token = psi_token_copy($NSNAME);
1511         $func->return_reference = $r;
1512 }
1513 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1514         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1515         $func->token = psi_token_copy($NSNAME);
1516         $func->return_reference = $r;
1517 }
1518 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1519         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1520         $func->token = psi_token_copy($NSNAME);
1521         $func->return_reference = $r;
1522         $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1523         $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1524 }
1525 ;
1526
1527 impl_args[args]:
1528         impl_arg[arg] {
1529         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1530 }
1531 |       impl_args[args_] COMMA impl_arg[arg] {
1532         $args = psi_plist_add($args_, &$arg);
1533 }
1534 ;
1535
1536 impl_arg[arg]:
1537         impl_type[type] impl_var[var] {
1538         $arg = psi_impl_arg_init($type, $var, NULL);
1539 }
1540 |       impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1541         $arg = psi_impl_arg_init($type, $var, $val);
1542 }
1543 ;
1544
1545 impl_var[var]:
1546         reference DOLLAR_NAME {
1547         $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1548         $var->token = psi_token_copy($DOLLAR_NAME);
1549 }
1550 ;
1551
1552 impl_type[type]:
1553         impl_type_token[token] {
1554         $type = psi_impl_type_init($token->type, $token->text);
1555         $type->token = psi_token_copy($token);
1556 }
1557 ;
1558
1559 impl_type_token:
1560         VOID
1561 |       MIXED
1562 |       BOOL
1563 |       INT
1564 |       FLOAT
1565 |       STRING
1566 |       ARRAY
1567 |       OBJECT
1568 |       CALLABLE
1569 ;
1570
1571 impl_stmts[stmts]:
1572         impl_stmt[stmt] {
1573         $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1574 }
1575 |       impl_stmts[stmts_] impl_stmt[stmt] {
1576         $stmts = psi_plist_add($stmts_, &$stmt);
1577 }
1578 ;
1579
1580 impl_stmt[stmt]:
1581         return_stmt[s] {
1582         $stmt = (struct psi_token **) $s;
1583 }
1584 |       let_stmt[s] {
1585         $stmt = (struct psi_token **) $s;
1586 }
1587 |       set_stmt[s] {
1588         $stmt = (struct psi_token **) $s;
1589 }
1590 |       assert_stmt[s] {
1591         $stmt = (struct psi_token **) $s;
1592 }
1593 |       free_stmt[s] {
1594         $stmt = (struct psi_token **) $s;
1595 }
1596 ;
1597
1598 let_stmt[let]:
1599         LET let_exp_assign[exp] EOS {
1600         $let = psi_let_stmt_init($exp);
1601         $let->token = psi_token_copy($LET);
1602 }
1603 |       TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1604         $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1605         $let->token = psi_token_copy($TEMP);
1606         $let->exp->is_reference = $reference;
1607 }
1608 ;
1609
1610 let_exp[exp]:
1611         let_exp_assign
1612 |       byref let_exp_byref[exp_] {
1613         $exp = $exp_;
1614         $exp->is_reference = true;
1615 }
1616 |       let_exp_byref[exp_] {
1617         $exp = $exp_;
1618         $exp->is_reference = false;
1619 }
1620 ;
1621
1622 let_exp_byref[exp]:
1623         NULL {
1624         $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1625 }
1626 |       let_calloc[calloc] {
1627         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1628 }
1629 |       STATIC let_calloc[calloc] {
1630         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1631         $calloc->static_memory = 1;
1632 }
1633 |       let_callback[callback] {
1634         $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1635 }
1636 |       let_func[func] {
1637         $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1638 }
1639 |       num_exp[num] {
1640         $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1641 }
1642 ;
1643
1644 let_exp_assign[exp]:
1645         decl_var[var] EQUALS let_exp_byref[exp_] {
1646         $exp = $exp_;
1647         $exp->var = $var;
1648 }
1649 |       decl_var[var] EQUALS byref let_exp_byref[exp_] {
1650         $exp = $exp_;
1651         $exp->is_reference = 1;
1652         $exp->var = $var;
1653 }
1654 ;
1655
1656 let_calloc[calloc]:
1657         CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1658         $calloc = psi_let_calloc_init($nmemb, $size);
1659         $calloc->token = psi_token_copy($CALLOC);
1660 }
1661 ;
1662
1663 let_callback[callback]:
1664         CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1665         $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args);
1666         $callback->func->token = psi_token_copy($func);
1667         $callback->token = psi_token_copy($CALLBACK);
1668 }
1669 ;
1670
1671 let_func[func]:
1672         let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1673         $func = psi_let_func_init($token->type, $token->text, $var);
1674         $func->token = psi_token_copy($token);
1675         $func->inner = $exps;
1676 }
1677 ;
1678
1679 let_func_token:
1680         ZVAL
1681 |       OBJVAL
1682 |       ARRVAL
1683 |       PATHVAL
1684 |       STRLEN
1685 |       STRVAL
1686 |       FLOATVAL
1687 |       INTVAL
1688 |       BOOLVAL
1689 |       COUNT
1690 ;
1691
1692 let_func_exps[exps]:
1693         %empty {
1694         $exps = NULL;
1695 }
1696 |       COMMA let_exps[exps_] {
1697         $exps = $exps_;
1698 }
1699 ;
1700
1701 let_exps[exps]:
1702         let_exp[exp] {
1703         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1704 }
1705 |       let_exps[exps_] COMMA let_exp[exp] {
1706         $exps = psi_plist_add($exps_, &$exp);
1707 }
1708 ;
1709
1710 callback_rval[rval]:
1711         VOID
1712 |       let_func_token
1713 ;
1714
1715 callback_arg_list[list]:
1716         %empty {
1717         $list = NULL;
1718 }
1719 |       callback_args[args] {
1720         $list = $args;
1721 }
1722 ;
1723
1724 callback_args[args]:
1725         set_exp[exp] {
1726         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1727 }
1728 |       callback_args[args_] COMMA set_exp[exp] {
1729         $args = psi_plist_add($args_, &$exp);
1730 }
1731 ;
1732
1733 return_stmt[return]:
1734         RETURN set_func[func] EOS {
1735         $return = psi_return_stmt_init(psi_set_exp_init(PSI_SET_FUNC, $func));
1736         $return->token = psi_token_copy($RETURN);
1737 }
1738 ;
1739
1740 set_stmt[set]:
1741         SET set_exp[exp] EOS {
1742         $set = psi_set_stmt_init($exp);
1743         $set->token = psi_token_copy($SET);
1744 }
1745 ;
1746
1747 set_exp[exp]:
1748         set_func[func] {
1749         $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1750 }
1751 |       num_exp[num] {
1752         $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1753 }
1754 |       impl_var[var] EQUALS set_exp[exp_] {
1755         $exp = $exp_;
1756         $exp->var = $var;
1757 }
1758 ;
1759
1760 set_func[func]:
1761         set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1762         $func = psi_set_func_init($token->type, $token->text, $var);
1763         $func->token = psi_token_copy($token);
1764         $func->inner = $exps;
1765 }
1766 |       set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
1767         $func = psi_set_func_init($token->type, $token->text, $var);
1768         $func->token = psi_token_copy($token);
1769         $func->recursive = 1;
1770 }
1771 ;
1772
1773 set_func_token:
1774         TO_OBJECT
1775 |       TO_ARRAY
1776 |       TO_STRING
1777 |       TO_INT
1778 |       TO_FLOAT
1779 |       TO_BOOL
1780 |       ZVAL
1781 |       VOID
1782 ;
1783
1784 set_func_exps[exps]:
1785         %empty {
1786         $exps = NULL;
1787 }
1788 |       COMMA set_exps[exps_] {
1789         $exps = $exps_;
1790 }
1791 ;
1792
1793 set_exps[exps]:
1794         set_exp[exp] {
1795         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1796 }
1797 |       set_exps[exps_] COMMA set_exp[exp] {
1798         $exps = psi_plist_add($exps_, &$exp);
1799 }
1800 ;
1801
1802 assert_stmt[assert]:
1803         assert_stmt_token[token] num_exp[exp] EOS {
1804         $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
1805         $assert->token = psi_token_copy($token);
1806 }
1807 ;
1808
1809 assert_stmt_token:
1810         PRE_ASSERT
1811 |       POST_ASSERT
1812 ;
1813
1814 free_stmt[free]:
1815         FREE free_exps[exps] EOS {
1816         $free = psi_free_stmt_init($exps);
1817         $free->token = psi_token_copy($FREE);
1818 }
1819 ;
1820
1821 free_exps[exps]:
1822         free_exp[exp] {
1823         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
1824 }
1825 |       free_exps[exps_] COMMA free_exp[exp] {
1826         $exps = psi_plist_add($exps_, &$exp);
1827 }
1828 ;
1829
1830 free_exp[exp]:
1831         name_token[NAME] LPAREN decl_vars[vars] RPAREN {
1832         $NAME->type = PSI_T_NAME;
1833         $exp = psi_free_exp_init($NAME->text, $vars);
1834         $exp->token = psi_token_copy($NAME);
1835 }
1836 ;
1837
1838 reference:
1839         %empty {
1840         $reference = false;
1841 }
1842 |       byref {
1843         $reference = true;
1844 }
1845 ;
1846
1847 byref:
1848         AMPERSAND %prec UNARY
1849 ;
1850
1851 %%
1852
1853 /* epilogue */
1854
1855 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
1856 {
1857         struct psi_token *token;
1858
1859         if (psi_plist_get(tokens, (*index)++, &token)) {
1860                 if (P->flags & PSI_DEBUG) {
1861                         psi_token_dump(2, token);
1862                 }
1863
1864                 *((struct psi_token **)lvalp) = token;
1865                 return token->type;
1866         } else {
1867                 (*index)--;
1868                 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
1869         }
1870
1871         return PSI_T_EOF;
1872 }
1873
1874 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
1875 {
1876         struct psi_token *T = NULL;
1877         size_t last;
1878
1879         if (*index == 0) {
1880                 last = 0;
1881         } else {
1882                 last = --(*index);
1883         }
1884
1885         psi_plist_get(tokens, last, &T);
1886         if (T) {
1887                 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
1888         } else {
1889                 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
1890         }
1891         P->errors++;
1892 }
1893