git.m6w6.name Git - m6w6/ext-psi/blob - src/parser_proc_grammar.y

   1 %code top {
   2 #include "php_psi_stdinc.h"
   3 }
   4
   5 %code {
   6 #include <assert.h>
   7 #include <stdarg.h>
   8
   9 #include "plist.h"
  10 #include "parser.h"
  11
  12 #define YYDEBUG 1
  13 #define PSI_PARSER_PROC_DEBUG 1
  14
  15 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
  16 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
  17
  18 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
  19 {
  20         assert(strct);
  21         if (!P->structs) {
  22                 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
  23         }
  24         P->structs = psi_plist_add(P->structs, &strct);
  25 }
  26 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
  27 {
  28         assert(u);
  29         if (!P->unions) {
  30                 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
  31         }
  32         P->unions = psi_plist_add(P->unions, &u);
  33 }
  34 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
  35 {
  36         assert(e);
  37         if (!P->enums) {
  38                 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
  39         }
  40         P->enums = psi_plist_add(P->enums, &e);
  41 }
  42 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
  43 {
  44         assert(def);
  45         if (!P->types) {
  46                 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
  47         }
  48         P->types = psi_plist_add(P->types, &def);
  49 }
  50 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
  51         assert(cnst);
  52         if (!P->consts) {
  53                 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
  54         }
  55         P->consts = psi_plist_add(P->consts, &cnst);
  56
  57 }
  58 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
  59         assert(decl);
  60
  61         if (psi_decl_is_blacklisted(decl->func->var->name)) {
  62                 psi_decl_free(&decl);
  63                 return;
  64         }
  65
  66         if (!P->decls) {
  67                 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
  68         }
  69         P->decls = psi_plist_add(P->decls, &decl);
  70 }
  71 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
  72         assert(impl);
  73         if (!P->impls) {
  74                 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
  75         }
  76         P->impls = psi_plist_add(P->impls, &impl);
  77 }
  78
  79 /* end code */
  80 }
  81
  82 %code requires {
  83 #include "plist.h"
  84 #include "types/layout.h"
  85
  86 struct psi_parser;
  87
  88 }
  89
  90 %require "3.0"
  91 %language "c"
  92 %name-prefix "psi_parser_proc_"
  93 %token-table
  94 %verbose
  95 %glr-parser
  96
  97 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
  98
  99 %define api.pure true
 100 %define api.token.prefix {PSI_T_}
 101 %define api.value.type union
 102
 103 %define parse.error verbose
 104 %define parse.trace true
 105
 106 %initial-action {
 107 }
 108
 109 %start file
 110
 111 %token <struct psi_token *> BOOL
 112 %token <struct psi_token *> CHAR
 113 %token <struct psi_token *> SHORT
 114 %token <struct psi_token *> INT
 115 %token <struct psi_token *> SIGNED
 116 %token <struct psi_token *> UNSIGNED
 117 %token <struct psi_token *> LONG
 118 %token <struct psi_token *> FLOAT
 119 %token <struct psi_token *> DOUBLE
 120 %token <struct psi_token *> STRING
 121 %token <struct psi_token *> MIXED
 122 %token <struct psi_token *> ARRAY
 123 %token <struct psi_token *> OBJECT
 124 %token <struct psi_token *> CALLABLE
 125 %token <struct psi_token *> VOID
 126 %token <struct psi_token *> ZVAL
 127 %token <struct psi_token *> NULL
 128 %token <struct psi_token *> TRUE
 129 %token <struct psi_token *> FALSE
 130 %token <struct psi_token *> NAME
 131 %token <struct psi_token *> NSNAME
 132 %token <struct psi_token *> DOLLAR_NAME
 133 %token <struct psi_token *> NUMBER
 134 %token <struct psi_token *> QUOTED_STRING
 135 %token <struct psi_token *> QUOTED_CHAR
 136 %token <struct psi_token *> SIZEOF
 137 %token <struct psi_token *> VOLATILE
 138
 139 %token <struct psi_token *> EOF 0               "end of file"
 140 %token <struct psi_token *> EOL                 "end of line"
 141 %token <struct psi_token *> EOS                 ";"
 142 %token <struct psi_token *> LPAREN              "("
 143 %token <struct psi_token *> RPAREN              ")"
 144 %token <struct psi_token *> COMMA               ","
 145 %token <struct psi_token *> COLON               ":"
 146 %token <struct psi_token *> LBRACE              "{"
 147 %token <struct psi_token *> RBRACE              "}"
 148 %token <struct psi_token *> LBRACKET    "["
 149 %token <struct psi_token *> RBRACKET    "]"
 150 %token <struct psi_token *> EQUALS              "="
 151 %token <struct psi_token *> HASH                "#"
 152 %token <struct psi_token *> PIPE                "|"
 153 %token <struct psi_token *> CARET               "^"
 154 %token <struct psi_token *> AMPERSAND   "&"
 155 %token <struct psi_token *> LSHIFT              "<<"
 156 %token <struct psi_token *> RSHIFT              ">>"
 157 %token <struct psi_token *> PLUS                "+"
 158 %token <struct psi_token *> MINUS               "-"
 159 %token <struct psi_token *> ASTERISK    "*"
 160 %token <struct psi_token *> SLASH               "/"
 161 %token <struct psi_token *> MODULO              "%"
 162 %token <struct psi_token *> LCHEVR              "<"
 163 %token <struct psi_token *> RCHEVR              ">"
 164 %token <struct psi_token *> CMP_GE              ">="
 165 %token <struct psi_token *> CMP_LE              "<="
 166 %token <struct psi_token *> OR                  "||"
 167 %token <struct psi_token *> AND                 "&&"
 168 %token <struct psi_token *> CMP_EQ              "=="
 169 %token <struct psi_token *> CMP_NE              "!="
 170 %token <struct psi_token *> TILDE               "~"
 171 %token <struct psi_token *> NOT                 "!"
 172 %token <struct psi_token *> PERIOD              "."
 173 %token <struct psi_token *> BACKSLASH   "\\"
 174 %token <struct psi_token *> ELLIPSIS    "..."
 175 %token <struct psi_token *> IIF                 "?"
 176
 177 %token <struct psi_token *> PRAGMA
 178 %token <struct psi_token *> PRAGMA_ONCE
 179 %token <struct psi_token *> LINE
 180 %token <struct psi_token *> ERROR
 181 %token <struct psi_token *> WARNING
 182 %token <struct psi_token *> IF
 183 %token <struct psi_token *> IFDEF
 184 %token <struct psi_token *> IFNDEF
 185 %token <struct psi_token *> ELSE
 186 %token <struct psi_token *> ELIF
 187 %token <struct psi_token *> ENDIF
 188 %token <struct psi_token *> DEFINE
 189 %token <struct psi_token *> DEFINED
 190 %token <struct psi_token *> UNDEF
 191 %token <struct psi_token *> IMPORT
 192 %token <struct psi_token *> INCLUDE
 193 %token <struct psi_token *> INCLUDE_NEXT
 194
 195 %token <struct psi_token *> TYPEDEF
 196 %token <struct psi_token *> STRUCT
 197 %token <struct psi_token *> UNION
 198 %token <struct psi_token *> ENUM
 199 %token <struct psi_token *> CONST
 200 %token <struct psi_token *> LIB
 201 %token <struct psi_token *> STATIC
 202 %token <struct psi_token *> CALLBACK
 203 %token <struct psi_token *> FUNCTION
 204 %token <struct psi_token *> LET
 205 %token <struct psi_token *> SET
 206 %token <struct psi_token *> TEMP
 207 %token <struct psi_token *> FREE
 208 %token <struct psi_token *> RETURN
 209 %token <struct psi_token *> AS
 210 %token <struct psi_token *> PRE_ASSERT
 211 %token <struct psi_token *> POST_ASSERT
 212 %token <struct psi_token *> BOOLVAL
 213 %token <struct psi_token *> INTVAL
 214 %token <struct psi_token *> STRVAL
 215 %token <struct psi_token *> PATHVAL
 216 %token <struct psi_token *> STRLEN
 217 %token <struct psi_token *> FLOATVAL
 218 %token <struct psi_token *> ARRVAL
 219 %token <struct psi_token *> OBJVAL
 220 %token <struct psi_token *> COUNT
 221 %token <struct psi_token *> CALLOC
 222 %token <struct psi_token *> TO_BOOL
 223 %token <struct psi_token *> TO_INT
 224 %token <struct psi_token *> TO_STRING
 225 %token <struct psi_token *> TO_FLOAT
 226 %token <struct psi_token *> TO_ARRAY
 227 %token <struct psi_token *> TO_OBJECT
 228
 229 %token <struct psi_token *> COMMENT
 230 %token <struct psi_token *> WHITESPACE
 231 %token <struct psi_token *> NO_WHITESPACE
 232 %token <struct psi_token *> CPP_HEADER
 233 %token <struct psi_token *> CPP_ATTRIBUTE
 234 %token <struct psi_token *> CPP_EXTENSION
 235 %token <struct psi_token *> CPP_PASTE
 236 %token <struct psi_token *> CPP_INLINE
 237 %token <struct psi_token *> CPP_RESTRICT
 238 %token <struct psi_token *> CPP_ASM
 239
 240 %precedence IIF COLON
 241 %precedence OR
 242 %precedence AND
 243 %precedence PIPE
 244 %precedence CARET
 245 %precedence AMPERSAND
 246 %precedence CMP_EQ CMP_NE
 247 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
 248 %precedence LSHIFT RSHIFT
 249 %precedence PLUS MINUS
 250 %precedence ASTERISK SLASH MODULO
 251 //%precedence NOT TILDE
 252 %precedence BINARY
 253 %precedence UNARY
 254
 255 %type           <struct psi_token *>                            lib optional_name enum_name struct_name union_name
 256 %destructor     {psi_token_free(&$$);}                          lib optional_name enum_name struct_name union_name
 257
 258 %type           <struct psi_token *>                            cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 259 %destructor     {}                                                                      cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 260
 261 %type           <struct psi_token *>                            name_token any_noeol_token binary_op_token unary_op_token
 262 %destructor     {}                                                                      name_token any_noeol_token binary_op_token unary_op_token
 263
 264 %type           <struct psi_token *>                            int_width int_width_types int_signed_types
 265 %destructor     {psi_token_free(&$$);}                          int_width int_width_types int_signed_types
 266
 267 %type           <struct psi_token *>                            signed_long_types signed_short_types int_signed
 268 %destructor     {}                                                                      signed_long_types signed_short_types int_signed
 269
 270 %type           <struct psi_cpp_exp *>                          cpp cpp_exp
 271 %destructor     {psi_cpp_exp_free(&$$);}                        cpp cpp_exp
 272 %type           <struct psi_cpp_macro_decl *>           cpp_macro_decl
 273 %destructor     {psi_cpp_macro_decl_free(&$$);}         cpp_macro_decl
 274 %type           <struct psi_plist *>                            cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 275 %destructor {psi_plist_free($$);}                               cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 276 %type           <struct psi_num_exp *>                          cpp_macro_exp
 277 %destructor     {psi_num_exp_free(&$$);}                        cpp_macro_exp
 278
 279 %type           <struct psi_token *>                            constant_type_token impl_def_val_token
 280 %destructor     {}                                                                      constant_type_token impl_def_val_token
 281
 282 %type           <struct psi_const *>                            constant
 283 %destructor     {psi_const_free(&$$);}                          constant
 284 %type           <struct psi_const_type *>                       constant_type
 285 %destructor     {psi_const_type_free(&$$);}                     constant_type
 286 %type           <struct psi_impl_def_val *>                     impl_def_val
 287 %destructor     {psi_impl_def_val_free(&$$);}           impl_def_val
 288
 289 %type           <struct psi_token *>                            decl_real_type decl_int_type decl_type_simple
 290 %destructor     {psi_token_free(&$$);}                          decl_real_type decl_int_type decl_type_simple
 291
 292 %type           <struct psi_decl_type *>                        decl_type qualified_decl_type decl_type_complex
 293 %destructor     {psi_decl_type_free(&$$);}                      decl_type qualified_decl_type decl_type_complex
 294 %type           <struct psi_decl *>                                     decl_stmt decl decl_body decl_func_body decl_functor_body
 295 %destructor     {psi_decl_free(&$$);}                           decl_stmt decl decl_body decl_func_body decl_functor_body
 296 %type           <struct psi_decl_arg *>                         decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
 297 %destructor     {psi_decl_arg_free(&$$);}                       decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
 298 %type           <struct psi_decl_var *>                         decl_var
 299 %destructor     {psi_decl_var_free(&$$);}                       decl_var
 300 %type           <struct psi_decl_struct *>                      decl_struct
 301 %destructor     {psi_decl_struct_free(&$$);}            decl_struct
 302 %type           <struct psi_decl_union *>                       decl_union
 303 %destructor     {psi_decl_union_free(&$$);}                     decl_union
 304 %type           <struct psi_decl_enum *>                        decl_enum
 305 %destructor     {psi_decl_enum_free(&$$);}                      decl_enum
 306 %type           <struct psi_decl_enum_item *>           decl_enum_item
 307 %destructor     {psi_decl_enum_item_free(&$$);}         decl_enum_item
 308 %type           <struct psi_plist *>                            decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars
 309 %destructor     {psi_plist_free($$);}                           decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars
 310
 311 %type           <struct psi_layout>                                     align_and_size
 312 %destructor     {}                                                                      align_and_size
 313 %type           <struct psi_layout *>                           decl_layout
 314 %destructor     {psi_layout_free(&$$);}                         decl_layout
 315
 316 %type           <struct psi_number *>                           sizeof sizeof_body sizeof_body_notypes
 317 %destructor     {psi_number_free(&$$);}                         sizeof sizeof_body sizeof_body_notypes
 318
 319 %type           <struct psi_impl *>                                     impl
 320 %destructor     {psi_impl_free(&$$);}                           impl
 321 %type           <struct psi_impl_func *>                        impl_func
 322 %destructor     {psi_impl_func_free(&$$);}                      impl_func
 323 %type           <struct psi_impl_arg *>                         impl_arg
 324 %destructor     {psi_impl_arg_free(&$$);}                       impl_arg
 325 %type           <struct psi_impl_type *>                        impl_type
 326 %destructor     {psi_impl_type_free(&$$);}                      impl_type
 327 %type           <struct psi_impl_var *>                         impl_var
 328 %destructor     {psi_impl_var_free(&$$);}                       impl_var
 329
 330 %type           <struct psi_let_stmt *>                         let_stmt
 331 %destructor     {psi_let_stmt_free(&$$);}                       let_stmt
 332 %type           <struct psi_let_exp *>                          let_exp let_exp_byref let_exp_assign
 333 %destructor     {psi_let_exp_free(&$$);}                        let_exp let_exp_byref let_exp_assign
 334 %type           <struct psi_let_calloc *>                       let_calloc
 335 %destructor     {psi_let_calloc_free(&$$);}                     let_calloc
 336 %type           <struct psi_let_callback *>                     let_callback
 337 %destructor     {psi_let_callback_free(&$$);}           let_callback
 338 %type           <struct psi_let_func *>                         let_func
 339 %destructor     {psi_let_func_free(&$$);}                       let_func
 340 %type           <struct psi_set_stmt *>                         set_stmt
 341 %destructor     {psi_set_stmt_free(&$$);}                       set_stmt
 342 %type           <struct psi_set_exp *>                          set_exp
 343 %destructor     {psi_set_exp_free(&$$);}                        set_exp
 344 %type           <struct psi_set_func *>                         set_func
 345 %destructor     {psi_set_func_free(&$$);}                       set_func
 346 %type           <struct psi_assert_stmt *>                      assert_stmt
 347 %destructor     {psi_assert_stmt_free(&$$);}            assert_stmt
 348 %type           <struct psi_return_stmt *>                      return_stmt
 349 %destructor     {psi_return_stmt_free(&$$);}            return_stmt
 350 %type           <struct psi_return_exp *>                       return_exp
 351 %destructor     {psi_return_exp_free(&$$);}                     return_exp
 352 %type           <struct psi_free_stmt *>                        free_stmt
 353 %destructor     {psi_free_stmt_free(&$$);}                      free_stmt
 354 %type           <struct psi_free_exp *>                         free_exp
 355 %destructor     {psi_free_exp_free(&$$);}                       free_exp
 356
 357 %type           <struct psi_token **>                           impl_stmt
 358 %destructor     {psi_impl_stmt_free(&$$);}                      impl_stmt
 359 %type           <struct psi_token *>                            impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 360 %destructor     {psi_token_free(&$$);}                          impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 361 %type           <struct psi_plist *>                            impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 362 %destructor     {psi_plist_free($$);}                           impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 363
 364 %type           <struct psi_num_exp *>                          num_exp
 365 %destructor     {psi_num_exp_free(&$$);}                        num_exp
 366 %type           <struct psi_number *>                           number
 367 %destructor     {psi_number_free(&$$);}                         number
 368
 369 %type           <size_t>                                                        indirection pointers asterisks array_size
 370 %destructor     {}                                                                      indirection pointers asterisks array_size
 371 %type           <bool>                                                          reference
 372 %destructor     {}                                                                      reference
 373
 374 %%
 375
 376 /* rules */
 377
 378
 379 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
 380 unary_op_token: TILDE | NOT | PLUS | MINUS ;
 381 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | AS | let_func_token | set_func_token;
 382 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
 383 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
 384
 385
 386 file:
 387         %empty
 388 |       blocks
 389 ;
 390 blocks:
 391         block
 392 |       blocks block
 393 ;
 394 block:
 395         EOS
 396 |       EOL
 397 |       COMMENT
 398 |       cpp {
 399         if ($cpp) {
 400                 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
 401                 psi_cpp_exp_free(&$cpp);
 402         }
 403 }
 404 |       lib {
 405         if (P->file.ln) {
 406                 P->error(PSI_DATA(P), $lib, PSI_WARNING,
 407                                 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
 408         } else {
 409                 P->file.ln = strndup($lib->text, $lib->size);
 410         }
 411 }
 412 |       constant {
 413         psi_parser_proc_add_const(P, $constant);
 414 }
 415 |       decl_stmt {
 416         psi_parser_proc_add_decl(P, $decl_stmt);
 417 }
 418 |       ignored_decl
 419 |       decl_ext_var_stmt
 420 |       decl_typedef[def] {
 421         psi_parser_proc_add_typedef(P, $def);
 422 }
 423 |       decl_struct[struct] {
 424         psi_parser_proc_add_struct(P, $struct);
 425 }
 426 |       decl_union[union] {
 427         psi_parser_proc_add_union(P, $union);
 428 }
 429 |       decl_enum[enum] {
 430         psi_parser_proc_add_enum(P, $enum);
 431 }
 432 |       impl {
 433         psi_parser_proc_add_impl(P, $impl);
 434 }
 435 ;
 436
 437 lib:
 438         LIB QUOTED_STRING EOS {
 439         $lib = $QUOTED_STRING;
 440 }
 441 ;
 442
 443 cpp:
 444         HASH EOL {
 445         $cpp = NULL;
 446 }
 447 |       HASH cpp_exp[exp] EOL {
 448         $cpp = $exp;
 449 }
 450 ;
 451
 452 cpp_exp[exp]:
 453         cpp_message_token cpp_macro_decl_tokens[tokens] {
 454         if ($tokens) {
 455                 struct psi_token *msg = NULL;
 456
 457                 if (psi_plist_get($tokens, 0, &msg)) {
 458                         size_t index = 1;
 459                         struct psi_token *next;
 460
 461                         msg = psi_token_copy(msg);
 462                         while (psi_plist_get($tokens, index++, &next)) {
 463                                 struct psi_token *old = msg;
 464                                 msg = psi_token_cat(" ", 2, msg, next);
 465                                 free(old);
 466                         }
 467                 }
 468                 psi_plist_free($tokens);
 469
 470                 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
 471         } else {
 472                 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
 473         }
 474         $exp->token = psi_token_copy($cpp_message_token);
 475 }
 476 |       cpp_include_token[INCLUDE] cpp_header_token {
 477         $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
 478         $exp->token = psi_token_copy($INCLUDE);
 479 }
 480 |       cpp_no_arg_token {
 481         $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
 482         $exp->token = psi_token_copy($cpp_no_arg_token);
 483 }
 484 |       cpp_name_arg_token cpp_special_name_token[name_token] {
 485         $name_token->type = PSI_T_NAME;
 486         $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
 487         $exp->token = psi_token_copy($cpp_name_arg_token);
 488 }
 489 |       DEFINE cpp_macro_decl {
 490         $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
 491         $exp->token = psi_token_copy($DEFINE);
 492 }
 493 |       cpp_exp_arg_token cpp_macro_exp {
 494         $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
 495         $exp->token = psi_token_copy($cpp_exp_arg_token);
 496 }
 497 |       PRAGMA_ONCE {
 498         $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
 499         $exp->token = psi_token_copy($PRAGMA_ONCE);
 500 }
 501 |       cpp_ignored_token cpp_macro_decl_tokens[tokens] {
 502         psi_plist_free($tokens);
 503         $exp = NULL;
 504 }
 505 ;
 506
 507 cpp_ignored_token:
 508         LINE
 509 |       PRAGMA
 510 ;
 511
 512 cpp_message_token:
 513         ERROR
 514 |       WARNING
 515 ;
 516
 517 cpp_include_token:
 518         IMPORT
 519 |       INCLUDE
 520 |       INCLUDE_NEXT
 521 ;
 522
 523 cpp_header_token:
 524         QUOTED_STRING
 525 |       CPP_HEADER
 526 ;
 527
 528 cpp_no_arg_token:
 529         ELSE
 530 |       ENDIF
 531 ;
 532
 533 cpp_name_arg_token:
 534         IFDEF
 535 |       IFNDEF
 536 |       UNDEF
 537 ;
 538
 539 cpp_exp_arg_token:
 540         IF
 541 |       ELIF
 542 ;
 543
 544 cpp_special_name_token:
 545         name_token
 546 |       NULL
 547 |       TRUE
 548 |       FALSE
 549 |       CPP_RESTRICT
 550 |       CPP_EXTENSION
 551 |       CPP_INLINE
 552 ;
 553
 554 cpp_macro_decl[macro]:
 555         name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
 556         $name_token->type = PSI_T_NAME;
 557         $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
 558         $macro->token = psi_token_copy($name_token);
 559 }
 560 |       cpp_special_name_token[name_token] cpp_macro_decl_tokens {
 561         $name_token->type = PSI_T_NAME;
 562         $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
 563         $macro->token = psi_token_copy($name_token);
 564 }
 565 ;
 566
 567 cpp_macro_sig[sig]:
 568         %empty {
 569         $sig = psi_plist_init(NULL);
 570 }
 571 |       ELLIPSIS {
 572         $sig = psi_plist_init(NULL); /* FIXME */
 573 }
 574 |       cpp_macro_sig_args
 575 |       cpp_macro_sig_args[args] COMMA ELLIPSIS {
 576         $sig = $args;
 577 }
 578 ;
 579
 580 cpp_macro_sig_args[args]:
 581         name_token {
 582         $name_token = psi_token_copy($name_token);
 583         $name_token->type = PSI_T_NAME;
 584         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
 585 }
 586 |       cpp_macro_sig_args[args_] COMMA name_token {
 587         $name_token = psi_token_copy($name_token);
 588         $name_token->type = PSI_T_NAME;
 589         $args = psi_plist_add($args_, &$name_token);
 590 }
 591 ;
 592
 593 cpp_macro_decl_tokens[tokens]:
 594         %empty {
 595         $tokens = NULL;
 596 }
 597 | cpp_macro_decl_token_list
 598 ;
 599
 600 cpp_macro_decl_token_list[tokens]:
 601         any_noeol_token[token] {
 602         $token = psi_token_copy($token);
 603         $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
 604 }
 605 |       cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
 606         $token = psi_token_copy($token);
 607         $tokens = psi_plist_add($tokens_, &$token);
 608 }
 609 ;
 610
 611 cpp_macro_exp[exp]:
 612         LPAREN cpp_macro_exp[exp_] RPAREN {
 613         $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
 614         $exp->token = psi_token_copy($LPAREN);
 615 }
 616 |       unary_op_token cpp_macro_exp[exp_] %prec UNARY {
 617         $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
 618         $exp->token = psi_token_copy($unary_op_token);
 619 }
 620 |       cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
 621         $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
 622         $exp->token = psi_token_copy($binary_op_token);
 623 }
 624 |       cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
 625         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
 626         $exp->token = psi_token_copy($IIF);
 627 }
 628
 629 |       DEFINED name_token {
 630         {
 631                 uint8_t exists;
 632
 633                 $name_token->type = PSI_T_NAME;
 634                 exists = psi_cpp_defined(P->preproc, $name_token);
 635                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 636                 $exp->token = psi_token_copy($name_token);
 637         }
 638 }
 639 |       DEFINED LPAREN name_token RPAREN {
 640         {
 641                 uint8_t exists;
 642
 643                 $name_token->type = PSI_T_NAME;
 644                 exists = psi_cpp_defined(P->preproc, $name_token);
 645                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 646                 $exp->token = psi_token_copy($name_token);
 647         }
 648 }
 649 |       NUMBER {
 650         $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
 651         $exp->token = psi_token_copy($NUMBER);
 652         $exp->data.n->token = psi_token_copy($NUMBER);
 653 }
 654 |       QUOTED_CHAR {
 655         $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
 656         $exp->token = psi_token_copy($QUOTED_CHAR);
 657         $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
 658 }
 659 |       sizeof {
 660         $exp = psi_num_exp_init_num($sizeof);
 661         $exp->token = psi_token_copy($sizeof->token);
 662 }
 663 |       name_token {
 664         $name_token->type = PSI_T_NAME;
 665         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
 666         $exp->token = psi_token_copy($name_token);
 667         $exp->data.n->token = psi_token_copy($name_token);
 668 }
 669 |       name_token LPAREN cpp_macro_call_args RPAREN {
 670         $name_token->type = PSI_T_NAME;
 671         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
 672                 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
 673         $exp->token = psi_token_copy($name_token);
 674 }
 675 ;
 676
 677 cpp_macro_call_args[args]:
 678         %empty {
 679         $args = NULL;
 680 }
 681 |       cpp_macro_call_arg_list
 682 ;
 683
 684 cpp_macro_call_arg_list[args]:
 685         cpp_macro_exp {
 686         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
 687                 &$cpp_macro_exp);
 688 }
 689 |       cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
 690         $args = psi_plist_add($args_, &$cpp_macro_exp);
 691 }
 692 ;
 693
 694 constant[const]:
 695         CONST constant_type NSNAME EQUALS impl_def_val EOS {
 696         $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
 697         $const->token = psi_token_copy($NSNAME);
 698 }
 699 ;
 700
 701 constant_type[type]:
 702         constant_type_token[token] {
 703         $type = psi_const_type_init($token->type, $token->text);
 704 }
 705 ;
 706
 707 constant_type_token:
 708         BOOL
 709 |       INT
 710 |       FLOAT
 711 |       STRING
 712 ;
 713
 714 impl_def_val[val]:
 715         %empty {
 716         $val = NULL;
 717 }
 718 |       num_exp[num] %dprec 1 {
 719         if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
 720                 impl_val res = {0};
 721                 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
 722
 723                 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
 724                         $val = psi_impl_def_val_init(type, NULL);
 725                 } else {
 726                         $val = psi_impl_def_val_init(PSI_T_INT, NULL);
 727                 }
 728
 729                 switch (type) {
 730                 case PSI_T_UINT8:       $val->ival.zend.lval = res.u8;  break;
 731                 case PSI_T_UINT16:      $val->ival.zend.lval = res.u16; break;
 732                 case PSI_T_UINT32:      $val->ival.zend.lval = res.u32; break;
 733                 case PSI_T_UINT64:      $val->ival.zend.lval = res.u64; break; /* FIXME */
 734                 case PSI_T_INT8:        $val->ival.zend.lval = res.i8;  break;
 735                 case PSI_T_INT16:       $val->ival.zend.lval = res.i16; break;
 736                 case PSI_T_INT32:       $val->ival.zend.lval = res.i32; break;
 737                 case PSI_T_INT64:       $val->ival.zend.lval = res.i64; break;
 738                 case PSI_T_FLOAT:       $val->ival.dval = res.fval;             break;
 739                 case PSI_T_DOUBLE:      $val->ival.dval = res.dval;             break;
 740                 default:
 741                         assert(0);
 742
 743                 }
 744         } else {
 745                 $val = NULL;
 746         }
 747         psi_num_exp_free(&$num);
 748 }
 749 |       impl_def_val_token[token] %dprec 2 {
 750         $val = psi_impl_def_val_init($token->type, $token->text);
 751         $val->token = psi_token_copy($token);
 752 }
 753 ;
 754
 755 impl_def_val_token:
 756         NULL
 757 |       TRUE
 758 |       FALSE
 759 |       QUOTED_STRING
 760 ;
 761
 762 decl_typedef[def]:
 763         TYPEDEF typedef[def_] EOS {
 764         $def = $def_;
 765 }
 766 |       TYPEDEF VOID name_token EOS {
 767         $def = psi_decl_arg_init(
 768                 psi_decl_type_init(PSI_T_VOID, $VOID->text),
 769                 psi_decl_var_init($name_token->text, 0, 0)
 770         );
 771         $def->token = psi_token_copy($VOID);
 772         $def->type->token = psi_token_copy($VOID);
 773         $def->var->token = psi_token_copy($name_token);
 774 }
 775 |       CPP_EXTENSION TYPEDEF typedef[def_] EOS {
 776         $def = $def_;
 777 }
 778 ;
 779
 780 typedef[def]:
 781         typedef_decl {
 782         $def = $typedef_decl;
 783 }
 784 |       CPP_EXTENSION typedef_decl {
 785         $def = $typedef_decl;
 786 }
 787 ;
 788
 789 typedef_anon[def]:
 790         typedef_anon_decl {
 791         $def = $typedef_anon_decl;
 792 }
 793 |       CPP_EXTENSION typedef_anon_decl {
 794         $def = $typedef_anon_decl;
 795 }
 796 ;
 797
 798 typedef_decl[def]:
 799         decl_arg
 800 |       decl_func_body[decl] {
 801         $def = psi_decl_arg_init(
 802                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
 803                 psi_decl_var_copy($decl->func->var)
 804         );
 805         $def->type->token = psi_token_copy($decl->func->token);
 806         $def->type->real.func = $decl;
 807 }
 808 |       decl_enum[enum] name_token {
 809         $name_token->type = PSI_T_NAME;
 810         $def = psi_decl_arg_init(
 811                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 812                 psi_decl_var_init($name_token->text, 0, 0)
 813         );
 814         $def->var->token = psi_token_copy($name_token);
 815         $def->type->token = psi_token_copy($enum->token);
 816         $def->type->real.enm = $enum;
 817         psi_parser_proc_add_enum(P, $enum);
 818 }
 819 |       struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
 820         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
 821         $def->type->token = $struct;
 822         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 823         $def->type->real.strct->token = psi_token_copy($struct);
 824         $def->type->real.strct->align = $as.pos;
 825         $def->type->real.strct->size = $as.len;
 826         psi_parser_proc_add_struct(P, $def->type->real.strct);
 827 }
 828 |       union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
 829         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
 830         $def->type->token = $union;
 831         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 832         $def->type->real.unn->token = psi_token_copy($union);
 833         $def->type->real.unn->align = $as.pos;
 834         $def->type->real.unn->size = $as.len;
 835         psi_parser_proc_add_union(P, $def->type->real.unn);
 836 }
 837 ;
 838
 839 typedef_anon_decl[def]:
 840         typedef_decl %dprec 2
 841 |       qualified_decl_type[type] %dprec 1 {
 842         $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
 843         $def->var->token = psi_token_copy($type->token);
 844 }
 845 |       decl_enum[enum] {
 846         $def = psi_decl_arg_init(
 847                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 848                 psi_decl_var_init(NULL, 0, 0)
 849         );
 850         $def->var->token = psi_token_copy($enum->token);
 851         $def->type->token = psi_token_copy($enum->token);
 852         $def->type->real.enm = $enum;
 853         psi_parser_proc_add_enum(P, $enum);
 854 }
 855 |       struct_name[struct] align_and_size[as] struct_args_block[args] {
 856         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
 857         $def->type->token = $struct;
 858         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 859         $def->type->real.strct->token = psi_token_copy($struct);
 860         $def->type->real.strct->align = $as.pos;
 861         $def->type->real.strct->size = $as.len;
 862         psi_parser_proc_add_struct(P, $def->type->real.strct);
 863 }
 864 |       union_name[union] align_and_size[as] struct_args_block[args] {
 865         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
 866         $def->type->token = $union;
 867         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 868         $def->type->real.unn->token = psi_token_copy($union);
 869         $def->type->real.unn->align = $as.pos;
 870         $def->type->real.unn->size = $as.len;
 871         psi_parser_proc_add_union(P, $def->type->real.unn);
 872 }
 873 ;
 874
 875 qualified_decl_type[type]:
 876         CONST decl_type[type_] {
 877         $type = $type_;
 878 }
 879 |       VOLATILE decl_type[type_] {
 880         $type = $type_;
 881 }
 882 |       decl_type
 883 ;
 884
 885 decl_type[type]:
 886         decl_type_simple[token] {
 887         $type = psi_decl_type_init($token->type, $token->text);
 888         $type->token = $token;
 889 }
 890 |       decl_type_complex
 891 ;
 892
 893 decl_type_complex[type]:
 894         STRUCT[token] name_token {
 895         $name_token->type = PSI_T_NAME;
 896         $type = psi_decl_type_init($token->type, $name_token->text);
 897         $type->token = psi_token_copy($name_token);
 898 }
 899 |       UNION[token] name_token {
 900         $name_token->type = PSI_T_NAME;
 901         $type = psi_decl_type_init($token->type, $name_token->text);
 902         $type->token = psi_token_copy($name_token);
 903 }
 904 |       ENUM[token] name_token {
 905         $name_token->type = PSI_T_NAME;
 906         $type = psi_decl_type_init($token->type, $name_token->text);
 907         $type->token = psi_token_copy($name_token);
 908 }
 909 ;
 910
 911 decl_type_simple[type]:
 912         decl_int_type
 913 |       decl_real_type
 914 |       NAME[type_] {
 915         $type = psi_token_copy($type_);
 916 }
 917 ;
 918
 919 decl_real_type[type]:
 920         FLOAT[type_] {
 921         $type = psi_token_copy($type_);
 922 }
 923 |       DOUBLE[type_] {
 924         $type = psi_token_copy($type_);
 925 }
 926 |       LONG DOUBLE {
 927         $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
 928 }
 929 ;
 930
 931 int_signed[i]:
 932         SIGNED
 933 |       UNSIGNED
 934 ;
 935
 936 int_width[i]:
 937         SHORT {
 938         $i = psi_token_copy($SHORT);
 939 }
 940 |       LONG {
 941         $i = psi_token_copy($LONG);
 942 }
 943 |       LONG[l1] LONG[l2] {
 944         $i = psi_token_cat(" ", 2, $l1, $l2);
 945 }
 946 ;
 947
 948 decl_int_type[type]:
 949         CHAR {
 950         $type = psi_token_copy($CHAR);
 951 }
 952 |       INT {
 953         $type = psi_token_copy($INT);
 954 }
 955 |       int_signed int_signed_types {
 956         if ($2) {
 957                 $type = psi_token_cat(" ", 2, $1, $2);
 958                 free($2);
 959         } else {
 960                 $type = psi_token_copy($1);
 961         }
 962 }
 963 |       int_width int_width_types {
 964         if ($2) {
 965                 $type = psi_token_cat(" ", 2, $1, $2);
 966                 free($1);
 967                 free($2);
 968         } else {
 969                 $type = $1;
 970         }
 971 }
 972 ;
 973
 974 int_signed_types[type]:
 975         %empty {
 976         $type = NULL;
 977 }
 978 |       NAME {
 979         $type = psi_token_copy($NAME);
 980 }
 981 |       CHAR {
 982         $type = psi_token_copy($CHAR);
 983 }
 984 |       SHORT signed_short_types {
 985         if ($2) {
 986                 $type = psi_token_cat(" ", 2, $1, $2);
 987         } else {
 988                 $type = psi_token_copy($1);
 989         }
 990 }
 991 |       INT {
 992         $type = psi_token_copy($INT);
 993 }
 994 |       LONG signed_long_types {
 995         if ($2) {
 996                 $type = psi_token_cat(" ", 2, $1, $2);
 997         } else {
 998                 $type = psi_token_copy($1);
 999         }
1000 }
1001 ;
1002
1003 signed_short_types[type]:
1004         %empty {
1005         $type = NULL;
1006 }
1007 |       INT
1008 ;
1009 signed_long_types[type]:
1010         %empty {
1011         $type = NULL;
1012 }
1013 |       INT
1014 |       LONG
1015 |       LONG INT
1016 ;
1017
1018 int_width_types[type]:
1019         %empty {
1020         $type = NULL;
1021 }
1022 |       INT {
1023         $type = psi_token_copy($INT);
1024 }
1025 |       int_signed int_signed_types {
1026         if ($2) {
1027                 $type = psi_token_cat(" ", 2, $1, $2);
1028                 free($2);
1029         } else {
1030                 $type = psi_token_copy($1);
1031         }
1032 }
1033 ;
1034
1035 decl_stmt:
1036         decl decl_asm EOS {
1037         $decl_stmt = $decl;
1038 }
1039 |       CPP_EXTENSION decl decl_asm EOS {
1040         $decl_stmt = $decl;
1041 }
1042 ;
1043
1044 decl_asm:
1045         %empty
1046 |       CPP_ASM LPAREN ignored_quoted_strings RPAREN
1047 ;
1048
1049 ignored_quoted_strings:
1050         QUOTED_STRING
1051 |       ignored_quoted_strings QUOTED_STRING
1052 ;
1053
1054 decl_ext_var_stmt:
1055         decl_ext_var EOS
1056 ;
1057
1058 decl_ext_var:
1059         NAME decl_arg decl_ext_var_list {
1060         psi_decl_arg_free(&$decl_arg);
1061 }
1062 ;
1063
1064 decl_ext_var_list:
1065         %empty
1066 |       COMMA decl_vars {
1067         psi_plist_free($decl_vars);
1068 }
1069 ;
1070
1071 decl_vars[vars]:
1072         decl_var[var] {
1073         $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1074 }
1075 |       decl_vars[vars_] COMMA decl_var[var] {
1076         $vars = psi_plist_add($vars_, &$var);
1077 }
1078 ;
1079
1080 ignored_decl:
1081         STATIC decl_body ignored_decl_body {
1082         psi_decl_free(&$decl_body);
1083 }
1084 |       CPP_INLINE decl_body ignored_decl_body {
1085         psi_decl_free(&$decl_body);
1086 }
1087 |       STATIC CPP_INLINE decl_body ignored_decl_body {
1088         psi_decl_free(&$decl_body);
1089 }
1090 ;
1091
1092 ignored_decl_body:
1093         LBRACE ignored_decl_body_stmts RBRACE
1094 ;
1095
1096 ignored_decl_body_stmts:
1097         ignored_decl_body_stmt
1098 |       ignored_decl_body_stmts ignored_decl_body_stmt
1099 ;
1100
1101 ignored_decl_body_stmt:
1102         any_nobrace_token
1103 |       ignored_decl_body
1104 ;
1105
1106 decl:
1107         decl_body
1108 |       NAME[abi] decl_body {
1109         $decl = $decl_body;
1110         $decl->abi = psi_decl_abi_init($abi->text);
1111 }
1112 ;
1113
1114 decl_body:
1115         decl_func_body
1116 |       decl_functor_body
1117 ;
1118
1119 decl_func_body[decl]:
1120         decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1121         $decl = psi_decl_init($func, $args);
1122         if ($as) {
1123                 $decl->func->var->pointer_level += 1;
1124                 $decl->func->var->array_size = $as;
1125         }
1126 }
1127 |       decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1128         $decl = psi_decl_init($func, $args);
1129         $decl->varargs = 1;
1130         if ($as) {
1131                 $decl->func->var->pointer_level += 1;
1132                 $decl->func->var->array_size = $as;
1133         }
1134 }
1135 ;
1136
1137 decl_functor_body[decl]:
1138         decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1139         $decl = psi_decl_init($func, $args);
1140         if ($as) {
1141                 $decl->func->var->pointer_level += 1;
1142                 $decl->func->var->array_size = $as;
1143         }
1144 }
1145 |       decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1146         $decl = psi_decl_init($func, $args);
1147         $decl->varargs = 1;
1148         if ($as) {
1149                 $decl->func->var->pointer_level += 1;
1150                 $decl->func->var->array_size = $as;
1151         }
1152 }
1153 ;
1154
1155 decl_functor[arg]:
1156         qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1157         (void) $unused1;
1158         $NAME->type = PSI_T_NAME;
1159         $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1160         $arg->var->token = psi_token_copy($NAME);
1161         $arg->token = psi_token_copy($NAME);
1162 }
1163 |       CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1164         (void) $unused1;
1165         $NAME->type = PSI_T_NAME;
1166         $arg = psi_decl_arg_init(
1167                 psi_decl_type_init($VOID->type, $VOID->text),
1168                 psi_decl_var_init($NAME->text, $pointers, 0)
1169         );
1170         $arg->type->token = psi_token_copy($VOID);
1171         $arg->var->token = psi_token_copy($NAME);
1172         $arg->token = psi_token_copy($NAME);
1173 }
1174 |       VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1175         (void) $unused1;
1176         $NAME->type = PSI_T_NAME;
1177         $arg = psi_decl_arg_init(
1178                 psi_decl_type_init($VOID->type, $VOID->text),
1179                 psi_decl_var_init($NAME->text, $pointers, 0)
1180         );
1181         $arg->type->token = psi_token_copy($VOID);
1182         $arg->var->token = psi_token_copy($NAME);
1183         $arg->token = psi_token_copy($NAME);
1184 }
1185 |       VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1186         (void) $unused1;
1187         $NAME->type = PSI_T_NAME;
1188         $arg = psi_decl_arg_init(
1189                 psi_decl_type_init($VOID->type, $VOID->text),
1190                 psi_decl_var_init($NAME->text, 0, 0)
1191         );
1192         $arg->type->token = psi_token_copy($VOID);
1193         $arg->var->token = psi_token_copy($NAME);
1194         $arg->token = psi_token_copy($NAME);
1195 }
1196 ;
1197
1198 decl_func[func]:
1199         decl_arg
1200 |       VOID name_token[NAME] {
1201         $func = psi_decl_arg_init(
1202                 psi_decl_type_init($VOID->type, $VOID->text),
1203                 psi_decl_var_init($NAME->text, 0, 0)
1204         );
1205         $func->type->token = psi_token_copy($VOID);
1206         $func->var->token = psi_token_copy($NAME);
1207         $func->token = psi_token_copy($NAME);
1208 }
1209 ;
1210
1211 decl_args[args]:
1212         %empty {
1213         $args = NULL;
1214 }
1215 |       VOID {
1216         $args = NULL;
1217 }
1218 |       decl_anon_arg[arg] {
1219         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1220 }
1221 |       decl_args[args_] COMMA decl_anon_arg[arg] {
1222         $args = psi_plist_add($args_, &$arg);
1223 }
1224 ;
1225
1226 decl_anon_arg[arg]:
1227 /* FIXME decl_functor_body_anon */
1228         decl_arg %dprec 2 {
1229         $arg = $decl_arg;
1230 }
1231 |       qualified_decl_type[type] indirection %dprec 1 {
1232         $arg = psi_decl_arg_init(
1233                 $type,
1234                 psi_decl_var_init(NULL, $indirection, 0)
1235         );
1236 }
1237 |       CONST VOID pointers {
1238         $arg = psi_decl_arg_init(
1239                 psi_decl_type_init($VOID->type, $VOID->text),
1240                 psi_decl_var_init(NULL, $pointers, 0)
1241         );
1242         $arg->type->token = psi_token_copy($VOID);
1243         $arg->var->token = psi_token_copy($VOID);
1244         $arg->token = psi_token_copy($VOID);
1245 }
1246 |       VOID pointers {
1247         $arg = psi_decl_arg_init(
1248                 psi_decl_type_init($VOID->type, $VOID->text),
1249                 psi_decl_var_init(NULL, $pointers, 0)
1250         );
1251         $arg->type->token = psi_token_copy($VOID);
1252         $arg->var->token = psi_token_copy($VOID);
1253         $arg->token = psi_token_copy($VOID);
1254 }
1255 ;
1256
1257 decl_arg[arg]:
1258         decl_functor_body[decl] {
1259         $arg = psi_decl_arg_init(
1260                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1261                 psi_decl_var_copy($decl->func->var)
1262         );
1263         $arg->type->token = psi_token_copy($decl->func->token);
1264         $arg->type->real.func = $decl;
1265 }
1266 |       qualified_decl_type[type] decl_var[var] {
1267         $arg = psi_decl_arg_init($type, $var);
1268 }
1269 |       CONST VOID pointers name_token[NAME] {
1270         $NAME->type = PSI_T_NAME;
1271         $arg = psi_decl_arg_init(
1272                 psi_decl_type_init($VOID->type, $VOID->text),
1273                 psi_decl_var_init($NAME->text, $pointers, 0)
1274         );
1275         $arg->type->token = psi_token_copy($VOID);
1276         $arg->var->token = psi_token_copy($NAME);
1277         $arg->token = psi_token_copy($NAME);
1278 }
1279 |       VOID pointers name_token[NAME] {
1280         $NAME->type = PSI_T_NAME;
1281         $arg = psi_decl_arg_init(
1282                 psi_decl_type_init($VOID->type, $VOID->text),
1283                 psi_decl_var_init($NAME->text, $pointers, 0)
1284         );
1285         $arg->type->token = psi_token_copy($VOID);
1286         $arg->var->token = psi_token_copy($NAME);
1287         $arg->token = psi_token_copy($NAME);
1288 }
1289 ;
1290
1291 decl_var[var]:
1292         pointers name_token array_size {
1293         $name_token->type = PSI_T_NAME;
1294         $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1295         $var->token = psi_token_copy($name_token);
1296 }
1297 |       name_token array_size {
1298         $name_token->type = PSI_T_NAME;
1299         $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1300         $var->token = psi_token_copy($name_token);
1301 }
1302 ;
1303
1304 decl_union[union]:
1305         UNION name_token align_and_size[as] decl_struct_args[args] {
1306         $name_token->type = PSI_T_NAME;
1307         $union = psi_decl_union_init($name_token->text, $args);
1308         $union->align = $as.pos;
1309         $union->size = $as.len;
1310         $union->token = psi_token_copy($name_token);
1311 }
1312 ;
1313
1314 decl_struct[struct]:
1315         STRUCT name_token align_and_size[as] decl_struct_args[args] {
1316         $name_token->type = PSI_T_NAME;
1317         $struct = psi_decl_struct_init($name_token->text, $args);
1318         $struct->align = $as.pos;
1319         $struct->size = $as.len;
1320         $struct->token = psi_token_copy($name_token);
1321 }
1322 ;
1323
1324 decl_struct_args[args]:
1325         EOS {
1326         $args = NULL;
1327 }
1328 |       struct_args_block
1329 ;
1330
1331 struct_args_block[args]:
1332         LBRACE struct_args RBRACE {
1333         $args = $struct_args;
1334 }
1335 ;
1336
1337 struct_args[args]:
1338         typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1339         $arg->layout = $layout;
1340         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1341         if ($vars) {
1342                 size_t i = 0;
1343                 struct psi_decl_arg *arg;
1344
1345                 while (psi_plist_get($vars, i++, &arg)) {
1346                         arg->type = psi_decl_type_copy($arg->type);
1347                         $args = psi_plist_add($args, &arg);
1348                 }
1349                 free($vars);
1350         }
1351 }
1352 |       struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1353         $arg->layout = $layout;
1354         $args = psi_plist_add($args_, &$arg);
1355         if ($vars) {
1356                 size_t i = 0;
1357                 struct psi_decl_arg *arg;
1358
1359                 while (psi_plist_get($vars, i++, &arg)) {
1360                         arg->type = psi_decl_type_copy($arg->type);
1361                         $args = psi_plist_add($args, &arg);
1362                 }
1363                 free($vars);
1364         }
1365 }
1366 ;
1367
1368 struct_arg_var_list[vars]:
1369         %empty {
1370         $vars = NULL;
1371 }
1372 |       COMMA decl_vars_with_layout[vars_] {
1373         $vars = $vars_;
1374 }
1375 ;
1376
1377 decl_vars_with_layout[vars]:
1378         decl_var[var] decl_layout[layout] {
1379         {
1380                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1381                 arg->layout = $layout;
1382                 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1383         }
1384 }
1385 |       decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1386         {
1387                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1388                 arg->layout = $layout;
1389                 $vars = psi_plist_add($vars_, &arg);
1390         }
1391 }
1392 ;
1393
1394 decl_enum[enum]:
1395         enum_name LBRACE decl_enum_items[list] RBRACE {
1396         $enum = psi_decl_enum_init($enum_name->text, $list);
1397         $enum->token = $enum_name;
1398 }
1399 ;
1400
1401 decl_enum_items[list]:
1402         decl_enum_item[i] {
1403         $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1404 }
1405 |       decl_enum_items[list_] COMMA decl_enum_item[i] {
1406         $list = psi_plist_add($list_, &$i);
1407 }
1408 ;
1409
1410 decl_enum_item[i]:
1411         name_token {
1412         $name_token->type = PSI_T_NAME;
1413         $i = psi_decl_enum_item_init($name_token->text, NULL);
1414         $i->token = psi_token_copy($name_token);
1415 }
1416 |       name_token EQUALS num_exp {
1417         $name_token->type = PSI_T_NAME;
1418         $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1419         $i->token = psi_token_copy($name_token);
1420 }
1421 ;
1422
1423 num_exp[exp]:
1424         number {
1425         $exp = psi_num_exp_init_num($number);
1426         $exp->token = psi_token_copy($number->token);
1427 }
1428 |       LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1429         $exp = psi_num_exp_init_cast($type, $exp_);
1430         $exp->token = psi_token_copy($type->token);
1431 }
1432 |       LPAREN num_exp[exp_] RPAREN {
1433         $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1434         $exp->token = psi_token_copy($LPAREN);
1435 }
1436 |       num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1437         $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1438         $exp->token = psi_token_copy($op);
1439 }
1440 |       unary_op_token[op] num_exp[exp_] %prec UNARY {
1441         $exp = psi_num_exp_init_unary($op->type, $exp_);
1442         $exp->token = psi_token_copy($op);
1443 }
1444 |       num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1445         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1446         $exp->token = psi_token_copy($IIF);
1447 }
1448 ;
1449
1450 number[num]:
1451         NUMBER[token] {
1452         $num = psi_number_init($token->type, $token->text, $token->flags);
1453         $num->token = psi_token_copy($token);
1454 }
1455 |       NSNAME[token] {
1456         $num = psi_number_init($token->type, $token->text, 0);
1457         $num->token = psi_token_copy($token);
1458 }
1459 |       QUOTED_CHAR[token] {
1460         $num = psi_number_init($token->type, $token->text, 0);
1461         $num->token = psi_token_copy($token);
1462 }
1463 |       NULL[token] {
1464         $num = psi_number_init($token->type, $token->text, 0);
1465         $num->token = psi_token_copy($token);
1466 }
1467 |       decl_var {
1468         $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1469         $num->token = psi_token_copy($decl_var->token);
1470 }
1471 |       sizeof {
1472         $num = $sizeof;
1473 }
1474 ;
1475
1476 sizeof:
1477         SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1478         $sizeof = $sizeof_;
1479         $sizeof->token = psi_token_copy($SIZEOF);
1480 }
1481 |       SIZEOF sizeof_body_notypes[sizeof_] {
1482         $sizeof = $sizeof_;
1483         $sizeof->token = psi_token_copy($SIZEOF);
1484 }
1485 ;
1486
1487 sizeof_body[sizeof]:
1488         sizeof_body_notypes[sizeof_] {
1489         $sizeof = $sizeof_;
1490 }
1491 |       decl_type indirection {
1492         if ($indirection) {
1493                 int8_t sizeof_void_p = sizeof(void *);
1494                 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1495         } else {
1496                 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1497         }
1498 }
1499 ;
1500
1501 sizeof_body_notypes[sizeof]:
1502         AMPERSAND NAME {
1503         int8_t sizeof_void_p = sizeof(void *);
1504         $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1505 }
1506 |       QUOTED_CHAR {
1507         int8_t sizeof_a = sizeof('a');
1508         $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1509 }
1510 |       QUOTED_STRING {
1511         $sizeof = psi_number_init(PSI_T_INT64, &$QUOTED_STRING->size, 0);
1512 }
1513 ;
1514
1515 enum_name[name]:
1516         ENUM optional_name[name_] {
1517         if ($name_) {
1518                 $name = psi_token_copy($name_);
1519         } else {
1520                 char digest[17];
1521
1522                 psi_token_hash($ENUM, digest);
1523                 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1524         }
1525 }
1526 ;
1527
1528 union_name[name]:
1529         UNION optional_name[name_] {
1530         if ($name_) {
1531                 $name = psi_token_copy($name_);
1532         } else {
1533                 char digest[17];
1534
1535                 psi_token_hash($UNION, digest);
1536                 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1537         }
1538 }
1539 ;
1540
1541 struct_name[name]:
1542         STRUCT optional_name[name_] {
1543         if ($name_) {
1544                 $name = psi_token_copy($name_);
1545         } else {
1546                 char digest[17];
1547
1548                 psi_token_hash($STRUCT, digest);
1549                 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1550         }
1551 }
1552 ;
1553
1554 optional_name[name]:
1555         %empty {
1556         $name = NULL;
1557 }
1558 |       name_token {
1559         $name = $name_token;
1560         $name->type = PSI_T_NAME;
1561 }
1562 ;
1563
1564 decl_layout[l]:
1565         %empty {
1566         $l = NULL;
1567 }
1568 |       COLON NUMBER[width] {
1569         $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1570 }
1571 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1572         $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1573 }
1574 |       COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1575         $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1576 }
1577 ;
1578
1579 align_and_size[as]:
1580         %empty {
1581         $as.pos = 0;
1582         $as.len = 0;
1583 }
1584 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1585         $as.pos = atol($align->text);
1586         $as.len = atol($size->text);
1587 }
1588 ;
1589
1590 array_size[as]:
1591         %empty {
1592         $as = 0;
1593 }
1594 |       LBRACKET RBRACKET {
1595         $as = 0;
1596 }
1597 |       LBRACKET num_exp RBRACKET {
1598         if (psi_num_exp_validate(PSI_DATA(P), $num_exp, NULL, NULL, NULL, NULL, NULL)) {
1599                 $as = psi_long_num_exp($num_exp, NULL, &P->preproc->defs);
1600         } else {
1601                 $as = 0;
1602         }
1603 }
1604 ;
1605
1606 indirection[i]:
1607         %empty {
1608         $i = 0;
1609 }
1610 |       pointers[p] %prec UNARY {
1611         $i = $p;
1612 }
1613 ;
1614
1615 pointers[p]:
1616         asterisks
1617 |       asterisks[a] CPP_RESTRICT {
1618         $p = $a;
1619 }
1620 ;
1621
1622 asterisks[a]:
1623         asterisk {
1624         $a = 1;
1625 }
1626 |       asterisks[a_] asterisk {
1627         $a = $a_ + 1;
1628 }
1629 ;
1630
1631 asterisk:
1632         ASTERISK
1633 |       ASTERISK CONST
1634 ;
1635
1636 /*
1637  *
1638  * impl
1639  *
1640  */
1641
1642 impl:
1643         impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1644         $impl = psi_impl_init($func, $stmts);
1645 }
1646 |       STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1647         $impl = psi_impl_init($func, $stmts);
1648         $func->static_memory = 1;
1649 }
1650 ;
1651
1652 impl_func[func]:
1653         FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1654         $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1655         $func->token = psi_token_copy($NSNAME);
1656         $func->return_reference = $r;
1657 }
1658 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1659         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1660         $func->token = psi_token_copy($NSNAME);
1661         $func->return_reference = $r;
1662 }
1663 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1664         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1665         $func->token = psi_token_copy($NSNAME);
1666         $func->return_reference = $r;
1667         $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1668         $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1669 }
1670 ;
1671
1672 impl_args[args]:
1673         impl_arg[arg] {
1674         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1675 }
1676 |       impl_args[args_] COMMA impl_arg[arg] {
1677         $args = psi_plist_add($args_, &$arg);
1678 }
1679 ;
1680
1681 impl_arg[arg]:
1682         impl_type[type] impl_var[var] {
1683         $arg = psi_impl_arg_init($type, $var, NULL);
1684 }
1685 |       impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1686         $arg = psi_impl_arg_init($type, $var, $val);
1687 }
1688 ;
1689
1690 impl_var[var]:
1691         reference DOLLAR_NAME {
1692         $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1693         $var->token = psi_token_copy($DOLLAR_NAME);
1694 }
1695 ;
1696
1697 impl_type[type]:
1698         impl_type_token[token] {
1699         $type = psi_impl_type_init($token->type, $token->text);
1700         $type->token = psi_token_copy($token);
1701 }
1702 ;
1703
1704 impl_type_token:
1705         VOID
1706 |       MIXED
1707 |       BOOL
1708 |       INT
1709 |       FLOAT
1710 |       STRING
1711 |       ARRAY
1712 |       OBJECT
1713 |       CALLABLE
1714 ;
1715
1716 impl_stmts[stmts]:
1717         impl_stmt[stmt] {
1718         $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1719 }
1720 |       impl_stmts[stmts_] impl_stmt[stmt] {
1721         $stmts = psi_plist_add($stmts_, &$stmt);
1722 }
1723 ;
1724
1725 impl_stmt[stmt]:
1726         return_stmt[s] {
1727         $stmt = (struct psi_token **) $s;
1728 }
1729 |       let_stmt[s] {
1730         $stmt = (struct psi_token **) $s;
1731 }
1732 |       set_stmt[s] {
1733         $stmt = (struct psi_token **) $s;
1734 }
1735 |       assert_stmt[s] {
1736         $stmt = (struct psi_token **) $s;
1737 }
1738 |       free_stmt[s] {
1739         $stmt = (struct psi_token **) $s;
1740 }
1741 ;
1742
1743 let_stmt[let]:
1744         LET let_exp_assign[exp] EOS {
1745         $let = psi_let_stmt_init($exp);
1746         $let->token = psi_token_copy($LET);
1747 }
1748 |       TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1749         $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1750         $let->token = psi_token_copy($TEMP);
1751         $let->exp->is_reference = $reference;
1752 }
1753 ;
1754
1755 let_exp[exp]:
1756         let_exp_assign
1757 |       byref let_exp_byref[exp_] {
1758         $exp = $exp_;
1759         $exp->is_reference = true;
1760 }
1761 |       let_exp_byref[exp_] {
1762         $exp = $exp_;
1763         $exp->is_reference = false;
1764 }
1765 ;
1766
1767 let_exp_byref[exp]:
1768         NULL %dprec 2 {
1769         $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1770 }
1771 |       num_exp[num] %dprec 1 {
1772         $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1773 }
1774 |       let_calloc[calloc] {
1775         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1776 }
1777 |       STATIC let_calloc[calloc] {
1778         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1779         $calloc->static_memory = 1;
1780 }
1781 |       let_callback[callback] {
1782         $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1783 }
1784 |       let_func[func] {
1785         $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1786 }
1787 ;
1788
1789 let_exp_assign[exp]:
1790         decl_var[var] EQUALS let_exp_byref[exp_] {
1791         $exp = $exp_;
1792         $exp->var = $var;
1793 }
1794 |       decl_var[var] EQUALS byref let_exp_byref[exp_] {
1795         $exp = $exp_;
1796         $exp->is_reference = 1;
1797         $exp->var = $var;
1798 }
1799 ;
1800
1801 let_calloc[calloc]:
1802         CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1803         $calloc = psi_let_calloc_init($nmemb, $size);
1804         $calloc->token = psi_token_copy($CALLOC);
1805 }
1806 ;
1807
1808 let_callback[callback]:
1809         CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1810         $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args);
1811         $callback->func->token = psi_token_copy($func);
1812         $callback->token = psi_token_copy($CALLBACK);
1813 }
1814 ;
1815
1816 let_func[func]:
1817         let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1818         $func = psi_let_func_init($token->type, $token->text, $var);
1819         $func->token = psi_token_copy($token);
1820         $func->inner = $exps;
1821 }
1822 ;
1823
1824 let_func_token:
1825         ZVAL
1826 |       OBJVAL
1827 |       ARRVAL
1828 |       PATHVAL
1829 |       STRLEN
1830 |       STRVAL
1831 |       FLOATVAL
1832 |       INTVAL
1833 |       BOOLVAL
1834 |       COUNT
1835 ;
1836
1837 let_func_exps[exps]:
1838         %empty {
1839         $exps = NULL;
1840 }
1841 |       COMMA let_exps[exps_] {
1842         $exps = $exps_;
1843 }
1844 ;
1845
1846 let_exps[exps]:
1847         let_exp[exp] {
1848         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1849 }
1850 |       let_exps[exps_] COMMA let_exp[exp] {
1851         $exps = psi_plist_add($exps_, &$exp);
1852 }
1853 ;
1854
1855 callback_rval[rval]:
1856         VOID
1857 |       let_func_token
1858 ;
1859
1860 callback_arg_list[list]:
1861         %empty {
1862         $list = NULL;
1863 }
1864 |       callback_args[args] {
1865         $list = $args;
1866 }
1867 ;
1868
1869 callback_args[args]:
1870         set_exp[exp] {
1871         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1872 }
1873 |       callback_args[args_] COMMA set_exp[exp] {
1874         $args = psi_plist_add($args_, &$exp);
1875 }
1876 ;
1877
1878 return_stmt[return]:
1879         RETURN return_exp EOS {
1880         $return = psi_return_stmt_init($return_exp);
1881         $return->token = psi_token_copy($RETURN);
1882 }
1883 ;
1884
1885 return_exp:
1886         decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
1887         $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1888         $return_exp->token = psi_token_copy($func->token);
1889 }
1890 |       set_func {
1891         $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1892         $return_exp->token = psi_token_copy($set_func->token);
1893 }
1894 ;
1895
1896 call_decl_vars[args]:
1897         %empty {
1898         $args = NULL;
1899 }
1900 |       VOID {
1901         $args = NULL;
1902 }
1903 |       decl_vars[vars] {
1904         $args = $vars;
1905 }
1906 ;
1907
1908 set_stmt[set]:
1909         SET set_exp[exp] EOS {
1910         $set = psi_set_stmt_init($exp);
1911         $set->token = psi_token_copy($SET);
1912 }
1913 ;
1914
1915 set_exp[exp]:
1916         set_func[func] {
1917         $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1918 }
1919 |       num_exp[num] {
1920         $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1921 }
1922 |       impl_var[var] EQUALS set_exp[exp_] {
1923         $exp = $exp_;
1924         $exp->var = $var;
1925 }
1926 ;
1927
1928 set_func[func]:
1929         set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1930         $func = psi_set_func_init($token->type, $token->text, $var);
1931         $func->token = psi_token_copy($token);
1932         $func->inner = $exps;
1933 }
1934 |       set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
1935         $func = psi_set_func_init($token->type, $token->text, $var);
1936         $func->token = psi_token_copy($token);
1937         $func->recursive = 1;
1938 }
1939 ;
1940
1941 set_func_token:
1942         TO_OBJECT
1943 |       TO_ARRAY
1944 |       TO_STRING
1945 |       TO_INT
1946 |       TO_FLOAT
1947 |       TO_BOOL
1948 |       ZVAL
1949 |       VOID
1950 ;
1951
1952 set_func_exps[exps]:
1953         %empty {
1954         $exps = NULL;
1955 }
1956 |       COMMA set_exps[exps_] {
1957         $exps = $exps_;
1958 }
1959 ;
1960
1961 set_exps[exps]:
1962         set_exp[exp] {
1963         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1964 }
1965 |       set_exps[exps_] COMMA set_exp[exp] {
1966         $exps = psi_plist_add($exps_, &$exp);
1967 }
1968 ;
1969
1970 assert_stmt[assert]:
1971         assert_stmt_token[token] num_exp[exp] EOS {
1972         $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
1973         $assert->token = psi_token_copy($token);
1974 }
1975 ;
1976
1977 assert_stmt_token:
1978         PRE_ASSERT
1979 |       POST_ASSERT
1980 ;
1981
1982 free_stmt[free]:
1983         FREE free_exps[exps] EOS {
1984         $free = psi_free_stmt_init($exps);
1985         $free->token = psi_token_copy($FREE);
1986 }
1987 ;
1988
1989 free_exps[exps]:
1990         free_exp[exp] {
1991         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
1992 }
1993 |       free_exps[exps_] COMMA free_exp[exp] {
1994         $exps = psi_plist_add($exps_, &$exp);
1995 }
1996 ;
1997
1998 free_exp[exp]:
1999         name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2000         $NAME->type = PSI_T_NAME;
2001         $exp = psi_free_exp_init($NAME->text, $vars);
2002         $exp->token = psi_token_copy($NAME);
2003 }
2004 ;
2005
2006 reference:
2007         %empty {
2008         $reference = false;
2009 }
2010 |       byref {
2011         $reference = true;
2012 }
2013 ;
2014
2015 byref:
2016         AMPERSAND %prec UNARY
2017 ;
2018
2019 %%
2020
2021 /* epilogue */
2022
2023 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2024 {
2025         struct psi_token *token;
2026
2027         if (psi_plist_get(tokens, (*index)++, &token)) {
2028                 if (P->flags & PSI_DEBUG) {
2029                         psi_token_dump(2, token);
2030                 }
2031
2032                 *((struct psi_token **)lvalp) = token;
2033                 return token->type;
2034         } else {
2035                 (*index)--;
2036                 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
2037         }
2038
2039         return PSI_T_EOF;
2040 }
2041
2042 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2043 {
2044         struct psi_token *T = NULL;
2045         size_t last;
2046
2047         if (*index == 0) {
2048                 last = 0;
2049         } else {
2050                 last = --(*index);
2051         }
2052
2053         psi_plist_get(tokens, last, &T);
2054         if (T) {
2055                 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2056         } else {
2057                 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2058         }
2059         P->errors++;
2060 }
2061