git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi_type.m4

   1 # psi_type_pair(type, size)
   2 psi_type_pair() {
   3         local psi_type_name=`tr -cd A-Za-z0-9_ <<<$1`
   4         local psi_type_lower=`tr A-Z a-z <<<$psi_type_name`
   5         case $psi_type_lower in
   6         int*|uint*)
   7                 local psi_type_upper=`tr a-z A-Z <<<$psi_type_name`
   8                 local psi_type_bits=`expr $2 \* 8`
   9                 echo "PSI_T_${psi_type_upper}${psi_type_bits}, \"${psi_type_lower}${psi_type_bits}_t\""
  10                 eval AS_TR_SH([psi_standard_type_]$1)="${psi_type_lower}${psi_type_bits}_t"
  11                 ;;
  12         struct*)
  13                 echo "PSI_T_STRUCT, \"$2\""
  14                 ;;
  15         void)
  16                 echo "PSI_T_VOID, \"void\""
  17                 ;;
  18         *)
  19                 echo "PSI_T_NAME, \"$psi_type_name\""
  20                 ;;
  21         esac
  22 }
  23
  24 dnl PSI_TYPE(type name, basic type, includes)
  25 AC_DEFUN(PSI_TYPE, [
  26         ifdef(AS_TR_CPP(AC_TYPE_$1), AS_TR_CPP(AC_TYPE_$1))
  27         PSI_CHECK_SIZEOF($1, PSI_INCLUDES)
  28         psi_basic_type=$2
  29         case $psi_basic_type in
  30         int)
  31                 AX_CHECK_SIGN($1, :, [
  32                         psi_basic_type=uint
  33                 ], $psi_header)
  34                 ;;
  35         sint)
  36                 psi_basic_type=int
  37                 ;;
  38         esac
  39         if test "$2" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0; then
  40                 AS_TR_SH(psi_basic_type_$1)=$psi_basic_type
  41                 PSI_TYPES="{`psi_type_pair $psi_basic_type $AS_TR_SH([ac_cv_sizeof_]$1)`, \"$1\"}, $PSI_TYPES"
  42         fi
  43 ])
  44
  45 dnl unsigned char* buf[16] -> unsigned char*
  46 dnl AC_DEFUN(PSI_VAR_TYPE, [m4_bregexp([$1], [\(\(struct \)?[^ ]+\)[ *]+[^ ]+$], [\1])])
  47 AC_DEFUN(PSI_VAR_TYPE, [m4_bregexp([$1], [^\(const \)?\(.*\) \([*]*\)[^ ]+$], [\2\3])])
  48 dnl unsigned char* buf[16] -> buf
  49 AC_DEFUN(PSI_VAR_NAME, [m4_bregexp(m4_bregexp([$1], [\([^ ]+\)$], [\1]), [\w+], [\&])])
  50 dnl PSI_TYPE_SIZE(type, pointer level, array size)
  51 AC_DEFUN(PSI_TYPE_SIZE, [ifelse(
  52         [$3], 0,
  53                 [ifelse([$2], 0, $AS_TR_SH([ac_cv_sizeof_]$1), $ac_cv_sizeof_void_p)],
  54                 [ifelse([$2], 1, [`expr $3 \* $AS_TR_SH([ac_cv_sizeof_]$1)`], $ac_cv_sizeof_void_p)]
  55 )])
  56 dnl PSI_TYPE_BITS(type)
  57 AC_DEFUN(PSI_TYPE_BITS, [`expr 8 \* $AS_TR_SH([ac_cv_sizeof_]$1)`])
  58
  59 dnl PSI_TYPE_INDIRECTION(type, size, pointer_level_var, array_size_var)
  60 AC_DEFUN(PSI_TYPE_INDIRECTION, [
  61         AC_MSG_CHECKING(indirection of $1)
  62         m4_define([pointer_level], m4_len(m4_bpatsubst([PSI_VAR_TYPE($1)], [[^*]])))
  63         m4_define([array_size], [m4_bregexp([PSI_VAR_TYPE($1)], [@<:@\([0-9]+\)@:>@], [\1])])
  64
  65         ifelse(array_size.$2,0., [
  66                 AC_MSG_ERROR([cannot compute dynamic array size of a non-struct member])
  67         ], [
  68                 ifelse(pointer_level,0,[
  69                         m4_define([type_size],[$]AS_TR_SH([ac_cv_sizeof_]m4_bregexp(PSI_VAR_TYPE([$1]), [^\( \|\w\)+], [\&])))
  70                 ],[
  71                         m4_define([type_size],$ac_cv_sizeof_void_p)
  72                 ])
  73         ])
  74
  75         m4_case(array_size,,[
  76                 $3=pointer_level
  77                 $4=0]
  78         ,0,[
  79                 $3=m4_incr(pointer_level)
  80                 $4="`expr $2 / type_size`"
  81         ], [
  82                 $3=m4_incr(pointer_level)
  83                 $4=array_size
  84         ])
  85
  86         AC_MSG_RESULT([[$]$3, [$]$4])
  87 ])
  88
  89 AC_DEFUN(PSI_TYPE_PAIR, [m4_case(m4_bregexp([$1], [^\w+], [\&]),
  90         [void], [PSI_T_VOID, \"void\"],
  91         [struct], [PSI_T_STRUCT, \"m4_bregexp([$1], [^struct \(\w+\)], [\1])\"],
  92         [PSI_T_NAME, \"m4_bregexp([$1], [^\(\w+ \)*\w+], [\&])\"])])
  93
  94 AC_DEFUN(PSI_CHECK_STD_TYPES, [
  95         AC_CHECK_HEADERS(stdint.h)
  96
  97         AC_TYPE_INT8_T
  98         PSI_CHECK_SIZEOF(int8_t)
  99         AC_CHECK_ALIGNOF(int8_t)
 100         AC_TYPE_UINT8_T
 101         PSI_CHECK_SIZEOF(uint8_t)
 102         AC_CHECK_ALIGNOF(uint8_t)
 103         AC_TYPE_INT16_T
 104         PSI_CHECK_SIZEOF(int16_t)
 105         AC_CHECK_ALIGNOF(int16_t)
 106         AC_TYPE_UINT16_T
 107         PSI_CHECK_SIZEOF(uint16_t)
 108         AC_CHECK_ALIGNOF(uint16_t)
 109         AC_TYPE_INT32_T
 110         PSI_CHECK_SIZEOF(int32_t)
 111         AC_CHECK_ALIGNOF(int32_t)
 112         AC_TYPE_UINT32_T
 113         PSI_CHECK_SIZEOF(uint32_t)
 114         AC_CHECK_ALIGNOF(uint32_t)
 115         AC_TYPE_INT64_T
 116         PSI_CHECK_SIZEOF(int64_t)
 117         AC_CHECK_ALIGNOF(int64_t)
 118         AC_TYPE_UINT64_T
 119         PSI_CHECK_SIZEOF(uint64_t)
 120         AC_CHECK_ALIGNOF(uint64_t)
 121
 122         PSI_TYPE(float)
 123         AC_CHECK_ALIGNOF(float)
 124         PSI_TYPE(double)
 125         AC_CHECK_ALIGNOF(double)
 126         PSI_TYPE(void *)
 127         AC_CHECK_ALIGNOF(void *)
 128
 129         PSI_TYPE(char, int)
 130         PSI_TYPE(unsigned char, uint)
 131         PSI_TYPE(short, int)
 132         PSI_TYPE(unsigned short, uint)
 133         PSI_TYPE(int, int)
 134         PSI_TYPE(unsigned int, uint)
 135         PSI_TYPE(unsigned, uint)
 136         PSI_TYPE(long, int)
 137         PSI_TYPE(unsigned long, uint)
 138 ])