git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi_type.m4

   1 # psi_type_pair(type, size)
   2 psi_type_pair() {
   3         local psi_type_name=`tr -cd A-Za-z0-9_ <<<$1`
   4         local psi_type_lower=`tr A-Z a-z <<<$psi_type_name`
   5         case $psi_type_lower in
   6         int*|uint*)
   7                 local psi_type_upper=`tr a-z A-Z <<<$psi_type_name`
   8                 local psi_type_bits=`expr $2 \* 8`
   9                 echo "PSI_T_${psi_type_upper}${psi_type_bits}, \"${psi_type_lower}${psi_type_bits}_t\""
  10                 #eval AS_TR_SH([psi_standard_type_]$1)="${psi_type_lower}${psi_type_bits}_t"
  11                 ;;
  12         struct*)
  13                 echo "PSI_T_STRUCT, \"$2\""
  14                 ;;
  15         void)
  16                 echo "PSI_T_VOID, \"void\""
  17                 ;;
  18         *)
  19                 echo "PSI_T_NAME, \"$psi_type_name\""
  20                 ;;
  21         esac
  22 }
  23
  24 dnl PSI_TYPE(type name, basic type)
  25 AC_DEFUN(PSI_TYPE, [
  26         ifdef(AS_TR_CPP(AC_TYPE_$1), AS_TR_CPP(AC_TYPE_$1))
  27         PSI_CHECK_SIZEOF($1, PSI_INCLUDES)
  28         psi_basic_type=AS_TR_SH($2)
  29         case $psi_basic_type in
  30         int)
  31                 AX_CHECK_SIGN($1, :, [
  32                         psi_basic_type=uint
  33                 ], PSI_INCLUDES)
  34                 ;;
  35         sint)
  36                 psi_basic_type=int
  37                 ;;
  38         esac
  39         if test "$2" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0; then
  40                 AS_TR_SH(psi_basic_type_$1)=$psi_basic_type
  41                 cat >>$PSI_TYPES <<<"   {`psi_type_pair $psi_basic_type $AS_TR_SH([ac_cv_sizeof_]$1)`, \"$1\"}, "
  42         fi
  43 ])
  44
  45 AC_DEFUN(PSI_OPAQUE_TYPE, [
  46         ifdef(AS_TR_CPP(AC_TYPE_$1), AS_TR_CPP(AC_TYPE_$1))
  47         PSI_CHECK_SIZEOF($1, PSI_INCLUDES)
  48         if test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0; then
  49                 psi_type_class=
  50                 AC_CACHE_CHECK(type class of $1, AS_TR_SH([psi_cv_type_class_]$1), [
  51                         AC_TRY_COMPILE(PSI_INCLUDES, [char test@<:@($1)1@:>@;], [
  52                                 psi_type_class=scalar
  53                         ], [
  54                                 AC_TRY_COMPILE(PSI_INCLUDES, [$1 test = 0;], [
  55                                         AC_TRY_COMPILE(PSI_INCLUDES, [$1 test = (($1)0)+1;], [
  56                                                 psi_type_class="pointer of known type"
  57                                         ], [
  58                                                 psi_type_class="pointer of opaque type"
  59                                         ])
  60                                 ], [
  61                                         psi_type_class=struct
  62                                 ])
  63                         ])
  64                         AS_TR_SH([psi_cv_type_class_]$1)="$psi_type_class"
  65                 ])
  66                 case "$AS_TR_SH([psi_cv_type_class_]$1)" in
  67                 scalar)
  68                         PSI_TYPE($1, int)
  69                         ;;
  70                 struct)
  71                         PSI_STRUCT($1)
  72                         ;;
  73                 pointer*)
  74                         cat >>$PSI_TYPES <<<"   {PSI_T_POINTER, \"void\", \"$1\"}, "
  75                         ;;
  76                 *)
  77                         AC_MSG_WARN(could not detect type class of $1)
  78                         ;;
  79                 esac
  80         fi
  81 ])
  82
  83 dnl unsigned char* buf[16] -> unsigned char*
  84 dnl AC_DEFUN(PSI_VAR_TYPE, [m4_bregexp([$1], [\(\(struct \)?[^ ]+\)[ *]+[^ ]+$], [\1])])
  85 AC_DEFUN(PSI_VAR_TYPE, [m4_bregexp([$1], [^\(const \)?\(.*\) \([*]*\)[^ ]+$], [\2\3])])
  86 dnl unsigned char* buf[16] -> buf
  87 AC_DEFUN(PSI_VAR_NAME, [m4_bregexp(m4_bregexp([$1], [\([^ ]+\)$], [\1]), [\w+], [\&])])
  88 dnl PSI_TYPE_SIZE(type, pointer level, array size)
  89 AC_DEFUN(PSI_TYPE_SIZE, [ifelse(
  90         [$3], 0,
  91                 [ifelse([$2], 0, $AS_TR_SH([ac_cv_sizeof_]$1), $ac_cv_sizeof_void_p)],
  92                 [ifelse([$2], 1, [`expr $3 \* $AS_TR_SH([ac_cv_sizeof_]$1)`], $ac_cv_sizeof_void_p)]
  93 )])
  94 dnl PSI_TYPE_BITS(type)
  95 AC_DEFUN(PSI_TYPE_BITS, [`expr 8 \* $AS_TR_SH([ac_cv_sizeof_]$1)`])
  96
  97 dnl PSI_TYPE_INDIRECTION(type, size, pointer_level_var, array_size_var)
  98 AC_DEFUN(PSI_TYPE_INDIRECTION, [
  99         dnl AC_MSG_CHECKING(indirection of $1)
 100         m4_define([psi_pointer_level], m4_len(m4_bpatsubst([PSI_VAR_TYPE($1)], [[^*]])))
 101         m4_define([psi_array_size], [m4_bregexp([PSI_VAR_TYPE($1)], [@<:@\([0-9]+\)@:>@], [\1])])
 102
 103         ifelse(psi_array_size.$2,0., [
 104                 AC_MSG_ERROR([cannot compute dynamic array size of a non-struct member])
 105         ], [
 106                 ifelse(psi_pointer_level,0,[
 107                         m4_define([psi_type_size],[$]AS_TR_SH([ac_cv_sizeof_]m4_bregexp(PSI_VAR_TYPE([$1]), [^\( \|\w\)+], [\&])))
 108                 ],[
 109                         m4_define([psi_type_size],$ac_cv_sizeof_void_p)
 110                 ])
 111         ])
 112
 113         m4_case(psi_array_size,,[
 114                 $3=psi_pointer_level
 115                 $4=0]
 116         ,0,[
 117                 $3=m4_incr(psi_pointer_level)
 118                 $4="`expr $2 / psi_type_size`"
 119         ], [
 120                 $3=m4_incr(psi_pointer_level)
 121                 $4=psi_array_size
 122         ])
 123
 124         dnl AC_MSG_RESULT([[$]$3, [$]$4])
 125 ])
 126
 127 AC_DEFUN(PSI_TYPE_PAIR, [m4_case(m4_bregexp([$1], [^\w+], [\&]),
 128         [void], [PSI_T_VOID, \"void\"],
 129         [struct], [PSI_T_STRUCT, \"m4_bregexp([$1], [^struct \(\w+\)], [\1])\"],
 130         [PSI_T_NAME, \"m4_bregexp([$1], [^\(\w+ \)*\w+], [\&])\"])])
 131
 132 AC_DEFUN(PSI_CHECK_STD_TYPES, [
 133         AC_CHECK_HEADERS(stdint.h)
 134
 135         AC_TYPE_INT8_T
 136         PSI_CHECK_SIZEOF(int8_t)
 137         AC_CHECK_ALIGNOF(int8_t)
 138         AC_TYPE_UINT8_T
 139         PSI_CHECK_SIZEOF(uint8_t)
 140         AC_CHECK_ALIGNOF(uint8_t)
 141         AC_TYPE_INT16_T
 142         PSI_CHECK_SIZEOF(int16_t)
 143         AC_CHECK_ALIGNOF(int16_t)
 144         AC_TYPE_UINT16_T
 145         PSI_CHECK_SIZEOF(uint16_t)
 146         AC_CHECK_ALIGNOF(uint16_t)
 147         AC_TYPE_INT32_T
 148         PSI_CHECK_SIZEOF(int32_t)
 149         AC_CHECK_ALIGNOF(int32_t)
 150         AC_TYPE_UINT32_T
 151         PSI_CHECK_SIZEOF(uint32_t)
 152         AC_CHECK_ALIGNOF(uint32_t)
 153         AC_TYPE_INT64_T
 154         PSI_CHECK_SIZEOF(int64_t)
 155         AC_CHECK_ALIGNOF(int64_t)
 156         AC_TYPE_UINT64_T
 157         PSI_CHECK_SIZEOF(uint64_t)
 158         AC_CHECK_ALIGNOF(uint64_t)
 159
 160         PSI_TYPE(float)
 161         AC_CHECK_ALIGNOF(float)
 162         PSI_TYPE(double)
 163         AC_CHECK_ALIGNOF(double)
 164         PSI_TYPE(void *)
 165         AC_CHECK_ALIGNOF(void *)
 166
 167         PSI_TYPE(char, int)
 168         PSI_TYPE(unsigned char, uint)
 169         PSI_TYPE(short, int)
 170         PSI_TYPE(unsigned short, uint)
 171         PSI_TYPE(int, int)
 172         PSI_TYPE(unsigned int, uint)
 173         PSI_TYPE(unsigned, uint)
 174         PSI_TYPE(long, int)
 175         PSI_TYPE(unsigned long, uint)
 176 ])