projects / m6w6 / ext-psi / blob
? search:
summary | shortlog | log | commit | commitdiff | tree | github
history | raw | HEAD
fix macro expansion
[m6w6/ext-psi] / src / parser_proc_grammar.y
1 %code top {
2 #ifdef HAVE_CONFIG_H
3 # include "config.h"
4 #else
5 # include "php_config.h"
6 #endif
7 }
8
9 %code {
10 #include <assert.h>
11 #include <stdarg.h>
12
13 #include "plist.h"
14 #include "parser.h"
15
16 #define YYDEBUG 1
17 #define PSI_PARSER_PROC_DEBUG 1
18
19 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
20 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
21
22 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
23 {
24 assert(strct);
25 if (!P->structs) {
26 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
27 }
28 P->structs = psi_plist_add(P->structs, &strct);
29 }
30 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
31 {
32 assert(u);
33 if (!P->unions) {
34 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
35 }
36 P->unions = psi_plist_add(P->unions, &u);
37 }
38 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
39 {
40 assert(e);
41 if (!P->enums) {
42 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
43 }
44 P->enums = psi_plist_add(P->enums, &e);
45 }
46 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
47 {
48 assert(def);
49 if (!P->types) {
50 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
51 }
52 P->types = psi_plist_add(P->types, &def);
53 }
54 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
55 assert(cnst);
56 if (!P->consts) {
57 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
58 }
59 P->consts = psi_plist_add(P->consts, &cnst);
60
61 }
62 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
63 assert(decl);
64
65 if (psi_decl_is_blacklisted(decl->func->var->name->val)) {
66 psi_decl_free(&decl);
67 return;
68 }
69
70 if (!P->decls) {
71 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
72 }
73 P->decls = psi_plist_add(P->decls, &decl);
74 }
75 static inline void psi_parser_proc_add_decl_extvars(struct psi_parser *P, struct psi_plist *list) {
76 assert(list);
77 if (!P->vars) {
78 P->vars = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
79 }
80 P->vars = psi_plist_add_r(P->vars, psi_plist_count(list), psi_plist_eles(list));
81 free(list);
82 }
83 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
84 assert(impl);
85 if (!P->impls) {
86 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
87 }
88 P->impls = psi_plist_add(P->impls, &impl);
89 }
90
91 /* end code */
92 }
93
94 %code requires {
95 #include "plist.h"
96 #include "types/layout.h"
97
98 #define yytokentype psi_token_type
99
100 #define PSI_T_CAST PSI_T_EQUALS
101 #define PSI_T_POINTER PSI_T_ASTERISK
102
103 struct psi_parser;
104
105 }
106
107 %require "3.0"
108 %language "c"
109 %name-prefix "psi_parser_proc_"
110 %token-table
111 %verbose
112 %glr-parser
113
114 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
115
116 %define api.pure true
117 %define api.token.prefix {PSI_T_}
118 %define api.value.type union
119
120 %define parse.error verbose
121 %define parse.trace true
122
123 %initial-action {
124 }
125
126 %start file
127
128 %token <struct psi_token *> BOOL
129 %token <struct psi_token *> CHAR
130 %token <struct psi_token *> SHORT
131 %token <struct psi_token *> INT
132 %token <struct psi_token *> SIGNED
133 %token <struct psi_token *> UNSIGNED
134 %token <struct psi_token *> LONG
135 %token <struct psi_token *> FLOAT
136 %token <struct psi_token *> DOUBLE
137 %token <struct psi_token *> STRING
138 %token <struct psi_token *> MIXED
139 %token <struct psi_token *> ARRAY
140 %token <struct psi_token *> OBJECT
141 %token <struct psi_token *> CALLABLE
142 %token <struct psi_token *> VOID
143 %token <struct psi_token *> ZVAL
144 %token <struct psi_token *> NULL
145 %token <struct psi_token *> TRUE
146 %token <struct psi_token *> FALSE
147 %token <struct psi_token *> NAME
148 %token <struct psi_token *> NSNAME
149 %token <struct psi_token *> DOLLAR_NAME
150 %token <struct psi_token *> NUMBER
151 %token <struct psi_token *> QUOTED_STRING
152 %token <struct psi_token *> QUOTED_CHAR
153 %token <struct psi_token *> SIZEOF
154 %token <struct psi_token *> VOLATILE
155
156 %token <struct psi_token *> EOF 0 "end of file"
157 %token <struct psi_token *> EOL "end of line"
158 %token <struct psi_token *> EOS ";"
159 %token <struct psi_token *> LPAREN "("
160 %token <struct psi_token *> RPAREN ")"
161 %token <struct psi_token *> COMMA ","
162 %token <struct psi_token *> COLON ":"
163 %token <struct psi_token *> LBRACE "{"
164 %token <struct psi_token *> RBRACE "}"
165 %token <struct psi_token *> LBRACKET "["
166 %token <struct psi_token *> RBRACKET "]"
167 %token <struct psi_token *> EQUALS "="
168 %token <struct psi_token *> HASH "#"
169 %token <struct psi_token *> PIPE "|"
170 %token <struct psi_token *> CARET "^"
171 %token <struct psi_token *> AMPERSAND "&"
172 %token <struct psi_token *> LSHIFT "<<"
173 %token <struct psi_token *> RSHIFT ">>"
174 %token <struct psi_token *> PLUS "+"
175 %token <struct psi_token *> MINUS "-"
176 %token <struct psi_token *> ASTERISK "*"
177 %token <struct psi_token *> SLASH "/"
178 %token <struct psi_token *> MODULO "%"
179 %token <struct psi_token *> LCHEVR "<"
180 %token <struct psi_token *> RCHEVR ">"
181 %token <struct psi_token *> CMP_GE ">="
182 %token <struct psi_token *> CMP_LE "<="
183 %token <struct psi_token *> OR "||"
184 %token <struct psi_token *> AND "&&"
185 %token <struct psi_token *> CMP_EQ "=="
186 %token <struct psi_token *> CMP_NE "!="
187 %token <struct psi_token *> TILDE "~"
188 %token <struct psi_token *> NOT "!"
189 %token <struct psi_token *> PERIOD "."
190 %token <struct psi_token *> BACKSLASH "\\"
191 %token <struct psi_token *> ELLIPSIS "..."
192 %token <struct psi_token *> IIF "?"
193
194 %token <struct psi_token *> PRAGMA
195 %token <struct psi_token *> PRAGMA_ONCE
196 %token <struct psi_token *> LINE
197 %token <struct psi_token *> ERROR
198 %token <struct psi_token *> WARNING
199 %token <struct psi_token *> IF
200 %token <struct psi_token *> IFDEF
201 %token <struct psi_token *> IFNDEF
202 %token <struct psi_token *> ELSE
203 %token <struct psi_token *> ELIF
204 %token <struct psi_token *> ENDIF
205 %token <struct psi_token *> DEFINE
206 %token <struct psi_token *> DEFINED
207 %token <struct psi_token *> UNDEF
208 %token <struct psi_token *> IMPORT
209 %token <struct psi_token *> INCLUDE
210 %token <struct psi_token *> INCLUDE_NEXT
211
212 %token <struct psi_token *> TYPEDEF
213 %token <struct psi_token *> STRUCT
214 %token <struct psi_token *> UNION
215 %token <struct psi_token *> ENUM
216 %token <struct psi_token *> CONST
217 %token <struct psi_token *> LIB
218 %token <struct psi_token *> STATIC
219 %token <struct psi_token *> CALLBACK
220 %token <struct psi_token *> FUNCTION
221 %token <struct psi_token *> LET
222 %token <struct psi_token *> SET
223 %token <struct psi_token *> TEMP
224 %token <struct psi_token *> FREE
225 %token <struct psi_token *> RETURN
226 %token <struct psi_token *> AS
227 %token <struct psi_token *> PRE_ASSERT
228 %token <struct psi_token *> POST_ASSERT
229 %token <struct psi_token *> BOOLVAL
230 %token <struct psi_token *> INTVAL
231 %token <struct psi_token *> STRVAL
232 %token <struct psi_token *> PATHVAL
233 %token <struct psi_token *> STRLEN
234 %token <struct psi_token *> FLOATVAL
235 %token <struct psi_token *> ARRVAL
236 %token <struct psi_token *> OBJVAL
237 %token <struct psi_token *> COUNT
238 %token <struct psi_token *> CALLOC
239 %token <struct psi_token *> TO_BOOL
240 %token <struct psi_token *> TO_INT
241 %token <struct psi_token *> TO_STRING
242 %token <struct psi_token *> TO_FLOAT
243 %token <struct psi_token *> TO_ARRAY
244 %token <struct psi_token *> TO_OBJECT
245
246 %token <struct psi_token *> COMMENT
247 %token <struct psi_token *> WHITESPACE
248 %token <struct psi_token *> NO_WHITESPACE
249 %token <struct psi_token *> CPP_HEADER
250 %token <struct psi_token *> CPP_ATTRIBUTE
251 %token <struct psi_token *> CPP_EXTENSION
252 %token <struct psi_token *> CPP_PASTE
253 %token <struct psi_token *> CPP_INLINE
254 %token <struct psi_token *> CPP_RESTRICT
255 %token <struct psi_token *> CPP_ASM
256
257 /* virtual tokens */
258 %token <struct psi_token *> BSLASH
259 %token <struct psi_token *> LONG_DOUBLE
260 %token <struct psi_token *> INT8
261 %token <struct psi_token *> UINT8
262 %token <struct psi_token *> INT16
263 %token <struct psi_token *> UINT16
264 %token <struct psi_token *> INT32
265 %token <struct psi_token *> UINT32
266 %token <struct psi_token *> INT64
267 %token <struct psi_token *> UINT64
268 %token <struct psi_token *> INT128
269 %token <struct psi_token *> UINT128
270
271
272 %precedence IIF COLON
273 %precedence OR
274 %precedence AND
275 %precedence PIPE
276 %precedence CARET
277 %precedence AMPERSAND
278 %precedence CMP_EQ CMP_NE
279 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
280 %precedence LSHIFT RSHIFT
281 %precedence PLUS MINUS
282 %precedence ASTERISK SLASH MODULO
283 //%precedence NOT TILDE
284 %precedence BINARY
285 %precedence UNARY
286
287 %type <struct psi_token *> lib optional_name enum_name struct_name union_name
288 %destructor {psi_token_free(&$$);} lib optional_name enum_name struct_name union_name
289
290 %type <struct psi_token *> cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token
291 %destructor {} cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token
292
293 %type <struct psi_token *> name_token any_noeol_token binary_op_token unary_op_token
294 %destructor {} name_token any_noeol_token binary_op_token unary_op_token
295
296 %type <struct psi_token *> int_width int_width_types int_signed_types
297 %destructor {psi_token_free(&$$);} int_width int_width_types int_signed_types
298
299 %type <struct psi_token *> signed_long_types signed_short_types int_signed
300 %destructor {} signed_long_types signed_short_types int_signed
301
302 %type <struct psi_cpp_exp *> cpp cpp_exp
303 %destructor {psi_cpp_exp_free(&$$);} cpp cpp_exp
304 %type <struct psi_cpp_macro_decl *> cpp_macro_decl
305 %destructor {psi_cpp_macro_decl_free(&$$);} cpp_macro_decl
306 %type <struct psi_plist *> cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
307 %destructor {psi_plist_free($$);} cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
308 %type <struct psi_num_exp *> cpp_macro_exp
309 %destructor {psi_num_exp_free(&$$);} cpp_macro_exp
310
311 %type <struct psi_token *> impl_def_val_token
312 %destructor {} impl_def_val_token
313
314 %type <struct psi_const *> constant
315 %destructor {psi_const_free(&$$);} constant
316 %type <struct psi_impl_def_val *> impl_def_val
317 %destructor {psi_impl_def_val_free(&$$);} impl_def_val
318
319 %type <struct psi_token *> decl_real_type decl_int_type decl_type_simple
320 %destructor {psi_token_free(&$$);} decl_real_type decl_int_type decl_type_simple
321
322 %type <struct psi_token *> decl_asm quoted_strings
323 %destructor {psi_token_free(&$$);} decl_asm quoted_strings
324
325 %type <struct psi_decl_type *> decl_type qualified_decl_type decl_type_complex
326 %destructor {psi_decl_type_free(&$$);} decl_type qualified_decl_type decl_type_complex
327 %type <struct psi_decl *> decl_stmt decl decl_body decl_func_body decl_functor_body decl_anon_functor_body ignored_decl
328 %destructor {psi_decl_free(&$$);} decl_stmt decl decl_body decl_func_body decl_functor_body decl_anon_functor_body ignored_decl
329 %type <struct psi_decl_arg *> decl_typedef decl_func decl_functor decl_anon_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
330 %destructor {psi_decl_arg_free(&$$);} decl_typedef decl_func decl_functor decl_anon_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
331 %type <struct psi_decl_var *> decl_var
332 %destructor {psi_decl_var_free(&$$);} decl_var
333 %type <struct psi_decl_struct *> decl_struct
334 %destructor {psi_decl_struct_free(&$$);} decl_struct
335 %type <struct psi_decl_union *> decl_union
336 %destructor {psi_decl_union_free(&$$);} decl_union
337 %type <struct psi_decl_enum *> decl_enum
338 %destructor {psi_decl_enum_free(&$$);} decl_enum
339 %type <struct psi_decl_enum_item *> decl_enum_item
340 %destructor {psi_decl_enum_item_free(&$$);} decl_enum_item
341 %type <struct psi_plist *> decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
342 %destructor {psi_plist_free($$);} decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
343
344 %type <struct psi_layout> align_and_size
345 %destructor {} align_and_size
346 %type <struct psi_layout *> decl_layout
347 %destructor {psi_layout_free(&$$);} decl_layout
348
349 %type <struct psi_number *> sizeof sizeof_body sizeof_body_notypes
350 %destructor {psi_number_free(&$$);} sizeof sizeof_body sizeof_body_notypes
351
352 %type <struct psi_impl *> impl
353 %destructor {psi_impl_free(&$$);} impl
354 %type <struct psi_impl_func *> impl_func
355 %destructor {psi_impl_func_free(&$$);} impl_func
356 %type <struct psi_impl_arg *> impl_arg
357 %destructor {psi_impl_arg_free(&$$);} impl_arg
358 %type <struct psi_impl_type *> impl_type impl_type_restricted
359 %destructor {psi_impl_type_free(&$$);} impl_type impl_type_restricted
360 %type <struct psi_impl_var *> impl_var
361 %destructor {psi_impl_var_free(&$$);} impl_var
362
363 %type <struct psi_let_stmt *> let_stmt
364 %destructor {psi_let_stmt_free(&$$);} let_stmt
365 %type <struct psi_let_exp *> let_exp let_exp_byref let_exp_assign
366 %destructor {psi_let_exp_free(&$$);} let_exp let_exp_byref let_exp_assign
367 %type <struct psi_let_calloc *> let_calloc
368 %destructor {psi_let_calloc_free(&$$);} let_calloc
369 %type <struct psi_let_callback *> let_callback
370 %destructor {psi_let_callback_free(&$$);} let_callback
371 %type <struct psi_let_func *> let_func
372 %destructor {psi_let_func_free(&$$);} let_func
373 %type <struct psi_set_stmt *> set_stmt
374 %destructor {psi_set_stmt_free(&$$);} set_stmt
375 %type <struct psi_set_exp *> set_exp
376 %destructor {psi_set_exp_free(&$$);} set_exp
377 %type <struct psi_set_func *> set_func
378 %destructor {psi_set_func_free(&$$);} set_func
379 %type <struct psi_assert_stmt *> assert_stmt
380 %destructor {psi_assert_stmt_free(&$$);} assert_stmt
381 %type <struct psi_return_stmt *> return_stmt
382 %destructor {psi_return_stmt_free(&$$);} return_stmt
383 %type <struct psi_return_exp *> return_exp
384 %destructor {psi_return_exp_free(&$$);} return_exp
385 %type <struct psi_free_stmt *> free_stmt
386 %destructor {psi_free_stmt_free(&$$);} free_stmt
387 %type <struct psi_free_exp *> free_exp
388 %destructor {psi_free_exp_free(&$$);} free_exp
389
390 %type <struct psi_token **> impl_stmt
391 %destructor {psi_impl_stmt_free(&$$);} impl_stmt
392 %type <struct psi_token *> impl_type_token impl_type_restricted_token impl_type_extended_token callback_rval let_func_token set_func_token assert_stmt_token
393 %destructor {} impl_type_token impl_type_restricted_token impl_type_extended_token callback_rval let_func_token set_func_token assert_stmt_token
394 %type <struct psi_plist *> impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
395 %destructor {psi_plist_free($$);} impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
396
397 %type <struct psi_num_exp *> num_exp
398 %destructor {psi_num_exp_free(&$$);} num_exp
399 %type <struct psi_number *> number
400 %destructor {psi_number_free(&$$);} number
401
402 %type <size_t> indirection pointers asterisks array_size
403 %destructor {} indirection pointers asterisks array_size
404 %type <bool> reference
405 %destructor {} reference
406
407 %%
408
409 /* rules */
410
411
412 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
413 unary_op_token: TILDE | NOT | PLUS | MINUS ;
414 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | MIXED | ARRAY | OBJECT | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | AS | let_func_token | set_func_token;
415 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
416 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
417
418
419 file:
420 %empty
421 | blocks
422 ;
423 blocks:
424 block
425 | blocks block
426 ;
427 block:
428 EOS
429 | EOL
430 | COMMENT
431 | cpp {
432 if ($cpp) {
433 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
434 psi_cpp_exp_free(&$cpp);
435 }
436 }
437 | lib {
438 char *libname = strdup($lib->text->val);
439 P->file.libnames = psi_plist_add(P->file.libnames, &libname);
440 }
441 | constant {
442 psi_parser_proc_add_const(P, $constant);
443 }
444 | decl_stmt {
445 psi_parser_proc_add_decl(P, $decl_stmt);
446 }
447 | decl_extvar_stmt[list] {
448 psi_parser_proc_add_decl_extvars(P, $list);
449 }
450 | ignored_decl {
451 if (P->flags & PSI_DEBUG) {
452 P->error(PSI_DATA(P), $ignored_decl->func->token, PSI_NOTICE, "Ignored decl: %s", $ignored_decl->func->var->name->val);
453 }
454 psi_decl_free(&$ignored_decl);
455 }
456 | decl_typedef[def] {
457 psi_parser_proc_add_typedef(P, $def);
458 }
459 | decl_struct[struct] {
460 psi_parser_proc_add_struct(P, $struct);
461 }
462 | decl_union[union] {
463 psi_parser_proc_add_union(P, $union);
464 }
465 | decl_enum[enum] {
466 psi_parser_proc_add_enum(P, $enum);
467 }
468 | impl {
469 psi_parser_proc_add_impl(P, $impl);
470 }
471 ;
472
473 lib:
474 LIB QUOTED_STRING EOS {
475 $lib = $QUOTED_STRING;
476 }
477 ;
478
479 cpp:
480 HASH EOL {
481 $cpp = NULL;
482 }
483 | HASH cpp_exp[exp] EOL {
484 $cpp = $exp;
485 }
486 ;
487
488 cpp_exp[exp]:
489 cpp_message_token cpp_macro_decl_tokens[tokens] {
490 if ($tokens) {
491 struct psi_token *msg = NULL;
492
493 if (psi_plist_get($tokens, 0, &msg)) {
494 size_t index = 1;
495 struct psi_token *next;
496
497 msg = psi_token_copy(msg);
498 while (psi_plist_get($tokens, index++, &next)) {
499 struct psi_token *old = msg;
500 msg = psi_token_cat(" ", 2, msg, next);
501 psi_token_free(&old);
502 }
503 }
504 psi_plist_free($tokens);
505
506 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
507 } else {
508 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
509 }
510 $exp->token = psi_token_copy($cpp_message_token);
511 }
512 | cpp_include_token[INCLUDE] cpp_header_token {
513 $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
514 $exp->token = psi_token_copy($INCLUDE);
515 }
516 | cpp_no_arg_token {
517 $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
518 $exp->token = psi_token_copy($cpp_no_arg_token);
519 }
520 | cpp_name_arg_token any_noeol_token[name_token] {
521 $name_token->type = PSI_T_NAME;
522 $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
523 $exp->token = psi_token_copy($cpp_name_arg_token);
524 }
525 | DEFINE cpp_macro_decl {
526 $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
527 $exp->token = psi_token_copy($DEFINE);
528 }
529 | cpp_exp_arg_token cpp_macro_exp {
530 $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
531 $exp->token = psi_token_copy($cpp_exp_arg_token);
532 }
533 | PRAGMA_ONCE {
534 $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
535 $exp->token = psi_token_copy($PRAGMA_ONCE);
536 }
537 | cpp_ignored_token cpp_macro_decl_tokens[tokens] {
538 psi_plist_free($tokens);
539 $exp = NULL;
540 }
541 ;
542
543 cpp_ignored_token:
544 LINE
545 | PRAGMA
546 ;
547
548 cpp_message_token:
549 ERROR
550 | WARNING
551 ;
552
553 cpp_include_token:
554 IMPORT
555 | INCLUDE
556 | INCLUDE_NEXT
557 ;
558
559 cpp_header_token:
560 QUOTED_STRING
561 | CPP_HEADER
562 ;
563
564 cpp_no_arg_token:
565 ELSE
566 | ENDIF
567 ;
568
569 cpp_name_arg_token:
570 IFDEF
571 | IFNDEF
572 | UNDEF
573 ;
574
575 cpp_exp_arg_token:
576 IF
577 | ELIF
578 ;
579
580 cpp_macro_decl[macro]:
581 any_noeol_token[name_token] cpp_macro_decl_tokens %dprec 1 {
582 $name_token->type = PSI_T_NAME;
583 $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
584 $macro->token = psi_token_copy($name_token);
585 }
586 | name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens %dprec 2 {
587 $name_token->type = PSI_T_NAME;
588 $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
589 $macro->token = psi_token_copy($name_token);
590 }
591 | name_token cpp_macro_exp[num_exp] %dprec 2 {
592 $name_token->type = PSI_T_NAME;
593 $macro = psi_cpp_macro_decl_init(NULL, psi_num_exp_tokens($num_exp, NULL), $num_exp);
594 $macro->token = psi_token_copy($name_token);
595 }
596 | name_token quoted_strings[strings] %dprec 2 {
597 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_token_free);
598 $name_token->type = PSI_T_NAME;
599 $macro = psi_cpp_macro_decl_init(NULL, psi_plist_add(list, &$strings), NULL);
600 $macro->token = psi_token_copy($name_token);
601 }
602 ;
603
604 cpp_macro_sig[sig]:
605 %empty {
606 $sig = psi_plist_init(NULL);
607 }
608 | ELLIPSIS {
609 $sig = psi_plist_init(NULL); /* FIXME */
610 }
611 | cpp_macro_sig_args
612 | cpp_macro_sig_args[args] COMMA ELLIPSIS {
613 $sig = $args;
614 }
615 ;
616
617 cpp_macro_sig_args[args]:
618 name_token {
619 $name_token = psi_token_copy($name_token);
620 $name_token->type = PSI_T_NAME;
621 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
622 }
623 | cpp_macro_sig_args[args_] COMMA name_token {
624 $name_token = psi_token_copy($name_token);
625 $name_token->type = PSI_T_NAME;
626 $args = psi_plist_add($args_, &$name_token);
627 }
628 ;
629
630 cpp_macro_decl_tokens[tokens]:
631 %empty {
632 $tokens = NULL;
633 }
634 | cpp_macro_decl_token_list
635 ;
636
637 cpp_macro_decl_token_list[tokens]:
638 any_noeol_token[token] {
639 $token = psi_token_copy($token);
640 $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
641 }
642 | cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
643 $token = psi_token_copy($token);
644 $tokens = psi_plist_add($tokens_, &$token);
645 }
646 ;
647
648 cpp_macro_exp[exp]:
649 LPAREN cpp_macro_exp[exp_] RPAREN {
650 $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
651 $exp->token = psi_token_copy($LPAREN);
652 }
653 | unary_op_token cpp_macro_exp[exp_] %prec UNARY {
654 $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
655 $exp->token = psi_token_copy($unary_op_token);
656 }
657 | cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
658 $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
659 $exp->token = psi_token_copy($binary_op_token);
660 }
661 | cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
662 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
663 $exp->token = psi_token_copy($IIF);
664 }
665
666 | DEFINED name_token {
667 {
668 uint8_t exists;
669
670 $name_token->type = PSI_T_NAME;
671 exists = psi_cpp_defined(P->preproc, $name_token);
672 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINED, &exists, 0));
673 $exp->token = psi_token_copy($DEFINED);
674 $exp->data.n->token = psi_token_copy($name_token);
675 }
676 }
677 | DEFINED LPAREN name_token RPAREN {
678 {
679 uint8_t exists;
680
681 $name_token->type = PSI_T_NAME;
682 exists = psi_cpp_defined(P->preproc, $name_token);
683 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINED, &exists, 0));
684 $exp->token = psi_token_copy($DEFINED);
685 $exp->data.n->token = psi_token_copy($name_token);
686 }
687 }
688 | NUMBER {
689 $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
690 $exp->token = psi_token_copy($NUMBER);
691 $exp->data.n->token = psi_token_copy($NUMBER);
692 }
693 | QUOTED_CHAR {
694 $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
695 $exp->token = psi_token_copy($QUOTED_CHAR);
696 $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
697 }
698 | sizeof {
699 $exp = psi_num_exp_init_num($sizeof);
700 $exp->token = psi_token_copy($sizeof->token);
701 }
702 | name_token {
703 $name_token->type = PSI_T_NAME;
704 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
705 $exp->token = psi_token_copy($name_token);
706 $exp->data.n->token = psi_token_copy($name_token);
707 }
708 | name_token LPAREN cpp_macro_call_args RPAREN {
709 $name_token->type = PSI_T_NAME;
710 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
711 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
712 $exp->token = psi_token_copy($name_token);
713 $exp->data.n->token = psi_token_copy($name_token);
714 $exp->data.n->data.call->token = psi_token_copy($name_token);
715 }
716 ;
717
718 cpp_macro_call_args[args]:
719 %empty {
720 $args = NULL;
721 }
722 | cpp_macro_call_arg_list
723 ;
724
725 cpp_macro_call_arg_list[args]:
726 CPP_HEADER {
727 /* TODO: clang include test macros */
728 uint8_t no = 1;
729 struct psi_num_exp *exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &no, 0));
730 exp->token = psi_token_copy($CPP_HEADER);
731 exp->data.n->token = psi_token_copy($CPP_HEADER);
732 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free), &exp);
733 }
734 | cpp_macro_exp {
735 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
736 &$cpp_macro_exp);
737 }
738 | cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
739 $args = psi_plist_add($args_, &$cpp_macro_exp);
740 }
741 ;
742
743 constant[const]:
744 CONST impl_type_restricted[type] NSNAME EQUALS impl_def_val EOS {
745 $const = psi_const_init($type, $NSNAME->text, $impl_def_val);
746 $const->token = psi_token_copy($NSNAME);
747 }
748 | CONST NSNAME EQUALS impl_def_val EOS {
749 $const = psi_const_init(NULL, $NSNAME->text, $impl_def_val);
750 $const->token = psi_token_copy($NSNAME);
751 }
752 ;
753
754 impl_def_val[val]:
755 impl_def_val_token[token] %dprec 2 {
756 $val = psi_impl_def_val_init($token->type, $token->text);
757 $val->token = psi_token_copy($token);
758 }
759 | num_exp[num] %dprec 1 {
760 $val = psi_impl_def_val_init(PSI_T_NUMBER, $num);
761 $val->token = psi_token_copy($num->token);
762 }
763 | quoted_strings[token] {
764 $val = psi_impl_def_val_init($token->type, $token->text);
765 $val->token = $token;
766 }
767 ;
768
769 impl_def_val_token:
770 NULL
771 | TRUE
772 | FALSE
773 ;
774
775 decl_typedef[def]:
776 TYPEDEF typedef[def_] EOS {
777 $def = $def_;
778 }
779 /*
780 | TYPEDEF VOID name_token EOS {
781 $def = psi_decl_arg_init(
782 psi_decl_type_init(PSI_T_VOID, $VOID->text),
783 psi_decl_var_init($name_token->text, 0, 0)
784 );
785 $def->token = psi_token_copy($VOID);
786 $def->type->token = psi_token_copy($VOID);
787 $def->var->token = psi_token_copy($name_token);
788 }
789 */
790 | CPP_EXTENSION TYPEDEF typedef[def_] EOS {
791 $def = $def_;
792 }
793 ;
794
795 typedef[def]:
796 typedef_decl {
797 $def = $typedef_decl;
798 }
799 | CPP_EXTENSION typedef_decl {
800 $def = $typedef_decl;
801 }
802 ;
803
804 typedef_anon[def]:
805 typedef_anon_decl {
806 $def = $typedef_anon_decl;
807 }
808 | CPP_EXTENSION typedef_anon_decl {
809 $def = $typedef_anon_decl;
810 }
811 ;
812
813 typedef_decl[def]:
814 decl_arg
815 | decl_func_body[decl] {
816 $def = psi_decl_arg_init(
817 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
818 psi_decl_var_copy($decl->func->var)
819 );
820 $def->type->token = psi_token_copy($decl->func->token);
821 $def->type->real.func = $decl;
822 }
823 | decl_enum[enum] name_token {
824 $name_token->type = PSI_T_NAME;
825 $def = psi_decl_arg_init(
826 psi_decl_type_init(PSI_T_ENUM, $enum->name),
827 psi_decl_var_init($name_token->text, 0, 0)
828 );
829 $def->var->token = psi_token_copy($name_token);
830 $def->type->token = psi_token_copy($enum->token);
831 $def->type->real.enm = $enum;
832 psi_parser_proc_add_enum(P, $enum);
833 }
834 | struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
835 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
836 $def->type->token = $struct;
837 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
838 $def->type->real.strct->token = psi_token_copy($struct);
839 $def->type->real.strct->align = $as.pos;
840 $def->type->real.strct->size = $as.len;
841 psi_parser_proc_add_struct(P, $def->type->real.strct);
842 }
843 | union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
844 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
845 $def->type->token = $union;
846 $def->type->real.unn = psi_decl_union_init($union->text, $args);
847 $def->type->real.unn->token = psi_token_copy($union);
848 $def->type->real.unn->align = $as.pos;
849 $def->type->real.unn->size = $as.len;
850 psi_parser_proc_add_union(P, $def->type->real.unn);
851 }
852 ;
853
854 typedef_anon_decl[def]:
855 typedef_decl %dprec 2
856 | qualified_decl_type[type] %dprec 1 {
857 $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
858 $def->var->token = psi_token_copy($type->token);
859 }
860 | decl_enum[enum] {
861 $def = psi_decl_arg_init(
862 psi_decl_type_init(PSI_T_ENUM, $enum->name),
863 psi_decl_var_init(NULL, 0, 0)
864 );
865 $def->var->token = psi_token_copy($enum->token);
866 $def->type->token = psi_token_copy($enum->token);
867 $def->type->real.enm = $enum;
868 psi_parser_proc_add_enum(P, $enum);
869 }
870 | struct_name[struct] align_and_size[as] struct_args_block[args] {
871 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
872 $def->type->token = $struct;
873 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
874 $def->type->real.strct->token = psi_token_copy($struct);
875 $def->type->real.strct->align = $as.pos;
876 $def->type->real.strct->size = $as.len;
877 psi_parser_proc_add_struct(P, $def->type->real.strct);
878 }
879 | union_name[union] align_and_size[as] struct_args_block[args] {
880 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
881 $def->type->token = $union;
882 $def->type->real.unn = psi_decl_union_init($union->text, $args);
883 $def->type->real.unn->token = psi_token_copy($union);
884 $def->type->real.unn->align = $as.pos;
885 $def->type->real.unn->size = $as.len;
886 psi_parser_proc_add_union(P, $def->type->real.unn);
887 }
888 ;
889
890 qualified_decl_type[type]:
891 decl_type
892 | decl_type_qualifier_token decl_type[type_] {
893 $type = $type_;
894 }
895 | qualified_decl_type[type_] decl_type_qualifier_token {
896 $type = $type_;
897 }
898 ;
899
900 decl_type_qualifier_token:
901 CONST
902 | VOLATILE
903 ;
904
905 decl_type[type]:
906 decl_type_simple[token] {
907 $type = psi_decl_type_init($token->type, $token->text);
908 $type->token = $token;
909 }
910 | decl_type_complex
911 ;
912
913 decl_type_complex[type]:
914 STRUCT[token] name_token {
915 $name_token->type = PSI_T_NAME;
916 $type = psi_decl_type_init($token->type, $name_token->text);
917 $type->token = psi_token_copy($name_token);
918 }
919 | UNION[token] name_token {
920 $name_token->type = PSI_T_NAME;
921 $type = psi_decl_type_init($token->type, $name_token->text);
922 $type->token = psi_token_copy($name_token);
923 }
924 | ENUM[token] name_token {
925 $name_token->type = PSI_T_NAME;
926 $type = psi_decl_type_init($token->type, $name_token->text);
927 $type->token = psi_token_copy($name_token);
928 }
929 ;
930
931 decl_type_simple[type]:
932 decl_int_type
933 | decl_real_type
934 | NAME[type_] {
935 $type = psi_token_copy($type_);
936 }
937 | VOID[type_] {
938 $type = psi_token_copy($type_);
939 }
940 ;
941
942 decl_real_type[type]: /* allocated, so free, if set */
943 FLOAT[type_] {
944 $type = psi_token_copy($type_);
945 }
946 | DOUBLE[type_] {
947 $type = psi_token_copy($type_);
948 }
949 | LONG DOUBLE {
950 $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
951 }
952 ;
953
954 int_signed[i]:
955 SIGNED
956 | UNSIGNED
957 ;
958
959 int_width[i]: /* allocated, so free, if set */
960 SHORT {
961 $i = psi_token_copy($SHORT);
962 }
963 | LONG {
964 $i = psi_token_copy($LONG);
965 }
966 | LONG[l1] LONG[l2] {
967 $i = psi_token_cat(" ", 2, $l1, $l2);
968 }
969 ;
970
971 decl_int_type[type]: /* allocated, so free, if set */
972 CHAR {
973 $type = psi_token_copy($CHAR);
974 }
975 | INT {
976 $type = psi_token_copy($INT);
977 }
978 | int_signed int_signed_types {
979 if ($2) {
980 $type = psi_token_cat(" ", 2, $1, $2);
981 psi_token_free(&$2);
982 } else {
983 $type = psi_token_copy($1);
984 }
985 }
986 | int_width int_width_types {
987 if ($2) {
988 $type = psi_token_cat(" ", 2, $1, $2);
989 psi_token_free(&$1);
990 psi_token_free(&$2);
991 } else {
992 $type = $1;
993 }
994 }
995 ;
996
997 int_signed_types[type]: /* allocated, so free, if set */
998 %empty {
999 $type = NULL;
1000 }
1001 | NAME {
1002 $type = psi_token_copy($NAME);
1003 }
1004 | CHAR {
1005 $type = psi_token_copy($CHAR);
1006 }
1007 | SHORT signed_short_types {
1008 if ($2) {
1009 $type = psi_token_cat(" ", 2, $1, $2);
1010 } else {
1011 $type = psi_token_copy($1);
1012 }
1013 }
1014 | INT {
1015 $type = psi_token_copy($INT);
1016 }
1017 | LONG signed_long_types {
1018 if ($2) {
1019 $type = psi_token_cat(" ", 2, $1, $2);
1020 } else {
1021 $type = psi_token_copy($1);
1022 }
1023 }
1024 ;
1025
1026 signed_short_types[type]:
1027 %empty {
1028 $type = NULL;
1029 }
1030 | INT
1031 ;
1032 signed_long_types[type]:
1033 %empty {
1034 $type = NULL;
1035 }
1036 | INT
1037 | LONG
1038 | LONG INT
1039 ;
1040
1041 int_width_types[type]: /* allocated, so free, if set */
1042 %empty {
1043 $type = NULL;
1044 }
1045 | INT {
1046 $type = psi_token_copy($INT);
1047 }
1048 | int_signed int_signed_types {
1049 if ($2) {
1050 $type = psi_token_cat(" ", 2, $1, $2);
1051 psi_token_free(&$2);
1052 } else {
1053 $type = psi_token_copy($1);
1054 }
1055 }
1056 ;
1057
1058 decl_stmt:
1059 decl decl_asm EOS {
1060 $decl_stmt = $decl;
1061 if ($decl_asm) {
1062 $decl->redir = zend_string_copy($decl_asm->text);
1063 psi_token_free(&$decl_asm);
1064 }
1065 }
1066 | CPP_EXTENSION decl decl_asm EOS {
1067 $decl_stmt = $decl;
1068 if ($decl_asm) {
1069 $decl->redir = zend_string_copy($decl_asm->text);
1070 psi_token_free(&$decl_asm);
1071 }
1072 }
1073 ;
1074
1075 decl_asm:
1076 %empty {
1077 $decl_asm = NULL;
1078 }
1079 | CPP_ASM LPAREN quoted_strings RPAREN {
1080 $decl_asm = $quoted_strings;
1081 }
1082 ;
1083
1084 quoted_strings[strings]:
1085 QUOTED_STRING {
1086 $strings = psi_token_copy($QUOTED_STRING);
1087 }
1088 | quoted_strings[strings_] QUOTED_STRING {
1089 $strings = psi_token_cat("", 2, $strings_, $QUOTED_STRING);
1090 psi_token_free(&$strings_);
1091 }
1092 ;
1093
1094 decl_extvar_stmt[list]:
1095 NAME decl_arg decl_extvar_list[vars] decl_asm EOS {
1096 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
1097
1098 if ($vars) {
1099 size_t i = 0;
1100 struct psi_decl_var *var;
1101
1102 while (psi_plist_get($vars, i++, &var)) {
1103 if (psi_decl_extvar_is_blacklisted(var->name->val)) {
1104 psi_decl_var_free(&var);
1105 } else {
1106 struct psi_decl_extvar *evar = psi_decl_extvar_init(
1107 psi_decl_arg_init(psi_decl_type_copy($decl_arg->type), var));
1108 list = psi_plist_add(list, &evar);
1109 }
1110 }
1111 free($vars);
1112 }
1113
1114 if (psi_decl_extvar_is_blacklisted($decl_arg->var->name->val)) {
1115 psi_decl_arg_free(&$decl_arg);
1116 } else {
1117 struct psi_decl_extvar *evar = psi_decl_extvar_init($decl_arg);
1118
1119 if ($decl_asm) {
1120 evar->redir = zend_string_copy($decl_asm->text);
1121 psi_token_free(&$decl_asm);
1122 }
1123 list = psi_plist_add(list, &evar);
1124 }
1125
1126 $list = list;
1127 }
1128 ;
1129
1130 decl_extvar_list[list]:
1131 %empty {
1132 $list = NULL;
1133 }
1134 | COMMA decl_vars {
1135 $list = $decl_vars;
1136 }
1137 ;
1138
1139 decl_vars[vars]:
1140 decl_var[var] {
1141 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1142 }
1143 | decl_vars[vars_] COMMA decl_var[var] {
1144 $vars = psi_plist_add($vars_, &$var);
1145 }
1146 ;
1147
1148 ignored_decl:
1149 ignored_decl_qualifiers decl_body ignored_decl_body {
1150 $ignored_decl = $decl_body;
1151 }
1152 ;
1153
1154 ignored_decl_qualifiers:
1155 STATIC
1156 | STATIC CPP_INLINE
1157 | CPP_EXTENSION CPP_INLINE
1158 | CPP_EXTENSION STATIC CPP_INLINE
1159 | CPP_INLINE
1160 | NAME CPP_INLINE
1161 ;
1162
1163 ignored_decl_body:
1164 LBRACE ignored_decl_body_stmts RBRACE
1165 ;
1166
1167 ignored_decl_body_stmts:
1168 ignored_decl_body_stmt
1169 | ignored_decl_body_stmts ignored_decl_body_stmt
1170 ;
1171
1172 ignored_decl_body_stmt:
1173 any_nobrace_token
1174 | ignored_decl_body
1175 ;
1176
1177 decl:
1178 decl_body
1179 | NAME[abi] decl_body {
1180 $decl = $decl_body;
1181 $decl->abi = psi_decl_abi_init($abi->text);
1182 }
1183 ;
1184
1185 decl_body:
1186 decl_func_body
1187 | decl_functor_body
1188 ;
1189
1190 decl_func_body[decl]:
1191 decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1192 $decl = psi_decl_init($func, $args);
1193 if ($as) {
1194 $decl->func->var->pointer_level += 1;
1195 $decl->func->var->array_size = $as;
1196 }
1197 }
1198 | decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1199 $decl = psi_decl_init($func, $args);
1200 $decl->varargs = 1;
1201 if ($as) {
1202 $decl->func->var->pointer_level += 1;
1203 $decl->func->var->array_size = $as;
1204 }
1205 }
1206 ;
1207
1208 decl_functor_body[decl]:
1209 decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1210 $decl = psi_decl_init($func, $args);
1211 if ($as) {
1212 $decl->func->var->pointer_level += 1;
1213 $decl->func->var->array_size = $as;
1214 }
1215 }
1216 | decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1217 $decl = psi_decl_init($func, $args);
1218 $decl->varargs = 1;
1219 if ($as) {
1220 $decl->func->var->pointer_level += 1;
1221 $decl->func->var->array_size = $as;
1222 }
1223 }
1224 | qualified_decl_type[rval_type] indirection[i] LPAREN indirection[unused1] name_token[NAME] LPAREN decl_args[args] RPAREN RPAREN LPAREN decl_args[rval_args] RPAREN array_size[as] {
1225 (void) $unused1;
1226 $NAME->type = PSI_T_NAME;
1227
1228 struct psi_token *type_token = psi_token_append("@", psi_token_copy($NAME), 1, "rval");
1229 struct psi_decl_arg *rval_func = psi_decl_arg_init($rval_type, psi_decl_var_init(type_token->text, $i, 0));
1230 struct psi_decl *rval_decl = psi_decl_init(rval_func, $rval_args);
1231
1232 rval_func->var->token = psi_token_copy(type_token);
1233 rval_func->token = psi_token_copy(type_token);
1234 if ($as) {
1235 rval_func->var->pointer_level += 1;
1236 rval_func->var->array_size = $as;
1237 }
1238
1239 struct psi_decl_type *type = psi_decl_type_init(PSI_T_FUNCTION, type_token->text);
1240 struct psi_decl_arg *func = psi_decl_arg_init(type, psi_decl_var_init($NAME->text, 1, 0));
1241
1242 type->real.func = rval_decl;
1243 func->var->token = psi_token_copy($NAME);
1244 func->token = psi_token_copy($NAME);
1245
1246 $decl = psi_decl_init(func, $args);
1247 }
1248 | qualified_decl_type[rval_type] indirection[i] LPAREN indirection[unused1] LPAREN indirection[unused2] name_token[NAME] RPAREN LPAREN decl_args[args] RPAREN RPAREN LPAREN decl_args[rval_args] RPAREN array_size[as] {
1249 (void) $unused1;
1250 (void) $unused2;
1251 $NAME->type = PSI_T_NAME;
1252
1253 struct psi_token *type_token = psi_token_append("@", psi_token_copy($NAME), 1, "rval");
1254 struct psi_decl_arg *rval_func = psi_decl_arg_init($rval_type, psi_decl_var_init(type_token->text, $i, 0));
1255 struct psi_decl *rval_decl = psi_decl_init(rval_func, $rval_args);
1256
1257 rval_func->var->token = psi_token_copy(type_token);
1258 rval_func->token = psi_token_copy(type_token);
1259 if ($as) {
1260 rval_func->var->pointer_level += 1;
1261 rval_func->var->array_size = $as;
1262 }
1263
1264 struct psi_decl_type *type = psi_decl_type_init(PSI_T_FUNCTION, type_token->text);
1265 struct psi_decl_arg *func = psi_decl_arg_init(type, psi_decl_var_init($NAME->text, 1, 0));
1266
1267 type->real.func = rval_decl;
1268 func->var->token = psi_token_copy($NAME);
1269 func->token = psi_token_copy($NAME);
1270 type->token = type_token;
1271
1272 $decl = psi_decl_init(func, $args);
1273 }
1274 ;
1275
1276 decl_anon_functor_body[decl]:
1277 decl_anon_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1278 $decl = psi_decl_init($func, $args);
1279 if ($as) {
1280 $decl->func->var->pointer_level += 1;
1281 $decl->func->var->array_size = $as;
1282 }
1283 }
1284 | decl_anon_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1285 $decl = psi_decl_init($func, $args);
1286 $decl->varargs = 1;
1287 if ($as) {
1288 $decl->func->var->pointer_level += 1;
1289 $decl->func->var->array_size = $as;
1290 }
1291 }
1292 ;
1293
1294 decl_functor[arg]:
1295 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1296 (void) $unused1;
1297 $NAME->type = PSI_T_NAME;
1298 $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1299 $arg->var->token = psi_token_copy($NAME);
1300 $arg->token = psi_token_copy($NAME);
1301 }
1302
1303 /*
1304 | CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1305 (void) $unused1;
1306 $NAME->type = PSI_T_NAME;
1307 $arg = psi_decl_arg_init(
1308 psi_decl_type_init($VOID->type, $VOID->text),
1309 psi_decl_var_init($NAME->text, $pointers, 0)
1310 );
1311 $arg->type->token = psi_token_copy($VOID);
1312 $arg->var->token = psi_token_copy($NAME);
1313 $arg->token = psi_token_copy($NAME);
1314 }
1315 | VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1316 (void) $unused1;
1317 $NAME->type = PSI_T_NAME;
1318 $arg = psi_decl_arg_init(
1319 psi_decl_type_init($VOID->type, $VOID->text),
1320 psi_decl_var_init($NAME->text, $pointers, 0)
1321 );
1322 $arg->type->token = psi_token_copy($VOID);
1323 $arg->var->token = psi_token_copy($NAME);
1324 $arg->token = psi_token_copy($NAME);
1325 }
1326 | VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1327 (void) $unused1;
1328 $NAME->type = PSI_T_NAME;
1329 $arg = psi_decl_arg_init(
1330 psi_decl_type_init($VOID->type, $VOID->text),
1331 psi_decl_var_init($NAME->text, 0, 0)
1332 );
1333 $arg->type->token = psi_token_copy($VOID);
1334 $arg->var->token = psi_token_copy($NAME);
1335 $arg->token = psi_token_copy($NAME);
1336 }
1337 */
1338 ;
1339
1340 decl_anon_functor[arg]:
1341 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] RPAREN {
1342 (void) $unused1;
1343 $arg = psi_decl_arg_init($type, psi_decl_var_init(NULL, $i, 0));
1344 $arg->var->token = psi_token_copy($LPAREN);
1345 $arg->token = psi_token_copy($LPAREN);
1346 }
1347 /*
1348 | CONST VOID pointers LPAREN indirection[unused1] RPAREN {
1349 (void) $unused1;
1350 $arg = psi_decl_arg_init(
1351 psi_decl_type_init($VOID->type, $VOID->text),
1352 psi_decl_var_init(NULL, $pointers, 0)
1353 );
1354 $arg->type->token = psi_token_copy($VOID);
1355 $arg->var->token = psi_token_copy($VOID);
1356 $arg->token = psi_token_copy($VOID);
1357 }
1358 | VOID pointers LPAREN indirection[unused1] RPAREN {
1359 (void) $unused1;
1360 $arg = psi_decl_arg_init(
1361 psi_decl_type_init($VOID->type, $VOID->text),
1362 psi_decl_var_init(NULL, $pointers, 0)
1363 );
1364 $arg->type->token = psi_token_copy($VOID);
1365 $arg->var->token = psi_token_copy($VOID);
1366 $arg->token = psi_token_copy($VOID);
1367 }
1368 | VOID LPAREN indirection[unused1] RPAREN {
1369 (void) $unused1;
1370 $arg = psi_decl_arg_init(
1371 psi_decl_type_init($VOID->type, $VOID->text),
1372 psi_decl_var_init(NULL, 0, 0)
1373 );
1374 $arg->type->token = psi_token_copy($VOID);
1375 $arg->var->token = psi_token_copy($VOID);
1376 $arg->token = psi_token_copy($VOID);
1377 }
1378 */
1379 ;
1380
1381 decl_func[func]:
1382 decl_arg
1383 /*
1384 | VOID name_token[NAME] {
1385 $func = psi_decl_arg_init(
1386 psi_decl_type_init($VOID->type, $VOID->text),
1387 psi_decl_var_init($NAME->text, 0, 0)
1388 );
1389 $func->type->token = psi_token_copy($VOID);
1390 $func->var->token = psi_token_copy($NAME);
1391 $func->token = psi_token_copy($NAME);
1392 }
1393 */
1394 ;
1395
1396 decl_args[args]:
1397 %empty {
1398 $args = NULL;
1399 }
1400 | VOID %dprec 2 {
1401 $args = NULL;
1402 }
1403 | decl_arg_list[args_] %dprec 1 {
1404 $args = $args_;
1405 }
1406 ;
1407
1408 decl_arg_list[args]:
1409 decl_anon_arg[arg] {
1410 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1411 }
1412 | decl_arg_list[args_] COMMA decl_anon_arg[arg] {
1413 $args = psi_plist_add($args_, &$arg);
1414 }
1415 ;
1416
1417 decl_anon_arg[arg]:
1418 decl_anon_functor_body[decl] {
1419 char digest[17];
1420 struct psi_token *name;
1421
1422 psi_token_hash($decl->func->token, digest);
1423 name = psi_token_append("@", psi_token_copy($decl->func->token), 2, "funct", digest);
1424
1425 $arg = psi_decl_arg_init(
1426 psi_decl_type_init(PSI_T_FUNCTION, name->text),
1427 psi_decl_var_copy($decl->func->var)
1428 );
1429 $arg->token = name;
1430 $arg->type->token = psi_token_copy($decl->func->token);
1431 $arg->type->real.func = $decl;
1432 }
1433 | decl_arg %dprec 2 {
1434 $arg = $decl_arg;
1435 }
1436 | qualified_decl_type[type] indirection array_size[as] %dprec 1 {
1437 $arg = psi_decl_arg_init(
1438 $type,
1439 psi_decl_var_init(NULL, $indirection, $as)
1440 );
1441 }
1442 /*
1443 | CONST VOID pointers {
1444 $arg = psi_decl_arg_init(
1445 psi_decl_type_init($VOID->type, $VOID->text),
1446 psi_decl_var_init(NULL, $pointers, 0)
1447 );
1448 $arg->type->token = psi_token_copy($VOID);
1449 $arg->var->token = psi_token_copy($VOID);
1450 $arg->token = psi_token_copy($VOID);
1451 }
1452 | VOID pointers {
1453 $arg = psi_decl_arg_init(
1454 psi_decl_type_init($VOID->type, $VOID->text),
1455 psi_decl_var_init(NULL, $pointers, 0)
1456 );
1457 $arg->type->token = psi_token_copy($VOID);
1458 $arg->var->token = psi_token_copy($VOID);
1459 $arg->token = psi_token_copy($VOID);
1460 }
1461 */
1462 ;
1463
1464 decl_arg[arg]:
1465 decl_functor_body[decl] {
1466 $arg = psi_decl_arg_init(
1467 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1468 psi_decl_var_copy($decl->func->var)
1469 );
1470 $arg->type->token = psi_token_copy($decl->func->token);
1471 $arg->type->real.func = $decl;
1472 }
1473 | qualified_decl_type[type] decl_var[var] {
1474 $arg = psi_decl_arg_init($type, $var);
1475 }
1476 /*
1477 | CONST VOID pointers name_token[NAME] {
1478 $NAME->type = PSI_T_NAME;
1479 $arg = psi_decl_arg_init(
1480 psi_decl_type_init($VOID->type, $VOID->text),
1481 psi_decl_var_init($NAME->text, $pointers, 0)
1482 );
1483 $arg->type->token = psi_token_copy($VOID);
1484 $arg->var->token = psi_token_copy($NAME);
1485 $arg->token = psi_token_copy($NAME);
1486 }
1487 | VOID pointers name_token[NAME] {
1488 $NAME->type = PSI_T_NAME;
1489 $arg = psi_decl_arg_init(
1490 psi_decl_type_init($VOID->type, $VOID->text),
1491 psi_decl_var_init($NAME->text, $pointers, 0)
1492 );
1493 $arg->type->token = psi_token_copy($VOID);
1494 $arg->var->token = psi_token_copy($NAME);
1495 $arg->token = psi_token_copy($NAME);
1496 }
1497 */
1498 ;
1499
1500 decl_var[var]:
1501 pointers name_token array_size {
1502 $name_token->type = PSI_T_NAME;
1503 $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1504 $var->token = psi_token_copy($name_token);
1505 }
1506 | name_token array_size {
1507 $name_token->type = PSI_T_NAME;
1508 $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1509 $var->token = psi_token_copy($name_token);
1510 }
1511 ;
1512
1513 decl_union[union]:
1514 UNION name_token align_and_size[as] decl_struct_args[args] {
1515 $name_token->type = PSI_T_NAME;
1516 $union = psi_decl_union_init($name_token->text, $args);
1517 $union->align = $as.pos;
1518 $union->size = $as.len;
1519 $union->token = psi_token_copy($name_token);
1520 }
1521 ;
1522
1523 decl_struct[struct]:
1524 STRUCT name_token align_and_size[as] decl_struct_args[args] {
1525 $name_token->type = PSI_T_NAME;
1526 $struct = psi_decl_struct_init($name_token->text, $args);
1527 $struct->align = $as.pos;
1528 $struct->size = $as.len;
1529 $struct->token = psi_token_copy($name_token);
1530 }
1531 ;
1532
1533 decl_struct_args[args]:
1534 EOS {
1535 $args = NULL;
1536 }
1537 | struct_args_block
1538 ;
1539
1540 struct_args_block[args]:
1541 LBRACE struct_args RBRACE {
1542 $args = $struct_args;
1543 }
1544 ;
1545
1546 struct_args[args]:
1547 typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1548 $arg->layout = $layout;
1549 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1550 if ($vars) {
1551 size_t i = 0;
1552 struct psi_decl_arg *arg;
1553
1554 while (psi_plist_get($vars, i++, &arg)) {
1555 arg->type = psi_decl_type_copy($arg->type);
1556 $args = psi_plist_add($args, &arg);
1557 }
1558 free($vars);
1559 }
1560 }
1561 | struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1562 $arg->layout = $layout;
1563 $args = psi_plist_add($args_, &$arg);
1564 if ($vars) {
1565 size_t i = 0;
1566 struct psi_decl_arg *arg;
1567
1568 while (psi_plist_get($vars, i++, &arg)) {
1569 arg->type = psi_decl_type_copy($arg->type);
1570 $args = psi_plist_add($args, &arg);
1571 }
1572 free($vars);
1573 }
1574 }
1575 ;
1576
1577 struct_arg_var_list[vars]:
1578 %empty {
1579 $vars = NULL;
1580 }
1581 | COMMA decl_vars_with_layout[vars_] {
1582 $vars = $vars_;
1583 }
1584 ;
1585
1586 decl_vars_with_layout[vars]:
1587 decl_var[var] decl_layout[layout] {
1588 {
1589 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1590 arg->layout = $layout;
1591 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1592 }
1593 }
1594 | decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1595 {
1596 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1597 arg->layout = $layout;
1598 $vars = psi_plist_add($vars_, &arg);
1599 }
1600 }
1601 | decl_layout[layout] {
1602 {
1603 struct psi_decl_var *var = psi_decl_var_init(NULL, 0, 0);
1604 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, var);
1605 arg->layout = $layout;
1606 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1607 }
1608 }
1609 | decl_vars_with_layout[vars_] COMMA decl_layout[layout] {
1610 {
1611 struct psi_decl_var *var = psi_decl_var_init(NULL, 0, 0);
1612 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, var);
1613 arg->layout = $layout;
1614 $vars = psi_plist_add($vars_, &arg);
1615 }
1616 }
1617 ;
1618
1619 decl_enum[enum]:
1620 enum_name LBRACE decl_enum_items[list] optional_comma RBRACE {
1621 $enum = psi_decl_enum_init($enum_name->text, $list);
1622 $enum->token = $enum_name;
1623 }
1624 ;
1625
1626 decl_enum_items[list]:
1627 decl_enum_item[i] {
1628 $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1629 }
1630 | decl_enum_items[list_] COMMA decl_enum_item[i] {
1631 $list = psi_plist_add($list_, &$i);
1632 }
1633 ;
1634
1635 decl_enum_item[i]:
1636 name_token {
1637 $name_token->type = PSI_T_NAME;
1638 $i = psi_decl_enum_item_init($name_token->text, NULL);
1639 $i->token = psi_token_copy($name_token);
1640 }
1641 | name_token EQUALS num_exp {
1642 $name_token->type = PSI_T_NAME;
1643 $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1644 $i->token = psi_token_copy($name_token);
1645 }
1646 ;
1647
1648 num_exp[exp]:
1649 number {
1650 $exp = psi_num_exp_init_num($number);
1651 $exp->token = psi_token_copy($number->token);
1652 }
1653 | LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1654 $exp = psi_num_exp_init_cast($type, $exp_);
1655 $exp->token = psi_token_copy($type->token);
1656 }
1657 | LPAREN num_exp[exp_] RPAREN {
1658 $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1659 $exp->token = psi_token_copy($LPAREN);
1660 }
1661 | num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1662 $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1663 $exp->token = psi_token_copy($op);
1664 }
1665 | unary_op_token[op] num_exp[exp_] %prec UNARY {
1666 $exp = psi_num_exp_init_unary($op->type, $exp_);
1667 $exp->token = psi_token_copy($op);
1668 }
1669 | num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1670 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1671 $exp->token = psi_token_copy($IIF);
1672 }
1673 ;
1674
1675 number[num]:
1676 NUMBER[token] {
1677 $num = psi_number_init($token->type, $token->text, $token->flags);
1678 $num->token = psi_token_copy($token);
1679 }
1680 | NSNAME[token] {
1681 $num = psi_number_init($token->type, $token->text, 0);
1682 $num->token = psi_token_copy($token);
1683 }
1684 | QUOTED_CHAR[token] {
1685 $num = psi_number_init($token->type, $token->text, 0);
1686 $num->token = psi_token_copy($token);
1687 }
1688 | NULL[token] {
1689 $num = psi_number_init($token->type, $token->text, 0);
1690 $num->token = psi_token_copy($token);
1691 }
1692 | decl_var {
1693 $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1694 $num->token = psi_token_copy($decl_var->token);
1695 }
1696 | sizeof {
1697 $num = $sizeof;
1698 }
1699 ;
1700
1701 sizeof:
1702 SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1703 $sizeof = $sizeof_;
1704 $sizeof->token = psi_token_copy($SIZEOF);
1705 }
1706 | SIZEOF sizeof_body_notypes[sizeof_] {
1707 $sizeof = $sizeof_;
1708 $sizeof->token = psi_token_copy($SIZEOF);
1709 }
1710 ;
1711
1712 sizeof_body[sizeof]:
1713 sizeof_body_notypes[sizeof_] {
1714 $sizeof = $sizeof_;
1715 }
1716 | decl_type indirection {
1717 if ($indirection) {
1718 int8_t sizeof_void_p = sizeof(void *);
1719 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1720 psi_decl_type_free(&$decl_type);
1721 } else {
1722 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1723 }
1724 }
1725 ;
1726
1727 sizeof_body_notypes[sizeof]:
1728 AMPERSAND NAME {
1729 int8_t sizeof_void_p = sizeof(void *);
1730 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1731 }
1732 | QUOTED_CHAR {
1733 int8_t sizeof_a = sizeof('a');
1734 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1735 }
1736 | QUOTED_STRING {
1737 uint64_t len = $QUOTED_STRING->text->len + 1;
1738 $sizeof = psi_number_init(PSI_T_UINT64, &len, 0);
1739 }
1740 ;
1741
1742 enum_name[name]:
1743 ENUM optional_name[name_] {
1744 if ($name_) {
1745 $name = psi_token_copy($name_);
1746 } else {
1747 char digest[17];
1748
1749 psi_token_hash($ENUM, digest);
1750 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1751 }
1752 }
1753 ;
1754
1755 union_name[name]:
1756 UNION optional_name[name_] {
1757 if ($name_) {
1758 $name = psi_token_copy($name_);
1759 } else {
1760 char digest[17];
1761
1762 psi_token_hash($UNION, digest);
1763 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1764 }
1765 }
1766 ;
1767
1768 struct_name[name]:
1769 STRUCT optional_name[name_] {
1770 if ($name_) {
1771 $name = psi_token_copy($name_);
1772 } else {
1773 char digest[17];
1774
1775 psi_token_hash($STRUCT, digest);
1776 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1777 }
1778 }
1779 ;
1780
1781 optional_name[name]:
1782 %empty {
1783 $name = NULL;
1784 }
1785 | name_token {
1786 $name = $name_token;
1787 $name->type = PSI_T_NAME;
1788 }
1789 ;
1790
1791 optional_comma:
1792 %empty
1793 | COMMA
1794 ;
1795
1796 decl_layout[l]:
1797 %empty {
1798 $l = NULL;
1799 }
1800 | COLON NUMBER[width] {
1801 $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text->val), NULL));
1802 }
1803 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1804 $l = psi_layout_init(atol($align->text->val), atol($size->text->val), NULL);
1805 }
1806 | COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1807 $l = psi_layout_init(atol($align->text->val), atol($size->text->val), psi_layout_init(0, atol($width->text->val), NULL));
1808 }
1809 ;
1810
1811 align_and_size[as]:
1812 %empty {
1813 $as.pos = 0;
1814 $as.len = 0;
1815 }
1816 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1817 $as.pos = atol($align->text->val);
1818 $as.len = atol($size->text->val);
1819 }
1820 ;
1821
1822 array_size[as]:
1823 %empty {
1824 $as = 0;
1825 }
1826 | LBRACKET array_qualifier_token RBRACKET {
1827 $as = 0;
1828 }
1829 | LBRACKET num_exp RBRACKET {
1830 struct psi_validate_scope scope = {0};
1831 psi_validate_scope_ctor(&scope);
1832 scope.cpp = P->preproc;
1833 if (psi_num_exp_validate(PSI_DATA(P), $num_exp, &scope)) {
1834 $as = psi_num_exp_get_long($num_exp, NULL, P->preproc);
1835 } else {
1836 $as = 0;
1837 }
1838 psi_num_exp_free(&$num_exp);
1839 psi_validate_scope_dtor(&scope);
1840 }
1841 ;
1842
1843 array_qualifier_token:
1844 %empty
1845 | CPP_RESTRICT
1846 | VOLATILE
1847 | CONST
1848 ;
1849
1850 indirection[i]:
1851 %empty {
1852 $i = 0;
1853 }
1854 | pointers[p] %prec UNARY {
1855 $i = $p;
1856 }
1857 ;
1858
1859 pointers[p]:
1860 asterisks
1861 | asterisks[a] CPP_RESTRICT {
1862 $p = $a;
1863 }
1864 ;
1865
1866 asterisks[a]:
1867 asterisk {
1868 $a = 1;
1869 }
1870 | asterisks[a_] asterisk {
1871 $a = $a_ + 1;
1872 }
1873 ;
1874
1875 asterisk:
1876 ASTERISK
1877 | ASTERISK pointer_qualifier_token
1878 ;
1879
1880 pointer_qualifier_token:
1881 CONST
1882 | VOLATILE
1883 ;
1884
1885 /*
1886 *
1887 * impl
1888 *
1889 */
1890
1891 impl:
1892 impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1893 $impl = psi_impl_init($func, $stmts);
1894 }
1895 | STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1896 $impl = psi_impl_init($func, $stmts);
1897 $func->static_memory = 1;
1898 }
1899 ;
1900
1901 impl_func[func]:
1902 FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1903 $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1904 $func->token = psi_token_copy($NSNAME);
1905 $func->return_reference = $r;
1906 }
1907 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1908 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1909 $func->token = psi_token_copy($NSNAME);
1910 $func->return_reference = $r;
1911 }
1912 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1913 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1914 $func->token = psi_token_copy($NSNAME);
1915 $func->return_reference = $r;
1916 $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1917 $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1918 }
1919 ;
1920
1921 impl_args[args]:
1922 impl_arg[arg] {
1923 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1924 }
1925 | impl_args[args_] COMMA impl_arg[arg] {
1926 $args = psi_plist_add($args_, &$arg);
1927 }
1928 ;
1929
1930 impl_arg[arg]:
1931 impl_type[type] impl_var[var] {
1932 $arg = psi_impl_arg_init($type, $var, NULL);
1933 }
1934 | impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1935 $arg = psi_impl_arg_init($type, $var, $val);
1936 }
1937 ;
1938
1939 impl_var[var]:
1940 reference DOLLAR_NAME {
1941 $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1942 $var->token = psi_token_copy($DOLLAR_NAME);
1943 }
1944 ;
1945
1946 impl_type[type]:
1947 impl_type_token[token] {
1948 $type = psi_impl_type_init($token->type, $token->text);
1949 $type->token = psi_token_copy($token);
1950 }
1951 ;
1952
1953 impl_type_restricted[type]:
1954 impl_type_restricted_token[token] {
1955 $type = psi_impl_type_init($token->type, $token->text);
1956 $type->token = psi_token_copy($token);
1957 }
1958 ;
1959
1960 impl_type_token:
1961 impl_type_restricted_token
1962 | impl_type_extended_token
1963 ;
1964
1965 impl_type_restricted_token:
1966 BOOL
1967 | INT
1968 | FLOAT
1969 | STRING
1970 | MIXED
1971 ;
1972
1973 impl_type_extended_token:
1974 VOID
1975 | ARRAY
1976 | OBJECT
1977 | CALLABLE
1978 ;
1979
1980 impl_stmts[stmts]:
1981 impl_stmt[stmt] {
1982 $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1983 }
1984 | impl_stmts[stmts_] impl_stmt[stmt] {
1985 $stmts = psi_plist_add($stmts_, &$stmt);
1986 }
1987 ;
1988
1989 impl_stmt[stmt]:
1990 return_stmt[s] {
1991 $stmt = (struct psi_token **) $s;
1992 }
1993 | let_stmt[s] {
1994 $stmt = (struct psi_token **) $s;
1995 }
1996 | set_stmt[s] {
1997 $stmt = (struct psi_token **) $s;
1998 }
1999 | assert_stmt[s] {
2000 $stmt = (struct psi_token **) $s;
2001 }
2002 | free_stmt[s] {
2003 $stmt = (struct psi_token **) $s;
2004 }
2005 ;
2006
2007 let_stmt[let]:
2008 LET let_exp_assign[exp] EOS {
2009 $let = psi_let_stmt_init($exp);
2010 $let->token = psi_token_copy($LET);
2011 }
2012 | TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
2013 $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
2014 $let->token = psi_token_copy($TEMP);
2015 $let->exp->is_reference = $reference;
2016 }
2017 ;
2018
2019 let_exp[exp]:
2020 let_exp_assign
2021 | byref let_exp_byref[exp_] {
2022 $exp = $exp_;
2023 $exp->is_reference = true;
2024 }
2025 | let_exp_byref[exp_] {
2026 $exp = $exp_;
2027 $exp->is_reference = false;
2028 }
2029 ;
2030
2031 let_exp_byref[exp]:
2032 NULL %dprec 2 {
2033 $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
2034 }
2035 | num_exp[num] %dprec 1 {
2036 $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
2037 }
2038 | let_calloc[calloc] {
2039 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
2040 }
2041 | STATIC let_calloc[calloc] {
2042 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
2043 $calloc->static_memory = 1;
2044 }
2045 | let_callback[callback] {
2046 $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
2047 }
2048 | let_func[func] {
2049 $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
2050 }
2051 ;
2052
2053 let_exp_assign[exp]:
2054 decl_var[var] EQUALS let_exp_byref[exp_] {
2055 $exp = $exp_;
2056 $exp->var = $var;
2057 }
2058 | decl_var[var] EQUALS byref let_exp_byref[exp_] {
2059 $exp = $exp_;
2060 $exp->is_reference = 1;
2061 $exp->var = $var;
2062 }
2063 ;
2064
2065 let_calloc[calloc]:
2066 CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
2067 $calloc = psi_let_calloc_init($nmemb, $size);
2068 $calloc->token = psi_token_copy($CALLOC);
2069 }
2070 ;
2071
2072 let_callback[callback]:
2073 CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
2074 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, NULL);
2075 $callback->func->token = psi_token_copy($func);
2076 $callback->token = psi_token_copy($CALLBACK);
2077 }
2078 | CALLBACK LPAREN call_decl_vars[cb_args] RPAREN AS callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
2079 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, $cb_args);
2080 $callback->func->token = psi_token_copy($func);
2081 $callback->token = psi_token_copy($CALLBACK);
2082 }
2083 ;
2084
2085 let_func[func]:
2086 let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
2087 $func = psi_let_func_init($token->type, $token->text, $var);
2088 $func->token = psi_token_copy($token);
2089 $func->inner = $exps;
2090 }
2091 ;
2092
2093 let_func_token:
2094 ZVAL
2095 | OBJVAL
2096 | ARRVAL
2097 | PATHVAL
2098 | STRLEN
2099 | STRVAL
2100 | FLOATVAL
2101 | INTVAL
2102 | BOOLVAL
2103 | COUNT
2104 ;
2105
2106 let_func_exps[exps]:
2107 %empty {
2108 $exps = NULL;
2109 }
2110 | COMMA let_exps[exps_] {
2111 $exps = $exps_;
2112 }
2113 ;
2114
2115 let_exps[exps]:
2116 let_exp[exp] {
2117 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
2118 }
2119 | let_exps[exps_] COMMA let_exp[exp] {
2120 $exps = psi_plist_add($exps_, &$exp);
2121 }
2122 ;
2123
2124 callback_rval[rval]:
2125 VOID
2126 | let_func_token
2127 ;
2128
2129 callback_arg_list[list]:
2130 %empty {
2131 $list = NULL;
2132 }
2133 | callback_args[args] {
2134 $list = $args;
2135 }
2136 ;
2137
2138 callback_args[args]:
2139 set_exp[exp] {
2140 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2141 }
2142 | callback_args[args_] COMMA set_exp[exp] {
2143 $args = psi_plist_add($args_, &$exp);
2144 }
2145 ;
2146
2147 return_stmt[return]:
2148 RETURN return_exp EOS {
2149 $return = psi_return_stmt_init($return_exp);
2150 $return->token = psi_token_copy($RETURN);
2151 }
2152 ;
2153
2154 return_exp:
2155 decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
2156 $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
2157 $return_exp->token = psi_token_copy($func->token);
2158 }
2159 | set_func {
2160 $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
2161 $return_exp->token = psi_token_copy($set_func->token);
2162 }
2163 ;
2164
2165 call_decl_vars[args]:
2166 %empty {
2167 $args = NULL;
2168 }
2169 | VOID {
2170 $args = NULL;
2171 }
2172 | decl_vars[vars] {
2173 $args = $vars;
2174 }
2175 ;
2176
2177 set_stmt[set]:
2178 SET set_exp[exp] EOS {
2179 $set = psi_set_stmt_init($exp);
2180 $set->token = psi_token_copy($SET);
2181 }
2182 ;
2183
2184 set_exp[exp]:
2185 set_func[func] {
2186 $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
2187 }
2188 | num_exp[num] {
2189 $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
2190 }
2191 | impl_var[var] EQUALS set_exp[exp_] {
2192 $exp = $exp_;
2193 $exp->var = $var;
2194 }
2195 ;
2196
2197 set_func[func]:
2198 set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
2199 $func = psi_set_func_init($token->type, $token->text, $var);
2200 $func->token = psi_token_copy($token);
2201 $func->inner = $exps;
2202 }
2203 | set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
2204 $func = psi_set_func_init($token->type, $token->text, $var);
2205 $func->token = psi_token_copy($token);
2206 $func->recursive = 1;
2207 }
2208 ;
2209
2210 set_func_token:
2211 TO_OBJECT
2212 | TO_ARRAY
2213 | TO_STRING
2214 | TO_INT
2215 | TO_FLOAT
2216 | TO_BOOL
2217 | ZVAL
2218 | VOID
2219 ;
2220
2221 set_func_exps[exps]:
2222 %empty {
2223 $exps = NULL;
2224 }
2225 | COMMA set_exps[exps_] {
2226 $exps = $exps_;
2227 }
2228 ;
2229
2230 set_exps[exps]:
2231 set_exp[exp] {
2232 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2233 }
2234 | set_exps[exps_] COMMA set_exp[exp] {
2235 $exps = psi_plist_add($exps_, &$exp);
2236 }
2237 ;
2238
2239 assert_stmt[assert]:
2240 assert_stmt_token[token] num_exp[exp] EOS {
2241 $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
2242 $assert->token = psi_token_copy($token);
2243 }
2244 ;
2245
2246 assert_stmt_token:
2247 PRE_ASSERT
2248 | POST_ASSERT
2249 ;
2250
2251 free_stmt[free]:
2252 FREE free_exps[exps] EOS {
2253 $free = psi_free_stmt_init($exps);
2254 $free->token = psi_token_copy($FREE);
2255 }
2256 ;
2257
2258 free_exps[exps]:
2259 free_exp[exp] {
2260 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
2261 }
2262 | free_exps[exps_] COMMA free_exp[exp] {
2263 $exps = psi_plist_add($exps_, &$exp);
2264 }
2265 ;
2266
2267 free_exp[exp]:
2268 name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2269 $NAME->type = PSI_T_NAME;
2270 $exp = psi_free_exp_init($NAME->text, $vars);
2271 $exp->token = psi_token_copy($NAME);
2272 }
2273 ;
2274
2275 reference:
2276 %empty {
2277 $reference = false;
2278 }
2279 | byref {
2280 $reference = true;
2281 }
2282 ;
2283
2284 byref:
2285 AMPERSAND %prec UNARY
2286 ;
2287
2288 %%
2289
2290 /* epilogue */
2291
2292 #define PSI_DEBUG_LEX 0
2293 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2294 {
2295 struct psi_token *token;
2296 #if PSI_DEBUG_LEX
2297 PSI_DEBUG_PRINT(P, "PSI: LEX index %4zu ", *index);
2298 #endif
2299 if (psi_plist_get(tokens, (*index)++, &token) && token) {
2300 #if PSI_DEBUG_LEX
2301 PSI_DEBUG_DUMP(P, psi_token_dump, token);
2302 #endif
2303 *((struct psi_token **)lvalp) = token;
2304 return token->type;
2305 } else {
2306 #if PSI_DEBUG_LEX
2307 PSI_DEBUG_PRINT(P, "EOF\n");
2308 #endif
2309 (*index)--;
2310 }
2311
2312 return PSI_T_EOF;
2313 }
2314
2315 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2316 {
2317 struct psi_token *T = NULL;
2318 size_t last;
2319
2320 if (*index == 0) {
2321 last = 0;
2322 } else {
2323 last = --(*index);
2324 }
2325
2326 psi_plist_get(tokens, last, &T);
2327 if (T) {
2328 size_t i = (last >= 5) ? last - 5 : 0;
2329
2330 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2331 while (i <= last || T->type != PSI_T_EOS) {
2332 const char *pos;
2333
2334 if (!psi_plist_get(tokens, i++, &T)) {
2335 break;
2336 }
2337
2338 if (i < last + 1) {
2339 pos = "preceding";
2340 } else if (i > last + 1) {
2341 pos = "following";
2342 } else {
2343 pos = "offending";
2344 }
2345
2346 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s token '%s' at col %u",
2347 pos, T ? T->text->val : "<deleted>", T ? T->col : 0);
2348 }
2349 } else {
2350 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2351 }
2352 P->errors++;
2353 }
2354
PHP System Interface / POSIX Standard Interface