git.m6w6.name Git - m6w6/ext-psi/blob - psi.d/netdb.psi

   1 #include <netdb.h>
   2
   3 function psi\endhostent() : void {
   4         return endhostent() as void(endhostent);
   5 }
   6 function psi\endnetent() : void {
   7         return endnetent() as void(endnetent);
   8 }
   9 function psi\endprotoent() : void {
  10         return endprotoent() as void(endprotoent);
  11 }
  12 function psi\endservent() : void {
  13         return endservent() as void(endservent);
  14 }
  15
  16 function psi\sethostent(bool $stayopen) : void {
  17         let stayopen = intval($stayopen);
  18         return sethostent(stayopen) as void(sethostent);
  19 }
  20 function psi\setnetent(bool $stayopen) : void {
  21         let stayopen = intval($stayopen);
  22         return setnetent(stayopen) as void(setnetent);
  23 }
  24 function psi\setprotoent(bool $stayopen) : void {
  25         let stayopen = intval($stayopen);
  26         return setprotoent(stayopen) as void(setprotoent);
  27 }
  28 function psi\setservent(bool $stayopen) : void {
  29         let stayopen = intval($stayopen);
  30         return setservent(stayopen) as void(setservent);
  31 }
  32
  33 function psi\gethostent() : array {
  34         return gethostent() as to_array(*gethostent,
  35                 to_string(h_name),
  36                 to_array(h_aliases, to_string(h_aliases)),
  37                 to_int(h_addrtype),
  38                 to_int(h_length),
  39                 to_array(h_addr_list, to_string(h_addr_list, h_length))
  40         );
  41 }
  42
  43 function psi\gai_strerror(int $errcode) : string {
  44         let errcode = intval($errcode);
  45         return gai_strerror(errcode) as to_string(gai_strerror);
  46 }
  47
  48 // extern int getaddrinfo(const char *node, const char *service, const struct addrinfo *hints, struct addrinfo **res)
  49 function psi\getaddrinfo(string $node, string $service, array $hints = NULL, object &$res = NULL) : int {
  50         let node = strval($node);
  51         let service = strval($service);
  52         let hints = &arrval($hints,
  53                 intval($ai_flags),
  54                 intval($ai_family),
  55                 intval($ai_socktype),
  56                 intval($ai_protocol)
  57         );
  58         let res = &NULL;
  59         return getaddrinfo(node, service, hints, res) as to_int(getaddrinfo);
  60         set $res = to_array(**res,
  61                 to_int(ai_flags),
  62                 to_int(ai_family),
  63                 to_int(ai_socktype),
  64                 to_int(ai_protocol),
  65                 to_int(ai_addrlen),
  66                 to_string(ai_addr, ai_addrlen),
  67                 to_string(ai_canonname),
  68                 to_array(*ai_next, ...)
  69         );
  70         free freeaddrinfo(*res);
  71 }
  72
  73 // extern int getnameinfo(struct sockaddr *sa, socklen_t salen, char *host, socklen_t hostlen, char *serv, socklen_t servlen, int flags)
  74 function psi\getnameinfo(string $addr, string &$host = NULL, string &$service = NULL, int $flags = 0) : int {
  75         let sa = strval($addr);
  76         let salen = strlen($addr);
  77         let hostlen = NI_MAXHOST;
  78         let host = calloc(hostlen, sizeof(char));
  79         let servlen = NI_MAXSERV;
  80         let serv = calloc(servlen, sizeof(char));
  81         let flags = intval($flags);
  82         return getnameinfo(sa, salen, host, hostlen, serv, servlen, flags) as to_int(getnameinfo);
  83         set $host = to_string(host);
  84         set $service = to_string(serv);
  85 }