projects / m6w6 / ext-psi / blob
? search:
summary | shortlog | log | commit | commitdiff | tree | github
history | raw | HEAD
PHP 8 compatibility
[m6w6/ext-psi] / src / parser_proc_grammar.y
1 %code top {
2 #ifdef HAVE_CONFIG_H
3 # include "config.h"
4 #else
5 # include "php_config.h"
6 #endif
7 }
8
9 %code {
10 #include <assert.h>
11 #include <stdarg.h>
12
13 #include "plist.h"
14 #include "parser.h"
15
16 #define YYDEBUG 1
17 #define PSI_PARSER_PROC_DEBUG 1
18
19 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
20 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
21
22 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
23 {
24 assert(strct);
25 if (!P->structs) {
26 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
27 }
28 P->structs = psi_plist_add(P->structs, &strct);
29 }
30 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
31 {
32 assert(u);
33 if (!P->unions) {
34 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
35 }
36 P->unions = psi_plist_add(P->unions, &u);
37 }
38 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
39 {
40 assert(e);
41 if (!P->enums) {
42 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
43 }
44 P->enums = psi_plist_add(P->enums, &e);
45 }
46 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
47 {
48 assert(def);
49 if (!P->types) {
50 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
51 }
52 P->types = psi_plist_add(P->types, &def);
53 }
54 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
55 assert(cnst);
56 if (!P->consts) {
57 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
58 }
59 P->consts = psi_plist_add(P->consts, &cnst);
60
61 }
62 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
63 assert(decl);
64
65 if (psi_decl_is_blacklisted(decl->func->var->name->val)) {
66 psi_decl_free(&decl);
67 return;
68 }
69
70 if (!P->decls) {
71 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
72 }
73 P->decls = psi_plist_add(P->decls, &decl);
74 }
75 static inline void psi_parser_proc_add_decl_extvars(struct psi_parser *P, struct psi_plist *list) {
76 assert(list);
77 if (!P->vars) {
78 P->vars = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
79 }
80 P->vars = psi_plist_add_r(P->vars, psi_plist_count(list), psi_plist_eles(list));
81 free(list);
82 }
83 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
84 assert(impl);
85 if (!P->impls) {
86 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
87 }
88 P->impls = psi_plist_add(P->impls, &impl);
89 }
90
91 /* end code */
92 }
93
94 %code requires {
95 #include "plist.h"
96 #include "types/layout.h"
97
98 #define yytokentype psi_token_type
99
100 #define PSI_T_CAST PSI_T_EQUALS
101 #define PSI_T_POINTER PSI_T_ASTERISK
102
103 struct psi_parser;
104
105 }
106
107 %require "3.0"
108 %language "c"
109 %name-prefix "psi_parser_proc_"
110 %token-table
111 %verbose
112 %glr-parser
113
114 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
115
116 %define api.pure true
117 %define api.token.prefix {PSI_T_}
118 %define api.value.type union
119
120 %define parse.error verbose
121 %define parse.trace true
122
123 %initial-action {
124 }
125
126 %start file
127
128 %token <struct psi_token *> BOOL
129 %token <struct psi_token *> CHAR
130 %token <struct psi_token *> SHORT
131 %token <struct psi_token *> INT
132 %token <struct psi_token *> SIGNED
133 %token <struct psi_token *> UNSIGNED
134 %token <struct psi_token *> LONG
135 %token <struct psi_token *> FLOAT
136 %token <struct psi_token *> DOUBLE
137 %token <struct psi_token *> STRING
138 %token <struct psi_token *> MIXED
139 %token <struct psi_token *> ARRAY
140 %token <struct psi_token *> OBJECT
141 %token <struct psi_token *> CALLABLE
142 %token <struct psi_token *> VOID
143 %token <struct psi_token *> ZVAL
144 %token <struct psi_token *> NULL
145 %token <struct psi_token *> TRUE
146 %token <struct psi_token *> FALSE
147 %token <struct psi_token *> NAME
148 %token <struct psi_token *> NSNAME
149 %token <struct psi_token *> DOLLAR_NAME
150 %token <struct psi_token *> NUMBER
151 %token <struct psi_token *> QUOTED_STRING
152 %token <struct psi_token *> QUOTED_CHAR
153 %token <struct psi_token *> SIZEOF
154 %token <struct psi_token *> VOLATILE
155
156 %token <struct psi_token *> EOF 0 "end of file"
157 %token <struct psi_token *> EOL "end of line"
158 %token <struct psi_token *> EOS ";"
159 %token <struct psi_token *> LPAREN "("
160 %token <struct psi_token *> RPAREN ")"
161 %token <struct psi_token *> COMMA ","
162 %token <struct psi_token *> COLON ":"
163 %token <struct psi_token *> LBRACE "{"
164 %token <struct psi_token *> RBRACE "}"
165 %token <struct psi_token *> LBRACKET "["
166 %token <struct psi_token *> RBRACKET "]"
167 %token <struct psi_token *> EQUALS "="
168 %token <struct psi_token *> HASH "#"
169 %token <struct psi_token *> PIPE "|"
170 %token <struct psi_token *> CARET "^"
171 %token <struct psi_token *> AMPERSAND "&"
172 %token <struct psi_token *> LSHIFT "<<"
173 %token <struct psi_token *> RSHIFT ">>"
174 %token <struct psi_token *> PLUS "+"
175 %token <struct psi_token *> MINUS "-"
176 %token <struct psi_token *> ASTERISK "*"
177 %token <struct psi_token *> SLASH "/"
178 %token <struct psi_token *> MODULO "%"
179 %token <struct psi_token *> LCHEVR "<"
180 %token <struct psi_token *> RCHEVR ">"
181 %token <struct psi_token *> CMP_GE ">="
182 %token <struct psi_token *> CMP_LE "<="
183 %token <struct psi_token *> OR "||"
184 %token <struct psi_token *> AND "&&"
185 %token <struct psi_token *> CMP_EQ "=="
186 %token <struct psi_token *> CMP_NE "!="
187 %token <struct psi_token *> TILDE "~"
188 %token <struct psi_token *> NOT "!"
189 %token <struct psi_token *> PERIOD "."
190 %token <struct psi_token *> BACKSLASH "\\"
191 %token <struct psi_token *> ELLIPSIS "..."
192 %token <struct psi_token *> IIF "?"
193
194 %token <struct psi_token *> PRAGMA
195 %token <struct psi_token *> LINE
196 %token <struct psi_token *> ERROR
197 %token <struct psi_token *> WARNING
198 %token <struct psi_token *> IF
199 %token <struct psi_token *> IFDEF
200 %token <struct psi_token *> IFNDEF
201 %token <struct psi_token *> ELSE
202 %token <struct psi_token *> ELIF
203 %token <struct psi_token *> ENDIF
204 %token <struct psi_token *> DEFINE
205 %token <struct psi_token *> DEFINED
206 %token <struct psi_token *> UNDEF
207 %token <struct psi_token *> IMPORT
208 %token <struct psi_token *> INCLUDE
209 %token <struct psi_token *> INCLUDE_NEXT
210
211 %token <struct psi_token *> TYPEDEF
212 %token <struct psi_token *> STRUCT
213 %token <struct psi_token *> UNION
214 %token <struct psi_token *> ENUM
215 %token <struct psi_token *> CONST
216 %token <struct psi_token *> STATIC
217 %token <struct psi_token *> CALLBACK
218 %token <struct psi_token *> FUNCTION
219 %token <struct psi_token *> LET
220 %token <struct psi_token *> SET
221 %token <struct psi_token *> TEMP
222 %token <struct psi_token *> FREE
223 %token <struct psi_token *> RETURN
224 %token <struct psi_token *> AS
225 %token <struct psi_token *> PRE_ASSERT
226 %token <struct psi_token *> POST_ASSERT
227 %token <struct psi_token *> BOOLVAL
228 %token <struct psi_token *> INTVAL
229 %token <struct psi_token *> STRVAL
230 %token <struct psi_token *> PATHVAL
231 %token <struct psi_token *> STRLEN
232 %token <struct psi_token *> FLOATVAL
233 %token <struct psi_token *> ARRVAL
234 %token <struct psi_token *> OBJVAL
235 %token <struct psi_token *> COUNT
236 %token <struct psi_token *> CALLOC
237 %token <struct psi_token *> TO_BOOL
238 %token <struct psi_token *> TO_INT
239 %token <struct psi_token *> TO_STRING
240 %token <struct psi_token *> TO_FLOAT
241 %token <struct psi_token *> TO_ARRAY
242 %token <struct psi_token *> TO_OBJECT
243
244 %token <struct psi_token *> COMMENT
245 %token <struct psi_token *> WHITESPACE
246 %token <struct psi_token *> NO_WHITESPACE
247 %token <struct psi_token *> CPP_HEADER
248 %token <struct psi_token *> CPP_ATTRIBUTE
249 %token <struct psi_token *> CPP_EXTENSION
250 %token <struct psi_token *> CPP_PASTE
251 %token <struct psi_token *> CPP_INLINE
252 %token <struct psi_token *> CPP_RESTRICT
253 %token <struct psi_token *> CPP_ASM
254
255 /* virtual tokens */
256 %token <struct psi_token *> BSLASH
257 %token <struct psi_token *> LONG_DOUBLE
258 %token <struct psi_token *> INT8
259 %token <struct psi_token *> UINT8
260 %token <struct psi_token *> INT16
261 %token <struct psi_token *> UINT16
262 %token <struct psi_token *> INT32
263 %token <struct psi_token *> UINT32
264 %token <struct psi_token *> INT64
265 %token <struct psi_token *> UINT64
266 %token <struct psi_token *> INT128
267 %token <struct psi_token *> UINT128
268
269
270 %precedence IIF COLON
271 %precedence OR
272 %precedence AND
273 %precedence PIPE
274 %precedence CARET
275 %precedence AMPERSAND
276 %precedence CMP_EQ CMP_NE
277 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
278 %precedence LSHIFT RSHIFT
279 %precedence PLUS MINUS
280 %precedence ASTERISK SLASH MODULO
281 //%precedence NOT TILDE
282 %precedence BINARY
283 %precedence UNARY
284
285 %type <struct psi_token *> optional_name enum_name struct_name union_name
286 %destructor {psi_token_free(&$$);} optional_name enum_name struct_name union_name
287
288 %type <struct psi_token *> cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_macro_decl_arg_token
289 %destructor {} cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_macro_decl_arg_token
290
291 %type <struct psi_token *> name_token any_noeol_token binary_op_token unary_op_token
292 %destructor {} name_token any_noeol_token binary_op_token unary_op_token
293
294 %type <struct psi_token *> int_width int_width_types int_signed_types
295 %destructor {psi_token_free(&$$);} int_width int_width_types int_signed_types
296
297 %type <struct psi_token *> signed_long_types signed_short_types int_signed
298 %destructor {} signed_long_types signed_short_types int_signed
299
300 %type <struct psi_cpp_exp *> cpp cpp_exp
301 %destructor {psi_cpp_exp_free(&$$);} cpp cpp_exp
302 %type <struct psi_cpp_macro_decl *> cpp_macro_decl
303 %destructor {psi_cpp_macro_decl_free(&$$);} cpp_macro_decl
304 %type <struct psi_plist *> cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
305 %destructor {psi_plist_free($$);} cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
306 %type <struct psi_num_exp *> cpp_macro_exp
307 %destructor {psi_num_exp_free(&$$);} cpp_macro_exp
308
309 %type <struct psi_token *> impl_def_val_token
310 %destructor {} impl_def_val_token
311
312 %type <struct psi_const *> constant
313 %destructor {psi_const_free(&$$);} constant
314 %type <struct psi_impl_def_val *> impl_def_val
315 %destructor {psi_impl_def_val_free(&$$);} impl_def_val
316
317 %type <struct psi_token *> decl_real_type decl_int_type decl_type_simple
318 %destructor {psi_token_free(&$$);} decl_real_type decl_int_type decl_type_simple
319
320 %type <struct psi_token *> decl_asm quoted_strings
321 %destructor {psi_token_free(&$$);} decl_asm quoted_strings
322
323 %type <struct psi_decl_type *> decl_type qualified_decl_type decl_type_complex
324 %destructor {psi_decl_type_free(&$$);} decl_type qualified_decl_type decl_type_complex
325 %type <struct psi_decl *> decl_stmt decl decl_body decl_func_body decl_functor_body decl_anon_functor_body ignored_decl
326 %destructor {psi_decl_free(&$$);} decl_stmt decl decl_body decl_func_body decl_functor_body decl_anon_functor_body ignored_decl
327 %type <struct psi_decl_arg *> decl_typedef decl_func decl_functor decl_anon_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
328 %destructor {psi_decl_arg_free(&$$);} decl_typedef decl_func decl_functor decl_anon_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
329 %type <struct psi_decl_var *> decl_var
330 %destructor {psi_decl_var_free(&$$);} decl_var
331 %type <struct psi_decl_struct *> decl_struct
332 %destructor {psi_decl_struct_free(&$$);} decl_struct
333 %type <struct psi_decl_union *> decl_union
334 %destructor {psi_decl_union_free(&$$);} decl_union
335 %type <struct psi_decl_enum *> decl_enum
336 %destructor {psi_decl_enum_free(&$$);} decl_enum
337 %type <struct psi_decl_enum_item *> decl_enum_item
338 %destructor {psi_decl_enum_item_free(&$$);} decl_enum_item
339 %type <struct psi_plist *> decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
340 %destructor {psi_plist_free($$);} decl_args decl_arg_list decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout call_decl_vars decl_extvar_stmt decl_extvar_list
341
342 %type <struct psi_layout> align_and_size
343 %destructor {} align_and_size
344 %type <struct psi_layout *> decl_layout
345 %destructor {psi_layout_free(&$$);} decl_layout
346
347 %type <struct psi_number *> sizeof sizeof_body sizeof_body_notypes
348 %destructor {psi_number_free(&$$);} sizeof sizeof_body sizeof_body_notypes
349
350 %type <struct psi_impl *> impl
351 %destructor {psi_impl_free(&$$);} impl
352 %type <struct psi_impl_func *> impl_func
353 %destructor {psi_impl_func_free(&$$);} impl_func
354 %type <struct psi_impl_arg *> impl_arg
355 %destructor {psi_impl_arg_free(&$$);} impl_arg
356 %type <struct psi_impl_type *> impl_type impl_type_restricted
357 %destructor {psi_impl_type_free(&$$);} impl_type impl_type_restricted
358 %type <struct psi_impl_var *> impl_var
359 %destructor {psi_impl_var_free(&$$);} impl_var
360
361 %type <struct psi_let_stmt *> let_stmt
362 %destructor {psi_let_stmt_free(&$$);} let_stmt
363 %type <struct psi_let_exp *> let_exp let_exp_byref let_exp_assign
364 %destructor {psi_let_exp_free(&$$);} let_exp let_exp_byref let_exp_assign
365 %type <struct psi_let_calloc *> let_calloc
366 %destructor {psi_let_calloc_free(&$$);} let_calloc
367 %type <struct psi_let_callback *> let_callback
368 %destructor {psi_let_callback_free(&$$);} let_callback
369 %type <struct psi_let_func *> let_func
370 %destructor {psi_let_func_free(&$$);} let_func
371 %type <struct psi_set_stmt *> set_stmt
372 %destructor {psi_set_stmt_free(&$$);} set_stmt
373 %type <struct psi_set_exp *> set_exp
374 %destructor {psi_set_exp_free(&$$);} set_exp
375 %type <struct psi_set_func *> set_func
376 %destructor {psi_set_func_free(&$$);} set_func
377 %type <struct psi_assert_stmt *> assert_stmt
378 %destructor {psi_assert_stmt_free(&$$);} assert_stmt
379 %type <struct psi_return_stmt *> return_stmt
380 %destructor {psi_return_stmt_free(&$$);} return_stmt
381 %type <struct psi_return_exp *> return_exp
382 %destructor {psi_return_exp_free(&$$);} return_exp
383 %type <struct psi_free_stmt *> free_stmt
384 %destructor {psi_free_stmt_free(&$$);} free_stmt
385 %type <struct psi_free_exp *> free_exp
386 %destructor {psi_free_exp_free(&$$);} free_exp
387
388 %type <struct psi_token **> impl_stmt
389 %destructor {psi_impl_stmt_free(&$$);} impl_stmt
390 %type <struct psi_token *> impl_type_token impl_type_restricted_token impl_type_extended_token callback_rval let_func_token set_func_token assert_stmt_token
391 %destructor {} impl_type_token impl_type_restricted_token impl_type_extended_token callback_rval let_func_token set_func_token assert_stmt_token
392 %type <struct psi_plist *> impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
393 %destructor {psi_plist_free($$);} impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
394
395 %type <struct psi_num_exp *> num_exp
396 %destructor {psi_num_exp_free(&$$);} num_exp
397 %type <struct psi_number *> number
398 %destructor {psi_number_free(&$$);} number
399
400 %type <size_t> indirection pointers asterisks array_size
401 %destructor {} indirection pointers asterisks array_size
402 %type <bool> reference
403 %destructor {} reference
404
405 %%
406
407 /* rules */
408
409
410 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
411 unary_op_token: TILDE | NOT | PLUS | MINUS ;
412 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | BOOL | STRING | MIXED | ARRAY | OBJECT | ERROR | WARNING | LINE | PRAGMA | AS | let_func_token | set_func_token;
413 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
414 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE | AS;
415
416
417 file:
418 %empty
419 | blocks
420 ;
421 blocks:
422 block
423 | blocks block
424 ;
425 block:
426 EOS
427 | EOL
428 | COMMENT
429 | cpp {
430 if ($cpp) {
431 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
432 psi_cpp_exp_free(&$cpp);
433 }
434 }
435 | constant {
436 psi_parser_proc_add_const(P, $constant);
437 }
438 | decl_stmt {
439 psi_parser_proc_add_decl(P, $decl_stmt);
440 }
441 | decl_extvar_stmt[list] {
442 psi_parser_proc_add_decl_extvars(P, $list);
443 }
444 | ignored_decl {
445 if (P->flags & PSI_DEBUG) {
446 P->error(PSI_DATA(P), $ignored_decl->func->token, PSI_NOTICE, "Ignored decl: %s", $ignored_decl->func->var->name->val);
447 }
448 psi_decl_free(&$ignored_decl);
449 }
450 | decl_typedef[def] {
451 psi_parser_proc_add_typedef(P, $def);
452 }
453 | decl_struct[struct] {
454 psi_parser_proc_add_struct(P, $struct);
455 }
456 | decl_union[union] {
457 psi_parser_proc_add_union(P, $union);
458 }
459 | decl_enum[enum] {
460 psi_parser_proc_add_enum(P, $enum);
461 }
462 | impl {
463 psi_parser_proc_add_impl(P, $impl);
464 }
465 ;
466
467 cpp:
468 HASH EOL {
469 $cpp = NULL;
470 }
471 | HASH cpp_exp[exp] EOL {
472 $cpp = $exp;
473 }
474 ;
475
476 cpp_exp[exp]:
477 cpp_message_token cpp_macro_decl_tokens[tokens] {
478 if ($tokens) {
479 struct psi_token *msg = NULL;
480
481 if (psi_plist_get($tokens, 0, &msg)) {
482 size_t index = 1;
483 struct psi_token *next;
484
485 msg = psi_token_copy(msg);
486 while (psi_plist_get($tokens, index++, &next)) {
487 struct psi_token *old = msg;
488 msg = psi_token_cat(" ", 2, msg, next);
489 psi_token_free(&old);
490 }
491 }
492 psi_plist_free($tokens);
493
494 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
495 } else {
496 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
497 }
498 $exp->token = psi_token_copy($cpp_message_token);
499 }
500 | cpp_include_token[INCLUDE] cpp_header_token {
501 $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
502 $exp->token = psi_token_copy($INCLUDE);
503 }
504 | cpp_no_arg_token {
505 $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
506 $exp->token = psi_token_copy($cpp_no_arg_token);
507 }
508 | cpp_name_arg_token any_noeol_token[name_token] {
509 $name_token->type = PSI_T_NAME;
510 $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
511 $exp->token = psi_token_copy($cpp_name_arg_token);
512 }
513 | cpp_macro_decl_arg_token cpp_macro_decl {
514 $exp = psi_cpp_exp_init($cpp_macro_decl_arg_token->type, $cpp_macro_decl);
515 $exp->token = psi_token_copy($cpp_macro_decl_arg_token);
516 }
517 | cpp_exp_arg_token cpp_macro_exp {
518 $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
519 $exp->token = psi_token_copy($cpp_exp_arg_token);
520 }
521 | cpp_ignored_token cpp_macro_decl_tokens[tokens] {
522 psi_plist_free($tokens);
523 $exp = NULL;
524 }
525 ;
526
527 cpp_macro_decl_arg_token:
528 DEFINE
529 | PRAGMA
530
531 ;
532
533 cpp_ignored_token:
534 LINE
535 ;
536
537 cpp_message_token:
538 ERROR
539 | WARNING
540 ;
541
542 cpp_include_token:
543 IMPORT
544 | INCLUDE
545 | INCLUDE_NEXT
546 ;
547
548 cpp_header_token:
549 QUOTED_STRING
550 | CPP_HEADER
551 ;
552
553 cpp_no_arg_token:
554 ELSE
555 | ENDIF
556 ;
557
558 cpp_name_arg_token:
559 IFDEF
560 | IFNDEF
561 | UNDEF
562 ;
563
564 cpp_exp_arg_token:
565 IF
566 | ELIF
567 ;
568
569 cpp_macro_decl[macro]:
570 any_noeol_token[name_token] cpp_macro_decl_tokens %dprec 1 {
571 $name_token->type = PSI_T_NAME;
572 $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
573 $macro->token = psi_token_copy($name_token);
574 }
575 | name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens %dprec 2 {
576 $name_token->type = PSI_T_NAME;
577 $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
578 $macro->token = psi_token_copy($name_token);
579 }
580 | name_token cpp_macro_exp[num_exp] %dprec 2 {
581 $name_token->type = PSI_T_NAME;
582 $macro = psi_cpp_macro_decl_init(NULL, psi_num_exp_tokens($num_exp, NULL), $num_exp);
583 $macro->token = psi_token_copy($name_token);
584 }
585 | name_token quoted_strings[strings] %dprec 2 {
586 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_token_free);
587 $name_token->type = PSI_T_NAME;
588 $macro = psi_cpp_macro_decl_init(NULL, psi_plist_add(list, &$strings), NULL);
589 $macro->token = psi_token_copy($name_token);
590 }
591 ;
592
593 cpp_macro_sig[sig]:
594 %empty {
595 $sig = psi_plist_init(NULL);
596 }
597 | ELLIPSIS {
598 $sig = psi_plist_init(NULL); /* FIXME */
599 }
600 | cpp_macro_sig_args
601 | cpp_macro_sig_args[args] COMMA ELLIPSIS {
602 $sig = $args;
603 }
604 ;
605
606 cpp_macro_sig_args[args]:
607 name_token {
608 $name_token = psi_token_copy($name_token);
609 $name_token->type = PSI_T_NAME;
610 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
611 }
612 | cpp_macro_sig_args[args_] COMMA name_token {
613 $name_token = psi_token_copy($name_token);
614 $name_token->type = PSI_T_NAME;
615 $args = psi_plist_add($args_, &$name_token);
616 }
617 ;
618
619 cpp_macro_decl_tokens[tokens]:
620 %empty {
621 $tokens = NULL;
622 }
623 | cpp_macro_decl_token_list
624 ;
625
626 cpp_macro_decl_token_list[tokens]:
627 any_noeol_token[token] {
628 $token = psi_token_copy($token);
629 $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
630 }
631 | cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
632 $token = psi_token_copy($token);
633 $tokens = psi_plist_add($tokens_, &$token);
634 }
635 ;
636
637 cpp_macro_exp[exp]:
638 LPAREN cpp_macro_exp[exp_] RPAREN {
639 $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
640 $exp->token = psi_token_copy($LPAREN);
641 }
642 | unary_op_token cpp_macro_exp[exp_] %prec UNARY {
643 $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
644 $exp->token = psi_token_copy($unary_op_token);
645 }
646 | cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
647 $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
648 $exp->token = psi_token_copy($binary_op_token);
649 }
650 | cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
651 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
652 $exp->token = psi_token_copy($IIF);
653 }
654
655 | DEFINED name_token {
656 {
657 uint8_t exists;
658
659 $name_token->type = PSI_T_NAME;
660 exists = psi_cpp_defined(P->preproc, $name_token);
661 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINED, &exists, 0));
662 $exp->token = psi_token_copy($DEFINED);
663 $exp->data.n->token = psi_token_copy($name_token);
664 }
665 }
666 | DEFINED LPAREN name_token RPAREN {
667 {
668 uint8_t exists;
669
670 $name_token->type = PSI_T_NAME;
671 exists = psi_cpp_defined(P->preproc, $name_token);
672 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINED, &exists, 0));
673 $exp->token = psi_token_copy($DEFINED);
674 $exp->data.n->token = psi_token_copy($name_token);
675 }
676 }
677 | NUMBER {
678 $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
679 $exp->token = psi_token_copy($NUMBER);
680 $exp->data.n->token = psi_token_copy($NUMBER);
681 }
682 | QUOTED_CHAR {
683 $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
684 $exp->token = psi_token_copy($QUOTED_CHAR);
685 $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
686 }
687 | sizeof {
688 $exp = psi_num_exp_init_num($sizeof);
689 $exp->token = psi_token_copy($sizeof->token);
690 }
691 | name_token {
692 $name_token->type = PSI_T_NAME;
693 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
694 $exp->token = psi_token_copy($name_token);
695 $exp->data.n->token = psi_token_copy($name_token);
696 }
697 | name_token LPAREN cpp_macro_call_args RPAREN {
698 $name_token->type = PSI_T_NAME;
699 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
700 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
701 $exp->token = psi_token_copy($name_token);
702 $exp->data.n->token = psi_token_copy($name_token);
703 $exp->data.n->data.call->token = psi_token_copy($name_token);
704 }
705 ;
706
707 cpp_macro_call_args[args]:
708 %empty {
709 $args = NULL;
710 }
711 | cpp_macro_call_arg_list
712 ;
713
714 cpp_macro_call_arg_list[args]:
715 CPP_HEADER {
716 /* TODO: clang include test macros */
717 uint8_t no = 1;
718 struct psi_num_exp *exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &no, 0));
719 exp->token = psi_token_copy($CPP_HEADER);
720 exp->data.n->token = psi_token_copy($CPP_HEADER);
721 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free), &exp);
722 }
723 | cpp_macro_exp {
724 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
725 &$cpp_macro_exp);
726 }
727 | cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
728 $args = psi_plist_add($args_, &$cpp_macro_exp);
729 }
730 ;
731
732 constant[const]:
733 CONST impl_type_restricted[type] NSNAME EQUALS impl_def_val EOS {
734 $const = psi_const_init($type, $NSNAME->text, $impl_def_val);
735 $const->token = psi_token_copy($NSNAME);
736 }
737 | CONST NSNAME EQUALS impl_def_val EOS {
738 $const = psi_const_init(NULL, $NSNAME->text, $impl_def_val);
739 $const->token = psi_token_copy($NSNAME);
740 }
741 ;
742
743 impl_def_val[val]:
744 impl_def_val_token[token] %dprec 2 {
745 $val = psi_impl_def_val_init($token->type, $token->text);
746 $val->token = psi_token_copy($token);
747 }
748 | num_exp[num] %dprec 1 {
749 $val = psi_impl_def_val_init(PSI_T_NUMBER, $num);
750 $val->token = psi_token_copy($num->token);
751 }
752 | quoted_strings[token] {
753 $val = psi_impl_def_val_init($token->type, $token->text);
754 $val->token = $token;
755 }
756 ;
757
758 impl_def_val_token:
759 NULL
760 | TRUE
761 | FALSE
762 ;
763
764 decl_typedef[def]:
765 TYPEDEF typedef[def_] EOS {
766 $def = $def_;
767 }
768 /*
769 | TYPEDEF VOID name_token EOS {
770 $def = psi_decl_arg_init(
771 psi_decl_type_init(PSI_T_VOID, $VOID->text),
772 psi_decl_var_init($name_token->text, 0, 0)
773 );
774 $def->token = psi_token_copy($VOID);
775 $def->type->token = psi_token_copy($VOID);
776 $def->var->token = psi_token_copy($name_token);
777 }
778 */
779 | CPP_EXTENSION TYPEDEF typedef[def_] EOS {
780 $def = $def_;
781 }
782 ;
783
784 typedef[def]:
785 typedef_decl {
786 $def = $typedef_decl;
787 }
788 | CPP_EXTENSION typedef_decl {
789 $def = $typedef_decl;
790 }
791 ;
792
793 typedef_anon[def]:
794 typedef_anon_decl {
795 $def = $typedef_anon_decl;
796 }
797 | CPP_EXTENSION typedef_anon_decl {
798 $def = $typedef_anon_decl;
799 }
800 ;
801
802 typedef_decl[def]:
803 decl_arg
804 | decl_func_body[decl] {
805 $def = psi_decl_arg_init(
806 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
807 psi_decl_var_copy($decl->func->var)
808 );
809 $def->type->token = psi_token_copy($decl->func->token);
810 $def->type->real.func = $decl;
811 }
812 | decl_enum[enum] name_token {
813 $name_token->type = PSI_T_NAME;
814 $def = psi_decl_arg_init(
815 psi_decl_type_init(PSI_T_ENUM, $enum->name),
816 psi_decl_var_init($name_token->text, 0, 0)
817 );
818 $def->var->token = psi_token_copy($name_token);
819 $def->type->token = psi_token_copy($enum->token);
820 $def->type->real.enm = $enum;
821 psi_parser_proc_add_enum(P, $enum);
822 }
823 | struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
824 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
825 $def->type->token = $struct;
826 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
827 $def->type->real.strct->token = psi_token_copy($struct);
828 $def->type->real.strct->align = $as.pos;
829 $def->type->real.strct->size = $as.len;
830 psi_parser_proc_add_struct(P, $def->type->real.strct);
831 }
832 | union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
833 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
834 $def->type->token = $union;
835 $def->type->real.unn = psi_decl_union_init($union->text, $args);
836 $def->type->real.unn->token = psi_token_copy($union);
837 $def->type->real.unn->align = $as.pos;
838 $def->type->real.unn->size = $as.len;
839 psi_parser_proc_add_union(P, $def->type->real.unn);
840 }
841 ;
842
843 typedef_anon_decl[def]:
844 typedef_decl %dprec 2
845 | qualified_decl_type[type] %dprec 1 {
846 $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
847 $def->var->token = psi_token_copy($type->token);
848 }
849 | decl_enum[enum] {
850 $def = psi_decl_arg_init(
851 psi_decl_type_init(PSI_T_ENUM, $enum->name),
852 psi_decl_var_init(NULL, 0, 0)
853 );
854 $def->var->token = psi_token_copy($enum->token);
855 $def->type->token = psi_token_copy($enum->token);
856 $def->type->real.enm = $enum;
857 psi_parser_proc_add_enum(P, $enum);
858 }
859 | struct_name[struct] align_and_size[as] struct_args_block[args] {
860 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
861 $def->type->token = $struct;
862 $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
863 $def->type->real.strct->token = psi_token_copy($struct);
864 $def->type->real.strct->align = $as.pos;
865 $def->type->real.strct->size = $as.len;
866 psi_parser_proc_add_struct(P, $def->type->real.strct);
867 }
868 | union_name[union] align_and_size[as] struct_args_block[args] {
869 $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
870 $def->type->token = $union;
871 $def->type->real.unn = psi_decl_union_init($union->text, $args);
872 $def->type->real.unn->token = psi_token_copy($union);
873 $def->type->real.unn->align = $as.pos;
874 $def->type->real.unn->size = $as.len;
875 psi_parser_proc_add_union(P, $def->type->real.unn);
876 }
877 ;
878
879 qualified_decl_type[type]:
880 decl_type
881 | decl_type_qualifier_token decl_type[type_] {
882 $type = $type_;
883 }
884 | qualified_decl_type[type_] decl_type_qualifier_token {
885 $type = $type_;
886 }
887 ;
888
889 decl_type_qualifier_token:
890 CONST
891 | VOLATILE
892 ;
893
894 decl_type[type]:
895 decl_type_simple[token] {
896 $type = psi_decl_type_init($token->type, $token->text);
897 $type->token = $token;
898 }
899 | decl_type_complex
900 ;
901
902 decl_type_complex[type]:
903 STRUCT[token] name_token {
904 $name_token->type = PSI_T_NAME;
905 $type = psi_decl_type_init($token->type, $name_token->text);
906 $type->token = psi_token_copy($name_token);
907 }
908 | UNION[token] name_token {
909 $name_token->type = PSI_T_NAME;
910 $type = psi_decl_type_init($token->type, $name_token->text);
911 $type->token = psi_token_copy($name_token);
912 }
913 | ENUM[token] name_token {
914 $name_token->type = PSI_T_NAME;
915 $type = psi_decl_type_init($token->type, $name_token->text);
916 $type->token = psi_token_copy($name_token);
917 }
918 ;
919
920 decl_type_simple[type]:
921 decl_int_type
922 | decl_real_type
923 | NAME[type_] {
924 $type = psi_token_copy($type_);
925 }
926 | VOID[type_] {
927 $type = psi_token_copy($type_);
928 }
929 ;
930
931 decl_real_type[type]: /* allocated, so free, if set */
932 FLOAT[type_] {
933 $type = psi_token_copy($type_);
934 }
935 | DOUBLE[type_] {
936 $type = psi_token_copy($type_);
937 }
938 | LONG DOUBLE {
939 $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
940 }
941 ;
942
943 int_signed[i]:
944 SIGNED
945 | UNSIGNED
946 ;
947
948 int_width[i]: /* allocated, so free, if set */
949 SHORT {
950 $i = psi_token_copy($SHORT);
951 }
952 | LONG {
953 $i = psi_token_copy($LONG);
954 }
955 | LONG[l1] LONG[l2] {
956 $i = psi_token_cat(" ", 2, $l1, $l2);
957 }
958 ;
959
960 decl_int_type[type]: /* allocated, so free, if set */
961 CHAR {
962 $type = psi_token_copy($CHAR);
963 }
964 | INT {
965 $type = psi_token_copy($INT);
966 }
967 | int_signed int_signed_types {
968 if ($2) {
969 $type = psi_token_cat(" ", 2, $1, $2);
970 psi_token_free(&$2);
971 } else {
972 $type = psi_token_copy($1);
973 }
974 }
975 | int_width int_width_types {
976 if ($2) {
977 $type = psi_token_cat(" ", 2, $1, $2);
978 psi_token_free(&$1);
979 psi_token_free(&$2);
980 } else {
981 $type = $1;
982 }
983 }
984 ;
985
986 int_signed_types[type]: /* allocated, so free, if set */
987 %empty {
988 $type = NULL;
989 }
990 | NAME {
991 $type = psi_token_copy($NAME);
992 }
993 | CHAR {
994 $type = psi_token_copy($CHAR);
995 }
996 | SHORT signed_short_types {
997 if ($2) {
998 $type = psi_token_cat(" ", 2, $1, $2);
999 } else {
1000 $type = psi_token_copy($1);
1001 }
1002 }
1003 | INT {
1004 $type = psi_token_copy($INT);
1005 }
1006 | LONG signed_long_types {
1007 if ($2) {
1008 $type = psi_token_cat(" ", 2, $1, $2);
1009 } else {
1010 $type = psi_token_copy($1);
1011 }
1012 }
1013 ;
1014
1015 signed_short_types[type]:
1016 %empty {
1017 $type = NULL;
1018 }
1019 | INT
1020 ;
1021 signed_long_types[type]:
1022 %empty {
1023 $type = NULL;
1024 }
1025 | INT
1026 | LONG
1027 | LONG INT
1028 ;
1029
1030 int_width_types[type]: /* allocated, so free, if set */
1031 %empty {
1032 $type = NULL;
1033 }
1034 | INT {
1035 $type = psi_token_copy($INT);
1036 }
1037 | int_signed int_signed_types {
1038 if ($2) {
1039 $type = psi_token_cat(" ", 2, $1, $2);
1040 psi_token_free(&$2);
1041 } else {
1042 $type = psi_token_copy($1);
1043 }
1044 }
1045 ;
1046
1047 decl_stmt:
1048 decl decl_asm EOS {
1049 $decl_stmt = $decl;
1050 if ($decl_asm) {
1051 $decl->redir = zend_string_copy($decl_asm->text);
1052 psi_token_free(&$decl_asm);
1053 }
1054 }
1055 | CPP_EXTENSION decl decl_asm EOS {
1056 $decl_stmt = $decl;
1057 if ($decl_asm) {
1058 $decl->redir = zend_string_copy($decl_asm->text);
1059 psi_token_free(&$decl_asm);
1060 }
1061 }
1062 ;
1063
1064 decl_asm:
1065 %empty {
1066 $decl_asm = NULL;
1067 }
1068 | CPP_ASM LPAREN quoted_strings RPAREN {
1069 $decl_asm = $quoted_strings;
1070 }
1071 ;
1072
1073 quoted_strings[strings]:
1074 QUOTED_STRING {
1075 $strings = psi_token_copy($QUOTED_STRING);
1076 }
1077 | quoted_strings[strings_] QUOTED_STRING {
1078 $strings = psi_token_cat("", 2, $strings_, $QUOTED_STRING);
1079 psi_token_free(&$strings_);
1080 }
1081 ;
1082
1083 decl_extvar_stmt[list]:
1084 NAME decl_arg decl_extvar_list[vars] decl_asm EOS {
1085 struct psi_plist *list = psi_plist_init((psi_plist_dtor) psi_decl_extvar_free);
1086
1087 if ($vars) {
1088 size_t i = 0;
1089 struct psi_decl_var *var;
1090
1091 while (psi_plist_get($vars, i++, &var)) {
1092 if (psi_decl_extvar_is_blacklisted(var->name->val)) {
1093 psi_decl_var_free(&var);
1094 } else {
1095 struct psi_decl_extvar *evar = psi_decl_extvar_init(
1096 psi_decl_arg_init(psi_decl_type_copy($decl_arg->type), var));
1097 list = psi_plist_add(list, &evar);
1098 }
1099 }
1100 free($vars);
1101 }
1102
1103 if (psi_decl_extvar_is_blacklisted($decl_arg->var->name->val)) {
1104 psi_decl_arg_free(&$decl_arg);
1105 } else {
1106 struct psi_decl_extvar *evar = psi_decl_extvar_init($decl_arg);
1107
1108 if ($decl_asm) {
1109 evar->redir = zend_string_copy($decl_asm->text);
1110 psi_token_free(&$decl_asm);
1111 }
1112 list = psi_plist_add(list, &evar);
1113 }
1114
1115 $list = list;
1116 }
1117 ;
1118
1119 decl_extvar_list[list]:
1120 %empty {
1121 $list = NULL;
1122 }
1123 | COMMA decl_vars {
1124 $list = $decl_vars;
1125 }
1126 ;
1127
1128 decl_vars[vars]:
1129 decl_var[var] {
1130 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1131 }
1132 | decl_vars[vars_] COMMA decl_var[var] {
1133 $vars = psi_plist_add($vars_, &$var);
1134 }
1135 ;
1136
1137 ignored_decl:
1138 ignored_decl_qualifiers decl_body ignored_decl_body {
1139 $ignored_decl = $decl_body;
1140 }
1141 ;
1142
1143 ignored_decl_qualifiers:
1144 STATIC
1145 | STATIC CPP_INLINE
1146 | CPP_EXTENSION CPP_INLINE
1147 | CPP_EXTENSION STATIC CPP_INLINE
1148 | CPP_INLINE
1149 | NAME CPP_INLINE
1150 ;
1151
1152 ignored_decl_body:
1153 LBRACE ignored_decl_body_stmts RBRACE
1154 ;
1155
1156 ignored_decl_body_stmts:
1157 ignored_decl_body_stmt
1158 | ignored_decl_body_stmts ignored_decl_body_stmt
1159 ;
1160
1161 ignored_decl_body_stmt:
1162 any_nobrace_token
1163 | ignored_decl_body
1164 ;
1165
1166 decl:
1167 decl_body
1168 | NAME[abi] decl_body {
1169 $decl = $decl_body;
1170 $decl->abi = psi_decl_abi_init($abi->text);
1171 }
1172 ;
1173
1174 decl_body:
1175 decl_func_body
1176 | decl_functor_body
1177 ;
1178
1179 decl_func_body[decl]:
1180 decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1181 $decl = psi_decl_init($func, $args);
1182 if ($as) {
1183 $decl->func->var->pointer_level += 1;
1184 $decl->func->var->array_size = $as;
1185 }
1186 }
1187 | decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1188 $decl = psi_decl_init($func, $args);
1189 $decl->varargs = 1;
1190 if ($as) {
1191 $decl->func->var->pointer_level += 1;
1192 $decl->func->var->array_size = $as;
1193 }
1194 }
1195 ;
1196
1197 decl_functor_body[decl]:
1198 decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1199 $decl = psi_decl_init($func, $args);
1200 if ($as) {
1201 $decl->func->var->pointer_level += 1;
1202 $decl->func->var->array_size = $as;
1203 }
1204 }
1205 | decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1206 $decl = psi_decl_init($func, $args);
1207 $decl->varargs = 1;
1208 if ($as) {
1209 $decl->func->var->pointer_level += 1;
1210 $decl->func->var->array_size = $as;
1211 }
1212 }
1213 | qualified_decl_type[rval_type] indirection[i] LPAREN indirection[unused1] name_token[NAME] LPAREN decl_args[args] RPAREN RPAREN LPAREN decl_args[rval_args] RPAREN array_size[as] {
1214 (void) $unused1;
1215 $NAME->type = PSI_T_NAME;
1216
1217 struct psi_token *type_token = psi_token_append("@", psi_token_copy($NAME), 1, "rval");
1218 struct psi_decl_arg *rval_func = psi_decl_arg_init($rval_type, psi_decl_var_init(type_token->text, $i, 0));
1219 struct psi_decl *rval_decl = psi_decl_init(rval_func, $rval_args);
1220
1221 rval_func->var->token = psi_token_copy(type_token);
1222 rval_func->token = psi_token_copy(type_token);
1223 if ($as) {
1224 rval_func->var->pointer_level += 1;
1225 rval_func->var->array_size = $as;
1226 }
1227
1228 struct psi_decl_type *type = psi_decl_type_init(PSI_T_FUNCTION, type_token->text);
1229 struct psi_decl_arg *func = psi_decl_arg_init(type, psi_decl_var_init($NAME->text, 1, 0));
1230
1231 type->real.func = rval_decl;
1232 func->var->token = psi_token_copy($NAME);
1233 func->token = psi_token_copy($NAME);
1234
1235 $decl = psi_decl_init(func, $args);
1236 }
1237 | qualified_decl_type[rval_type] indirection[i] LPAREN indirection[unused1] LPAREN indirection[unused2] name_token[NAME] RPAREN LPAREN decl_args[args] RPAREN RPAREN LPAREN decl_args[rval_args] RPAREN array_size[as] {
1238 (void) $unused1;
1239 (void) $unused2;
1240 $NAME->type = PSI_T_NAME;
1241
1242 struct psi_token *type_token = psi_token_append("@", psi_token_copy($NAME), 1, "rval");
1243 struct psi_decl_arg *rval_func = psi_decl_arg_init($rval_type, psi_decl_var_init(type_token->text, $i, 0));
1244 struct psi_decl *rval_decl = psi_decl_init(rval_func, $rval_args);
1245
1246 rval_func->var->token = psi_token_copy(type_token);
1247 rval_func->token = psi_token_copy(type_token);
1248 if ($as) {
1249 rval_func->var->pointer_level += 1;
1250 rval_func->var->array_size = $as;
1251 }
1252
1253 struct psi_decl_type *type = psi_decl_type_init(PSI_T_FUNCTION, type_token->text);
1254 struct psi_decl_arg *func = psi_decl_arg_init(type, psi_decl_var_init($NAME->text, 1, 0));
1255
1256 type->real.func = rval_decl;
1257 func->var->token = psi_token_copy($NAME);
1258 func->token = psi_token_copy($NAME);
1259 type->token = type_token;
1260
1261 $decl = psi_decl_init(func, $args);
1262 }
1263 ;
1264
1265 decl_anon_functor_body[decl]:
1266 decl_anon_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1267 $decl = psi_decl_init($func, $args);
1268 if ($as) {
1269 $decl->func->var->pointer_level += 1;
1270 $decl->func->var->array_size = $as;
1271 }
1272 }
1273 | decl_anon_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1274 $decl = psi_decl_init($func, $args);
1275 $decl->varargs = 1;
1276 if ($as) {
1277 $decl->func->var->pointer_level += 1;
1278 $decl->func->var->array_size = $as;
1279 }
1280 }
1281 ;
1282
1283 decl_functor[arg]:
1284 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1285 (void) $unused1;
1286 $NAME->type = PSI_T_NAME;
1287 $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1288 $arg->var->token = psi_token_copy($NAME);
1289 $arg->token = psi_token_copy($NAME);
1290 }
1291
1292 /*
1293 | CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1294 (void) $unused1;
1295 $NAME->type = PSI_T_NAME;
1296 $arg = psi_decl_arg_init(
1297 psi_decl_type_init($VOID->type, $VOID->text),
1298 psi_decl_var_init($NAME->text, $pointers, 0)
1299 );
1300 $arg->type->token = psi_token_copy($VOID);
1301 $arg->var->token = psi_token_copy($NAME);
1302 $arg->token = psi_token_copy($NAME);
1303 }
1304 | VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1305 (void) $unused1;
1306 $NAME->type = PSI_T_NAME;
1307 $arg = psi_decl_arg_init(
1308 psi_decl_type_init($VOID->type, $VOID->text),
1309 psi_decl_var_init($NAME->text, $pointers, 0)
1310 );
1311 $arg->type->token = psi_token_copy($VOID);
1312 $arg->var->token = psi_token_copy($NAME);
1313 $arg->token = psi_token_copy($NAME);
1314 }
1315 | VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1316 (void) $unused1;
1317 $NAME->type = PSI_T_NAME;
1318 $arg = psi_decl_arg_init(
1319 psi_decl_type_init($VOID->type, $VOID->text),
1320 psi_decl_var_init($NAME->text, 0, 0)
1321 );
1322 $arg->type->token = psi_token_copy($VOID);
1323 $arg->var->token = psi_token_copy($NAME);
1324 $arg->token = psi_token_copy($NAME);
1325 }
1326 */
1327 ;
1328
1329 decl_anon_functor[arg]:
1330 qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] RPAREN {
1331 (void) $unused1;
1332 $arg = psi_decl_arg_init($type, psi_decl_var_init(NULL, $i, 0));
1333 $arg->var->token = psi_token_copy($LPAREN);
1334 $arg->token = psi_token_copy($LPAREN);
1335 }
1336 /*
1337 | CONST VOID pointers LPAREN indirection[unused1] RPAREN {
1338 (void) $unused1;
1339 $arg = psi_decl_arg_init(
1340 psi_decl_type_init($VOID->type, $VOID->text),
1341 psi_decl_var_init(NULL, $pointers, 0)
1342 );
1343 $arg->type->token = psi_token_copy($VOID);
1344 $arg->var->token = psi_token_copy($VOID);
1345 $arg->token = psi_token_copy($VOID);
1346 }
1347 | VOID pointers LPAREN indirection[unused1] RPAREN {
1348 (void) $unused1;
1349 $arg = psi_decl_arg_init(
1350 psi_decl_type_init($VOID->type, $VOID->text),
1351 psi_decl_var_init(NULL, $pointers, 0)
1352 );
1353 $arg->type->token = psi_token_copy($VOID);
1354 $arg->var->token = psi_token_copy($VOID);
1355 $arg->token = psi_token_copy($VOID);
1356 }
1357 | VOID LPAREN indirection[unused1] RPAREN {
1358 (void) $unused1;
1359 $arg = psi_decl_arg_init(
1360 psi_decl_type_init($VOID->type, $VOID->text),
1361 psi_decl_var_init(NULL, 0, 0)
1362 );
1363 $arg->type->token = psi_token_copy($VOID);
1364 $arg->var->token = psi_token_copy($VOID);
1365 $arg->token = psi_token_copy($VOID);
1366 }
1367 */
1368 ;
1369
1370 decl_func[func]:
1371 decl_arg
1372 /*
1373 | VOID name_token[NAME] {
1374 $func = psi_decl_arg_init(
1375 psi_decl_type_init($VOID->type, $VOID->text),
1376 psi_decl_var_init($NAME->text, 0, 0)
1377 );
1378 $func->type->token = psi_token_copy($VOID);
1379 $func->var->token = psi_token_copy($NAME);
1380 $func->token = psi_token_copy($NAME);
1381 }
1382 */
1383 ;
1384
1385 decl_args[args]:
1386 %empty {
1387 $args = NULL;
1388 }
1389 | VOID %dprec 2 {
1390 $args = NULL;
1391 }
1392 | decl_arg_list[args_] %dprec 1 {
1393 $args = $args_;
1394 }
1395 ;
1396
1397 decl_arg_list[args]:
1398 decl_anon_arg[arg] {
1399 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1400 }
1401 | decl_arg_list[args_] COMMA decl_anon_arg[arg] {
1402 $args = psi_plist_add($args_, &$arg);
1403 }
1404 ;
1405
1406 decl_anon_arg[arg]:
1407 decl_anon_functor_body[decl] {
1408 char digest[17];
1409 struct psi_token *name;
1410
1411 psi_token_hash($decl->func->token, digest);
1412 name = psi_token_append("@", psi_token_copy($decl->func->token), 2, "funct", digest);
1413
1414 $arg = psi_decl_arg_init(
1415 psi_decl_type_init(PSI_T_FUNCTION, name->text),
1416 psi_decl_var_copy($decl->func->var)
1417 );
1418 $arg->token = name;
1419 $arg->type->token = psi_token_copy($decl->func->token);
1420 $arg->type->real.func = $decl;
1421 }
1422 | decl_arg %dprec 2 {
1423 $arg = $decl_arg;
1424 }
1425 | qualified_decl_type[type] indirection array_size[as] %dprec 1 {
1426 $arg = psi_decl_arg_init(
1427 $type,
1428 psi_decl_var_init(NULL, $indirection, $as)
1429 );
1430 }
1431 /*
1432 | CONST VOID pointers {
1433 $arg = psi_decl_arg_init(
1434 psi_decl_type_init($VOID->type, $VOID->text),
1435 psi_decl_var_init(NULL, $pointers, 0)
1436 );
1437 $arg->type->token = psi_token_copy($VOID);
1438 $arg->var->token = psi_token_copy($VOID);
1439 $arg->token = psi_token_copy($VOID);
1440 }
1441 | VOID pointers {
1442 $arg = psi_decl_arg_init(
1443 psi_decl_type_init($VOID->type, $VOID->text),
1444 psi_decl_var_init(NULL, $pointers, 0)
1445 );
1446 $arg->type->token = psi_token_copy($VOID);
1447 $arg->var->token = psi_token_copy($VOID);
1448 $arg->token = psi_token_copy($VOID);
1449 }
1450 */
1451 ;
1452
1453 decl_arg[arg]:
1454 decl_functor_body[decl] {
1455 $arg = psi_decl_arg_init(
1456 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1457 psi_decl_var_copy($decl->func->var)
1458 );
1459 $arg->type->token = psi_token_copy($decl->func->token);
1460 $arg->type->real.func = $decl;
1461 }
1462 | qualified_decl_type[type] decl_var[var] {
1463 $arg = psi_decl_arg_init($type, $var);
1464 }
1465 /*
1466 | CONST VOID pointers name_token[NAME] {
1467 $NAME->type = PSI_T_NAME;
1468 $arg = psi_decl_arg_init(
1469 psi_decl_type_init($VOID->type, $VOID->text),
1470 psi_decl_var_init($NAME->text, $pointers, 0)
1471 );
1472 $arg->type->token = psi_token_copy($VOID);
1473 $arg->var->token = psi_token_copy($NAME);
1474 $arg->token = psi_token_copy($NAME);
1475 }
1476 | VOID pointers name_token[NAME] {
1477 $NAME->type = PSI_T_NAME;
1478 $arg = psi_decl_arg_init(
1479 psi_decl_type_init($VOID->type, $VOID->text),
1480 psi_decl_var_init($NAME->text, $pointers, 0)
1481 );
1482 $arg->type->token = psi_token_copy($VOID);
1483 $arg->var->token = psi_token_copy($NAME);
1484 $arg->token = psi_token_copy($NAME);
1485 }
1486 */
1487 ;
1488
1489 decl_var[var]:
1490 pointers name_token array_size {
1491 $name_token->type = PSI_T_NAME;
1492 $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1493 $var->token = psi_token_copy($name_token);
1494 }
1495 | name_token array_size {
1496 $name_token->type = PSI_T_NAME;
1497 $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1498 $var->token = psi_token_copy($name_token);
1499 }
1500 ;
1501
1502 decl_union[union]:
1503 UNION name_token align_and_size[as] decl_struct_args[args] {
1504 $name_token->type = PSI_T_NAME;
1505 $union = psi_decl_union_init($name_token->text, $args);
1506 $union->align = $as.pos;
1507 $union->size = $as.len;
1508 $union->token = psi_token_copy($name_token);
1509 }
1510 ;
1511
1512 decl_struct[struct]:
1513 STRUCT name_token align_and_size[as] decl_struct_args[args] {
1514 $name_token->type = PSI_T_NAME;
1515 $struct = psi_decl_struct_init($name_token->text, $args);
1516 $struct->align = $as.pos;
1517 $struct->size = $as.len;
1518 $struct->token = psi_token_copy($name_token);
1519 }
1520 ;
1521
1522 decl_struct_args[args]:
1523 EOS {
1524 $args = NULL;
1525 }
1526 | struct_args_block
1527 ;
1528
1529 struct_args_block[args]:
1530 LBRACE struct_args RBRACE {
1531 $args = $struct_args;
1532 }
1533 ;
1534
1535 struct_args[args]:
1536 typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1537 $arg->layout = $layout;
1538 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1539 if ($vars) {
1540 size_t i = 0;
1541 struct psi_decl_arg *arg;
1542
1543 while (psi_plist_get($vars, i++, &arg)) {
1544 arg->type = psi_decl_type_copy($arg->type);
1545 $args = psi_plist_add($args, &arg);
1546 }
1547 free($vars);
1548 }
1549 }
1550 | struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1551 $arg->layout = $layout;
1552 $args = psi_plist_add($args_, &$arg);
1553 if ($vars) {
1554 size_t i = 0;
1555 struct psi_decl_arg *arg;
1556
1557 while (psi_plist_get($vars, i++, &arg)) {
1558 arg->type = psi_decl_type_copy($arg->type);
1559 $args = psi_plist_add($args, &arg);
1560 }
1561 free($vars);
1562 }
1563 }
1564 ;
1565
1566 struct_arg_var_list[vars]:
1567 %empty {
1568 $vars = NULL;
1569 }
1570 | COMMA decl_vars_with_layout[vars_] {
1571 $vars = $vars_;
1572 }
1573 ;
1574
1575 decl_vars_with_layout[vars]:
1576 decl_var[var] decl_layout[layout] {
1577 {
1578 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1579 arg->layout = $layout;
1580 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1581 }
1582 }
1583 | decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1584 {
1585 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1586 arg->layout = $layout;
1587 $vars = psi_plist_add($vars_, &arg);
1588 }
1589 }
1590 | decl_layout[layout] {
1591 {
1592 struct psi_decl_var *var = psi_decl_var_init(NULL, 0, 0);
1593 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, var);
1594 arg->layout = $layout;
1595 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1596 }
1597 }
1598 | decl_vars_with_layout[vars_] COMMA decl_layout[layout] {
1599 {
1600 struct psi_decl_var *var = psi_decl_var_init(NULL, 0, 0);
1601 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, var);
1602 arg->layout = $layout;
1603 $vars = psi_plist_add($vars_, &arg);
1604 }
1605 }
1606 ;
1607
1608 decl_enum[enum]:
1609 enum_name LBRACE decl_enum_items[list] optional_comma RBRACE {
1610 $enum = psi_decl_enum_init($enum_name->text, $list);
1611 $enum->token = $enum_name;
1612 }
1613 ;
1614
1615 decl_enum_items[list]:
1616 decl_enum_item[i] {
1617 $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1618 }
1619 | decl_enum_items[list_] COMMA decl_enum_item[i] {
1620 $list = psi_plist_add($list_, &$i);
1621 }
1622 ;
1623
1624 decl_enum_item[i]:
1625 name_token {
1626 $name_token->type = PSI_T_NAME;
1627 $i = psi_decl_enum_item_init($name_token->text, NULL);
1628 $i->token = psi_token_copy($name_token);
1629 }
1630 | name_token EQUALS num_exp {
1631 $name_token->type = PSI_T_NAME;
1632 $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1633 $i->token = psi_token_copy($name_token);
1634 }
1635 ;
1636
1637 num_exp[exp]:
1638 number {
1639 $exp = psi_num_exp_init_num($number);
1640 $exp->token = psi_token_copy($number->token);
1641 }
1642 | LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1643 $exp = psi_num_exp_init_cast($type, $exp_);
1644 $exp->token = psi_token_copy($type->token);
1645 }
1646 | LPAREN num_exp[exp_] RPAREN {
1647 $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1648 $exp->token = psi_token_copy($LPAREN);
1649 }
1650 | num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1651 $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1652 $exp->token = psi_token_copy($op);
1653 }
1654 | unary_op_token[op] num_exp[exp_] %prec UNARY {
1655 $exp = psi_num_exp_init_unary($op->type, $exp_);
1656 $exp->token = psi_token_copy($op);
1657 }
1658 | num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1659 $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1660 $exp->token = psi_token_copy($IIF);
1661 }
1662 ;
1663
1664 number[num]:
1665 NUMBER[token] {
1666 $num = psi_number_init($token->type, $token->text, $token->flags);
1667 $num->token = psi_token_copy($token);
1668 }
1669 | NSNAME[token] {
1670 $num = psi_number_init($token->type, $token->text, 0);
1671 $num->token = psi_token_copy($token);
1672 }
1673 | QUOTED_CHAR[token] {
1674 $num = psi_number_init($token->type, $token->text, 0);
1675 $num->token = psi_token_copy($token);
1676 }
1677 | NULL[token] {
1678 $num = psi_number_init($token->type, $token->text, 0);
1679 $num->token = psi_token_copy($token);
1680 }
1681 | decl_var {
1682 $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1683 $num->token = psi_token_copy($decl_var->token);
1684 }
1685 | sizeof {
1686 $num = $sizeof;
1687 }
1688 ;
1689
1690 sizeof:
1691 SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1692 $sizeof = $sizeof_;
1693 $sizeof->token = psi_token_copy($SIZEOF);
1694 }
1695 | SIZEOF sizeof_body_notypes[sizeof_] {
1696 $sizeof = $sizeof_;
1697 $sizeof->token = psi_token_copy($SIZEOF);
1698 }
1699 ;
1700
1701 sizeof_body[sizeof]:
1702 sizeof_body_notypes[sizeof_] {
1703 $sizeof = $sizeof_;
1704 }
1705 | decl_type indirection {
1706 if ($indirection) {
1707 int8_t sizeof_void_p = sizeof(void *);
1708 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1709 psi_decl_type_free(&$decl_type);
1710 } else {
1711 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1712 }
1713 }
1714 ;
1715
1716 sizeof_body_notypes[sizeof]:
1717 AMPERSAND NAME {
1718 int8_t sizeof_void_p = sizeof(void *);
1719 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1720 }
1721 | QUOTED_CHAR {
1722 int8_t sizeof_a = sizeof('a');
1723 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1724 }
1725 | QUOTED_STRING {
1726 uint64_t len = $QUOTED_STRING->text->len + 1;
1727 $sizeof = psi_number_init(PSI_T_UINT64, &len, 0);
1728 }
1729 ;
1730
1731 enum_name[name]:
1732 ENUM optional_name[name_] {
1733 if ($name_) {
1734 $name = psi_token_copy($name_);
1735 } else {
1736 char digest[17];
1737
1738 psi_token_hash($ENUM, digest);
1739 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1740 }
1741 }
1742 ;
1743
1744 union_name[name]:
1745 UNION optional_name[name_] {
1746 if ($name_) {
1747 $name = psi_token_copy($name_);
1748 } else {
1749 char digest[17];
1750
1751 psi_token_hash($UNION, digest);
1752 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1753 }
1754 }
1755 ;
1756
1757 struct_name[name]:
1758 STRUCT optional_name[name_] {
1759 if ($name_) {
1760 $name = psi_token_copy($name_);
1761 } else {
1762 char digest[17];
1763
1764 psi_token_hash($STRUCT, digest);
1765 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1766 }
1767 }
1768 ;
1769
1770 optional_name[name]:
1771 %empty {
1772 $name = NULL;
1773 }
1774 | name_token {
1775 $name = $name_token;
1776 $name->type = PSI_T_NAME;
1777 }
1778 ;
1779
1780 optional_comma:
1781 %empty
1782 | COMMA
1783 ;
1784
1785 decl_layout[l]:
1786 %empty {
1787 $l = NULL;
1788 }
1789 | COLON NUMBER[width] {
1790 $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text->val), NULL));
1791 }
1792 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1793 $l = psi_layout_init(atol($align->text->val), atol($size->text->val), NULL);
1794 }
1795 | COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1796 $l = psi_layout_init(atol($align->text->val), atol($size->text->val), psi_layout_init(0, atol($width->text->val), NULL));
1797 }
1798 ;
1799
1800 align_and_size[as]:
1801 %empty {
1802 $as.pos = 0;
1803 $as.len = 0;
1804 }
1805 | COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1806 $as.pos = atol($align->text->val);
1807 $as.len = atol($size->text->val);
1808 }
1809 ;
1810
1811 array_size[as]:
1812 %empty {
1813 $as = 0;
1814 }
1815 | LBRACKET array_qualifier_token RBRACKET {
1816 $as = 0;
1817 }
1818 | LBRACKET num_exp RBRACKET {
1819 struct psi_validate_scope scope = {0};
1820 psi_validate_scope_ctor(&scope);
1821 scope.cpp = P->preproc;
1822 if (psi_num_exp_validate(PSI_DATA(P), $num_exp, &scope)) {
1823 $as = psi_num_exp_get_long($num_exp, NULL, P->preproc);
1824 } else {
1825 $as = 0;
1826 }
1827 psi_num_exp_free(&$num_exp);
1828 psi_validate_scope_dtor(&scope);
1829 }
1830 ;
1831
1832 array_qualifier_token:
1833 %empty
1834 | CPP_RESTRICT
1835 | VOLATILE
1836 | CONST
1837 ;
1838
1839 indirection[i]:
1840 %empty {
1841 $i = 0;
1842 }
1843 | pointers[p] %prec UNARY {
1844 $i = $p;
1845 }
1846 ;
1847
1848 pointers[p]:
1849 asterisks
1850 | asterisks[a] CPP_RESTRICT {
1851 $p = $a;
1852 }
1853 ;
1854
1855 asterisks[a]:
1856 asterisk {
1857 $a = 1;
1858 }
1859 | asterisks[a_] asterisk {
1860 $a = $a_ + 1;
1861 }
1862 ;
1863
1864 asterisk:
1865 ASTERISK
1866 | ASTERISK pointer_qualifier_token
1867 ;
1868
1869 pointer_qualifier_token:
1870 CONST
1871 | VOLATILE
1872 ;
1873
1874 /*
1875 *
1876 * impl
1877 *
1878 */
1879
1880 impl:
1881 impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1882 $impl = psi_impl_init($func, $stmts);
1883 }
1884 | STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1885 $impl = psi_impl_init($func, $stmts);
1886 $func->static_memory = 1;
1887 }
1888 ;
1889
1890 impl_func[func]:
1891 FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1892 $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1893 $func->token = psi_token_copy($NSNAME);
1894 $func->return_reference = $r;
1895 }
1896 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1897 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1898 $func->token = psi_token_copy($NSNAME);
1899 $func->return_reference = $r;
1900 }
1901 | FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1902 $func = psi_impl_func_init($NSNAME->text, $args, $type);
1903 $func->token = psi_token_copy($NSNAME);
1904 $func->return_reference = $r;
1905 $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1906 $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1907 }
1908 ;
1909
1910 impl_args[args]:
1911 impl_arg[arg] {
1912 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1913 }
1914 | impl_args[args_] COMMA impl_arg[arg] {
1915 $args = psi_plist_add($args_, &$arg);
1916 }
1917 ;
1918
1919 impl_arg[arg]:
1920 impl_type[type] impl_var[var] {
1921 $arg = psi_impl_arg_init($type, $var, NULL);
1922 }
1923 | impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1924 $arg = psi_impl_arg_init($type, $var, $val);
1925 }
1926 ;
1927
1928 impl_var[var]:
1929 reference DOLLAR_NAME {
1930 $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1931 $var->token = psi_token_copy($DOLLAR_NAME);
1932 }
1933 ;
1934
1935 impl_type[type]:
1936 impl_type_token[token] {
1937 $type = psi_impl_type_init($token->type, $token->text);
1938 $type->token = psi_token_copy($token);
1939 }
1940 ;
1941
1942 impl_type_restricted[type]:
1943 impl_type_restricted_token[token] {
1944 $type = psi_impl_type_init($token->type, $token->text);
1945 $type->token = psi_token_copy($token);
1946 }
1947 ;
1948
1949 impl_type_token:
1950 impl_type_restricted_token
1951 | impl_type_extended_token
1952 ;
1953
1954 impl_type_restricted_token:
1955 BOOL
1956 | INT
1957 | FLOAT
1958 | STRING
1959 | MIXED
1960 ;
1961
1962 impl_type_extended_token:
1963 VOID
1964 | ARRAY
1965 | OBJECT
1966 | CALLABLE
1967 ;
1968
1969 impl_stmts[stmts]:
1970 impl_stmt[stmt] {
1971 $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1972 }
1973 | impl_stmts[stmts_] impl_stmt[stmt] {
1974 $stmts = psi_plist_add($stmts_, &$stmt);
1975 }
1976 ;
1977
1978 impl_stmt[stmt]:
1979 return_stmt[s] {
1980 $stmt = (struct psi_token **) $s;
1981 }
1982 | let_stmt[s] {
1983 $stmt = (struct psi_token **) $s;
1984 }
1985 | set_stmt[s] {
1986 $stmt = (struct psi_token **) $s;
1987 }
1988 | assert_stmt[s] {
1989 $stmt = (struct psi_token **) $s;
1990 }
1991 | free_stmt[s] {
1992 $stmt = (struct psi_token **) $s;
1993 }
1994 ;
1995
1996 let_stmt[let]:
1997 LET let_exp_assign[exp] EOS {
1998 $let = psi_let_stmt_init($exp);
1999 $let->token = psi_token_copy($LET);
2000 }
2001 | TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
2002 $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
2003 $let->token = psi_token_copy($TEMP);
2004 $let->exp->is_reference = $reference;
2005 }
2006 ;
2007
2008 let_exp[exp]:
2009 let_exp_assign
2010 | byref let_exp_byref[exp_] {
2011 $exp = $exp_;
2012 $exp->is_reference = true;
2013 }
2014 | let_exp_byref[exp_] {
2015 $exp = $exp_;
2016 $exp->is_reference = false;
2017 }
2018 ;
2019
2020 let_exp_byref[exp]:
2021 NULL %dprec 2 {
2022 $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
2023 }
2024 | num_exp[num] %dprec 1 {
2025 $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
2026 }
2027 | let_calloc[calloc] {
2028 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
2029 }
2030 | STATIC let_calloc[calloc] {
2031 $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
2032 $calloc->static_memory = 1;
2033 }
2034 | let_callback[callback] {
2035 $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
2036 }
2037 | let_func[func] {
2038 $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
2039 }
2040 ;
2041
2042 let_exp_assign[exp]:
2043 decl_var[var] EQUALS let_exp_byref[exp_] {
2044 $exp = $exp_;
2045 $exp->var = $var;
2046 }
2047 | decl_var[var] EQUALS byref let_exp_byref[exp_] {
2048 $exp = $exp_;
2049 $exp->is_reference = 1;
2050 $exp->var = $var;
2051 }
2052 ;
2053
2054 let_calloc[calloc]:
2055 CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
2056 $calloc = psi_let_calloc_init($nmemb, $size);
2057 $calloc->token = psi_token_copy($CALLOC);
2058 }
2059 ;
2060
2061 let_callback[callback]:
2062 CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
2063 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, NULL);
2064 $callback->func->token = psi_token_copy($func);
2065 $callback->token = psi_token_copy($CALLBACK);
2066 }
2067 | CALLBACK LPAREN call_decl_vars[cb_args] RPAREN AS callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
2068 $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args, $cb_args);
2069 $callback->func->token = psi_token_copy($func);
2070 $callback->token = psi_token_copy($CALLBACK);
2071 }
2072 ;
2073
2074 let_func[func]:
2075 let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
2076 $func = psi_let_func_init($token->type, $token->text, $var);
2077 $func->token = psi_token_copy($token);
2078 $func->inner = $exps;
2079 }
2080 ;
2081
2082 let_func_token:
2083 ZVAL
2084 | OBJVAL
2085 | ARRVAL
2086 | PATHVAL
2087 | STRLEN
2088 | STRVAL
2089 | FLOATVAL
2090 | INTVAL
2091 | BOOLVAL
2092 | COUNT
2093 ;
2094
2095 let_func_exps[exps]:
2096 %empty {
2097 $exps = NULL;
2098 }
2099 | COMMA let_exps[exps_] {
2100 $exps = $exps_;
2101 }
2102 ;
2103
2104 let_exps[exps]:
2105 let_exp[exp] {
2106 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
2107 }
2108 | let_exps[exps_] COMMA let_exp[exp] {
2109 $exps = psi_plist_add($exps_, &$exp);
2110 }
2111 ;
2112
2113 callback_rval[rval]:
2114 VOID
2115 | let_func_token
2116 ;
2117
2118 callback_arg_list[list]:
2119 %empty {
2120 $list = NULL;
2121 }
2122 | callback_args[args] {
2123 $list = $args;
2124 }
2125 ;
2126
2127 callback_args[args]:
2128 set_exp[exp] {
2129 $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2130 }
2131 | callback_args[args_] COMMA set_exp[exp] {
2132 $args = psi_plist_add($args_, &$exp);
2133 }
2134 ;
2135
2136 return_stmt[return]:
2137 RETURN return_exp EOS {
2138 $return = psi_return_stmt_init($return_exp);
2139 $return->token = psi_token_copy($RETURN);
2140 }
2141 ;
2142
2143 return_exp:
2144 decl_var[func] LPAREN call_decl_vars[args] RPAREN AS set_func {
2145 $return_exp = psi_return_exp_init($func, $args, psi_set_exp_init(PSI_SET_FUNC, $set_func));
2146 $return_exp->token = psi_token_copy($func->token);
2147 }
2148 | set_func {
2149 $return_exp = psi_return_exp_init(NULL, NULL, psi_set_exp_init(PSI_SET_FUNC, $set_func));
2150 $return_exp->token = psi_token_copy($set_func->token);
2151 }
2152 ;
2153
2154 call_decl_vars[args]:
2155 %empty {
2156 $args = NULL;
2157 }
2158 | VOID {
2159 $args = NULL;
2160 }
2161 | decl_vars[vars] {
2162 $args = $vars;
2163 }
2164 ;
2165
2166 set_stmt[set]:
2167 SET set_exp[exp] EOS {
2168 $set = psi_set_stmt_init($exp);
2169 $set->token = psi_token_copy($SET);
2170 }
2171 ;
2172
2173 set_exp[exp]:
2174 set_func[func] {
2175 $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
2176 }
2177 | num_exp[num] {
2178 $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
2179 }
2180 | impl_var[var] EQUALS set_exp[exp_] {
2181 $exp = $exp_;
2182 $exp->var = $var;
2183 }
2184 ;
2185
2186 set_func[func]:
2187 set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
2188 $func = psi_set_func_init($token->type, $token->text, $var);
2189 $func->token = psi_token_copy($token);
2190 $func->inner = $exps;
2191 }
2192 | set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
2193 $func = psi_set_func_init($token->type, $token->text, $var);
2194 $func->token = psi_token_copy($token);
2195 $func->recursive = 1;
2196 }
2197 ;
2198
2199 set_func_token:
2200 TO_OBJECT
2201 | TO_ARRAY
2202 | TO_STRING
2203 | TO_INT
2204 | TO_FLOAT
2205 | TO_BOOL
2206 | ZVAL
2207 | VOID
2208 ;
2209
2210 set_func_exps[exps]:
2211 %empty {
2212 $exps = NULL;
2213 }
2214 | COMMA set_exps[exps_] {
2215 $exps = $exps_;
2216 }
2217 ;
2218
2219 set_exps[exps]:
2220 set_exp[exp] {
2221 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
2222 }
2223 | set_exps[exps_] COMMA set_exp[exp] {
2224 $exps = psi_plist_add($exps_, &$exp);
2225 }
2226 ;
2227
2228 assert_stmt[assert]:
2229 assert_stmt_token[token] num_exp[exp] EOS {
2230 $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
2231 $assert->token = psi_token_copy($token);
2232 }
2233 ;
2234
2235 assert_stmt_token:
2236 PRE_ASSERT
2237 | POST_ASSERT
2238 ;
2239
2240 free_stmt[free]:
2241 FREE free_exps[exps] EOS {
2242 $free = psi_free_stmt_init($exps);
2243 $free->token = psi_token_copy($FREE);
2244 }
2245 ;
2246
2247 free_exps[exps]:
2248 free_exp[exp] {
2249 $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
2250 }
2251 | free_exps[exps_] COMMA free_exp[exp] {
2252 $exps = psi_plist_add($exps_, &$exp);
2253 }
2254 ;
2255
2256 free_exp[exp]:
2257 name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2258 $NAME->type = PSI_T_NAME;
2259 $exp = psi_free_exp_init($NAME->text, $vars);
2260 $exp->token = psi_token_copy($NAME);
2261 }
2262 ;
2263
2264 reference:
2265 %empty {
2266 $reference = false;
2267 }
2268 | byref {
2269 $reference = true;
2270 }
2271 ;
2272
2273 byref:
2274 AMPERSAND %prec UNARY
2275 ;
2276
2277 %%
2278
2279 /* epilogue */
2280
2281 #define PSI_DEBUG_LEX 0
2282 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2283 {
2284 struct psi_token *token;
2285 #if PSI_DEBUG_LEX
2286 PSI_DEBUG_PRINT(P, "PSI: LEX index %4zu ", *index);
2287 #endif
2288 if (psi_plist_get(tokens, (*index)++, &token) && token) {
2289 #if PSI_DEBUG_LEX
2290 PSI_DEBUG_DUMP(P, psi_token_dump, token);
2291 #endif
2292 *((struct psi_token **)lvalp) = token;
2293 return token->type;
2294 } else {
2295 #if PSI_DEBUG_LEX
2296 PSI_DEBUG_PRINT(P, "EOF\n");
2297 #endif
2298 (*index)--;
2299 }
2300
2301 return PSI_T_EOF;
2302 }
2303
2304 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2305 {
2306 struct psi_token *T = NULL;
2307 size_t last;
2308
2309 if (*index == 0) {
2310 last = 0;
2311 } else {
2312 last = --(*index);
2313 }
2314
2315 psi_plist_get(tokens, last, &T);
2316 if (T) {
2317 size_t i = (last >= 5) ? last - 5 : 0;
2318
2319 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2320 while (i <= last || T->type != PSI_T_EOS) {
2321 const char *pos;
2322
2323 if (!psi_plist_get(tokens, i++, &T)) {
2324 break;
2325 }
2326
2327 if (i < last + 1) {
2328 pos = "preceding";
2329 } else if (i > last + 1) {
2330 pos = "following";
2331 } else {
2332 pos = "offending";
2333 }
2334
2335 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s token '%s' at col %u",
2336 pos, T ? T->text->val : "<deleted>", T ? T->col : 0);
2337 }
2338 } else {
2339 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2340 }
2341 P->errors++;
2342 }
2343
PHP System Interface / POSIX Standard Interface