git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi_type.m4

   1 # psi_type_pair(type, size)
   2 psi_type_pair() {
   3         local psi_type_name=`tr -cd A-Za-z0-9_ <<<$1`
   4         local psi_type_lower=`tr A-Z a-z <<<$psi_type_name`
   5         case $psi_type_lower in
   6         int*|uint*)
   7                 local psi_type_upper=`tr a-z A-Z <<<$psi_type_name`
   8                 local psi_type_bits=`expr $2 \* 8`
   9                 echo "PSI_T_${psi_type_upper}${psi_type_bits}, \"${psi_type_lower}${psi_type_bits}_t\""
  10                 eval AS_TR_SH([psi_standard_type_]$1)="${psi_type_lower}${psi_type_bits}_t"
  11                 ;;
  12         struct*)
  13                 echo "PSI_T_STRUCT, \"$2\""
  14                 ;;
  15         void)
  16                 echo "PSI_T_VOID, \"void\""
  17                 ;;
  18         *)
  19                 echo "PSI_T_NAME, \"$psi_type_name\""
  20                 ;;
  21         esac
  22 }
  23
  24 dnl PSI_TYPE(type name, basic type, includes)
  25 AC_DEFUN(PSI_TYPE, [
  26         ifdef(AS_TR_CPP(AC_TYPE_$1), AS_TR_CPP(AC_TYPE_$1))
  27         AC_CHECK_SIZEOF($1, [], PSI_INCLUDES)
  28         psi_basic_type=$2
  29         case $psi_basic_type in
  30         int)
  31                 AX_CHECK_SIGN($1, :, [
  32                         psi_basic_type=uint
  33                 ], $psi_header)
  34                 ;;
  35         sint)
  36                 psi_basic_type=int
  37                 ;;
  38         esac
  39         if test "$2" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0; then
  40                 AS_TR_SH(psi_basic_type_$1)=$psi_basic_type
  41                 PSI_TYPES="{`psi_type_pair $psi_basic_type $AS_TR_SH([ac_cv_sizeof_]$1)`, \"$1\"}, $PSI_TYPES"
  42         fi
  43 ])
  44
  45 dnl unsigned char* buf[16] -> char
  46 AC_DEFUN(PSI_VAR_TYPE, [m4_bregexp([$1], [\(\(struct \)?[^ ]+\)[ *]+[^ ]+$], [\1])])
  47 dnl unsigned char* buf[16] -> buf
  48 AC_DEFUN(PSI_VAR_NAME, [m4_bregexp(m4_bregexp([$1], [\([^ ]+\)$], [\1]), [\w+], [\&])])
  49 dnl PSI_TYPE_SIZE(type, pointer level, array size)
  50 AC_DEFUN(PSI_TYPE_SIZE, [ifelse(
  51         [$3], 0,
  52                 [ifelse([$2], 0, $AS_TR_SH([ac_cv_sizeof_]$1), $ac_cv_sizeof_void_p)],
  53                 [ifelse([$2], 1, [`expr $3 \* $AS_TR_SH([ac_cv_sizeof_]$1)`], $ac_cv_sizeof_void_p)]
  54 )])
  55 dnl PSI_TYPE_BITS(type)
  56 AC_DEFUN(PSI_TYPE_BITS, [`expr 8 \* $AS_TR_SH([ac_cv_sizeof_]$1)`])
  57
  58 AC_DEFUN(PSI_TYPE_PAIR, [m4_case(m4_bregexp([$1], [^\w+], [\&]),
  59         [void], [PSI_T_VOID, \"void\"],
  60         [struct], [PSI_T_STRUCT, \"m4_bregexp([$1], [^struct \(\w+\)], [\1])\"],
  61         [PSI_T_NAME, \"$1\"])])
  62
  63 AC_DEFUN(PSI_CHECK_STD_TYPES, [
  64         AC_CHECK_HEADERS(stdint.h)
  65
  66         AC_TYPE_INT8_T
  67         AC_CHECK_SIZEOF(int8_t)
  68         AC_CHECK_ALIGNOF(int8_t)
  69         AC_TYPE_UINT8_T
  70         AC_CHECK_SIZEOF(uint8_t)
  71         AC_CHECK_ALIGNOF(uint8_t)
  72         AC_TYPE_INT16_T
  73         AC_CHECK_SIZEOF(int16_t)
  74         AC_CHECK_ALIGNOF(int16_t)
  75         AC_TYPE_UINT16_T
  76         AC_CHECK_SIZEOF(uint16_t)
  77         AC_CHECK_ALIGNOF(uint16_t)
  78         AC_TYPE_INT32_T
  79         AC_CHECK_SIZEOF(int32_t)
  80         AC_CHECK_ALIGNOF(int32_t)
  81         AC_TYPE_UINT32_T
  82         AC_CHECK_SIZEOF(uint32_t)
  83         AC_CHECK_ALIGNOF(uint32_t)
  84         AC_TYPE_INT64_T
  85         AC_CHECK_SIZEOF(int64_t)
  86         AC_CHECK_ALIGNOF(int64_t)
  87         AC_TYPE_UINT64_T
  88         AC_CHECK_SIZEOF(uint64_t)
  89         AC_CHECK_ALIGNOF(uint64_t)
  90
  91         PSI_TYPE(float)
  92         AC_CHECK_ALIGNOF(float)
  93         PSI_TYPE(double)
  94         AC_CHECK_ALIGNOF(double)
  95         PSI_TYPE(void *)
  96         AC_CHECK_ALIGNOF(void *)
  97
  98         PSI_TYPE(char, int)
  99         PSI_TYPE(unsigned char, uint)
 100         PSI_TYPE(short, int)
 101         PSI_TYPE(unsigned short, uint)
 102         PSI_TYPE(int, int)
 103         PSI_TYPE(unsigned int, uint)
 104         PSI_TYPE(unsigned, uint)
 105         PSI_TYPE(long, int)
 106         PSI_TYPE(unsigned long, uint)
 107 ])