projects / m6w6 / ext-psi / blob
? search:


570af95fd3f11ad362e234061be2449f522a9d1b
[m6w6/ext-psi] / src / parser_proc_grammar.y
1 %code top {
2 #include "php_psi_stdinc.h"
3 }
4
5 %code {
6 #include <assert.h>
7 #include <stdarg.h>
8
9 #include "plist.h"
10 #include "parser.h"
11
12 #define YYDEBUG 1
13 #define PSI_PARSER_PROC_DEBUG 1
14
15 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
16 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
17
18 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
19 {
20 assert(strct);
21 if (!P->structs) {
22 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
23 }
24 P->structs = psi_plist_add(P->structs, &strct);
25 }
26 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
27 {
28 assert(u);
29 if (!P->unions) {
30 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
31 }
32 P->unions = psi_plist_add(P->unions, &u);
33 }
34 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
35 {
36 assert(e);
37 if (!P->enums) {
38 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
39 }
40 P->enums = psi_plist_add(P->enums, &e);
41 }
42 static inline void psi_parser_proc_deanon_typedef(struct psi_decl_arg *def)
43 {
44 switch (def->type->type) {
45 case PSI_T_STRUCT:
46 if (!psi_decl_type_is_anon(def->type->name, "struct")) {
47 return;
48 }
49 break;
50 case PSI_T_UNION:
51 if (!psi_decl_type_is_anon(def->type->name, "union")) {
52 return;
53 }
54 break;
55 case PSI_T_ENUM:
56 if (!psi_decl_type_is_anon(def->type->name, "enum")) {
57 return;
58 }
59 break;
60 default:
61 return;
62 }
63 free(def->type->name);
64 def->type->name = strdup(def->var->name);
65 }
66 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
67 {
68 assert(def);
69 if (!P->types) {
70 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
71 }
72 psi_parser_proc_deanon_typedef(def);
73 P->types = psi_plist_add(P->types, &def);
74 }
75 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
76 assert(cnst);
77 if (!P->consts) {
78 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
79 }
80 P->consts = psi_plist_add(P->consts, &cnst);
81
82 }
83 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
84 assert(decl);
85
86 if (psi_decl_is_blacklisted(decl->func->var->name)) {
87 psi_decl_free(&decl);
88 return;
89 }
90
91 if (!P->decls) {
92 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
93 }
94 P->decls = psi_plist_add(P->decls, &decl);
95 }
96 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
97 assert(impl);
98 if (!P->impls) {
99 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
100 }
101 P->impls = psi_plist_add(P->impls, &impl);
102 }
103
104 /* end code */
105 }
106
107 %code requires {
108 #include "plist.h"
109 #include "types/layout.h"
110
111 #define yytokentype psi_token_type
112
113 #define PSI_T_CAST PSI_T_EQUALS
114 #define PSI_T_POINTER PSI_T_ASTERISK
115
116 struct psi_parser;
117
118 }
119
120 %require "3.0"
121 %language "c"
122 %name-prefix "psi_parser_proc_"
123 %token-table
124 %verbose
125 %glr-parser
126
127 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
128
129 %define api.pure true
130 %define api.token.prefix {PSI_T_}
131 %define api.value.type union
132
133 %define parse.error verbose
134 %define parse.trace true
135
136 %initial-action {
137 }
138
139 %start file
140
141 %token <struct psi_token *> BOOL
142 %token <struct psi_token *> CHAR
143 %token <struct psi_token *> SHORT
144 %token <struct psi_token *> INT
145 %token <struct psi_token *> SIGNED
146 %token <struct psi_token *> UNSIGNED
147 %token <struct psi_token *> LONG
148 %token <struct psi_token *> FLOAT
149 %token <struct psi_token *> DOUBLE
150 %token <struct psi_token *> STRING
151 %token <struct psi_token *> MIXED
152 %token <struct psi_token *> ARRAY
153 %token <struct psi_token *> OBJECT
154 %token <struct psi_token *> CALLABLE
155 %token <struct psi_token *> VOID
156 %token <struct psi_token *> ZVAL
157 %token <struct psi_token *> NULL
158 %token <struct psi_token *> TRUE
159 %token <struct psi_token *> FALSE
160 %token <struct psi_token *> NAME
161 %token <struct psi_token *> NSNAME
162 %token <struct psi_token *> DOLLAR_NAME
163 %token <struct psi_token *> NUMBER
164 %token <struct psi_token *> QUOTED_STRING
165 %token <struct psi_token *> QUOTED_CHAR
166 %token <struct psi_token *> SIZEOF
167 %token <struct psi_token *> VOLATILE
168
169 %token <struct psi_token *> EOF 0 "end of file"
170 %token <struct psi_token *> EOL "end of line"
171 %token <struct psi_token *> EOS ";"
172 %token <struct psi_token *> LPAREN "("
173 %token <struct psi_token *> RPAREN ")"
174 %token <struct psi_token *> COMMA ","
175 %token <struct psi_token *> COLON ":"
176 %token <struct psi_token *> LBRACE "{"
177 %token <struct psi_token *> RBRACE "}"
178 %token <struct psi_token *> LBRACKET "["
179 %token <struct psi_token *> RBRACKET "]"
180 %token <struct psi_token *> EQUALS "="
181 %token <struct psi_token *> HASH "#"
182 %token <struct psi_token *> PIPE "|"
183 %token <struct psi_token *> CARET "^"
184 %token <struct psi_token *> AMPERSAND "&"
185 %token <struct psi_token *> LSHIFT "<<"
186 %token <struct psi_token *> RSHIFT ">>"
187 %token <struct psi_token *> PLUS "+"
188 %token <struct psi_token *> MINUS "-"
189 %token <struct psi_token *> ASTERISK "*"
190 %token <struct psi_token *> SLASH "/"
191 %token <struct psi_token *> MODULO "%"
192 %token <struct psi_token *> LCHEVR "<"
193 %token <struct psi_token *> RCHEVR ">"
194 %token <struct psi_token *> CMP_GE ">="
195 %token <struct psi_token *> CMP_LE "<="
196 %token <struct psi_token *> OR "||"
197 %token <struct psi_token *> AND "&&"
198 %token <struct psi_token *> CMP_EQ "=="
199 %token <struct psi_token *> CMP_NE "!="
200 %token <struct psi_token *> TILDE "~"
201 %token <struct psi_token *> NOT "!"
202 %token <struct psi_token *> PERIOD "."
203 %token <struct psi_token *> BACKSLASH "\\"
204 %token <struct psi_token *> ELLIPSIS "..."
205 %token <struct psi_token *> IIF "?"
206
207 %token <struct psi_token *> PRAGMA
208 %token <struct psi_token *> PRAGMA_ONCE
209 %token <struct psi_token *> LINE
210 %token <struct psi_token *> ERROR
211 %token <struct psi_token *> WARNING
212 %token <struct psi_token *> IF
213 %token <struct psi_token *> IFDEF
214 %token <struct psi_token *> IFNDEF
215 %token <struct psi_token *> ELSE
216 %token <struct psi_token *> ELIF
217 %token <struct psi_token *> ENDIF
218 %token <struct psi_token *> DEFINE
219 %token <struct psi_token *> DEFINED
220 %token <struct psi_token *> UNDEF
221 %token <struct psi_token *> IMPORT
222 %token <struct psi_token *> INCLUDE
223 %token <struct psi_token *> INCLUDE_NEXT
224
225 %token <struct psi_token *> TYPEDEF
226 %token <struct psi_token *> STRUCT
227 %token <struct psi_token *> UNION
228 %token <struct psi_token *> ENUM
229 %token <struct psi_token *> CONST
230 %token <struct psi_token *> LIB
231 %token <struct psi_token *> STATIC
232 %token <struct psi_token *> CALLBACK
233 %token <struct psi_token *> FUNCTION
234 %token <struct psi_token *> LET
235 %token <struct psi_token *> SET
236 %token <struct psi_token *> TEMP
237 %token <struct psi_token *> FREE
238 %token <struct psi_token *> RETURN
239 %token <struct psi_token *> AS
240 %token <struct psi_token *> PRE_ASSERT
241 %token <struct psi_token *> POST_ASSERT
242 %token <struct psi_token *> BOOLVAL
243 %token <struct psi_token *> INTVAL
244 %token <struct psi_token *> STRVAL
245 %token <struct psi_token *> PATHVAL
246 %token <struct psi_token *> STRLEN
247 %token <struct psi_token *> FLOATVAL
248 %token <struct psi_token *> ARRVAL
249 %token <struct psi_token *> OBJVAL
250 %token <struct psi_token *> COUNT
251 %token <struct psi_token *> CALLOC
252 %token <struct psi_token *> TO_BOOL
253 %token <struct psi_token *> TO_INT
254 %token <struct psi_token *> TO_STRING
255 %token <struct psi_token *> TO_FLOAT
256 %token <struct psi_token *> TO_ARRAY
257 %token <struct psi_token *> TO_OBJECT
258
259 %token <struct psi_token *> COMMENT
260 %token <struct psi_token *> WHITESPACE
261 %token <struct psi_token *> NO_WHITESPACE
262 %token <struct psi_token *> CPP_HEADER
263 %token <struct psi_token *> CPP_ATTRIBUTE
264 %token <struct psi_token *> CPP_EXTENSION
265 %token <struct psi_token *> CPP_PASTE
266 %token <struct psi_token *> CPP_INLINE
267 %token <struct psi_token *> CPP_RESTRICT
268 %token <struct psi_token *> CPP_ASM
269
270 /* virtual tokens */
271 %token <struct psi_token *> BSLASH
272 %token <struct psi_token *> LONG_DOUBLE
273 %token <struct psi_token *> INT8
274 %token <struct psi_token *> UINT8
275 %token <struct psi_token *> INT16
276 %token <struct psi_token *> UINT16
277 %token <struct psi_token *> INT32
278 %token <struct psi_token *> UINT32
279 %token <struct psi_token *> INT64
280 %token <struct psi_token *> UINT64
281 %token <struct psi_token *> INT128
282 %token <struct psi_token *> UINT128
283
284
285 %precedence IIF COLON
286 %precedence OR
287 %precedence AND
288 %precedence PIPE
289 %precedence CARET
290 %precedence AMPERSAND
291 %precedence CMP_EQ CMP_NE
292 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
293 %precedence LSHIFT RSHIFT
294 %precedence PLUS MINUS
295 %precedence ASTERISK SLASH MODULO
296 //%precedence NOT TILDE
297 %precedence BINARY
298 %precedence UNARY
299
300 %type <struct psi_token *> lib optional_name enum_name struct_name union_name
301 %destructor {psi_token_free(&$$);} lib optional_name enum_name struct_name union_name
302
303 %type <struct psi_token *> cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
304 %destructor {} cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
305
306 %type <struct psi_token *> name_token any_noeol_token binary_op_token unary_op_token
307 %destructor {} name_token any_noeol_token binary_op_token unary_op_token
308
309 %type <struct psi_token *> int_width int_width_types int_signed_types
310 %destructor {psi_token_free(&$$);} int_width int_width_types int_signed_types
311
312 %type <struct psi_token *> signed_long_types signed_short_types int_signed
313 %destructor {} signed_long_types signed_short_types int_signed
314
315 %type <struct psi_cpp_exp *> cpp cpp_exp
316 %destructor {psi_cpp_exp_free(&$$);} cpp cpp_exp
317 %type <struct psi_cpp_macro_decl *> cpp_macro_decl
318 %destructor {psi_cpp_macro_decl_free(&$$);} cpp_macro_decl
319 %type <struct psi_plist *> cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
320 %destructor {psi_plist_free($$);} cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
321 %type <struct psi_num_exp *> cpp_macro_exp
322 %destructor {psi_num_exp_free(&$$);} cpp_macro_exp
323
324 %type <struct psi_token *> constant_type_token impl_def_val_token
325 %destructor {} constant_type_token impl_def_val_token
326
327 %type <struct psi_const *> constant
328 %destructor {psi_const_free(&$$);} constant
329 %type <struct psi_const_type *> constant_type
330 %destructor {psi_const_type_free(&$$);} constant_type
331 %type <struct psi_impl_def_val *> impl_def_val
332 %destructor {psi_impl_def_val_free(&$$);} impl_def_val
333
334 %type <struct psi_token *> decl_real_type decl_int_type decl_type_simple
335 %destructor {psi_token_free(&$$);} decl_real_type decl_int_type decl_type_simple
336
337 %type <struct psi_decl_type *> decl_type qualified_decl_type decl_type_complex
338 %destructor {psi_decl_type_free(&$$);} decl_type qualified_decl_type decl_type_complex
339 %type <struct psi_decl *> decl_stmt decl decl_body decl_func_body decl_functor_body
340 %destructor {psi_decl_free(&$$);} decl_stmt decl decl_body decl_func_body decl_functor_body
341 %type <struct psi_decl_arg *> decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
342 %destructor {psi_decl_arg_free(&$$);} decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
343 %type <struct psi_decl_var *> decl_var
344 %destructor {psi_decl_var_free(&$$);} decl_var
345 %type <struct psi_decl_struct *> decl_struct
346 %destructor {psi_decl_struct_free(&$$);} decl_struct
347 %type <struct psi_decl_union *> decl_union
348 %destructor {psi_decl_union_free(&$$);} decl_union
349 %type <struct psi_decl_enum *> decl_enum
350 %destructor {psi_decl_enum_free(&$$);} decl_enum
351 %type <struct psi_decl_enum_item *> decl_enum_item
352 %destructor {psi_decl_enum_item_free(&$$);} decl_enum_item
353 %type <struct psi_plist *> decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars
354 %destructor {psi_plist_free($$);} decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars
355
356 %type <struct psi_layout> align_and_size
357 %destructor {} align_and_size
358 %type <struct psi_layout *> decl_layout
359 %destructor {psi_layout_free(&$$);} decl_layout
360
361 %type <struct psi_number *> sizeof sizeof_body sizeof_body_notypes
362 %destructor {psi_number_free(&$$);} sizeof sizeof_body sizeof_body_notypes
363
364 %type <struct psi_impl *> impl
365 %destructor {psi_impl_free(&$$);} impl
366 %type <struct psi_impl_func *> impl_func
367 %destructor {psi_impl_func_free(&$$);} impl_func
368 %type <struct psi_impl_arg *> impl_arg
369 %destructor {psi_impl_arg_free(&$$);} impl_arg
370 %type <struct psi_impl_type *> impl_type
371 %destructor {psi_impl_type_free(&$$);} impl_type
372 %type <struct psi_impl_var *> impl_var
373 %destructor {psi_impl_var_free(&$$);} impl_var
374
375 %type <struct psi_let_stmt *> let_stmt
376 %destructor {psi_let_stmt_free(&$$);} let_stmt
377 %type <struct psi_let_exp *> let_exp let_exp_byref let_exp_assign
378 %destructor {psi_let_exp_free(&$$);} let_exp let_exp_byref let_exp_assign
379 %type <struct psi_let_calloc *> let_calloc
380 %destructor {psi_let_calloc_free(&$$);} let_calloc
381 %type <struct psi_let_callback *> let_callback
382 %destructor {psi_let_callback_free(&$$);} let_callback
383 %type <struct psi_let_func *> let_func
384 %destructor {psi_let_func_free(&$$);} let_func
385 %type <struct psi_set_stmt *> set_stmt
386 %destructor {psi_set_stmt_free(&$$);} set_stmt
387 %type <struct psi_set_exp *> set_exp
388 %destructor {psi_set_exp_free(&$$);} set_exp
389 %type <struct psi_set_func *> set_func
390 %destructor {psi_set_func_free(&$$);} set_func
391 %type <struct psi_assert_stmt *> assert_stmt
392 %destructor {psi_assert_stmt_free(&$$);} assert_stmt
393 %type <struct psi_return_stmt *> return_stmt
394 %destructor {psi_return_stmt_free(&$$);} return_stmt
395 %type <struct psi_return_exp *> return_exp
396 %destructor {psi_return_exp_free(&$$);} return_exp
397 %type <struct psi_free_stmt *> free_stmt
398 %destructor {psi_free_stmt_free(&$$);} free_stmt
399 %type <struct psi_free_exp *> free_exp
400 %destructor {psi_free_exp_free(&$$);} free_exp
401
402 %type <struct psi_token **> impl_stmt
403 %destructor {psi_impl_stmt_free(&$$);} impl_stmt
404 %type <struct psi_token *> impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
405 %destructor {psi_token_free(&$$);} impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
406 %type <struct psi_plist *> impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
407 %destructor {psi_plist_free($$);} impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
408
409 %type <struct psi_num_exp *> num_exp
410 %destructor {psi_num_exp_free(&$$);} num_exp
411 %type <struct psi_number *> number
412 %destructor {psi_number_free(&$$);} number
413
414 %type <size_t> indirection pointers asterisks array_size
415 %destructor {} indirection pointers asterisks array_size
416 %type <bool> reference
417 %destructor {} reference
418
419 %%
420
421 /* rules */
422
423
424 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
425 unary_op_token: TILDE | NOT | PLUS | MINUS ;
426 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | AS | let_func_token | set_func_token;
427 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
428 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
429
430
431 file:
432 %empty
433 | blocks
434 ;
435 blocks:
436 block
437 | blocks block
438 ;
439 block:
440 EOS
441 | EOL
442 | COMMENT
443 | cpp {
444 if ($cpp) {
445 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
446 psi_cpp_exp_free(&$cpp);
447 }
448 }
449 | lib {
450 if (P->file.ln) {
451 P->error(PSI_DATA(P), $lib, PSI_WARNING,
452 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
453 } else {
454 P->file.ln = strndup($lib->text, $lib->size);
455 }
456 }
457 | constant {
458 psi_parser_proc_add_const(P, $constant);
459 }
460 | decl_stmt {
461 psi_parser_proc_add_decl(P, $decl_stmt);
462 }
463 | ignored_decl
464 | decl_ext_var_stmt
465 | decl_typedef[def] {
466 psi_parser_proc_add_typedef(P, $def);
467 }
468 | decl_struct[struct] {
469 psi_parser_proc_add_struct(P, $struct);
470 }
471 | decl_union[union] {
472 psi_parser_proc_add_union(P, $union);
473 }
474 | decl_enum[enum] {
475 psi_parser_proc_add_enum(P, $enum);
476 }
477 | impl {
478 psi_parser_proc_add_impl(P, $impl);
479 }
480 ;
481
482 lib:
483 LIB QUOTED_STRING EOS {
484 $lib = $QUOTED_STRING;
485 }
486 ;
487
488 cpp:
489 HASH EOL {
490 $cpp = NULL;
491 }
492 | HASH cpp_exp[exp] EOL {
493 $cpp = $exp;
494 }
495 ;
496
497 cpp_exp[exp]:
498 cpp_message_token cpp_macro_decl_tokens[tokens] {
499 if ($tokens) {
500 struct psi_token *msg = NULL;
501
502 if (psi_plist_get($tokens, 0, &msg)) {
503 size_t index = 1;
504 struct psi_token *next;
505
506 msg = psi_token_copy(msg);
507 while (psi_plist_get($tokens, index++, &next)) {
508 struct psi_token *old = msg;
509 msg = psi_token_cat(" ", 2, msg, next);
510 free(old);
511 }
512 }
513 psi_plist_free($tokens);
514
515 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
516 } else {
517 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
518 }
519 $exp->token = psi_token_copy($cpp_message_token);
520 }
521 | cpp_include_token[INCLUDE] cpp_header_token {
522 $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
523 $exp->token = psi_token_copy($INCLUDE);
524 }
525 | cpp_no_arg_token {
526 $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
527 $exp->token = psi_token_copy($cpp_no_arg_token);
528 }
529 | cpp_name_arg_token cpp_special_name_token[name_token] {
530 $name_token->type = PSI_T_NAME;
531 $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
532 $exp->token = psi_token_copy($cpp_name_arg_token);
533 }
534 | DEFINE cpp_macro_decl {
535 $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
536 $exp->token = psi_token_copy($DEFINE);
537 }
538 | cpp_exp_arg_token cpp_macro_exp {
539 $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
540 $exp->token = psi_token_copy($cpp_exp_arg_token);
541 }
542 | PRAGMA_ONCE {
543 $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
544 $exp->token = psi_token_copy($PRAGMA_ONCE);
545 }
546 | cpp_ignored_token cpp_macro_decl_tokens[tokens] {
547 psi_plist_free($tokens);
548 $exp = NULL;
549 }
550 ;
551
552 cpp_ignored_token:
553 LINE
554 | PRAGMA
555 ;
556
557 cpp_message_token:
558 ERROR
559 | WARNING
560 ;
561
562 cpp_include_token:
563 IMPORT
564 | INCLUDE
565 | INCLUDE_NEXT
566 ;
567
568 cpp_header_token:
569 QUOTED_STRING
570 | CPP_HEADER
571 ;
572
573 cpp_no_arg_token:
574 ELSE
575 | ENDIF
576 ;
577
578 cpp_name_arg_token:
579 IFDEF
580 | IFNDEF
581 | UNDEF
582 ;
583
584 cpp_exp_arg_token:
585 IF
586 | ELIF
587 ;
588
589 cpp_special_name_token:
590 name_token
591 | NULL
592 | TRUE
593 | FALSE
594 | CPP_RESTRICT
595 | CPP_EXTENSION
596 | CPP_INLINE
597 ;
598
599 cpp_macro_decl[macro]:
600 name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
601 $name_token->type = PSI_T_NAME;
602 $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
603 $macro->token = psi_token_copy($name_token);
604 }
605 | cpp_special_name_token[name_token] cpp_macro_decl_tokens {
606 $name_token->type = PSI_T_NAME;
607 $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
608 $macro->token = psi_token_copy($name_token);
609 }
610 ;
611
612 cpp_macro_sig[sig]:
613 %empty {
614 $sig = psi_plist_init(NULL);
615 }
616 | ELLIPSIS {
617 $sig = psi_plist_init(NULL); /* FIXME */
618 }
619 | cpp_macro_sig_args
620 | cpp_macro_sig_args[args] COMMA ELLIPSIS {
621 $sig = $args;
622 }
623 ;
624
625 cpp_macro_sig_args[args]:
626 name_token {
627 $name_token = psi_token_copy($name_token);
628 $name_token->type = PSI_T_NAME;
629 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
630 }
631 | cpp_macro_sig_args[args_] COMMA name_token {
632 $name_token = psi_token_copy($name_token);
633 $name_token->type = PSI_T_NAME;
634 $args = psi_plist_add($args_, &$name_token);
635 }
636 ;
637
638 cpp_macro_decl_tokens[tokens]:
639 %empty {
640 $tokens = NULL;
641 }
642 | cpp_macro_decl_token_list
643 ;
644
645 cpp_macro_decl_token_list[tokens]:
646 any_noeol_token[token] {
647 $token = psi_token_copy($token);
648 $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
649 }
650 | cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
651 $token = psi_token_copy($token);
652 $tokens = psi_plist_add($tokens_, &$token);
653 }
654 ;
655
656 cpp_macro_exp[exp]:
657 LPAREN cpp_macro_exp[exp_] RPAREN {
658 $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
659 $exp->token = psi_token_copy($LPAREN);
660 }
661 | unary_op_token cpp_macro_exp[exp_] %prec UNARY {
662 $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
663 $exp->token = psi_token_copy($unary_op_token);
664 }
665 | cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
666 $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
667 $exp->token = psi_token_copy($binary_op_token);
668 }
669 | cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
670 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
671 $exp->token = psi_token_copy($IIF);
672 }
673
674 | DEFINED name_token {
675 {
676 uint8_t exists;
677
678 $name_token->type = PSI_T_NAME;
679 exists = psi_cpp_defined(P->preproc, $name_token);
680 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
681 $exp->token = psi_token_copy($name_token);
682 }
683 }
684 | DEFINED LPAREN name_token RPAREN {
685 {
686 uint8_t exists;
687
688 $name_token->type = PSI_T_NAME;
689 exists = psi_cpp_defined(P->preproc, $name_token);
690 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
691 $exp->token = psi_token_copy($name_token);
692 }
693 }
694 | NUMBER {
695 $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
696 $exp->token = psi_token_copy($NUMBER);
697 $exp->data.n->token = psi_token_copy($NUMBER);
698 }
699 | QUOTED_CHAR {
700 $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
701 $exp->token = psi_token_copy($QUOTED_CHAR);
702 $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
703 }
704 | sizeof {
705 $exp = psi_num_exp_init_num($sizeof);
706 $exp->token = psi_token_copy($sizeof->token);
707 }
708 | name_token {
709 $name_token->type = PSI_T_NAME;
710 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
711 $exp->token = psi_token_copy($name_token);
712 $exp->data.n->token = psi_token_copy($name_token);
713 }
714 | name_token LPAREN cpp_macro_call_args RPAREN {
715 $name_token->type = PSI_T_NAME;
716 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
717 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
718 $exp->token = psi_token_copy($name_token);
719 }
720 ;
721
722 cpp_macro_call_args[args]:
723 %empty {
724 $args = NULL;
725 }
726 | cpp_macro_call_arg_list
727 ;
728
729 cpp_macro_call_arg_list[args]:
730 cpp_macro_exp {
731 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
732 &$cpp_macro_exp);
733 }
734 | cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
735 $args = psi_plist_add($args_, &$cpp_macro_exp);
736 }
737 ;
738
739 constant[const]:
740 CONST constant_type NSNAME EQUALS impl_def_val EOS {
741 $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
742 $const->token = psi_token_copy($NSNAME);
743 }
744 ;
745
746 constant_type[type]:
747 constant_type_token[token] {
748 $type = psi_const_type_init($token->type, $token->text);
749 }
750 ;
751
752 constant_type_token:
753 BOOL
754 | INT
755 | FLOAT
756 | STRING
757 ;
758
759 impl_def_val[val]:
760 %empty {
761 $val = NULL;
762 }
763 | num_exp[num] %dprec 1 {
764 if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
765 impl_val res = {0};
766 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
767
768 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
769 $val = psi_impl_def_val_init(type, NULL);
770 } else {
771 $val = psi_impl_def_val_init(PSI_T_INT, NULL);
772 }
773
774 switch (type) {
775 case PSI_T_UINT8: $val->ival.zend.lval = res.u8; break;
776 case PSI_T_UINT16: $val->ival.zend.lval = res.u16; break;
777 case PSI_T_UINT32: $val->ival.zend.lval = res.u32; break;
778 case PSI_T_UINT64: $val->ival.zend.lval = res.u64; break; /* FIXME */
779 case PSI_T_INT8: $val->ival.zend.lval = res.i8; break;
780 case PSI_T_INT16: $val->ival.zend.lval = res.i16; break;
781 case PSI_T_INT32: $val->ival.zend.lval = res.i32; break;
782 case PSI_T_INT64: $val->ival.zend.lval = res.i64; break;
783 case PSI_T_FLOAT: $val->ival.dval = res.fval; break;
784 case PSI_T_DOUBLE: $val->ival.dval = res.dval; break;
785 default:
786 assert(0);
787
788 }
789 } else {
790 $val = NULL;
791 }
792 psi_num_exp_free(&$num);
793 }
794 | impl_def_val_token[token] %dprec 2 {
795 $val = psi_impl_def_val_init($token->type, $token->text);
796 $val->token = psi_token_copy($token);
797 }
798 ;
799
800 impl_def_val_token:
801 NULL
802 | TRUE
803 | FALSE
804 | QUOTED_STRING
805 ;
806
807 decl_typedef[def]:
808 TYPEDEF typedef[def_] EOS {
809 $def = $def_;
810 }
811 | TYPEDEF VOID name_token EOS {
812 $def = psi_decl_arg_init(
813 psi_decl_type_init(PSI_T_VOID, $VOID->text),
814 psi_decl_var_init($name_token->text, 0, 0)
815 );
816 $def->token = psi_token_copy($VOID);
817 $def->type->token = psi_token_copy($VOID);
818 $def->var->token = psi_token_copy($name_token);
819 }
820 | CPP_EXTENSION TYPEDEF typedef[def_] EOS {
821 $def = $def_;
822 }
823 ;
824
825 typedef[def]:
826 typedef_decl {
827 $def = $typedef_decl;
828 }
829 | CPP_EXTENSION typedef_decl {
830 $def = $typedef_decl;
831 }
832 ;
833
834 typedef_anon[def]:
835 typedef_anon_decl {
836 $def = $typedef_anon_decl;
837 }
838 | CPP_EXTENSION typedef_anon_decl {
839 $def = $typedef_anon_decl;
840 }
841 ;
842
843 typedef_decl[def]:
844 decl_arg
845 | decl_func_body[decl] {
846 $def = psi_decl_arg_init(
847 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
848 psi_decl_var_copy($decl->func->var)
849 );
850 $def->type->token = psi_token_copy($decl->func->token);
851 $def->type->real.func = $decl;
852 }
853 | decl_enum[enum] name_token {
854 $name_token->type = PSI_T_NAME;
855 $def = psi_decl_arg_init(
856 psi_decl_type_init(PSI_T_ENUM, $enum->name),
857 psi_decl_var_init($name_token->text, 0, 0)
858 );
859 $def->var->token = psi_token_copy($name_token);
860 $def->type->token = psi_token_copy($enum->token);
861 $def->type->real.enm = $enum;
862 psi_parser_proc_add_enum(P, $enum);
863 }
864 | struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
865 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
866 $def->type->token = $struct;
867 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
868 $def->type->real.strct->token = psi_token_copy($struct);
869 $def->type->real.strct->align = $as.pos;
870 $def->type->real.strct->size = $as.len;
871 psi_parser_proc_add_struct(P, $def->type->real.strct);
872 }
873 | union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
874 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
875 $def->type->token = $union;
876 $def->type->real.unn = psi_decl_union_init($union->text, $args);
877 $def->type->real.unn->token = psi_token_copy($union);
878 $def->type->real.unn->align = $as.pos;
879 $def->type->real.unn->size = $as.len;
880 psi_parser_proc_add_union(P, $def->type->real.unn);
881 }
882 ;
883
884 typedef_anon_decl[def]:
885 typedef_decl %dprec 2
886 | qualified_decl_type[type] %dprec 1 {
887 $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
888 $def->var->token = psi_token_copy($type->token);
889 }
890 | decl_enum[enum] {
891 $def = psi_decl_arg_init(
892 psi_decl_type_init(PSI_T_ENUM, $enum->name),
893 psi_decl_var_init(NULL, 0, 0)
894 );
895 $def->var->token = psi_token_copy($enum->token);
896 $def->type->token = psi_token_copy($enum->token);
897 $def->type->real.enm = $enum;
898 psi_parser_proc_add_enum(P, $enum);
899 }
900 | struct_name[struct] align_and_size[as] struct_args_block[args] {
901 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
902 $def->type->token = $struct;
903 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
904 $def->type->real.strct->token = psi_token_copy($struct);
905 $def->type->real.strct->align = $as.pos;
906 $def->type->real.strct->size = $as.len;
907 psi_parser_proc_add_struct(P, $def->type->real.strct);
908 }
909 | union_name[union] align_and_size[as] struct_args_block[args] {
910 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
911 $def->type->token = $union;
912 $def->type->real.unn = psi_decl_union_init($union->text, $args);
913 $def->type->real.unn->token = psi_token_copy($union);
914 $def->type->real.unn->align = $as.pos;
915 $def->type->real.unn->size = $as.len;
916 psi_parser_proc_add_union(P, $def->type->real.unn);
917 }
918 ;
919
920 qualified_decl_type[type]:
921 CONST decl_type[type_] {
922 $type = $type_;
923 }
924 | VOLATILE decl_type[type_] {
925 $type = $type_;
926 }
927 | decl_type
928 ;
929
930 decl_type[type]:
931 decl_type_simple[token] {
932 $type = psi_decl_type_init($token->type, $token->text);
933 $type->token = $token;
934 }
935 | decl_type_complex
936 ;
937
938 decl_type_complex[type]:
939 STRUCT[token] name_token {
940 $name_token->type = PSI_T_NAME;
941 $type = psi_decl_type_init($token->type, $name_token->text);
942 $type->token = psi_token_copy($name_token);
943 }
944 | UNION[token] name_token {
945 $name_token->type = PSI_T_NAME;
946 $type = psi_decl_type_init($token->type, $name_token->text);
947 $type->token = psi_token_copy($name_token);
948 }
949 | ENUM[token] name_token {
950 $name_token->type = PSI_T_NAME;
951 $type = psi_decl_type_init($token->type, $name_token->text);
952 $type->token = psi_token_copy($name_token);
953 }
954 ;
955
956 decl_type_simple[type]:
957 decl_int_type
958 | decl_real_type
959 | NAME[type_] {
960 $type = psi_token_copy($type_);
961 }
962 ;
963
964 decl_real_type[type]:
965 FLOAT[type_] {
966 $type = psi_token_copy($type_);
967 }
968 | DOUBLE[type_] {
969 $type = psi_token_copy($type_);
970 }
971 | LONG DOUBLE {
972 $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
973 }
974 ;
975
976 int_signed[i]:
977 SIGNED
978 | UNSIGNED
979 ;
980
981 int_width[i]:
982 SHORT {
983 $i = psi_token_copy($SHORT);
984 }
985 | LONG {
986 $i = psi_token_copy($LONG);
987 }
988 | LONG[l1] LONG[l2] {
989 $i = psi_token_cat(" ", 2, $l1, $l2);
990 }
991 ;
992
993 decl_int_type[type]:
994 CHAR {
995 $type = psi_token_copy($CHAR);
996 }
997 | INT {
998 $type = psi_token_copy($INT);
999 }
1000 | int_signed int_signed_types {
1001 if ($2) {
1002 $type = psi_token_cat(" ", 2, $1, $2);
1003 free($2);
1004 } else {
1005 $type = psi_token_copy($1);
1006 }
1007 }
1008 | int_width int_width_types {
1009 if ($2) {
1010 $type = psi_token_cat(" ", 2, $1, $2);
1011 free($1);
1012 free($2);
1013 } else {
1014 $type = $1;
1015 }
1016 }
1017 ;
1018
1019 int_signed_types[type]:
1020 %empty {
1021 $type = NULL;
1022 }
1023 | NAME {
1024 $type = psi_token_copy($NAME);
1025 }
1026 | CHAR {
1027 $type = psi_token_copy($CHAR);
1028 }
1029 | SHORT signed_short_types {
1030 if ($2) {
1031 $type = psi_token_cat(" ", 2, $1, $2);
1032 } else {
1033 $type = psi_token_copy($1);
1034 }
1035 }
1036 | INT {
1037 $type = psi_token_copy($INT);
1038 }
1039 | LONG signed_long_types {
1040 if ($2) {
1041 $type = psi_token_cat(" ", 2, $1, $2);
1042 } else {
1043 $type = psi_token_copy($1);
1044 }
1045 }
1046 ;
1047
1048 signed_short_types[type]:
1049 %empty {
1050 $type = NULL;
1051 }
1052 | INT
1053 ;
1054 signed_long_types[type]:
1055 %empty {
1056 $type = NULL;
1057 }
1058 | INT
1059 | LONG
1060 | LONG INT
1061 ;
1062
1063 int_width_types[type]:
1064 %empty {
1065 $type = NULL;
1066 }
1067 | INT {
1068 $type = psi_token_copy($INT);
1069 }
1070 | int_signed int_signed_types {
1071 if ($2) {
1072 $type = psi_token_cat(" ", 2, $1, $2);
1073 free($2);
1074 } else {
1075 $type = psi_token_copy($1);
1076 }
1077 }
1078 ;
1079
1080 decl_stmt:
1081 decl decl_asm EOS {
1082 $decl_stmt = $decl;
1083 }
1084 | CPP_EXTENSION decl decl_asm EOS {
1085 $decl_stmt = $decl;
1086 }
1087 ;
1088
1089 decl_asm:
1090 %empty
1091 | CPP_ASM LPAREN ignored_quoted_strings RPAREN
1092 ;
1093
1094 ignored_quoted_strings:
1095 QUOTED_STRING
1096 | ignored_quoted_strings QUOTED_STRING
1097 ;
1098
1099 decl_ext_var_stmt:
1100 decl_ext_var EOS
1101 ;
1102
1103 decl_ext_var:
1104 NAME decl_arg decl_ext_var_list {
1105 psi_decl_arg_free(&$decl_arg);
1106 }
1107 ;
1108
1109 decl_ext_var_list:
1110 %empty
1111 | COMMA decl_vars {
1112 psi_plist_free($decl_vars);
1113 }
1114 ;
1115
1116 decl_vars[vars]:
1117 decl_var[var] {
1118 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1119 }
1120 | decl_vars[vars_] COMMA decl_var[var] {
1121 $vars = psi_plist_add($vars_, &$var);
1122 }
1123 ;
1124
1125 ignored_decl:
1126 STATIC decl_body ignored_decl_body {
1127 psi_decl_free(&$decl_body);
1128 }
1129 | CPP_INLINE decl_body ignored_decl_body {
1130 psi_decl_free(&$decl_body);
1131 }
1132 | STATIC CPP_INLINE decl_body ignored_decl_body {
1133 psi_decl_free(&$decl_body);
1134 }
1135 ;
1136
1137 ignored_decl_body:
1138 LBRACE ignored_decl_body_stmts RBRACE
1139 ;
1140
1141 ignored_decl_body_stmts:
1142 ignored_decl_body_stmt
1143 | ignored_decl_body_stmts ignored_decl_body_stmt
1144 ;
1145
1146 ignored_decl_body_stmt:
1147 any_nobrace_token
1148 | ignored_decl_body
1149 ;
1150
1151 decl:
1152 decl_body
1153 | NAME[abi] decl_body {
1154 $decl = $decl_body;
1155 $decl->abi = psi_decl_abi_init($abi->text);
1156 }
1157 ;
1158
1159 decl_body:
1160 decl_func_body
1161 | decl_functor_body
1162 ;
1163
1164 decl_func_body[decl]:
1165 decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1166 $decl = psi_decl_init($func, $args);
1167 if ($as) {
1168 $decl->func->var->pointer_level += 1;
1169 $decl->func->var->array_size = $as;
1170 }
1171 }
1172 | decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1173 $decl = psi_decl_init($func, $args);
1174 $decl->varargs = 1;
1175 if ($as) {
1176 $decl->func->var->pointer_level += 1;
1177 $decl->func->var->array_size = $as;
1178 }
1179 }
1180 ;
1181
1182 decl_functor_body[decl]:
1183 decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1184 $decl = psi_decl_init($func, $args);
1185 if ($as) {
1186 $decl->func->var->pointer_level += 1;
1187 $decl->func->var->array_size = $as;
1188 }
1189 }
1190 | decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1191 $decl = psi_decl_init($func, $args);
1192 $decl->varargs = 1;
1193 if ($as) {
1194 $decl->func->var->pointer_level += 1;
1195 $decl->func->var->array_size = $as;
1196 }
1197 }
1198 ;
1199
1200 decl_functor[arg]:
1201 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1202 (void) $unused1;
1203 $NAME->type = PSI_T_NAME;
1204 $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1205 $arg->var->token = psi_token_copy($NAME);
1206 $arg->token = psi_token_copy($NAME);
1207 }
1208 | CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1209 (void) $unused1;
1210 $NAME->type = PSI_T_NAME;
1211 $arg = psi_decl_arg_init(
1212 psi_decl_type_init($VOID->type, $VOID->text),
1213 psi_decl_var_init($NAME->text, $pointers, 0)
1214 );
1215 $arg->type->token = psi_token_copy($VOID);
1216 $arg->var->token = psi_token_copy($NAME);
1217 $arg->token = psi_token_copy($NAME);
1218 }
1219 | VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1220 (void) $unused1;
1221 $NAME->type = PSI_T_NAME;
1222 $arg = psi_decl_arg_init(
1223 psi_decl_type_init($VOID->type, $VOID->text),
1224 psi_decl_var_init($NAME->text, $pointers, 0)
1225 );
1226 $arg->type->token = psi_token_copy($VOID);
1227 $arg->var->token = psi_token_copy($NAME);
1228 $arg->token = psi_token_copy($NAME);
1229 }
1230 | VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1231 (void) $unused1;
1232 $NAME->type = PSI_T_NAME;
1233 $arg = psi_decl_arg_init(
1234 psi_decl_type_init($VOID->type, $VOID->text),
1235 psi_decl_var_init($NAME->text, 0, 0)
1236 );
1237 $arg->type->token = psi_token_copy($VOID);
1238 $arg->var->token = psi_token_copy($NAME);
1239 $arg->token = psi_token_copy($NAME);
1240 }
1241 ;
1242
1243 decl_func[func]:
1244 decl_arg
1245 | VOID name_token[NAME] {
1246 $func = psi_decl_arg_init(
1247 psi_decl_type_init($VOID->type, $VOID->text),
1248 psi_decl_var_init($NAME->text, 0, 0)
1249 );
1250 $func->type->token = psi_token_copy($VOID);
1251 $func->var->token = psi_token_copy($NAME);
1252 $func->token = psi_token_copy($NAME);
1253 }
1254 ;
1255
1256 decl_args[args]:
1257 %empty {
1258 $args = NULL;
1259 }
1260 | VOID {
1261 $args = NULL;
1262 }
1263 | decl_arg_list[args_] {
1264 $args = $args_;
1265 }
1266 ;
1267
1268 decl_arg_list[args]:
1269 decl_anon_arg[arg] {
1270 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1271 }
1272 | decl_arg_list[args_] COMMA decl_anon_arg[arg] {
1273 $args = psi_plist_add($args_, &$arg);
1274 }
1275 ;
1276
1277 decl_anon_arg[arg]:
1278 /* FIXME decl_functor_body_anon */
1279 decl_arg %dprec 2 {
1280 $arg = $decl_arg;
1281 }
1282 | qualified_decl_type[type] indirection %dprec 1 {
1283 $arg = psi_decl_arg_init(
1284 $type,
1285 psi_decl_var_init(NULL, $indirection, 0)
1286 );
1287 }
1288 | CONST VOID pointers {
1289 $arg = psi_decl_arg_init(
1290 psi_decl_type_init($VOID->type, $VOID->text),
1291 psi_decl_var_init(NULL, $pointers, 0)
1292 );
1293 $arg->type->token = psi_token_copy($VOID);
1294 $arg->var->token = psi_token_copy($VOID);
1295 $arg->token = psi_token_copy($VOID);
1296 }
1297 | VOID pointers {
1298 $arg = psi_decl_arg_init(
1299 psi_decl_type_init($VOID->type, $VOID->text),
1300 psi_decl_var_init(NULL, $pointers, 0)
1301 );
1302 $arg->type->token = psi_token_copy($VOID);
1303 $arg->var->token = psi_token_copy($VOID);
1304 $arg->token = psi_token_copy($VOID);
1305 }
1306 ;
1307
1308 decl_arg[arg]:
1309 decl_functor_body[decl] {
1310 $arg = psi_decl_arg_init(
1311 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1312 psi_decl_var_copy($decl->func->var)
1313 );
1314 $arg->type->token = psi_token_copy($decl->func->token);
1315 $arg->type->real.func = $decl;
1316 }
1317 | qualified_decl_type[type] decl_var[var] {
1318 $arg = psi_decl_arg_init($type, $var);
1319 }
1320 | CONST VOID pointers name_token[NAME] {
1321 $NAME->type = PSI_T_NAME;
1322 $arg = psi_decl_arg_init(
1323 psi_decl_type_init($VOID->type, $VOID->text),
1324 psi_decl_var_init($NAME->text, $pointers, 0)
1325 );
1326 $arg->type->token = psi_token_copy($VOID);
1327 $arg->var->token = psi_token_copy($NAME);
1328 $arg->token = psi_token_copy($NAME);
1329 }
1330 | VOID pointers name_token[NAME] {
1331 $NAME->type = PSI_T_NAME;
1332 $arg = psi_decl_arg_init(
1333 psi_decl_type_init($VOID->type, $VOID->text),
1334 psi_decl_var_init($NAME->text, $pointers, 0)
1335 );
1336 $arg->type->token = psi_token_copy($VOID);
1337 $arg->var->token = psi_token_copy($NAME);
1338 $arg->token = psi_token_copy($NAME);
1339 }
1340 ;
1341
1342 decl_var[var]:
1343 pointers name_token array_size {
1344 $name_token->type = PSI_T_NAME;
1345 $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1346 $var->token = psi_token_copy($name_token);
1347 }
1348 | name_token array_size {
1349 $name_token->type = PSI_T_NAME;
1350 $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1351 $var->token = psi_token_copy($name_token);
1352 }
1353 ;
1354
1355 decl_union[union]:
1356 UNION name_token align_and_size[as] decl_struct_args[args] {
1357 $name_token->type = PSI_T_NAME;
1358 $union = psi_decl_union_init($name_token->text, $args);
1359 $union->align = $as.pos;
1360 $union->size = $as.len;
1361 $union->token = psi_token_copy($name_token);
1362 }
1363 ;
1364
1365 decl_struct[struct]:
1366 STRUCT name_token align_and_size[as] decl_struct_args[args] {
1367 $name_token->type = PSI_T_NAME;
1368 $struct = psi_decl_struct_init($name_token->text, $args);
1369 $struct->align = $as.pos;
1370 $struct->size = $as.len;
1371 $struct->token = psi_token_copy($name_token);
1372 }
1373 ;
1374
1375 decl_struct_args[args]:
1376 EOS {
1377 $args = NULL;
1378 }
1379 | struct_args_block
1380 ;
1381
1382 struct_args_block[args]:
1383 LBRACE struct_args RBRACE {
1384 $args = $struct_args;
1385 }
1386 ;
1387
1388 struct_args[args]:
1389 typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1390 $arg->layout = $layout;
1391 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1392 if ($vars) {
1393 size_t i = 0;
1394 struct psi_decl_arg *arg;
1395
1396 while (psi_plist_get($vars, i++, &arg)) {
1397 arg->type = psi_decl_type_copy($arg->type);
1398 $args = psi_plist_add($args, &arg);
1399 }
1400 free($vars);
1401 }
1402 }
1403 | struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1404 $arg->layout = $layout;
1405 $args = psi_plist_add($args_, &$arg);
1406 if ($vars) {
1407 size_t i = 0;
1408 struct psi_decl_arg *arg;
1409
1410 while (psi_plist_get($vars, i++, &arg)) {
1411 arg->type = psi_decl_type_copy($arg->type);
1412 $args = psi_plist_add($args, &arg);
1413 }
1414 free($vars);
1415 }
1416 }
1417 ;
1418
1419 struct_arg_var_list[vars]:
1420 %empty {
1421 $vars = NULL;
1422 }
1423 | COMMA decl_vars_with_layout[vars_] {
1424 $vars = $vars_;
1425 }
1426 ;
1427
1428 decl_vars_with_layout[vars]:
1429 decl_var[var] decl_layout[layout] {
1430 {
1431 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1432 arg->layout = $layout;
1433 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1434 }
1435 }
1436 | decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1437 {
1438 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1439 arg->layout = $layout;
1440 $vars = psi_plist_add($vars_, &arg);
1441 }
1442 }
1443 ;
1444
1445 decl_enum[enum]:
1446 enum_name LBRACE decl_enum_items[list] optional_comma RBRACE {
1447 $enum = psi_decl_enum_init($enum_name->text, $list);
1448 $enum->token = $enum_name;
1449 }
1450 ;
1451
1452 decl_enum_items[list]:
1453 decl_enum_item[i] {
1454 $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1455 }
1456 | decl_enum_items[list_] COMMA decl_enum_item[i] {
1457 $list = psi_plist_add($list_, &$i);
1458 }
1459 ;
1460
1461 decl_enum_item[i]:
1462 name_token {
1463 $name_token->type = PSI_T_NAME;
1464 $i = psi_decl_enum_item_init($name_token->text, NULL);
1465 $i->token = psi_token_copy($name_token);
1466 }
1467 | name_token EQUALS num_exp {
1468 $name_token->type = PSI_T_NAME;
1469 $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1470 $i->token = psi_token_copy($name_token);
1471 }
1472 ;
1473
1474 num_exp[exp]:
1475 number {
1476 $exp = psi_num_exp_init_num($number);
1477 $exp->token = psi_token_copy($number->token);
1478 }
1479 | LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1480 $exp = psi_num_exp_init_cast($type, $exp_);
1481 $exp->token = psi_token_copy($type->token);
1482 }
1483 | LPAREN num_exp[exp_] RPAREN {
1484 $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1485 $exp->token = psi_token_copy($LPAREN);
1486 }
1487 | num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1488 $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1489 $exp->token = psi_token_copy($op);
1490 }
1491 | unary_op_token[op] num_exp[exp_] %prec UNARY {
1492 $exp = psi_num_exp_init_unary($op->type, $exp_);
1493 $exp->token = psi_token_copy($op);
1494 }
1495 | num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1496 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1497 $exp->token = psi_token_copy($IIF);
1498 }
1499 ;
1500
1501 number[num]:
1502 NUMBER[token] {
1503 $num = psi_number_init($token->type, $token->text, $token->flags);
1504 $num->token = psi_token_copy($token);
1505 }
1506 | NSNAME[token] {
1507 $num = psi_number_init($token->type, $token->text, 0);
1508 $num->token = psi_token_copy($token);
1509 }
1510 | QUOTED_CHAR[token] {
1511 $num = psi_number_init($token->type, $token->text, 0);
1512 $num->token = psi_token_copy($token);
1513 }
1514 | NULL[token] {
1515 $num = psi_number_init($token->type, $token->text, 0);
1516 $num->token = psi_token_copy($token);
1517 }
1518 | decl_var {
1519 $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1520 $num->token = psi_token_copy($decl_var->token);
1521 }
1522 | sizeof {
1523 $num = $sizeof;
1524 }
1525 ;
1526
1527 sizeof:
1528 SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1529 $sizeof = $sizeof_;
1530 $sizeof->token = psi_token_copy($SIZEOF);
1531 }
1532 | SIZEOF sizeof_body_notypes[sizeof_] {
1533 $sizeof = $sizeof_;
1534 $sizeof->token = psi_token_copy($SIZEOF);
1535 }
1536 ;
1537
1538 sizeof_body[sizeof]:
1539 sizeof_body_notypes[sizeof_] {
1540 $sizeof = $sizeof_;
1541 }
1542 | decl_type indirection {
1543 if ($indirection) {
1544 int8_t sizeof_void_p = sizeof(void *);
1545 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1546 psi_decl_type_free(&$decl_type);
1547 } else {
1548 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1549 }
1550 }
1551 ;
1552
1553 sizeof_body_notypes[sizeof]:
1554 AMPERSAND NAME {
1555 int8_t sizeof_void_p = sizeof(void *);
1556 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1557 }
1558 | QUOTED_CHAR {
1559 int8_t sizeof_a = sizeof('a');
1560 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1561 }
1562 | QUOTED_STRING {
1563 $sizeof = psi_number_init(PSI_T_INT64, &$QUOTED_STRING->size, 0);
1564 }
1565 ;
1566
1567 enum_name[name]:
1568 ENUM optional_name[name_] {
1569 if ($name_) {
1570 $name = psi_token_copy($name_);
1571 } else {
1572 char digest[17];
1573
1574 psi_token_hash($ENUM, digest);
1575 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1576 }
1577 }
1578 ;
1579
1580 union_name[name]:
1581 UNION optional_name[name_] {
1582 if ($name_) {
1583 $name = psi_token_copy($name_);
1584 } else {
1585 char digest[17];
1586
1587 psi_token_hash($UNION, digest);
1588 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1589 }
1590 }
1591 ;
1592
1593 struct_name[name]:
1594 STRUCT optional_name[name_] {
1595 if ($name_) {
1596 $name = psi_token_copy($name_);
1597 } else {
1598 char digest[17];
1599
1600 psi_token_hash($STRUCT, digest);
1601 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1602 }
1603 }
1604 ;
1605
1606 optional_name[name]:
1607 %empty {
1608 $name = NULL;
1609 }
1610 | name_token {
1611 $name = $name_token;
1612 $name->type = PSI_T_NAME;
1613 }
1614 ;
1615
1616 optional_comma:
1617 %empty
1618 | COMMA
1619 ;
1620
1621 decl_layout[l]:
1622 %empty {
1623 $l = NULL;
1624 }
1625 | COLON NUMBER[width] {
1626 $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1627 }
1628 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1629 $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1630 }
1631 | COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1632 $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1633 }
1634 ;
1635
1636 align_and_size[as]:
1637 %empty {
1638 $as.pos = 0;
1639 $as.len = 0;
1640 }
1641 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1642 $as.pos = atol($align->text);
1643 $as.len = atol($size->text);
1644 }
1645 ;
1646
1647 array_size[as]:
1648 %empty {
1649 $as = 0;
1650 }
1651 | LBRACKET RBRACKET {
1652 $as = 0;
1653 }
1654 | LBRACKET CPP_RESTRICT RBRACKET {
1655 $as = 0;
1656 }
1657 | LBRACKET num_exp RBRACKET {
1658 if (psi_num_exp_validate(PSI_DATA(P), $num_exp, NULL, NULL, NULL, NULL, NULL)) {
1659 $as = psi_long_num_exp($num_exp, NULL, &P->preproc->defs);
1660 } else {
1661 $as = 0;
1662 }
1663 psi_num_exp_free(&$num_exp);
1664 }
1665 ;
1666
1667 indirection[i]:
1668 %empty {
1669 $i = 0;
1670 }
1671 | pointers[p] %prec UNARY {
1672 $i = $p;
1673 }
1674 ;
1675
1676 pointers[p]:
1677 asterisks
1678 | asterisks[a] CPP_RESTRICT {
1679 $p = $a;
1680 }
1681 ;
1682
1683 asterisks[a]:
1684 asterisk {
1685 $a = 1;
1686 }
1687 | asterisks[a_] asterisk {
1688 $a = $a_ + 1;
1689 }
1690 ;
1691
1692 asterisk:
1693 ASTERISK
1694 | ASTERISK CONST
1695 ;
1696
1697 /*
1698 *
1699 * impl
1700 *
1701 */
1702
1703 impl:
1704 impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1705 $impl = psi_impl_init($func, $stmts);
1706 }
1707 | STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1708 $impl = psi_impl_init($func, $stmts);
1709 $func->static_memory = 1;
1710 }
1711 ;
1712
1713 impl_func[func]:
1714 FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1715 $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1716 $func->token = psi_token_copy($NSNAME);
1717 $func->return_reference = $r;
1718 }
1719 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1720 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1721 $func->token = psi_token_copy($NSNAME);
1722 $func->return_reference = $r;
1723 }
1724 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1725 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1726 $func->token = psi_token_copy($NSNAME);
1727 $func->return_reference = $r;
1728 $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1729 $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1730 }
1731 ;
1732
1733 impl_args[args]:
1734 impl_arg[arg] {
1735 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1736 }
1737 | impl_args[args_] COMMA impl_arg[arg] {
1738 $args = psi_plist_add($args_, &$arg);
1739 }
1740 ;
1741
1742 impl_arg[arg]:
1743 impl_type[type] impl_var[var] {
1744 $arg = psi_impl_arg_init($type, $var, NULL);
1745 }
1746 | impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1747 $arg = psi_impl_arg_init($type, $var, $val);
1748 }
1749 ;
1750
1751 impl_var[var]:
1752 reference DOLLAR_NAME {
1753 $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1754 $var->token = psi_token_copy($DOLLAR_NAME);
1755 }
1756 ;
1757
1758 impl_type[type]:
1759 impl_type_token[token] {
1760 $type = psi_impl_type_init($token->type, $token->text);
1761 $type->token = psi_token_copy($token);
1762 }
1763 ;
1764
1765 impl_type_token:
1766 VOID
1767 | MIXED
1768 | BOOL
1769 | INT
1770 | FLOAT
1771 | STRING
1772 | ARRAY
1773 | OBJECT
1774 | CALLABLE
1775 ;
1776
1777 impl_stmts[stmts]:
1778 impl_stmt[stmt] {
1779 $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1780 }
1781 | impl_stmts[stmts_] impl_stmt[stmt] {
1782 $stmts = psi_plist_add($stmts_, &$stmt);
1783 }
1784 ;
1785
1786 impl_stmt[stmt]:
1787 return_stmt[s] {
1788 $stmt = (struct psi_token **) $s;
1789 }
1790 | let_stmt[s] {
1791 $stmt = (struct psi_token **) $s;
1792 }
1793 | set_stmt[s] {
1794 $stmt = (struct psi_token **) $s;
1795 }
1796 | assert_stmt[s] {
1797 $stmt = (struct psi_token **) $s;
1798 }
1799 | free_stmt[s] {
1800 $stmt = (struct psi_token **) $s;
1801 }
1802 ;
1803
1804 let_stmt[let]:
1805 LET let_exp_assign[exp] EOS {
1806 $let = psi_let_stmt_init($exp);
1807 $let->token = psi_token_copy($LET);
1808 }
1809 | TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1810 $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1811 $let->token = psi_token_copy($TEMP);
1812 $let->exp->is_reference = $reference;
1813 }
1814 ;
1815
1816 let_exp[exp]:
1817 let_exp_assign
1818 | byref let_exp_byref[exp_] {
1819 $exp = $exp_;
1820 $exp->is_reference = true;
1821 }
1822 | let_exp_byref[exp_] {
1823 $exp = $exp_;
1824 $exp->is_reference = false;
1825 }
1826 ;
1827
1828 let_exp_byref[exp]:
1829 NULL %dprec 2 {
1830 $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1831 }
1832 | num_exp[num] %dprec 1 {
1833 $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1834 }
1835 | let_calloc[calloc] {
1836 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1837 }
1838 | STATIC let_calloc[calloc] {
1839 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1840 $calloc->static_memory = 1;
1841 }
1842 | let_callback[callback] {
1843 $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1844 }
1845 | let_func[func] {
1846 $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1847 }
1848 ;
1849
1850 let_exp_assign[exp]:
1851 decl_var[var] EQUALS let_exp_byref[exp_] {
1852 $exp = $exp_;
1853 $exp->var = $var;
1854 }
1855 | decl_var[var] EQUALS byref let_exp_byref[exp_] {
1856 $exp = $exp_;
1857 $exp->is_reference = 1;
1858 $exp->var = $var;
1859 }
1860 ;
1861
1862 let_calloc[calloc]:
1863 CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1864 $calloc = psi_let_calloc_init($nmemb, $size);
1865 $calloc->token = psi_token_copy($CALLOC);
1866 }
1867 ;
1868
1869 let_callback[callback]:
1870 CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1871 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, NULL);
1872 $callback->func->token = psi_token_copy($func);
1873 $callback->token = psi_token_copy($CALLBACK);
1874 }
1875 | CALLBACK LPAREN call_decl_vars[cb_args] RPAREN AS callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1876 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, $cb_args);
1877 $callback->func->token = psi_token_copy($func);
1878 $callback->token = psi_token_copy($CALLBACK);
1879 }
1880 ;
1881
1882 let_func[func]:
1883 let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1884 $func = psi_let_func_init($token->type, $token->text, $var);
1885 $func->token = psi_token_copy($token);
1886 $func->inner = $exps;
1887 }
1888 ;
1889
1890 let_func_token:
1891 ZVAL
1892 | OBJVAL
1893 | ARRVAL
1894 | PATHVAL
1895 | STRLEN
1896 | STRVAL
1897 | FLOATVAL
1898 | INTVAL
1899 | BOOLVAL
1900 | COUNT
1901 ;
1902
1903 let_func_exps[exps]:
1904 %empty {
1905 $exps = NULL;
1906 }
1907 | COMMA let_exps[exps_] {
1908 $exps = $exps_;
1909 }
1910 ;
1911
1912 let_exps[exps]:
1913 let_exp[exp] {
1914 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1915 }
1916 | let_exps[exps_] COMMA let_exp[exp] {
1917 $exps = psi_plist_add($exps_, &$exp);
1918 }
1919 ;
1920
1921 callback_rval[rval]:
1922 VOID
1923 | let_func_token
1924 ;
1925
1926 callback_arg_list[list]:
1927 %empty {
1928 $list = NULL;
1929 }
1930 | callback_args[args] {
1931 $list = $args;
1932 }
1933 ;
1934
1935 callback_args[args]:
1936 set_exp[exp] {
1937 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1938 }
1939 | callback_args[args_] COMMA set_exp[exp] {
1940 $args = psi_plist_add($args_, &$exp);
1941 }
1942 ;
1943
1944 return_stmt[return]:
1945 RETURN return_exp EOS {
1946 $return = psi_return_stmt_init($return_exp);
1947 $return->token = psi_token_copy($RETURN);
1948 }
1949 ;
1950
1951 return_exp:
1952 decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
1953 $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1954 $return_exp->token = psi_token_copy($func->token);
1955 }
1956 | set_func {
1957 $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
1958 $return_exp->token = psi_token_copy($set_func->token);
1959 }
1960 ;
1961
1962 call_decl_vars[args]:
1963 %empty {
1964 $args = NULL;
1965 }
1966 | VOID {
1967 $args = NULL;
1968 }
1969 | decl_vars[vars] {
1970 $args = $vars;
1971 }
1972 ;
1973
1974 set_stmt[set]:
1975 SET set_exp[exp] EOS {
1976 $set = psi_set_stmt_init($exp);
1977 $set->token = psi_token_copy($SET);
1978 }
1979 ;
1980
1981 set_exp[exp]:
1982 set_func[func] {
1983 $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1984 }
1985 | num_exp[num] {
1986 $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1987 }
1988 | impl_var[var] EQUALS set_exp[exp_] {
1989 $exp = $exp_;
1990 $exp->var = $var;
1991 }
1992 ;
1993
1994 set_func[func]:
1995 set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1996 $func = psi_set_func_init($token->type, $token->text, $var);
1997 $func->token = psi_token_copy($token);
1998 $func->inner = $exps;
1999 }
2000 | set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
2001 $func = psi_set_func_init($token->type, $token->text, $var);
2002 $func->token = psi_token_copy($token);
2003 $func->recursive = 1;
2004 }
2005 ;
2006
2007 set_func_token:
2008 TO_OBJECT
2009 | TO_ARRAY
2010 | TO_STRING
2011 | TO_INT
2012 | TO_FLOAT
2013 | TO_BOOL
2014 | ZVAL
2015 | VOID
2016 ;
2017
2018 set_func_exps[exps]:
2019 %empty {
2020 $exps = NULL;
2021 }
2022 | COMMA set_exps[exps_] {
2023 $exps = $exps_;
2024 }
2025 ;
2026
2027 set_exps[exps]:
2028 set_exp[exp] {
2029 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2030 }
2031 | set_exps[exps_] COMMA set_exp[exp] {
2032 $exps = psi_plist_add($exps_, &$exp);
2033 }
2034 ;
2035
2036 assert_stmt[assert]:
2037 assert_stmt_token[token] num_exp[exp] EOS {
2038 $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
2039 $assert->token = psi_token_copy($token);
2040 }
2041 ;
2042
2043 assert_stmt_token:
2044 PRE_ASSERT
2045 | POST_ASSERT
2046 ;
2047
2048 free_stmt[free]:
2049 FREE free_exps[exps] EOS {
2050 $free = psi_free_stmt_init($exps);
2051 $free->token = psi_token_copy($FREE);
2052 }
2053 ;
2054
2055 free_exps[exps]:
2056 free_exp[exp] {
2057 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
2058 }
2059 | free_exps[exps_] COMMA free_exp[exp] {
2060 $exps = psi_plist_add($exps_, &$exp);
2061 }
2062 ;
2063
2064 free_exp[exp]:
2065 name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2066 $NAME->type = PSI_T_NAME;
2067 $exp = psi_free_exp_init($NAME->text, $vars);
2068 $exp->token = psi_token_copy($NAME);
2069 }
2070 ;
2071
2072 reference:
2073 %empty {
2074 $reference = false;
2075 }
2076 | byref {
2077 $reference = true;
2078 }
2079 ;
2080
2081 byref:
2082 AMPERSAND %prec UNARY
2083 ;
2084
2085 %%
2086
2087 /* epilogue */
2088
2089 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2090 {
2091 struct psi_token *token;
2092
2093 if (psi_plist_get(tokens, (*index)++, &token)) {
2094 if (P->flags & PSI_DEBUG) {
2095 psi_token_dump(2, token);
2096 }
2097
2098 *((struct psi_token **)lvalp) = token;
2099 return token->type;
2100 } else {
2101 (*index)--;
2102 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
2103 }
2104
2105 return PSI_T_EOF;
2106 }
2107
2108 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2109 {
2110 struct psi_token *T = NULL;
2111 size_t last;
2112
2113 if (*index == 0) {
2114 last = 0;
2115 } else {
2116 last = --(*index);
2117 }
2118
2119 psi_plist_get(tokens, last, &T);
2120 if (T) {
2121 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2122 } else {
2123 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2124 }
2125 P->errors++;
2126 }
2127
PHP System Interface / POSIX Standard Interface