git.m6w6.name Git - m6w6/ext-psi/blob - src/parser_proc_grammar.y

   1 %code top {
   2 #include "php_psi_stdinc.h"
   3 }
   4
   5 %code {
   6 #include <assert.h>
   7 #include <stdarg.h>
   8
   9 #include "plist.h"
  10 #include "parser.h"
  11 #define YYDEBUG 1
  12
  13 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
  14 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
  15
  16 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
  17 {
  18         assert(strct);
  19         if (!P->structs) {
  20                 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
  21         }
  22         P->structs = psi_plist_add(P->structs, &strct);
  23 }
  24 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
  25 {
  26         assert(u);
  27         if (!P->unions) {
  28                 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
  29         }
  30         P->unions = psi_plist_add(P->unions, &u);
  31 }
  32 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
  33 {
  34         assert(e);
  35         if (!P->enums) {
  36                 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
  37         }
  38         P->enums = psi_plist_add(P->enums, &e);
  39 }
  40 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
  41 {
  42         assert(def);
  43         if (!P->types) {
  44                 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
  45         }
  46         P->types = psi_plist_add(P->types, &def);
  47 }
  48 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
  49         assert(cnst);
  50         if (!P->consts) {
  51                 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
  52         }
  53         P->consts = psi_plist_add(P->consts, &cnst);
  54
  55 }
  56 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
  57         assert(decl);
  58         if (!P->decls) {
  59                 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
  60         }
  61         P->decls = psi_plist_add(P->decls, &decl);
  62 }
  63 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
  64         assert(impl);
  65         if (!P->impls) {
  66                 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
  67         }
  68         P->impls = psi_plist_add(P->impls, &impl);
  69 }
  70
  71 /* end code */
  72 }
  73
  74 %code requires {
  75 #include "plist.h"
  76 #include "types/layout.h"
  77
  78 struct psi_parser;
  79
  80 }
  81
  82 %require "3.0"
  83 %language "c"
  84 %name-prefix "psi_parser_proc_"
  85 %token-table
  86 %verbose
  87 %glr-parser
  88
  89 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
  90
  91 %define api.pure true
  92 %define api.token.prefix {PSI_T_}
  93 %define api.value.type union
  94
  95 %define parse.error verbose
  96 %define parse.trace true
  97
  98 %initial-action {
  99 }
 100
 101 %start file
 102
 103 %token <struct psi_token *> BOOL
 104 %token <struct psi_token *> CHAR
 105 %token <struct psi_token *> SHORT
 106 %token <struct psi_token *> INT
 107 %token <struct psi_token *> SIGNED
 108 %token <struct psi_token *> UNSIGNED
 109 %token <struct psi_token *> LONG
 110 %token <struct psi_token *> FLOAT
 111 %token <struct psi_token *> DOUBLE
 112 %token <struct psi_token *> STRING
 113 %token <struct psi_token *> MIXED
 114 %token <struct psi_token *> ARRAY
 115 %token <struct psi_token *> OBJECT
 116 %token <struct psi_token *> CALLABLE
 117 %token <struct psi_token *> VOID
 118 %token <struct psi_token *> ZVAL
 119 %token <struct psi_token *> INT8
 120 %token <struct psi_token *> UINT8
 121 %token <struct psi_token *> INT16
 122 %token <struct psi_token *> UINT16
 123 %token <struct psi_token *> INT32
 124 %token <struct psi_token *> UINT32
 125 %token <struct psi_token *> INT64
 126 %token <struct psi_token *> UINT64
 127 %token <struct psi_token *> NULL
 128 %token <struct psi_token *> TRUE
 129 %token <struct psi_token *> FALSE
 130 %token <struct psi_token *> NAME
 131 %token <struct psi_token *> NSNAME
 132 %token <struct psi_token *> DOLLAR_NAME
 133 %token <struct psi_token *> NUMBER
 134 %token <struct psi_token *> QUOTED_STRING
 135 %token <struct psi_token *> QUOTED_CHAR
 136
 137 %token <struct psi_token *> EOF 0               "end of file"
 138 %token <struct psi_token *> EOL                 "end of line"
 139 %token <struct psi_token *> EOS                 ";"
 140 %token <struct psi_token *> LPAREN              "("
 141 %token <struct psi_token *> RPAREN              ")"
 142 %token <struct psi_token *> COMMA               ","
 143 %token <struct psi_token *> COLON               ":"
 144 %token <struct psi_token *> LBRACE              "{"
 145 %token <struct psi_token *> RBRACE              "}"
 146 %token <struct psi_token *> LBRACKET    "["
 147 %token <struct psi_token *> RBRACKET    "]"
 148 %token <struct psi_token *> EQUALS              "="
 149 %token <struct psi_token *> HASH                "#"
 150 %token <struct psi_token *> PIPE                "|"
 151 %token <struct psi_token *> CARET               "^"
 152 %token <struct psi_token *> AMPERSAND   "&"
 153 %token <struct psi_token *> LSHIFT              "<<"
 154 %token <struct psi_token *> RSHIFT              ">>"
 155 %token <struct psi_token *> PLUS                "+"
 156 %token <struct psi_token *> MINUS               "-"
 157 %token <struct psi_token *> ASTERISK    "*"
 158 %token <struct psi_token *> SLASH               "/"
 159 %token <struct psi_token *> MODULO              "%"
 160 %token <struct psi_token *> LCHEVR              "<"
 161 %token <struct psi_token *> RCHEVR              ">"
 162 %token <struct psi_token *> CMP_GE              ">="
 163 %token <struct psi_token *> CMP_LE              "<="
 164 %token <struct psi_token *> OR                  "||"
 165 %token <struct psi_token *> AND                 "&&"
 166 %token <struct psi_token *> CMP_EQ              "=="
 167 %token <struct psi_token *> CMP_NE              "!="
 168 %token <struct psi_token *> TILDE               "~"
 169 %token <struct psi_token *> NOT                 "!"
 170 %token <struct psi_token *> PERIOD              "."
 171 %token <struct psi_token *> BACKSLASH   "\\"
 172 %token <struct psi_token *> ELLIPSIS    "..."
 173 %token <struct psi_token *> IIF                 "?"
 174
 175 %token <struct psi_token *> PRAGMA
 176 %token <struct psi_token *> PRAGMA_ONCE
 177 %token <struct psi_token *> LINE
 178 %token <struct psi_token *> ERROR
 179 %token <struct psi_token *> WARNING
 180 %token <struct psi_token *> IF
 181 %token <struct psi_token *> IFDEF
 182 %token <struct psi_token *> IFNDEF
 183 %token <struct psi_token *> ELSE
 184 %token <struct psi_token *> ELIF
 185 %token <struct psi_token *> ENDIF
 186 %token <struct psi_token *> DEFINE
 187 %token <struct psi_token *> DEFINED
 188 %token <struct psi_token *> UNDEF
 189 %token <struct psi_token *> IMPORT
 190 %token <struct psi_token *> INCLUDE
 191 %token <struct psi_token *> INCLUDE_NEXT
 192
 193 %token <struct psi_token *> TYPEDEF
 194 %token <struct psi_token *> STRUCT
 195 %token <struct psi_token *> UNION
 196 %token <struct psi_token *> ENUM
 197 %token <struct psi_token *> CONST
 198 %token <struct psi_token *> LIB
 199 %token <struct psi_token *> STATIC
 200 %token <struct psi_token *> CALLBACK
 201 %token <struct psi_token *> FUNCTION
 202 %token <struct psi_token *> LET
 203 %token <struct psi_token *> SET
 204 %token <struct psi_token *> TEMP
 205 %token <struct psi_token *> FREE
 206 %token <struct psi_token *> RETURN
 207 %token <struct psi_token *> PRE_ASSERT
 208 %token <struct psi_token *> POST_ASSERT
 209 %token <struct psi_token *> BOOLVAL
 210 %token <struct psi_token *> INTVAL
 211 %token <struct psi_token *> STRVAL
 212 %token <struct psi_token *> PATHVAL
 213 %token <struct psi_token *> STRLEN
 214 %token <struct psi_token *> FLOATVAL
 215 %token <struct psi_token *> ARRVAL
 216 %token <struct psi_token *> OBJVAL
 217 %token <struct psi_token *> COUNT
 218 %token <struct psi_token *> CALLOC
 219 %token <struct psi_token *> TO_BOOL
 220 %token <struct psi_token *> TO_INT
 221 %token <struct psi_token *> TO_STRING
 222 %token <struct psi_token *> TO_FLOAT
 223 %token <struct psi_token *> TO_ARRAY
 224 %token <struct psi_token *> TO_OBJECT
 225
 226 %token <struct psi_token *> COMMENT
 227 %token <struct psi_token *> WHITESPACE
 228 %token <struct psi_token *> NO_WHITESPACE
 229 %token <struct psi_token *> CPP_HEADER
 230 %token <struct psi_token *> CPP_ATTRIBUTE
 231 %token <struct psi_token *> CPP_EXTENSION
 232 %token <struct psi_token *> CPP_PASTE
 233 %token <struct psi_token *> CPP_RESTRICT
 234 %token <struct psi_token *> CPP_ASM
 235
 236 %precedence IIF COLON
 237 %precedence OR
 238 %precedence AND
 239 %precedence PIPE
 240 %precedence CARET
 241 %precedence AMPERSAND
 242 %precedence CMP_EQ CMP_NE
 243 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
 244 %precedence LSHIFT RSHIFT
 245 %precedence PLUS MINUS
 246 %precedence ASTERISK SLASH MODULO
 247 //%precedence NOT TILDE
 248 %precedence BINARY
 249 %precedence UNARY
 250
 251 %type           <struct psi_token *>                            lib optional_name enum_name struct_name union_name
 252 %destructor     {psi_token_free(&$$);}                          lib optional_name enum_name struct_name union_name
 253
 254 %type           <struct psi_token *>                            cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 255 %destructor     {}                                                                      cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 256
 257 %type           <struct psi_token *>                            name_token any_noeol_token binary_op_token unary_op_token
 258 %destructor     {}                                                                      name_token any_noeol_token binary_op_token unary_op_token
 259
 260 %type           <struct psi_token *>                            int_width int_width_types int_signed_types
 261 %destructor     {psi_token_free(&$$);}                          int_width int_width_types int_signed_types
 262
 263 %type           <struct psi_token *>                            signed_long_types signed_short_types int_signed
 264 %destructor     {}                                                                      signed_long_types signed_short_types int_signed
 265
 266 %type           <struct psi_cpp_exp *>                          cpp cpp_exp
 267 %destructor     {psi_cpp_exp_free(&$$);}                        cpp cpp_exp
 268 %type           <struct psi_cpp_macro_decl *>           cpp_macro_decl
 269 %destructor     {psi_cpp_macro_decl_free(&$$);}         cpp_macro_decl
 270 %type           <struct psi_plist *>                            cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 271 %destructor {psi_plist_free($$);}                               cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 272 %type           <struct psi_num_exp *>                          cpp_macro_exp
 273 %destructor     {psi_num_exp_free(&$$);}                        cpp_macro_exp
 274
 275 %type           <struct psi_token *>                            constant_type_token impl_def_val_token
 276 %destructor     {}                                                                      constant_type_token impl_def_val_token
 277
 278 %type           <struct psi_const *>                            constant
 279 %destructor     {psi_const_free(&$$);}                          constant
 280 %type           <struct psi_const_type *>                       constant_type
 281 %destructor     {psi_const_type_free(&$$);}                     constant_type
 282 %type           <struct psi_impl_def_val *>                     impl_def_val
 283 %destructor     {psi_impl_def_val_free(&$$);}           impl_def_val
 284
 285 %type           <struct psi_token *>                            decl_real_type decl_int_type decl_type_simple
 286 %destructor     {psi_token_free(&$$);}                          decl_real_type decl_int_type decl_type_simple
 287
 288 %type           <struct psi_token *>                            decl_stdint_type
 289 %destructor     {}                                                                      decl_stdint_type
 290
 291 %type           <struct psi_decl_type *>                        decl_type const_decl_type decl_type_complex
 292 %destructor     {psi_decl_type_free(&$$);}                      decl_type const_decl_type decl_type_complex
 293 %type           <struct psi_decl *>                                     decl_stmt decl decl_body decl_func_body decl_functor_body
 294 %destructor     {psi_decl_free(&$$);}                           decl_stmt decl decl_body decl_func_body decl_functor_body
 295 %type           <struct psi_decl_arg *>                         decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef
 296 %destructor     {psi_decl_arg_free(&$$);}                       decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef
 297 %type           <struct psi_decl_var *>                         decl_var
 298 %destructor     {psi_decl_var_free(&$$);}                       decl_var
 299 %type           <struct psi_decl_struct *>                      decl_struct
 300 %destructor     {psi_decl_struct_free(&$$);}            decl_struct
 301 %type           <struct psi_decl_union *>                       decl_union
 302 %destructor     {psi_decl_union_free(&$$);}                     decl_union
 303 %type           <struct psi_decl_enum *>                        decl_enum
 304 %destructor     {psi_decl_enum_free(&$$);}                      decl_enum
 305 %type           <struct psi_decl_enum_item *>           decl_enum_item
 306 %destructor     {psi_decl_enum_item_free(&$$);}         decl_enum_item
 307 %type           <struct psi_plist *>                            decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 308 %destructor     {psi_plist_free($$);}                           decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 309
 310 %type           <struct psi_layout>                                     align_and_size
 311 %destructor     {}                                                                      align_and_size
 312 %type           <struct psi_layout *>                           decl_layout
 313 %destructor     {psi_layout_free(&$$);}                         decl_layout
 314
 315 %type           <struct psi_impl *>                                     impl
 316 %destructor     {psi_impl_free(&$$);}                           impl
 317 %type           <struct psi_impl_func *>                        impl_func
 318 %destructor     {psi_impl_func_free(&$$);}                      impl_func
 319 %type           <struct psi_impl_arg *>                         impl_arg
 320 %destructor     {psi_impl_arg_free(&$$);}                       impl_arg
 321 %type           <struct psi_impl_type *>                        impl_type
 322 %destructor     {psi_impl_type_free(&$$);}                      impl_type
 323 %type           <struct psi_impl_var *>                         impl_var
 324 %destructor     {psi_impl_var_free(&$$);}                       impl_var
 325
 326 %type           <struct psi_let_stmt *>                         let_stmt
 327 %destructor     {psi_let_stmt_free(&$$);}                       let_stmt
 328 %type           <struct psi_let_exp *>                          let_exp let_exp_byref let_exp_assign
 329 %destructor     {psi_let_exp_free(&$$);}                        let_exp let_exp_byref let_exp_assign
 330 %type           <struct psi_let_calloc *>                       let_calloc
 331 %destructor     {psi_let_calloc_free(&$$);}                     let_calloc
 332 %type           <struct psi_let_callback *>                     let_callback
 333 %destructor     {psi_let_callback_free(&$$);}           let_callback
 334 %type           <struct psi_let_func *>                         let_func
 335 %destructor     {psi_let_func_free(&$$);}                       let_func
 336 %type           <struct psi_set_stmt *>                         set_stmt
 337 %destructor     {psi_set_stmt_free(&$$);}                       set_stmt
 338 %type           <struct psi_set_exp *>                          set_exp
 339 %destructor     {psi_set_exp_free(&$$);}                        set_exp
 340 %type           <struct psi_set_func *>                         set_func
 341 %destructor     {psi_set_func_free(&$$);}                       set_func
 342 %type           <struct psi_assert_stmt *>                      assert_stmt
 343 %destructor     {psi_assert_stmt_free(&$$);}            assert_stmt
 344 %type           <struct psi_return_stmt *>                      return_stmt
 345 %destructor     {psi_return_stmt_free(&$$);}            return_stmt
 346 %type           <struct psi_free_stmt *>                        free_stmt
 347 %destructor     {psi_free_stmt_free(&$$);}                      free_stmt
 348 %type           <struct psi_free_exp *>                         free_exp
 349 %destructor     {psi_free_exp_free(&$$);}                       free_exp
 350
 351 %type           <struct psi_token **>                           impl_stmt
 352 %destructor     {psi_impl_stmt_free(&$$);}                      impl_stmt
 353 %type           <struct psi_token *>                            impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 354 %destructor     {psi_token_free(&$$);}                          impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 355 %type           <struct psi_plist *>                            impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 356 %destructor     {psi_plist_free($$);}                           impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 357
 358 %type           <struct psi_num_exp *>                          num_exp
 359 %destructor     {psi_num_exp_free(&$$);}                        num_exp
 360 %type           <struct psi_number *>                           number
 361 %destructor     {psi_number_free(&$$);}                         number
 362
 363 %type           <size_t>                                                        indirection pointers asterisks array_size
 364 %destructor     {}                                                                      indirection pointers asterisks array_size
 365 %type           <bool>                                                          reference
 366 %destructor     {}                                                                      reference
 367
 368 %%
 369
 370 /* rules */
 371
 372
 373 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
 374 unary_op_token: TILDE | NOT | PLUS | MINUS ;
 375 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | let_func_token | set_func_token;
 376 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | INT8 | UINT8 | INT16 | UINT16 | INT32 | UINT32 | INT64 | UINT64 | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM;
 377
 378
 379 file:
 380         %empty
 381 |       blocks
 382 ;
 383 blocks:
 384         block
 385 |       blocks block
 386 ;
 387 block:
 388         EOS
 389 |       EOL
 390 |       COMMENT
 391 |       cpp {
 392         if ($cpp) {
 393                 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
 394                 psi_cpp_exp_free(&$cpp);
 395         }
 396 }
 397 |       lib {
 398         if (P->file.ln) {
 399                 P->error(PSI_DATA(P), $lib, PSI_WARNING,
 400                                 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
 401         } else {
 402                 P->file.ln = strndup($lib->text, $lib->size);
 403         }
 404 }
 405 |       constant {
 406         psi_parser_proc_add_const(P, $constant);
 407 }
 408 |       decl_stmt {
 409         psi_parser_proc_add_decl(P, $decl_stmt);
 410 }
 411 |       decl_ext_var_stmt
 412 |       decl_typedef[def] {
 413         psi_parser_proc_add_typedef(P, $def);
 414 }
 415 |       decl_struct[struct] {
 416         psi_parser_proc_add_struct(P, $struct);
 417 }
 418 |       decl_union[union] {
 419         psi_parser_proc_add_union(P, $union);
 420 }
 421 |       decl_enum[enum] {
 422         psi_parser_proc_add_enum(P, $enum);
 423 }
 424 |       impl {
 425         psi_parser_proc_add_impl(P, $impl);
 426 }
 427 ;
 428
 429 lib:
 430         LIB QUOTED_STRING EOS {
 431         $lib = $QUOTED_STRING;
 432 }
 433 ;
 434
 435 cpp:
 436         HASH EOL {
 437         $cpp = NULL;
 438 }
 439 |       HASH cpp_exp[exp] EOL {
 440         $cpp = $exp;
 441 }
 442 ;
 443
 444 cpp_exp[exp]:
 445         cpp_message_token cpp_macro_decl_tokens[tokens] {
 446         if ($tokens) {
 447                 struct psi_token *msg = NULL;
 448
 449                 if (psi_plist_get($tokens, 0, &msg)) {
 450                         size_t index = 1;
 451                         struct psi_token *next;
 452
 453                         msg = psi_token_copy(msg);
 454                         while (psi_plist_get($tokens, index++, &next)) {
 455                                 struct psi_token *old = msg;
 456                                 msg = psi_token_cat(" ", 2, msg, next);
 457                                 free(old);
 458                         }
 459                 }
 460                 psi_plist_free($tokens);
 461
 462                 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
 463         } else {
 464                 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
 465         }
 466         $exp->token = psi_token_copy($cpp_message_token);
 467 }
 468 |       cpp_include_token[INCLUDE] cpp_header_token {
 469         $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
 470         $exp->token = psi_token_copy($INCLUDE);
 471 }
 472 |       cpp_no_arg_token {
 473         $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
 474         $exp->token = psi_token_copy($cpp_no_arg_token);
 475 }
 476 |       cpp_name_arg_token cpp_special_name_token[name_token] {
 477         $name_token->type = PSI_T_NAME;
 478         $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
 479         $exp->token = psi_token_copy($cpp_name_arg_token);
 480 }
 481 |       DEFINE cpp_macro_decl {
 482         $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
 483         $exp->token = psi_token_copy($DEFINE);
 484 }
 485 |       cpp_exp_arg_token cpp_macro_exp {
 486         $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
 487         $exp->token = psi_token_copy($cpp_exp_arg_token);
 488 }
 489 |       PRAGMA_ONCE {
 490         $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
 491         $exp->token = psi_token_copy($PRAGMA_ONCE);
 492 }
 493 |       cpp_ignored_token cpp_macro_decl_tokens[tokens] {
 494         psi_plist_free($tokens);
 495         $exp = NULL;
 496 }
 497 ;
 498
 499 cpp_ignored_token:
 500         LINE
 501 |       PRAGMA
 502 ;
 503
 504 cpp_message_token:
 505         ERROR
 506 |       WARNING
 507 ;
 508
 509 cpp_include_token:
 510         IMPORT
 511 |       INCLUDE
 512 |       INCLUDE_NEXT
 513 ;
 514
 515 cpp_header_token:
 516         QUOTED_STRING
 517 |       CPP_HEADER
 518 ;
 519
 520 cpp_no_arg_token:
 521         ELSE
 522 |       ENDIF
 523 ;
 524
 525 cpp_name_arg_token:
 526         IFDEF
 527 |       IFNDEF
 528 |       UNDEF
 529 ;
 530
 531 cpp_exp_arg_token:
 532         IF
 533 |       ELIF
 534 ;
 535
 536 cpp_special_name_token:
 537         name_token
 538 |       NULL
 539 |       TRUE
 540 |       FALSE
 541 |       CPP_RESTRICT
 542 |       CPP_EXTENSION
 543 ;
 544
 545 cpp_macro_decl[macro]:
 546         name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
 547         $name_token->type = PSI_T_NAME;
 548         $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
 549         $macro->token = psi_token_copy($name_token);
 550 }
 551 |       cpp_special_name_token[name_token] cpp_macro_decl_tokens {
 552         $name_token->type = PSI_T_NAME;
 553         $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
 554         $macro->token = psi_token_copy($name_token);
 555 }
 556 ;
 557
 558 cpp_macro_sig[sig]:
 559         %empty {
 560         $sig = psi_plist_init(NULL);
 561 }
 562 |       ELLIPSIS {
 563         $sig = psi_plist_init(NULL); /* FIXME */
 564 }
 565 |       cpp_macro_sig_args
 566 |       cpp_macro_sig_args[args] COMMA ELLIPSIS {
 567         $sig = $args;
 568 }
 569 ;
 570
 571 cpp_macro_sig_args[args]:
 572         name_token {
 573         $name_token = psi_token_copy($name_token);
 574         $name_token->type = PSI_T_NAME;
 575         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
 576 }
 577 |       cpp_macro_sig_args[args_] COMMA name_token {
 578         $name_token = psi_token_copy($name_token);
 579         $name_token->type = PSI_T_NAME;
 580         $args = psi_plist_add($args_, &$name_token);
 581 }
 582 ;
 583
 584 cpp_macro_decl_tokens[tokens]:
 585         %empty {
 586         $tokens = NULL;
 587 }
 588 | cpp_macro_decl_token_list
 589 ;
 590
 591 cpp_macro_decl_token_list[tokens]:
 592         any_noeol_token[token] {
 593         $token = psi_token_copy($token);
 594         $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
 595 }
 596 |       cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
 597         $token = psi_token_copy($token);
 598         $tokens = psi_plist_add($tokens_, &$token);
 599 }
 600 ;
 601
 602 cpp_macro_exp[exp]:
 603         LPAREN cpp_macro_exp[exp_] RPAREN {
 604         $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
 605         $exp->token = psi_token_copy($LPAREN);
 606 }
 607 |       unary_op_token cpp_macro_exp[exp_] %prec UNARY {
 608         $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
 609         $exp->token = psi_token_copy($unary_op_token);
 610 }
 611 |       cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
 612         $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
 613         $exp->token = psi_token_copy($binary_op_token);
 614 }
 615 |       cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
 616         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
 617         $exp->token = psi_token_copy($IIF);
 618 }
 619
 620 |       DEFINED name_token {
 621         {
 622                 uint8_t exists;
 623
 624                 $name_token->type = PSI_T_NAME;
 625                 exists = psi_cpp_defined(P->preproc, $name_token);
 626                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 627                 $exp->token = psi_token_copy($name_token);
 628         }
 629 }
 630 |       DEFINED LPAREN name_token RPAREN {
 631         {
 632                 uint8_t exists;
 633
 634                 $name_token->type = PSI_T_NAME;
 635                 exists = psi_cpp_defined(P->preproc, $name_token);
 636                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 637                 $exp->token = psi_token_copy($name_token);
 638         }
 639 }
 640 |       NUMBER {
 641         $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
 642         $exp->token = psi_token_copy($NUMBER);
 643         $exp->data.n->token = psi_token_copy($NUMBER);
 644 }
 645 |       QUOTED_CHAR {
 646         $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
 647         $exp->token = psi_token_copy($QUOTED_CHAR);
 648         $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
 649 }
 650 |       name_token {
 651         $name_token->type = PSI_T_NAME;
 652         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
 653         $exp->token = psi_token_copy($name_token);
 654         $exp->data.n->token = psi_token_copy($name_token);
 655 }
 656 |       name_token LPAREN cpp_macro_call_args RPAREN {
 657         $name_token->type = PSI_T_NAME;
 658         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
 659                 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
 660         $exp->token = psi_token_copy($name_token);
 661 }
 662 ;
 663
 664 cpp_macro_call_args[args]:
 665         %empty {
 666         $args = NULL;
 667 }
 668 |       cpp_macro_call_arg_list
 669 ;
 670
 671 cpp_macro_call_arg_list[args]:
 672         cpp_macro_exp {
 673         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
 674                 &$cpp_macro_exp);
 675 }
 676 |       cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
 677         $args = psi_plist_add($args_, &$cpp_macro_exp);
 678 }
 679 ;
 680
 681 constant[const]:
 682         CONST constant_type NSNAME EQUALS impl_def_val EOS {
 683         $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
 684         $const->token = psi_token_copy($NSNAME);
 685 }
 686 ;
 687
 688 constant_type[type]:
 689         constant_type_token[token] {
 690         $type = psi_const_type_init($token->type, $token->text);
 691 }
 692 ;
 693
 694 constant_type_token:
 695         BOOL
 696 |       INT
 697 |       FLOAT
 698 |       STRING
 699 ;
 700
 701 impl_def_val[val]:
 702         %empty {
 703         $val = NULL;
 704 }
 705 |       num_exp[num] {
 706         if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
 707                 impl_val res = {0};
 708                 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
 709
 710                 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
 711                         $val = psi_impl_def_val_init(type, NULL);
 712                 } else {
 713                         $val = psi_impl_def_val_init(PSI_T_INT, NULL);
 714                 }
 715
 716                 switch (type) {
 717                 case PSI_T_UINT8:       $val->ival.zend.lval = res.u8;  break;
 718                 case PSI_T_UINT16:      $val->ival.zend.lval = res.u16; break;
 719                 case PSI_T_UINT32:      $val->ival.zend.lval = res.u32; break;
 720                 case PSI_T_UINT64:      $val->ival.zend.lval = res.u64; break; /* FIXME */
 721                 case PSI_T_INT8:        $val->ival.zend.lval = res.i8;  break;
 722                 case PSI_T_INT16:       $val->ival.zend.lval = res.i16; break;
 723                 case PSI_T_INT32:       $val->ival.zend.lval = res.i32; break;
 724                 case PSI_T_INT64:       $val->ival.zend.lval = res.i64; break;
 725                 case PSI_T_FLOAT:       $val->ival.dval = res.fval;             break;
 726                 case PSI_T_DOUBLE:      $val->ival.dval = res.dval;             break;
 727                 default:
 728                         assert(0);
 729
 730                 }
 731         } else {
 732                 $val = NULL;
 733         }
 734         psi_num_exp_free(&$num);
 735 }
 736 |       impl_def_val_token[token] {
 737         $val = psi_impl_def_val_init($token->type, $token->text);
 738         $val->token = psi_token_copy($token);
 739 }
 740 ;
 741
 742 impl_def_val_token:
 743         NULL
 744 |       TRUE
 745 |       FALSE
 746 |       QUOTED_STRING
 747 ;
 748
 749 decl_typedef[def]:
 750         TYPEDEF typedef[def_] EOS {
 751         $def = $def_;
 752 }
 753 |       TYPEDEF VOID name_token EOS {
 754         $def = psi_decl_arg_init(
 755                 psi_decl_type_init(PSI_T_VOID, $VOID->text),
 756                 psi_decl_var_init($name_token->text, 0, 0)
 757         );
 758         $def->token = psi_token_copy($VOID);
 759         $def->type->token = psi_token_copy($VOID);
 760         $def->var->token = psi_token_copy($name_token);
 761 }
 762 |       CPP_EXTENSION TYPEDEF typedef[def_] EOS {
 763         $def = $def_;
 764 }
 765 ;
 766
 767 typedef[def]:
 768         decl_arg
 769 |       decl_func_body[decl] {
 770         $def = psi_decl_arg_init(
 771                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
 772                 psi_decl_var_copy($decl->func->var)
 773         );
 774         $def->type->token = psi_token_copy($decl->func->token);
 775         $def->type->real.func = $decl;
 776 }
 777 |       decl_enum[enum] name_token {
 778         $name_token->type = PSI_T_NAME;
 779         $def = psi_decl_arg_init(
 780                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 781                 psi_decl_var_init($name_token->text, 0, 0)
 782         );
 783         $def->var->token = psi_token_copy($name_token);
 784         $def->type->token = psi_token_copy($enum->token);
 785         $def->type->real.enm = $enum;
 786         psi_parser_proc_add_enum(P, $enum);
 787 }
 788 |       struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
 789         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
 790         $def->type->token = $struct;
 791         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 792         $def->type->real.strct->token = psi_token_copy($struct);
 793         $def->type->real.strct->align = $as.pos;
 794         $def->type->real.strct->size = $as.len;
 795         psi_parser_proc_add_struct(P, $def->type->real.strct);
 796 }
 797 |       union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
 798         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
 799         $def->type->token = $union;
 800         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 801         $def->type->real.unn->token = psi_token_copy($union);
 802         $def->type->real.unn->align = $as.pos;
 803         $def->type->real.unn->size = $as.len;
 804         psi_parser_proc_add_union(P, $def->type->real.unn);
 805 }
 806 |       const_decl_type[type] decl_stdint_type[stdint] {
 807         $stdint->type = PSI_T_NAME;
 808         $def = psi_decl_arg_init($type, psi_decl_var_init($stdint->text, 0, 0));
 809         $def->var->token = psi_token_copy($stdint);
 810 }
 811 ;
 812
 813 const_decl_type[type]:
 814         CONST decl_type[type_] {
 815         $type = $type_;
 816 }
 817 |       decl_type
 818 ;
 819
 820 decl_type[type]:
 821         decl_type_simple[token] {
 822         $type = psi_decl_type_init($token->type, $token->text);
 823         $type->token = $token;
 824 }
 825 |       decl_type_complex
 826 ;
 827
 828 decl_type_complex[type]:
 829         STRUCT[token] name_token {
 830         $name_token->type = PSI_T_NAME;
 831         $type = psi_decl_type_init($token->type, $name_token->text);
 832         $type->token = psi_token_copy($name_token);
 833 }
 834 |       UNION[token] name_token {
 835         $name_token->type = PSI_T_NAME;
 836         $type = psi_decl_type_init($token->type, $name_token->text);
 837         $type->token = psi_token_copy($name_token);
 838 }
 839 |       ENUM[token] name_token {
 840         $name_token->type = PSI_T_NAME;
 841         $type = psi_decl_type_init($token->type, $name_token->text);
 842         $type->token = psi_token_copy($name_token);
 843 }
 844 ;
 845
 846 decl_type_simple[type]:
 847         decl_int_type
 848 |       decl_real_type
 849 |       decl_stdint_type[type_] {
 850         $type = psi_token_copy($type_);
 851 }
 852 |       NAME[type_] {
 853         $type = psi_token_copy($type_);
 854 }
 855 ;
 856
 857 decl_real_type[type]:
 858         FLOAT[type_] {
 859         $type = psi_token_copy($type_);
 860 }
 861 |       DOUBLE[type_] {
 862         $type = psi_token_copy($type_);
 863 }
 864 |       LONG DOUBLE {
 865         $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
 866 }
 867 ;
 868
 869 decl_stdint_type[type]:
 870         INT8
 871 |       UINT8
 872 |       INT16
 873 |       UINT16
 874 |       INT32
 875 |       UINT32
 876 |       INT64
 877 |       UINT64
 878 ;
 879
 880 int_signed[i]:
 881         SIGNED
 882 |       UNSIGNED
 883 ;
 884
 885 int_width[i]:
 886         SHORT {
 887         $i = psi_token_copy($SHORT);
 888 }
 889 |       LONG {
 890         $i = psi_token_copy($LONG);
 891 }
 892 |       LONG[l1] LONG[l2] {
 893         $i = psi_token_cat(" ", 2, $l1, $l2);
 894 }
 895 ;
 896
 897 decl_int_type[type]:
 898         CHAR {
 899         $type = psi_token_copy($CHAR);
 900 }
 901 |       INT {
 902         $type = psi_token_copy($INT);
 903 }
 904 |       int_signed int_signed_types {
 905         if ($2) {
 906                 $type = psi_token_cat(" ", 2, $1, $2);
 907                 free($2);
 908         } else {
 909                 $type = psi_token_copy($1);
 910         }
 911 }
 912 |       int_width int_width_types {
 913         if ($2) {
 914                 $type = psi_token_cat(" ", 2, $1, $2);
 915                 free($1);
 916                 free($2);
 917         } else {
 918                 $type = $1;
 919         }
 920 }
 921 ;
 922
 923 int_signed_types[type]:
 924         %empty {
 925         $type = NULL;
 926 }
 927 |       CHAR {
 928         $type = psi_token_copy($CHAR);
 929 }
 930 |       SHORT signed_short_types {
 931         if ($2) {
 932                 $type = psi_token_cat(" ", 2, $1, $2);
 933         } else {
 934                 $type = psi_token_copy($1);
 935         }
 936 }
 937 |       INT {
 938         $type = psi_token_copy($INT);
 939 }
 940 |       LONG signed_long_types {
 941         if ($2) {
 942                 $type = psi_token_cat(" ", 2, $1, $2);
 943         } else {
 944                 $type = psi_token_copy($1);
 945         }
 946 }
 947 ;
 948
 949 signed_short_types[type]:
 950         %empty {
 951         $type = NULL;
 952 }
 953 |       INT
 954 ;
 955 signed_long_types[type]:
 956         %empty {
 957         $type = NULL;
 958 }
 959 |       INT
 960 |       LONG
 961 ;
 962
 963 int_width_types[type]:
 964         %empty {
 965         $type = NULL;
 966 }
 967 |       INT {
 968         $type = psi_token_copy($INT);
 969 }
 970 |       int_signed int_signed_types {
 971         if ($2) {
 972                 $type = psi_token_cat(" ", 2, $1, $2);
 973                 free($2);
 974         } else {
 975                 $type = psi_token_copy($1);
 976         }
 977 }
 978 ;
 979
 980 decl_stmt:
 981         decl decl_asm EOS {
 982         $decl_stmt = $decl;
 983 }
 984 |       CPP_EXTENSION decl decl_asm EOS {
 985         $decl_stmt = $decl;
 986 }
 987 ;
 988
 989 decl_asm:
 990         %empty
 991 |       CPP_ASM LPAREN ignored_quoted_strings RPAREN
 992 ;
 993
 994 ignored_quoted_strings:
 995         QUOTED_STRING
 996 |       ignored_quoted_strings QUOTED_STRING
 997 ;
 998
 999 decl_ext_var_stmt:
1000         decl_ext_var EOS
1001 ;
1002
1003 decl_ext_var:
1004         NAME decl_arg decl_ext_var_list {
1005         psi_decl_arg_free(&$decl_arg);
1006 }
1007 ;
1008
1009 decl_ext_var_list:
1010         %empty
1011 |       COMMA decl_vars {
1012         psi_plist_free($decl_vars);
1013 }
1014 ;
1015
1016 decl_vars[vars]:
1017         decl_var[var] {
1018         $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1019 }
1020 |       decl_vars[vars_] COMMA decl_var[var] {
1021         $vars = psi_plist_add($vars_, &$var);
1022 }
1023 ;
1024
1025 decl:
1026         decl_body
1027 |       NAME[abi] decl_body {
1028         $decl = $decl_body;
1029         $decl->abi = psi_decl_abi_init($abi->text);
1030 }
1031 ;
1032
1033 decl_body:
1034         decl_func_body
1035 |       decl_functor_body
1036 ;
1037
1038 decl_func_body[decl]:
1039         decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1040         $decl = psi_decl_init($func, $args);
1041         if ($as) {
1042                 $decl->func->var->pointer_level += 1;
1043                 $decl->func->var->array_size = $as;
1044         }
1045 }
1046 |       decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1047         $decl = psi_decl_init($func, $args);
1048         $decl->varargs = 1;
1049         if ($as) {
1050                 $decl->func->var->pointer_level += 1;
1051                 $decl->func->var->array_size = $as;
1052         }
1053 }
1054 ;
1055
1056 decl_functor_body[decl]:
1057         decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1058         $decl = psi_decl_init($func, $args);
1059         if ($as) {
1060                 $decl->func->var->pointer_level += 1;
1061                 $decl->func->var->array_size = $as;
1062         }
1063 }
1064 |       decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1065         $decl = psi_decl_init($func, $args);
1066         $decl->varargs = 1;
1067         if ($as) {
1068                 $decl->func->var->pointer_level += 1;
1069                 $decl->func->var->array_size = $as;
1070         }
1071 }
1072 ;
1073
1074 decl_functor[arg]:
1075         const_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1076         (void) $unused1;
1077         $NAME->type = PSI_T_NAME;
1078         $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1079         $arg->var->token = psi_token_copy($NAME);
1080         $arg->token = psi_token_copy($NAME);
1081 }
1082 |       CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1083         (void) $unused1;
1084         $NAME->type = PSI_T_NAME;
1085         $arg = psi_decl_arg_init(
1086                 psi_decl_type_init($VOID->type, $VOID->text),
1087                 psi_decl_var_init($NAME->text, $pointers, 0)
1088         );
1089         $arg->type->token = psi_token_copy($VOID);
1090         $arg->var->token = psi_token_copy($NAME);
1091         $arg->token = psi_token_copy($NAME);
1092 }
1093 |       VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1094         (void) $unused1;
1095         $NAME->type = PSI_T_NAME;
1096         $arg = psi_decl_arg_init(
1097                 psi_decl_type_init($VOID->type, $VOID->text),
1098                 psi_decl_var_init($NAME->text, $pointers, 0)
1099         );
1100         $arg->type->token = psi_token_copy($VOID);
1101         $arg->var->token = psi_token_copy($NAME);
1102         $arg->token = psi_token_copy($NAME);
1103 }
1104 |       VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1105         (void) $unused1;
1106         $NAME->type = PSI_T_NAME;
1107         $arg = psi_decl_arg_init(
1108                 psi_decl_type_init($VOID->type, $VOID->text),
1109                 psi_decl_var_init($NAME->text, 0, 0)
1110         );
1111         $arg->type->token = psi_token_copy($VOID);
1112         $arg->var->token = psi_token_copy($NAME);
1113         $arg->token = psi_token_copy($NAME);
1114 }
1115 ;
1116
1117 decl_func[func]:
1118         decl_arg
1119 |       VOID name_token[NAME] {
1120         $func = psi_decl_arg_init(
1121                 psi_decl_type_init($VOID->type, $VOID->text),
1122                 psi_decl_var_init($NAME->text, 0, 0)
1123         );
1124         $func->type->token = psi_token_copy($VOID);
1125         $func->var->token = psi_token_copy($NAME);
1126         $func->token = psi_token_copy($NAME);
1127 }
1128 ;
1129
1130 decl_args[args]:
1131         %empty {
1132         $args = NULL;
1133 }
1134 |       VOID {
1135         $args = NULL;
1136 }
1137 |       decl_anon_arg[arg] {
1138         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1139 }
1140 |       decl_args[args_] COMMA decl_anon_arg[arg] {
1141         $args = psi_plist_add($args_, &$arg);
1142 }
1143 ;
1144
1145 decl_anon_arg[arg]:
1146 /* FIXME decl_functor_body_anon */
1147         decl_arg {
1148         $arg = $decl_arg;
1149 }
1150 |       const_decl_type[type] indirection {
1151         $arg = psi_decl_arg_init(
1152                 $type,
1153                 psi_decl_var_init(NULL, $indirection, 0)
1154         );
1155 }
1156 |       CONST VOID pointers {
1157         $arg = psi_decl_arg_init(
1158                 psi_decl_type_init($VOID->type, $VOID->text),
1159                 psi_decl_var_init(NULL, $pointers, 0)
1160         );
1161         $arg->type->token = psi_token_copy($VOID);
1162         $arg->var->token = psi_token_copy($VOID);
1163         $arg->token = psi_token_copy($VOID);
1164 }
1165 |       VOID pointers {
1166         $arg = psi_decl_arg_init(
1167                 psi_decl_type_init($VOID->type, $VOID->text),
1168                 psi_decl_var_init(NULL, $pointers, 0)
1169         );
1170         $arg->type->token = psi_token_copy($VOID);
1171         $arg->var->token = psi_token_copy($VOID);
1172         $arg->token = psi_token_copy($VOID);
1173 }
1174 ;
1175
1176 decl_arg[arg]:
1177         decl_functor_body[decl] {
1178         $arg = psi_decl_arg_init(
1179                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1180                 psi_decl_var_copy($decl->func->var)
1181         );
1182         $arg->type->token = psi_token_copy($decl->func->token);
1183         $arg->type->real.func = $decl;
1184 }
1185 |       const_decl_type[type] decl_var[var] {
1186         $arg = psi_decl_arg_init($type, $var);
1187 }
1188 |       CONST VOID pointers name_token[NAME] {
1189         $NAME->type = PSI_T_NAME;
1190         $arg = psi_decl_arg_init(
1191                 psi_decl_type_init($VOID->type, $VOID->text),
1192                 psi_decl_var_init($NAME->text, $pointers, 0)
1193         );
1194         $arg->type->token = psi_token_copy($VOID);
1195         $arg->var->token = psi_token_copy($NAME);
1196         $arg->token = psi_token_copy($NAME);
1197 }
1198 |       VOID pointers name_token[NAME] {
1199         $NAME->type = PSI_T_NAME;
1200         $arg = psi_decl_arg_init(
1201                 psi_decl_type_init($VOID->type, $VOID->text),
1202                 psi_decl_var_init($NAME->text, $pointers, 0)
1203         );
1204         $arg->type->token = psi_token_copy($VOID);
1205         $arg->var->token = psi_token_copy($NAME);
1206         $arg->token = psi_token_copy($NAME);
1207 }
1208 ;
1209
1210 decl_var[var]:
1211         pointers name_token array_size {
1212         $name_token->type = PSI_T_NAME;
1213         $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1214         $var->token = psi_token_copy($name_token);
1215 }
1216 |       name_token array_size {
1217         $name_token->type = PSI_T_NAME;
1218         $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1219         $var->token = psi_token_copy($name_token);
1220 }
1221 ;
1222
1223 decl_union[union]:
1224         UNION name_token align_and_size[as] decl_struct_args[args] {
1225         $name_token->type = PSI_T_NAME;
1226         $union = psi_decl_union_init($name_token->text, $args);
1227         $union->align = $as.pos;
1228         $union->size = $as.len;
1229         $union->token = psi_token_copy($name_token);
1230 }
1231 ;
1232
1233 decl_struct[struct]:
1234         STRUCT name_token align_and_size[as] decl_struct_args[args] {
1235         $name_token->type = PSI_T_NAME;
1236         $struct = psi_decl_struct_init($name_token->text, $args);
1237         $struct->align = $as.pos;
1238         $struct->size = $as.len;
1239         $struct->token = psi_token_copy($name_token);
1240 }
1241 ;
1242
1243 decl_struct_args[args]:
1244         EOS {
1245         $args = NULL;
1246 }
1247 |       struct_args_block
1248 ;
1249
1250 struct_args_block[args]:
1251         LBRACE struct_args RBRACE {
1252         $args = $struct_args;
1253 }
1254 ;
1255
1256 struct_args[args]:
1257         typedef[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1258         $arg->layout = $layout;
1259         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1260         if ($vars) {
1261                 size_t i = 0;
1262                 struct psi_decl_arg *arg;
1263
1264                 while (psi_plist_get($vars, i++, &arg)) {
1265                         arg->type = psi_decl_type_copy($arg->type);
1266                         $args = psi_plist_add($args, &arg);
1267                 }
1268                 free($vars);
1269         }
1270 }
1271 |       struct_args[args_] typedef[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1272         $arg->layout = $layout;
1273         $args = psi_plist_add($args_, &$arg);
1274         if ($vars) {
1275                 size_t i = 0;
1276                 struct psi_decl_arg *arg;
1277
1278                 while (psi_plist_get($vars, i++, &arg)) {
1279                         arg->type = psi_decl_type_copy($arg->type);
1280                         $args = psi_plist_add($args, &arg);
1281                 }
1282                 free($vars);
1283         }
1284 }
1285 ;
1286
1287 struct_arg_var_list[vars]:
1288         %empty {
1289         $vars = NULL;
1290 }
1291 |       COMMA decl_vars_with_layout[vars_] {
1292         $vars = $vars_;
1293 }
1294 ;
1295
1296 decl_vars_with_layout[vars]:
1297         decl_var[var] decl_layout[layout] {
1298         {
1299                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1300                 arg->layout = $layout;
1301                 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1302         }
1303 }
1304 |       decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1305         {
1306                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1307                 arg->layout = $layout;
1308                 $vars = psi_plist_add($vars_, &arg);
1309         }
1310 }
1311 ;
1312
1313 decl_enum[enum]:
1314         enum_name LBRACE decl_enum_items[list] RBRACE {
1315         $enum = psi_decl_enum_init($enum_name->text, $list);
1316         $enum->token = $enum_name;
1317 }
1318 ;
1319
1320 decl_enum_items[list]:
1321         decl_enum_item[i] {
1322         $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1323 }
1324 |       decl_enum_items[list_] COMMA decl_enum_item[i] {
1325         $list = psi_plist_add($list_, &$i);
1326 }
1327 ;
1328
1329 decl_enum_item[i]:
1330         name_token {
1331         $name_token->type = PSI_T_NAME;
1332         $i = psi_decl_enum_item_init($name_token->text, NULL);
1333         $i->token = psi_token_copy($name_token);
1334 }
1335 |       name_token EQUALS num_exp {
1336         $name_token->type = PSI_T_NAME;
1337         $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1338         $i->token = psi_token_copy($name_token);
1339 }
1340 ;
1341
1342 num_exp[exp]:
1343         number {
1344         $exp = psi_num_exp_init_num($number);
1345         $exp->token = psi_token_copy($number->token);
1346 }
1347 |       LPAREN const_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1348         $exp = psi_num_exp_init_cast($type, $exp_);
1349         $exp->token = psi_token_copy($type->token);
1350 }
1351 |       LPAREN num_exp[exp_] RPAREN {
1352         $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1353         $exp->token = psi_token_copy($LPAREN);
1354 }
1355 |       num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1356         $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1357         $exp->token = psi_token_copy($op);
1358 }
1359 |       unary_op_token[op] num_exp[exp_] %prec UNARY {
1360         $exp = psi_num_exp_init_unary($op->type, $exp_);
1361         $exp->token = psi_token_copy($op);
1362 }
1363 |       num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1364         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1365         $exp->token = psi_token_copy($IIF);
1366 }
1367 ;
1368
1369 number[num]:
1370         NUMBER[token] {
1371         $num = psi_number_init($token->type, $token->text, $token->flags);
1372         $num->token = psi_token_copy($token);
1373 }
1374 |       NSNAME[token] {
1375         $num = psi_number_init($token->type, $token->text, 0);
1376         $num->token = psi_token_copy($token);
1377 }
1378 |       QUOTED_CHAR[token] {
1379         $num = psi_number_init($token->type, $token->text, 0);
1380         $num->token = psi_token_copy($token);
1381 }
1382 |       decl_var {
1383         $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1384         $num->token = psi_token_copy($decl_var->token);
1385 }
1386 ;
1387
1388 enum_name[name]:
1389         ENUM optional_name[name_] {
1390         if ($name_) {
1391                 $name = psi_token_copy($name_);
1392         } else {
1393                 char digest[17];
1394
1395                 psi_token_hash($ENUM, digest);
1396                 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1397         }
1398 }
1399 ;
1400
1401 union_name[name]:
1402         UNION optional_name[name_] {
1403         if ($name_) {
1404                 $name = psi_token_copy($name_);
1405         } else {
1406                 char digest[17];
1407
1408                 psi_token_hash($UNION, digest);
1409                 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1410         }
1411 }
1412 ;
1413
1414 struct_name[name]:
1415         STRUCT optional_name[name_] {
1416         if ($name_) {
1417                 $name = psi_token_copy($name_);
1418         } else {
1419                 char digest[17];
1420
1421                 psi_token_hash($STRUCT, digest);
1422                 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1423         }
1424 }
1425 ;
1426
1427 optional_name[name]:
1428         %empty {
1429         $name = NULL;
1430 }
1431 |       name_token {
1432         $name = $name_token;
1433         $name->type = PSI_T_NAME;
1434 }
1435 ;
1436
1437 decl_layout[l]:
1438         %empty {
1439         $l = NULL;
1440 }
1441 |       COLON NUMBER[width] {
1442         $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1443 }
1444 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1445         $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1446 }
1447 |       COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1448         $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1449 }
1450 ;
1451
1452 align_and_size[as]:
1453         %empty {
1454         $as.pos = 0;
1455         $as.len = 0;
1456 }
1457 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1458         $as.pos = atol($align->text);
1459         $as.len = atol($size->text);
1460 }
1461 ;
1462
1463 array_size[as]:
1464         %empty {
1465         $as = 0;
1466 }
1467 |       LBRACKET RBRACKET {
1468         $as = 0;
1469 }
1470 |       LBRACKET NUMBER RBRACKET {
1471         $as = atol($NUMBER->text);
1472 }
1473 ;
1474
1475 indirection[i]:
1476         %empty {
1477         $i = 0;
1478 }
1479 |       pointers[p] %prec UNARY {
1480         $i = $p;
1481 }
1482 ;
1483
1484 pointers[p]:
1485         asterisks
1486 |       asterisks[a] CPP_RESTRICT {
1487         $p = $a;
1488 }
1489 ;
1490
1491 asterisks[a]:
1492         asterisk {
1493         $a = 1;
1494 }
1495 |       asterisks[a_] asterisk {
1496         $a = $a_ + 1;
1497 }
1498 ;
1499
1500 asterisk:
1501         ASTERISK
1502 |       ASTERISK CONST
1503 ;
1504
1505 /*
1506  *
1507  * impl
1508  *
1509  */
1510
1511 impl:
1512         impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1513         $impl = psi_impl_init($func, $stmts);
1514 }
1515 |       STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1516         $impl = psi_impl_init($func, $stmts);
1517         $func->static_memory = 1;
1518 }
1519 ;
1520
1521 impl_func[func]:
1522         FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1523         $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1524         $func->token = psi_token_copy($NSNAME);
1525         $func->return_reference = $r;
1526 }
1527 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1528         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1529         $func->token = psi_token_copy($NSNAME);
1530         $func->return_reference = $r;
1531 }
1532 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1533         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1534         $func->token = psi_token_copy($NSNAME);
1535         $func->return_reference = $r;
1536         $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1537         $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1538 }
1539 ;
1540
1541 impl_args[args]:
1542         impl_arg[arg] {
1543         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1544 }
1545 |       impl_args[args_] COMMA impl_arg[arg] {
1546         $args = psi_plist_add($args_, &$arg);
1547 }
1548 ;
1549
1550 impl_arg[arg]:
1551         impl_type[type] impl_var[var] {
1552         $arg = psi_impl_arg_init($type, $var, NULL);
1553 }
1554 |       impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1555         $arg = psi_impl_arg_init($type, $var, $val);
1556 }
1557 ;
1558
1559 impl_var[var]:
1560         reference DOLLAR_NAME {
1561         $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1562         $var->token = psi_token_copy($DOLLAR_NAME);
1563 }
1564 ;
1565
1566 impl_type[type]:
1567         impl_type_token[token] {
1568         $type = psi_impl_type_init($token->type, $token->text);
1569         $type->token = psi_token_copy($token);
1570 }
1571 ;
1572
1573 impl_type_token:
1574         VOID
1575 |       MIXED
1576 |       BOOL
1577 |       INT
1578 |       FLOAT
1579 |       STRING
1580 |       ARRAY
1581 |       OBJECT
1582 |       CALLABLE
1583 ;
1584
1585 impl_stmts[stmts]:
1586         impl_stmt[stmt] {
1587         $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1588 }
1589 |       impl_stmts[stmts_] impl_stmt[stmt] {
1590         $stmts = psi_plist_add($stmts_, &$stmt);
1591 }
1592 ;
1593
1594 impl_stmt[stmt]:
1595         return_stmt[s] {
1596         $stmt = (struct psi_token **) $s;
1597 }
1598 |       let_stmt[s] {
1599         $stmt = (struct psi_token **) $s;
1600 }
1601 |       set_stmt[s] {
1602         $stmt = (struct psi_token **) $s;
1603 }
1604 |       assert_stmt[s] {
1605         $stmt = (struct psi_token **) $s;
1606 }
1607 |       free_stmt[s] {
1608         $stmt = (struct psi_token **) $s;
1609 }
1610 ;
1611
1612 let_stmt[let]:
1613         LET let_exp_assign[exp] EOS {
1614         $let = psi_let_stmt_init($exp);
1615         $let->token = psi_token_copy($LET);
1616 }
1617 |       TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1618         $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1619         $let->token = psi_token_copy($TEMP);
1620         $let->exp->is_reference = $reference;
1621 }
1622 ;
1623
1624 let_exp[exp]:
1625         let_exp_assign
1626 |       byref let_exp_byref[exp_] {
1627         $exp = $exp_;
1628         $exp->is_reference = true;
1629 }
1630 |       let_exp_byref[exp_] {
1631         $exp = $exp_;
1632         $exp->is_reference = false;
1633 }
1634 ;
1635
1636 let_exp_byref[exp]:
1637         NULL {
1638         $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1639 }
1640 |       let_calloc[calloc] {
1641         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1642 }
1643 |       STATIC let_calloc[calloc] {
1644         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1645         $calloc->static_memory = 1;
1646 }
1647 |       let_callback[callback] {
1648         $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1649 }
1650 |       let_func[func] {
1651         $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1652 }
1653 |       num_exp[num] {
1654         $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1655 }
1656 ;
1657
1658 let_exp_assign[exp]:
1659         decl_var[var] EQUALS let_exp_byref[exp_] {
1660         $exp = $exp_;
1661         $exp->var = $var;
1662 }
1663 |       decl_var[var] EQUALS byref let_exp_byref[exp_] {
1664         $exp = $exp_;
1665         $exp->is_reference = 1;
1666         $exp->var = $var;
1667 }
1668 ;
1669
1670 let_calloc[calloc]:
1671         CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1672         $calloc = psi_let_calloc_init($nmemb, $size);
1673         $calloc->token = psi_token_copy($CALLOC);
1674 }
1675 ;
1676
1677 let_callback[callback]:
1678         CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1679         $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args);
1680         $callback->func->token = psi_token_copy($func);
1681         $callback->token = psi_token_copy($CALLBACK);
1682 }
1683 ;
1684
1685 let_func[func]:
1686         let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1687         $func = psi_let_func_init($token->type, $token->text, $var);
1688         $func->token = psi_token_copy($token);
1689         $func->inner = $exps;
1690 }
1691 ;
1692
1693 let_func_token:
1694         ZVAL
1695 |       OBJVAL
1696 |       ARRVAL
1697 |       PATHVAL
1698 |       STRLEN
1699 |       STRVAL
1700 |       FLOATVAL
1701 |       INTVAL
1702 |       BOOLVAL
1703 |       COUNT
1704 ;
1705
1706 let_func_exps[exps]:
1707         %empty {
1708         $exps = NULL;
1709 }
1710 |       COMMA let_exps[exps_] {
1711         $exps = $exps_;
1712 }
1713 ;
1714
1715 let_exps[exps]:
1716         let_exp[exp] {
1717         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1718 }
1719 |       let_exps[exps_] COMMA let_exp[exp] {
1720         $exps = psi_plist_add($exps_, &$exp);
1721 }
1722 ;
1723
1724 callback_rval[rval]:
1725         VOID
1726 |       let_func_token
1727 ;
1728
1729 callback_arg_list[list]:
1730         %empty {
1731         $list = NULL;
1732 }
1733 |       callback_args[args] {
1734         $list = $args;
1735 }
1736 ;
1737
1738 callback_args[args]:
1739         set_exp[exp] {
1740         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1741 }
1742 |       callback_args[args_] COMMA set_exp[exp] {
1743         $args = psi_plist_add($args_, &$exp);
1744 }
1745 ;
1746
1747 return_stmt[return]:
1748         RETURN set_func[func] EOS {
1749         $return = psi_return_stmt_init(psi_set_exp_init(PSI_SET_FUNC, $func));
1750         $return->token = psi_token_copy($RETURN);
1751 }
1752 ;
1753
1754 set_stmt[set]:
1755         SET set_exp[exp] EOS {
1756         $set = psi_set_stmt_init($exp);
1757         $set->token = psi_token_copy($SET);
1758 }
1759 ;
1760
1761 set_exp[exp]:
1762         set_func[func] {
1763         $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1764 }
1765 |       num_exp[num] {
1766         $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1767 }
1768 |       impl_var[var] EQUALS set_exp[exp_] {
1769         $exp = $exp_;
1770         $exp->var = $var;
1771 }
1772 ;
1773
1774 set_func[func]:
1775         set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1776         $func = psi_set_func_init($token->type, $token->text, $var);
1777         $func->token = psi_token_copy($token);
1778         $func->inner = $exps;
1779 }
1780 |       set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
1781         $func = psi_set_func_init($token->type, $token->text, $var);
1782         $func->token = psi_token_copy($token);
1783         $func->recursive = 1;
1784 }
1785 ;
1786
1787 set_func_token:
1788         TO_OBJECT
1789 |       TO_ARRAY
1790 |       TO_STRING
1791 |       TO_INT
1792 |       TO_FLOAT
1793 |       TO_BOOL
1794 |       ZVAL
1795 |       VOID
1796 ;
1797
1798 set_func_exps[exps]:
1799         %empty {
1800         $exps = NULL;
1801 }
1802 |       COMMA set_exps[exps_] {
1803         $exps = $exps_;
1804 }
1805 ;
1806
1807 set_exps[exps]:
1808         set_exp[exp] {
1809         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1810 }
1811 |       set_exps[exps_] COMMA set_exp[exp] {
1812         $exps = psi_plist_add($exps_, &$exp);
1813 }
1814 ;
1815
1816 assert_stmt[assert]:
1817         assert_stmt_token[token] num_exp[exp] EOS {
1818         $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
1819         $assert->token = psi_token_copy($token);
1820 }
1821 ;
1822
1823 assert_stmt_token:
1824         PRE_ASSERT
1825 |       POST_ASSERT
1826 ;
1827
1828 free_stmt[free]:
1829         FREE free_exps[exps] EOS {
1830         $free = psi_free_stmt_init($exps);
1831         $free->token = psi_token_copy($FREE);
1832 }
1833 ;
1834
1835 free_exps[exps]:
1836         free_exp[exp] {
1837         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
1838 }
1839 |       free_exps[exps_] COMMA free_exp[exp] {
1840         $exps = psi_plist_add($exps_, &$exp);
1841 }
1842 ;
1843
1844 free_exp[exp]:
1845         name_token[NAME] LPAREN decl_vars[vars] RPAREN {
1846         $NAME->type = PSI_T_NAME;
1847         $exp = psi_free_exp_init($NAME->text, $vars);
1848         $exp->token = psi_token_copy($NAME);
1849 }
1850 ;
1851
1852 reference:
1853         %empty {
1854         $reference = false;
1855 }
1856 |       byref {
1857         $reference = true;
1858 }
1859 ;
1860
1861 byref:
1862         AMPERSAND %prec UNARY
1863 ;
1864
1865 %%
1866
1867 /* epilogue */
1868
1869 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
1870 {
1871         struct psi_token *token;
1872
1873         if (psi_plist_get(tokens, (*index)++, &token)) {
1874                 if (P->flags & PSI_DEBUG) {
1875                         psi_token_dump(2, token);
1876                 }
1877
1878                 *((struct psi_token **)lvalp) = token;
1879                 return token->type;
1880         } else {
1881                 (*index)--;
1882                 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
1883         }
1884
1885         return PSI_T_EOF;
1886 }
1887
1888 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
1889 {
1890         struct psi_token *T = NULL;
1891         size_t last;
1892
1893         if (*index == 0) {
1894                 last = 0;
1895         } else {
1896                 last = --(*index);
1897         }
1898
1899         psi_plist_get(tokens, last, &T);
1900         if (T) {
1901                 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
1902         } else {
1903                 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
1904         }
1905         P->errors++;
1906 }
1907