git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi/psi.m4

   1
   2 dnl PSI_CONFIG_INIT()
   3 dnl Creates stubs of the headers with pre-defined types etc.
   4 dnl These headers are included by src/context.c.
   5 dnl This macro must be called prior any checks for a type, struct, decl etc.
   6 AC_DEFUN(PSI_CONFIG_INIT, [
   7         psi_save_LIBS=$LIBS
   8         LIBS=
   9
  10         ac_includes_default="AC_INCLUDES_DEFAULT"
  11
  12         AC_PROG_AWK
  13         AC_PATH_PROG(NM, nm)
  14         AC_CACHE_CHECK(for libc start main symbol, psi_cv_libc_main, [
  15                 psi_libc_main=
  16                 AC_TRY_LINK(PSI_INCLUDES, [(void)0;], [
  17                         psi_libc_main=`nm -g conftest$ac_exeext | $AWK -F ' *|@' '/^@<:@@<:@:space:@:>@@:>@+U / {print$[]3; exit}'`
  18                 ])
  19                 psi_cv_libc_main=$psi_libc_main
  20         ])
  21
  22         AC_MSG_CHECKING(for preprocessor defaults)
  23         psi_cpp_predef=`$CPP -Wp,-dM $CPPFLAGS -D_GNU_SOURCE -D_FILE_OFFSET_BITS=64 - </dev/null`
  24         psi_cpp_search=`$CPP -Wp,-v $CPPFLAGS -D_GNU_SOURCE -D_FILE_OFFSET_BITS=64 - </dev/null 2>&1 >/dev/null \
  25                 | $AWK '
  26                         /include.*search.*start/ {
  27                                 capture = 1
  28                                 next
  29                         }
  30                         /@<:@Ee@:>@nd.*search/ {
  31                                 capture = 0
  32                         }
  33                         {
  34                                 if (capture)
  35                                         print $1
  36                         }
  37                 ' \
  38         `
  39         psi_cpp_predef_count=`printf %s "$psi_cpp_predef" | wc -l`
  40         psi_cpp_search_count=`printf %s "$psi_cpp_search" | wc -l`
  41         AC_MSG_RESULT([$psi_cpp_predef_count predefined macros, and $psi_cpp_search_count search paths])
  42         PSI_CPP_PREDEF=`printf "%s\n" "$psi_cpp_predef" | \
  43                 $AWK '{
  44                         gsub(/"/, "\\\\\"");
  45                         printf "\"%s\\\n\"\n", $[]0
  46                 }' \
  47         `
  48         PSI_CPP_SEARCH=`printf %s "$psi_cpp_search" | \
  49                 $AWK '{
  50                         if (i) printf ":";
  51                         gsub(/^@<:@@<:@:space:@:>@@:>@+/,"");
  52                         gsub(/@<:@@<:@:space:@:>@@:>@+$/,"");
  53                         printf "%s", $[]0;
  54                         ++i
  55                 }' \
  56         `
  57
  58         if test "$PHP_PSI_MAINTAINER_MODE" = "yes"; then
  59                 PSI_FAST_CONFIG=true
  60                 PSI_DEPS=true
  61                 PSI_EXTRA_REDIRS=true
  62
  63                 PHP_SUBST(PSI_DEPS)
  64
  65                 PSI_CONFIG_TMP=$(mktemp -d)
  66         else
  67                 PSI_FAST_CONFIG=false
  68                 PSI_DEPS=false
  69                 if test "$PHP_DEBUG" = "1"; then
  70                         PSI_EXTRA_REDIRS=true
  71                 else
  72                         PSI_EXTRA_REDIRS=false
  73                 fi
  74         fi
  75
  76         PSI_STDTYPES=
  77         PSI_TYPES=
  78         PSI_COMPOSITES=
  79         PSI_CONSTS=
  80         PSI_REDIRS=
  81         PSI_MACROS=
  82         PSI_DECLS=
  83
  84         AC_CONFIG_FILES(
  85                 [$PHP_PSI_BUILDDIR/php_psi_stdinc.h:$PHP_PSI_SRCDIR/php_psi_stdinc.h.in]
  86                 [$PHP_PSI_BUILDDIR/php_psi_posix.h:$PHP_PSI_SRCDIR/php_psi_posix.h.in]
  87                 [$PHP_PSI_BUILDDIR/php_psi_cpp.h:$PHP_PSI_SRCDIR/php_psi_cpp.h.in]
  88         )
  89
  90 ])
  91
  92 dnl PSI_CONFIG_WAIT()
  93 dnl Internal: waits for sub configures in maintainer mode
  94 AC_DEFUN(PSI_CONFIG_WAIT, [
  95         wait
  96         if test $? -gt 0; then
  97                 cat $PSI_CONFIG_TMP/*/stderr.log >&2
  98                 exit 1
  99         fi
 100 ])
 101
 102 dnl PSI_CONFIG_DONE()
 103 dnl Finish the headers with the pre-defined types etc.
 104 AC_DEFUN(PSI_CONFIG_DONE, [
 105         PSI_CONFIG_WAIT
 106
 107         if $PSI_FAST_CONFIG; then
 108                 for conf_env in $PSI_CONFIG_TMP/*/conf.env; do
 109                         if test "$conf_env" != "$PSI_CONFIG_TMP/*/conf.env"; then
 110                                 source $conf_env
 111                         fi
 112                 done
 113         fi
 114
 115         psi_eval_LIBS=$LIBS
 116         LIBS=$psi_save_LIBS
 117         PHP_EVAL_LIBLINE($psi_eval_LIBS, PSI_SHARED_LIBADD)
 118
 119         [PSI_INCLUDES]="PSI_INCLUDES"
 120         AC_SUBST([PSI_INCLUDES])
 121         AC_SUBST([PSI_STDTYPES])
 122         AC_SUBST([PSI_TYPES])
 123         AC_SUBST([PSI_COMPOSITES])
 124         AC_SUBST([PSI_CONSTS])
 125         AC_SUBST([PSI_REDIRS])
 126         AC_SUBST([PSI_MACROS])
 127         AC_SUBST([PSI_DECLS])
 128         AC_SUBST([PSI_CPP_SEARCH])
 129         AC_SUBST([PSI_CPP_PREDEF])
 130 ])
 131
 132 dnl PSI_SH_CONFIG_POSIX_ENABLED(section)
 133 dnl Expand to $psi_config_posix_<section>
 134 AC_DEFUN(PSI_SH_CONFIG_POSIX_ENABLED, [$AS_TR_SH([psi_config_posix_]$1)])
 135
 136 dnl PSI_CONFIG_POSIX_ENABLED(section, action-if-yes, action-if-not)
 137 dnl Internal. Used to check if --enable-psi-posix=section was given.
 138 AC_DEFUN(PSI_CONFIG_POSIX_ENABLED, [
 139         AS_TR_SH([psi_config_posix_]$1)=false
 140         case "$PHP_PSI_POSIX" in
 141         yes|all)
 142                 AS_TR_SH([psi_config_posix_]$1)=true
 143                 ;;
 144         *)
 145                 if expr "$PHP_PSI_POSIX" : '.*\b$1\b' >/dev/null; then
 146                         AS_TR_SH([psi_config_posix_]$1)=true
 147                 fi
 148                 ;;
 149         esac
 150         if $AS_TR_SH([psi_config_posix_]$1); then
 151                 ifelse([$2],,:,[$2])
 152         else
 153                 ifelse([$3],,:,[$3])
 154         fi
 155 ])
 156
 157 dnl PSI_TEST_POSIX_ENABLED(section, action-if-yes, action-if-not)
 158 dnl Shell-if test if PSI POSIX section was configured.
 159 AC_DEFUN(PSI_SH_TEST_POSIX_ENABLED, [
 160         if test "PSI_SH_CONFIG_POSIX_ENABLED([$1])" && $PSI_SH_CONFIG_POSIX_ENABLED([$1]); then
 161                 ifelse([$2],,:,[$2])
 162         else
 163                 ifelse([$3],,:,[$3])
 164         fi
 165 ])
 166
 167 dnl PSI_CONFIG_POSIX(section, headers, dependents)
 168 AC_DEFUN(PSI_CONFIG_POSIX, [
 169         PSI_CONFIG_POSIX_ENABLED($1, [
 170                 if $PSI_FAST_CONFIG; then
 171                         PSI_CONFIG_POSIX_PARALLEL($1, $2, [$3])
 172                 else
 173                         ifelse([$2],,:,[AC_CHECK_HEADERS($2)])
 174                         AS_TR_CPP([PSI_CHECK_$1])
 175                         $3
 176                 fi
 177         ])
 178 ])
 179
 180 AC_DEFUN([PSI_CONFIG_POSIX_PARALLEL], [
 181         (
 182                 dnl chaway
 183                 mkdir $PSI_CONFIG_TMP/AS_TR_SH([$1])
 184                 cd $PSI_CONFIG_TMP/AS_TR_SH([$1])
 185
 186                 dnl AC_DEFINEs
 187                 ln -s $abs_builddir/confdefs.h confdefs.h
 188
 189                 dnl STDOUT, STDERR
 190                 exec {PSI_MESSAGE_FD}>&AS_MESSAGE_FD {PSI_ERROR_FD}>&2
 191                 exec AS_MESSAGE_FD>stdout.log 2>stderr.log
 192
 193                 dnl check for headers?
 194                 ifelse([$2],,:,[AC_CHECK_HEADERS($2)])
 195
 196                 dnl run checks
 197                 PSI_TYPES=
 198                 PSI_CONSTS=
 199                 PSI_COMPOSITES=
 200                 PSI_REDIRS=
 201                 PSI_MACROS=
 202                 PSI_DECLS=
 203                 AS_TR_CPP([PSI_CHECK_$1])
 204
 205                 dnl save env
 206                 cat >conf.env <<EOF
 207 LIBS="$LIBS \$LIBS"
 208 EOF
 209                 for env in TYPES CONSTS COMPOSITES MACROS REDIRS DECLS; do
 210                         eval var=\$PSI_$env
 211                         if test -n "$var"; then
 212                                 cat >>conf.env <<EOF
 213 PSI_$env='$var'"
 214 \$PSI_$env"
 215 EOF
 216                         fi
 217                 done
 218
 219                 _AC_CACHE_DUMP >>conf.env
 220                 dnl restore STDOUT,STDERR
 221                 exec AS_MESSAGE_FD>&$PSI_MESSAGE_FD 2>&$PSI_ERROR_FD
 222
 223                 dnl done
 224                 AS_ECHO_N(["$1 "])
 225                 cd - >/dev/null
 226
 227                 dnl run dependents
 228                 $3
 229
 230                 PSI_CONFIG_WAIT
 231         ) &
 232 ])
 233
 234 AC_DEFUN(PSI_PTHREAD_ONCE, [
 235         AX_PTHREAD([
 236                 LIBS="$PTHREAD_LIBS $LIBS"
 237                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 238         ])
 239 ])
 240 AC_DEFUN(PSI_PTHREAD, [
 241         AC_REQUIRE([PSI_PTHREAD_ONCE])
 242 ])
 243
 244 dnl PSI_INCLUDES()
 245 dnl Expands to a complete list of include statements including
 246 dnl autoconf's defaults.
 247 AC_DEFUN(PSI_INCLUDES, [
 248 #ifndef _GNU_SOURCE
 249 # define _GNU_SOURCE
 250 #endif
 251 #ifndef _REENTRANT
 252 # define _REENTRANT
 253 #endif
 254 $ac_includes_default
 255 #ifdef HAVE_STDBOOL_H
 256 # include <stdbool.h>
 257 #else
 258 # ifndef HAVE__BOOL
 259 #  ifdef __cplusplus
 260 typedef bool _Bool;
 261 #  else
 262 #   define _Bool signed char
 263 #  endif
 264 # endif
 265 # define bool _Bool
 266 # define false 0
 267 # define true 1
 268 # define __bool_true_false_are_defined 1
 269 #endif
 270 #ifdef HAVE_ERRNO_H
 271 # include <errno.h>
 272 #endif
 273 #ifdef HAVE_GLOB_H
 274 # include <glob.h>
 275 #endif
 276 #ifdef HAVE_LOCALE_H
 277 # include <locale.h>
 278 #endif
 279 #ifdef HAVE_XLOCALE_H
 280 # include <xlocale.h>
 281 #endif
 282 #ifdef HAVE_NETINET_IN_H
 283 # include <netinet/in.h>
 284 #endif
 285 #ifdef HAVE_NETINET_TCP_H
 286 # include <netinet/tcp.h>
 287 #endif
 288 #ifdef HAVE_ARPA_NAMESER_H
 289 # include <arpa/nameser.h>
 290 #endif
 291 #ifdef HAVE_ARPA_INET_H
 292 # include <arpa/inet.h>
 293 #endif
 294 #ifdef HAVE_FCNTL_H
 295 # include <fcntl.h>
 296 #endif
 297 #ifdef HAVE_RELIC_H
 298 # include <relic.h>
 299 #elif HAVE_NDBM_H
 300 # include <ndbm.h>
 301 #elif HAVE_GDBM_NDBM_H
 302 # include <gdbm-ndbm.h>
 303 #endif
 304 #ifdef HAVE_NETDB_H
 305 # include <netdb.h>
 306 #endif
 307 #ifdef HAVE_POLL_H
 308 # include <poll.h>
 309 #endif
 310 #ifdef HAVE_RESOLV_H
 311 # include <resolv.h>
 312 #endif
 313 #ifdef HAVE_SYS_SELECT_H
 314 # include <sys/select.h>
 315 #endif
 316 #ifdef HAVE_SYS_SOCKET_H
 317 # include <sys/socket.h>
 318 #endif
 319 #ifdef HAVE_SYS_TIME_H
 320 # include <sys/time.h>
 321 #endif
 322 #ifdef HAVE_SYS_TIMES_H
 323 # include <sys/times.h>
 324 #endif
 325 #ifdef HAVE_SYS_UIO_H
 326 # include <sys/uio.h>
 327 #endif
 328 #ifdef HAVE_SYS_UTSNAME_H
 329 # include <sys/utsname.h>
 330 #endif
 331 #ifdef HAVE_TIME_H
 332 # include <time.h>
 333 #endif
 334 #ifdef HAVE_SIGNAL_H
 335 # include <signal.h>
 336 #endif
 337 #ifdef HAVE_SYSLOG_H
 338 # include <syslog.h>
 339 #endif
 340 #ifdef HAVE_WCHAR_H
 341 # include <wchar.h>
 342 #endif
 343 #ifdef HAVE_WCTYPE_H
 344 # include <wctype.h>
 345 #endif
 346 ])
 347
 348 dnl PSI_LEMON()
 349 dnl Declare $LEMON precious, and check for a `lemon` in $PATH.
 350 AC_DEFUN(PSI_LEMON, [
 351         AC_ARG_VAR(LEMON, The lemon parser generator of the SQLite project)
 352         if test -z "$LEMON"
 353         then
 354                 AC_PATH_PROG(LEMON, lemon, $PHP_PSI_BUILDDIR/lemon)
 355                 if expr + "$LEMON" : "/" >/dev/null; then
 356                         LEMON_PATH=
 357                 else
 358                         LEMON_PATH=$abs_builddir/
 359                 fi
 360         fi
 361         PHP_SUBST(LEMON_PATH)
 362         PHP_SUBST(LEMON)
 363 ])
 364
 365 dnl PSI_PKG_CONFIG()
 366 dnl Check for `pkg-config` and add possible libjit and libffi directories to
 367 dnl $PKG_CONFIG_PATH, because those libs often ship with headers etc. in
 368 dnl arch-dependent locations.
 369 AC_DEFUN([PSI_PKG_CONFIG], [
 370         if test -z "$PKG_CONFIG"
 371         then
 372                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
 373         fi
 374         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
 375 ])
 376
 377 dnl PSI_SH_SIZEOF(type)
 378 dnl expand to shell variable $ac_cv_sizeof_<TYPE>
 379 AC_DEFUN([PSI_SH_SIZEOF], [$AS_TR_SH([ac_cv_sizeof_]$1)])
 380
 381 dnl PSI_SH_OFFSETOF(type)
 382 dnl Expand to shell variable $ac_cv_offsetof_<TYPE>
 383 AC_DEFUN([PSI_SH_OFFSETOF], [$AS_TR_SH([ac_cv_offsetof_]$1)])
 384
 385 dnl PSI_SH_ALIGNOF(type)
 386 dnl Expand to shell variable $ac_cv_offsetof_<TYPE>
 387 AC_DEFUN([PSI_SH_ALIGNOF], [$AS_TR_SH([ac_cv_alignof_]$1)])
 388
 389 dnl PSI_SH_TEST_SIZEOF(type)
 390 dnl `if` condition to test if $ac_cv_sizeof_$1 is greater than 0.
 391 AC_DEFUN([PSI_SH_TEST_SIZEOF], [test -n "$AS_TR_SH([ac_cv_sizeof_]$1)" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0])
 392
 393 dnl PSI_SH_TEST_ALIGNOF(type)
 394 dnl `if` condition to test if $ac_cv_alignof_$1 is greater than 0.
 395 AC_DEFUN([PSI_SH_TEST_ALIGNOF], [test -n "$AS_TR_SH([ac_cv_alignof_]$1)" && test "$AS_TR_SH([ac_cv_alignof_]$1)" -gt 0])
 396
 397 dnl PSI_CHECK_SIZEOF(type, special-includes)
 398 dnl AC_CHECK_SIZEOF wrapper with PSI_INCLUDES
 399 dnl Defines psi\\SIZEOF_<TYPE> pre-defined constant in $PSI_CONSTS_H.
 400 AC_DEFUN(PSI_CHECK_SIZEOF, [
 401         AC_CHECK_SIZEOF($1, [], PSI_INCLUDES
 402                 $2)
 403         if PSI_SH_TEST_SIZEOF($1); then
 404                 psi_add_int_const "AS_TR_CPP([SIZEOF_]$1)" "$AS_TR_SH([ac_cv_sizeof_]$1)"
 405         fi
 406 ])
 407
 408 dnl PSI_CHECK_ALIGNOF(type, special-includes)
 409 dnl AC_CHECK_ALIGNOF wrapper with PSI_INCLUDES
 410 dnl Defines psi\\ALIGNOF_<TYPE> pre-defined constant in $PSI_CONSTS_H.
 411 AC_DEFUN(PSI_CHECK_ALIGNOF, [
 412         AC_CHECK_ALIGNOF($1, PSI_INCLUDES
 413                 $2)
 414         if PSI_SH_TEST_ALIGNOF($1); then
 415                 psi_add_int_const "AS_TR_CPP([ALIGNOF_]$1)" "$AS_TR_SH([ac_cv_alignof_]$1)"
 416         fi
 417 ])
 418
 419 dnl PSI_CHECK_OFFSETOF(struct, element)
 420 dnl Check the offset of a struct element, implemented in the similar manner
 421 dnl like AC_CHECK_SIZEOF.
 422 dnl AC_DEFINEs OFFSETOF_<STRUCT>_<ELEMENT>.
 423 AC_DEFUN(PSI_CHECK_OFFSETOF, [
 424         _AC_CACHE_CHECK_INT(
 425                 [offset of $2 in $1],
 426                 [AS_TR_SH([ac_cv_offsetof_$1_$2])],
 427                 [(long int) (offsetof ($1, $2))],
 428                 PSI_INCLUDES,
 429                 [AC_MSG_FAILURE([cannot compute offsetof ($1, $2)])]
 430         )
 431         AC_DEFINE_UNQUOTED(
 432                 AS_TR_CPP(offsetof_$1_$2),
 433                 $AS_TR_SH([ac_cv_offsetof_$1_$2]),
 434                 [The offset of `$2' in `$1', as computed by offsetof.]
 435         )
 436 ])
 437
 438
 439 dnl PSI_COMPUTE_STR(variable, string or expression)
 440 dnl Compute a string constant value in a similar manner like AC_COMPUTE_INT.
 441 AC_DEFUN(PSI_COMPUTE_STR, [
 442         AC_TRY_RUN(
 443                 PSI_INCLUDES
 444                 [int main() {
 445                         return EOF == fputs($2, fopen("conftest.out", "w"));
 446                 }
 447         ], [
 448                 eval $1=\\\"`cat conftest.out`\\\"
 449         ])
 450 ])
 451
 452 dnl PSI_CHECK_LIBJIT()
 453 dnl Check for libjit in $PHP_PSI_LIBJIT or standard locations
 454 dnl AC_DEFINEs HAVE_LIBJIT.
 455 AC_DEFUN(PSI_CHECK_LIBJIT, [
 456         AC_CACHE_CHECK(for libjit, psi_cv_libjit_dir, [
 457                 for psi_cv_libjit_dir in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
 458                 do
 459                         if test -e $psi_cv_libjit_dir/include/jit/jit.h
 460                         then
 461                                 break
 462                         fi
 463                         psi_cv_libjit_dir=
 464                 done
 465         ])
 466         if test -n "$psi_cv_libjit_dir"
 467         then
 468                 PHP_ADD_INCLUDE($psi_cv_libjit_dir/include)
 469                 PHP_ADD_LIBRARY_WITH_PATH(jit, $psi_cv_libjit_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 470                 AC_DEFINE(HAVE_LIBJIT, 1, Have libjit)
 471         else
 472                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
 473         fi
 474 ])
 475
 476 dnl PSI_CHECK_LIBFFI()
 477 dnl Check for libffi with `pkg-config`. If that fails, `configure` looks into
 478 dnl $PHP_PSI_LIBFFI or standard locations to find libjit deps.
 479 dnl Checks for availability of recent closure API:
 480 dnl \ffi_closure_alloc and \ffi_prep_closure.
 481 dnl Checks for availability of recent vararg API:
 482 dnl \ffi_prep_cif_var.
 483 dnl AC_DEFINEs HAVE_LIBFFI, PSI_HAVE_FFI_CLOSURE_ALLOC,
 484 dnl PSI_HAVE_FFI_PREP_CLOSURE and PSI_HAVE_FFO_PREP_VIF_VAR.
 485 AC_DEFUN(PSI_CHECK_LIBFFI, [
 486         AC_REQUIRE([PSI_PKG_CONFIG])dnl
 487
 488         AC_CACHE_CHECK(for libffi through pkg-config, psi_cv_libffi, [
 489         if $PKG_CONFIG --exists libffi
 490         then
 491                 psi_cv_libffi=true
 492         else
 493                 psi_cv_libffi=false
 494         fi])
 495
 496         if $psi_cv_libffi
 497         then
 498                 AC_MSG_CHECKING(for libffi)
 499                 psi_cv_libffi_dir=`$PKG_CONFIG --variable=prefix libffi`
 500                 AC_MSG_RESULT($psi_cv_libffi_dir)
 501                 PHP_EVAL_INCLINE(`$PKG_CONFIG --cflags libffi`)
 502                 PHP_EVAL_LIBLINE(`$PKG_CONFIG --libs libffi`, PSI_SHARED_LIBADD)
 503                 AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 504                 AC_DEFINE_UNQUOTED([PHP_PSI_LIBFFI_VERSION], ["`$PKG_CONFIG --modversion libffi`"], [libffi version])
 505         else
 506                 AC_CACHE_CHECK(for libffi, psi_cv_libffi_dir, [
 507                 for psi_cv_libffi_dir in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
 508                 do
 509                         if test -e $psi_cv_libffi_dir/include/ffi/ffi.h
 510                         then
 511                                 break
 512                         fi
 513                         psi_cv_libffi_dir=
 514                 done])
 515                 if test -n "$psi_cv_libffi_dir"
 516                 then
 517                         PHP_ADD_INCLUDE($psi_cv_libffi_dir/include/ffi)
 518                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $psi_cv_libffi_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 519                         AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 520                 else
 521                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
 522                 fi
 523         fi
 524
 525         save_CFLAGS=$CFLAGS
 526         CFLAGS="$CFLAGS $INCLUDES"
 527         AC_CHECK_DECL(FFI_STDCALL,[AC_DEFINE([HAVE_FFI_STDCALL],[1],[ ])],,[#include "ffi.h"])
 528         AC_CHECK_DECL(FFI_FASTCALL,[AC_DEFINE([HAVE_FFI_FASTCALL],[1],[ ])],,[#include "ffi.h"])
 529         CFLAGS=$save_CFLAGS
 530
 531         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
 532                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
 533                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
 534                 ], [], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 535                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
 536         ], [
 537                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
 538                         AC_CHECK_HEADERS(sys/mman.h)
 539                         PHP_CHECK_FUNC(mmap)
 540                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
 541                 ], [
 542                 ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 543         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 544         PHP_CHECK_LIBRARY(ffi, ffi_prep_cif_var, [
 545                 AC_DEFINE(PSI_HAVE_FFI_PREP_CIF_VAR, 1, [ ])
 546         ], [
 547         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 548 ])