git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi/psi.m4

   1 dnl Generated headers with pre-defined types, structs, consts and decls.
   2 PSI_STDINC=$PHP_PSI_SRCDIR/php_psi_stdinc.h
   3 PSI_STDTYPES=$PHP_PSI_SRCDIR/php_psi_stdtypes.h
   4 PSI_TYPES=$PHP_PSI_SRCDIR/php_psi_types.h
   5 PSI_STRUCTS=$PHP_PSI_SRCDIR/php_psi_structs.h
   6 PSI_UNIONS=$PHP_PSI_SRCDIR/php_psi_unions.h
   7 PSI_CONSTS=$PHP_PSI_SRCDIR/php_psi_consts.h
   8 PSI_REDIRS=$PHP_PSI_SRCDIR/php_psi_redirs.h
   9 PSI_MACROS=$PHP_PSI_SRCDIR/php_psi_macros.h
  10 PSI_DECLS=$PHP_PSI_SRCDIR/php_psi_decls.h
  11 PSI_VA_DECLS=$PHP_PSI_SRCDIR/php_psi_va_decls.h
  12 PSI_FN_DECLS=$PHP_PSI_SRCDIR/php_psi_fn_decls.h
  13
  14 dnl PSI_CONFIG_INIT()
  15 dnl Creates stubs of the headers with pre-defined types etc.
  16 dnl These headers are included by src/context.c.
  17 dnl This macro must be called prior any checks for a type, struct, decl etc.
  18 AC_DEFUN(PSI_CONFIG_INIT, [
  19         psi_save_LIBS=$LIBS
  20         LIBS=
  21
  22         if test "$PHP_PSI_MAINTAINER_MODE" = "yes"; then
  23                 PSI_FAST_CONFIG=true
  24                 PSI_DEPS=true
  25                 PSI_EXTRA_REDIRS=true
  26
  27                 PHP_SUBST(PSI_DEPS)
  28
  29                 PSI_CONFIG_TMP=$(mktemp -d)
  30         else
  31                 PSI_FAST_CONFIG=false
  32                 PSI_DEPS=false
  33                 if test "$PHP_DEBUG" = "1"; then
  34                         PSI_EXTRA_REDIRS=true
  35                 else
  36                         PSI_EXTRA_REDIRS=false
  37                 fi
  38         fi
  39
  40         cat >$PHP_PSI_BUILDDIR/php_psi.dep <<EOF
  41 \$(PHP_PSI_SRCDIR)/php_psi.h:
  42 php_psi.h:
  43 \$(PHP_PSI_SRCDIR)/php_psi_stdinc.h:
  44 php_psi_stdinc.h:
  45 EOF
  46         for i in $PSI_STDTYPES $PSI_TYPES $PSI_STRUCTS $PSI_UNIONS $PSI_CONSTS $PSI_REDIRS $PSI_MACROS $PSI_DECLS $PSI_VA_DECLS $PSI_FN_DECLS; do
  47                 cat >>$PHP_PSI_BUILDDIR/php_psi.dep <<EOF
  48 $i:
  49 $(basename $i):
  50 EOF
  51                 cat >$i <<EOF
  52 /* generated by configure */
  53 #include "php_psi_stdinc.h"
  54 EOF
  55         done
  56         cat >>$PSI_STDTYPES <<EOF
  57 static struct psi_std_type {
  58         token_t type_tag;
  59         const char *type_name;
  60         const char *alias;
  61 } psi_std_types@<:@@:>@ = {
  62         {PSI_T_INT8, "int8_t", NULL},
  63         {PSI_T_INT16, "int16_t", NULL},
  64         {PSI_T_INT32, "int32_t", NULL},
  65         {PSI_T_INT64, "int64_t", NULL},
  66         {PSI_T_UINT8, "uint8_t", NULL},
  67         {PSI_T_UINT16, "uint16_t", NULL},
  68         {PSI_T_UINT32, "uint32_t", NULL},
  69         {PSI_T_UINT64, "uint64_t", NULL},
  70 EOF
  71         cat >>$PSI_TYPES <<EOF
  72 static struct psi_predef_type {
  73         token_t type_tag;
  74         const char *type_name;
  75         const char *alias;
  76 } psi_predef_types@<:@@:>@ = {
  77 EOF
  78         cat >>$PSI_STRUCTS <<EOF
  79 static struct psi_predef_struct {
  80         token_t type_tag;
  81         const char *type_name;
  82         const char *var_name;
  83         size_t offset;
  84         size_t size;
  85         size_t pointer_level;
  86         size_t array_size;
  87 } psi_predef_structs@<:@@:>@ = {
  88 EOF
  89         cat >>$PSI_UNIONS <<EOF
  90 static struct psi_predef_union {
  91         token_t type_tag;
  92         const char *type_name;
  93         const char *var_name;
  94         size_t offset;
  95         size_t size;
  96         size_t pointer_level;
  97         size_t array_size;
  98 } psi_predef_unions@<:@@:>@ = {
  99 EOF
 100         cat >>$PSI_CONSTS <<EOF
 101 static struct psi_predef_const {
 102         token_t type_tag;
 103         const char *type_name;
 104         const char *var_name;
 105         const char *val_text;
 106         token_t val_type_tag;
 107 } psi_predef_consts@<:@@:>@ = {
 108 EOF
 109         cat >>$PSI_REDIRS <<EOF
 110 typedef void (*psi_func_ptr)();
 111 static struct psi_func_redir {
 112         const char *name;
 113         psi_func_ptr func;
 114 } psi_func_redirs@<:@@:>@ = {
 115 EOF
 116         cat >>$PSI_MACROS <<EOF
 117 EOF
 118         cat >>$PSI_DECLS <<EOF
 119 static struct psi_predef_decl {
 120         token_t type_tag;
 121         const char *type_name;
 122         const char *var_name;
 123         size_t pointer_level;
 124         size_t array_size;
 125 } psi_predef_decls@<:@@:>@ = {
 126 EOF
 127         cat >>$PSI_VA_DECLS <<EOF
 128 static struct psi_predef_decl psi_predef_vararg_decls@<:@@:>@ = {
 129 EOF
 130         cat >>$PSI_FN_DECLS <<EOF
 131 static struct psi_predef_decl psi_predef_functor_decls@<:@@:>@ = {
 132 EOF
 133 ])
 134
 135 dnl PSI_CONFIG_DONE()
 136 dnl Finish the headers with the pre-defined types etc.
 137 AC_DEFUN(PSI_CONFIG_DONE, [
 138
 139         wait
 140
 141         if $PSI_FAST_CONFIG; then
 142                 for conf_env in $PSI_CONFIG_TMP/*/conf.env; do
 143                         source $conf_env
 144                 done
 145         fi
 146
 147         psi_eval_LIBS=$LIBS
 148         LIBS=$psi_save_LIBS
 149         PHP_EVAL_LIBLINE($psi_eval_LIBS, PSI_SHARED_LIBADD)
 150
 151         cat >$PSI_STDINC <<EOF
 152 /* generated by configure */
 153 #ifndef PSI_STDINC_H
 154 #define PSI_STDINC_H
 155
 156 #ifdef HAVE_CONFIG_H
 157 # include "config.h"
 158 #else
 159 # include "php_config.h"
 160 #endif
 161
 162 #ifndef _GNU_SOURCE
 163 # define _GNU_SOURCE
 164 #endif
 165 #ifndef _REENTRANT
 166 # define _REENTRANT
 167 #endif
 168
 169 PSI_INCLUDES
 170 #endif
 171 EOF
 172         for i in $PSI_STDTYPES $PSI_TYPES $PSI_STRUCTS $PSI_UNIONS $PSI_CONSTS $PSI_REDIRS $PSI_DECLS $PSI_VA_DECLS $PSI_FN_DECLS; do
 173                 cat >>$i <<EOF
 174         {0}
 175 };
 176 EOF
 177         done
 178 ])
 179
 180 dnl PSI_SH_CONFIG_POSIX_ENABLED(section)
 181 dnl Expand to $psi_config_posix_<section>
 182 AC_DEFUN(PSI_SH_CONFIG_POSIX_ENABLED, [$AS_TR_SH([psi_config_posix_]$1)])
 183
 184 dnl PSI_CONFIG_POSIX_ENABLED(section, action-if-yes, action-if-not)
 185 dnl Internal. Used to check if --enable-psi-posix=section was given.
 186 AC_DEFUN(PSI_CONFIG_POSIX_ENABLED, [
 187         AS_TR_SH([psi_config_posix_]$1)=false
 188         case "$PHP_PSI_POSIX" in
 189         yes|all)
 190                 AS_TR_SH([psi_config_posix_]$1)=true
 191                 ;;
 192         *)
 193                 if expr "$PHP_PSI_POSIX" : '\b$1\b' >/dev/null; then
 194                         AS_TR_SH([psi_config_posix_]$1)=true
 195                 fi
 196                 ;;
 197         esac
 198         if $AS_TR_SH([psi_config_posix_]$1); then
 199                 ifelse([$2],,:,[$2])
 200         else
 201                 ifelse([$3],,:,[$3])
 202         fi
 203 ])
 204
 205 dnl PSI_TEST_POSIX_ENABLED(section, action-if-yes, action-if-not)
 206 dnl Shell-if test if PSI POSIX section was configured.
 207 AC_DEFUN(PSI_SH_TEST_POSIX_ENABLED, [
 208         if test "PSI_SH_CONFIG_POSIX_ENABLED([$1])" && $PSI_SH_CONFIG_POSIX_ENABLED([$1]); then
 209                 ifelse([$2],,:,[$2])
 210         else
 211                 ifelse([$3],,:,[$3])
 212         fi
 213 ])
 214
 215 dnl PSI_CONFIG_POSIX(section, headers)
 216 AC_DEFUN(PSI_CONFIG_POSIX, [
 217         PSI_CONFIG_POSIX_ENABLED($1, [
 218                 if $PSI_FAST_CONFIG; then
 219                         PSI_CONFIG_POSIX_PARALLEL($1, $2)
 220                 else
 221                         ifelse([$2],,:,[AC_CHECK_HEADERS($2)])
 222                         AS_TR_CPP([PSI_CHECK_$1])
 223                 fi
 224         ])
 225 ])
 226
 227 AC_DEFUN([PSI_CONFIG_POSIX_PARALLEL], [
 228         (
 229                 dnl setup
 230                 mkdir $PSI_CONFIG_TMP/AS_TR_SH([$1])
 231                 ln -s $(pwd)/confdefs.h $PSI_CONFIG_TMP/AS_TR_SH([$1])/confdefs.h
 232
 233                 dnl restore stdio
 234                 exec 66>&AS_MESSAGE_FD
 235                 exec AS_MESSAGE_FD>$PSI_CONFIG_TMP/AS_TR_SH([$1])/stdout.log
 236                 exec 2>$PSI_CONFIG_TMP/AS_TR_SH([$1])/stderr.log
 237
 238                 dnl check for headers?
 239                 ifelse([$2],,:,[AC_CHECK_HEADERS($2)])
 240
 241                 dnl chaway
 242                 cd $PSI_CONFIG_TMP/AS_TR_SH([$1])
 243
 244                 dnl run checks
 245                 AS_TR_CPP([PSI_CHECK_$1])
 246
 247                 dnl save libs
 248                 cat >$PSI_CONFIG_TMP/AS_TR_SH([$1])/conf.env <<EOF
 249 LIBS="$LIBS \$LIBS"
 250 EOF
 251                 dnl done
 252                 printf "%s " "$1" >&66
 253         ) &
 254 ])
 255
 256 AC_DEFUN(PSI_PTHREAD_ONCE, [
 257         AX_PTHREAD([
 258                 LIBS="$PTHREAD_LIBS $LIBS"
 259                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 260         ])
 261 ])
 262 AC_DEFUN(PSI_PTHREAD, [
 263         AC_REQUIRE([PSI_PTHREAD_ONCE])
 264 ])
 265
 266 dnl PSI_INCLUDES()
 267 dnl Expands to a complete list of include statements including
 268 dnl AC_INCLUDES_DEFAULT().
 269 AC_DEFUN(PSI_INCLUDES, [dnl
 270 #define PSI_INCLUDES
 271 #ifndef _GNU_SOURCE
 272 # define _GNU_SOURCE
 273 #endif
 274 #ifndef _REENTRANT
 275 # define _REENTRANT
 276 #endif
 277 AC_INCLUDES_DEFAULT()
 278 #ifdef HAVE_STDBOOL_H
 279 # include <stdbool.h>
 280 #else
 281 # ifndef HAVE__BOOL
 282 #  ifdef __cplusplus
 283 typedef bool _Bool;
 284 #  else
 285 #   define _Bool signed char
 286 #  endif
 287 # endif
 288 # define bool _Bool
 289 # define false 0
 290 # define true 1
 291 # define __bool_true_false_are_defined 1
 292 #endif
 293 #ifdef HAVE_ERRNO_H
 294 # include <errno.h>
 295 #endif
 296 #ifdef HAVE_GLOB_H
 297 # include <glob.h>
 298 #endif
 299 #ifdef HAVE_LOCALE_H
 300 # include <locale.h>
 301 #endif
 302 #ifdef HAVE_XLOCALE_H
 303 # include <xlocale.h>
 304 #endif
 305 #ifdef HAVE_NETINET_IN_H
 306 # include <netinet/in.h>
 307 #endif
 308 #ifdef HAVE_NETINET_TCP_H
 309 # include <netinet/tcp.h>
 310 #endif
 311 #ifdef HAVE_ARPA_NAMESER_H
 312 # include <arpa/nameser.h>
 313 #endif
 314 #ifdef HAVE_FCNTL_H
 315 # include <fcntl.h>
 316 #endif
 317 #ifdef HAVE_RELIC_H
 318 # include <relic.h>
 319 #elif HAVE_NDBM_H
 320 # include <ndbm.h>
 321 #elif HAVE_GDBM_NDBM_H
 322 # include <gdbm-ndbm.h>
 323 #endif
 324 #ifdef HAVE_NETDB_H
 325 # include <netdb.h>
 326 #endif
 327 #ifdef HAVE_POLL_H
 328 # include <poll.h>
 329 #endif
 330 #ifdef HAVE_RESOLV_H
 331 # include <resolv.h>
 332 #endif
 333 #ifdef HAVE_SYS_SELECT_H
 334 # include <sys/select.h>
 335 #endif
 336 #ifdef HAVE_SYS_SOCKET_H
 337 # include <sys/socket.h>
 338 #endif
 339 #ifdef HAVE_SYS_TIME_H
 340 # include <sys/time.h>
 341 #endif
 342 #ifdef HAVE_SYS_TIMES_H
 343 # include <sys/times.h>
 344 #endif
 345 #ifdef HAVE_SYS_UIO_H
 346 # include <sys/uio.h>
 347 #endif
 348 #ifdef HAVE_SYS_UTSNAME_H
 349 # include <sys/utsname.h>
 350 #endif
 351 #ifdef HAVE_TIME_H
 352 # include <time.h>
 353 #endif
 354 #ifdef HAVE_SIGNAL_H
 355 # include <signal.h>
 356 #endif
 357 #ifdef HAVE_SYSLOG_H
 358 # include <syslog.h>
 359 #endif
 360 #ifdef HAVE_WCHAR_H
 361 # include <wchar.h>
 362 #endif
 363 #ifdef HAVE_WCTYPE_H
 364 # include <wctype.h>
 365 #endif
 366 ])
 367
 368 dnl PSI_LEMON()
 369 dnl Declare $LEMON precious, and check for a `lemon` in $PATH.
 370 AC_DEFUN(PSI_LEMON, [
 371         AC_ARG_VAR(LEMON, The lemon parser generator of the SQLite project)
 372         if test -z "$LEMON"
 373         then
 374                 AC_PATH_PROG(LEMON, lemon, ./lemon)
 375         fi
 376         PHP_SUBST(LEMON)
 377 ])
 378
 379 dnl PSI_PKG_CONFIG()
 380 dnl Check for `pkg-config` and add possible libjit and libffi directories to
 381 dnl $PKG_CONFIG_PATH, because those libs often ship with headers etc. in
 382 dnl arch-dependent locations.
 383 AC_DEFUN([PSI_PKG_CONFIG], [
 384         if test -z "$PKG_CONFIG"
 385         then
 386                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
 387         fi
 388         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
 389 ])
 390
 391 dnl PSI_SH_SIZEOF(type)
 392 dnl expand to shell variable $ac_cv_sizeof_<TYPE>
 393 AC_DEFUN([PSI_SH_SIZEOF], [$AS_TR_SH([ac_cv_sizeof_]$1)])
 394
 395 dnl PSI_SH_OFFSETOF(type)
 396 dnl Expand to shell variable $ac_cv_offsetof_<TYPE>
 397 AC_DEFUN([PSI_SH_OFFSETOF], [$AS_TR_SH([ac_cv_offsetof_]$1)])
 398
 399 dnl PSI_SH_ALIGNOF(type)
 400 dnl Expand to shell variable $ac_cv_offsetof_<TYPE>
 401 AC_DEFUN([PSI_SH_ALIGNOF], [$AS_TR_SH([ac_cv_alignof_]$1)])
 402
 403 dnl PSI_SH_TEST_SIZEOF(type)
 404 dnl `if` condition to test if $ac_cv_sizeof_$1 is greater than 0.
 405 AC_DEFUN([PSI_SH_TEST_SIZEOF], [test -n "$AS_TR_SH([ac_cv_sizeof_]$1)" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0])
 406
 407 dnl PSI_SH_TEST_ALIGNOF(type)
 408 dnl `if` condition to test if $ac_cv_alignof_$1 is greater than 0.
 409 AC_DEFUN([PSI_SH_TEST_ALIGNOF], [test -n "$AS_TR_SH([ac_cv_alignof_]$1)" && test "$AS_TR_SH([ac_cv_alignof_]$1)" -gt 0])
 410
 411 dnl PSI_CHECK_SIZEOF(type, special-includes)
 412 dnl AC_CHECK_SIZEOF wrapper with PSI_INCLUDES
 413 dnl Defines psi\\SIZEOF_<TYPE> pre-defined constant in $PSI_CONSTS.
 414 AC_DEFUN(PSI_CHECK_SIZEOF, [
 415         AC_CHECK_SIZEOF($1, [], PSI_INCLUDES
 416                 $2)
 417         if PSI_SH_TEST_SIZEOF($1); then
 418                 psi_add_int_const "AS_TR_CPP([SIZEOF_]$1)" "$AS_TR_SH([ac_cv_sizeof_]$1)"
 419         fi
 420 ])
 421
 422 dnl PSI_CHECK_ALIGNOF(type, special-includes)
 423 dnl AC_CHECK_ALIGNOF wrapper with PSI_INCLUDES
 424 dnl Defines psi\\ALIGNOF_<TYPE> pre-defined constant in $PSI_CONSTS.
 425 AC_DEFUN(PSI_CHECK_ALIGNOF, [
 426         AC_CHECK_ALIGNOF($1, PSI_INCLUDES
 427                 $2)
 428         if PSI_SH_TEST_ALIGNOF($1); then
 429                 psi_add_int_const "AS_TR_CPP([ALIGNOF_]$1)" "$AS_TR_SH([ac_cv_alignof_]$1)"
 430         fi
 431 ])
 432
 433 dnl PSI_CHECK_OFFSETOF(struct, element)
 434 dnl Check the offset of a struct element, implemented in the similar manner
 435 dnl like AC_CHECK_SIZEOF.
 436 dnl AC_DEFINEs OFFSETOF_<STRUCT>_<ELEMENT>.
 437 AC_DEFUN(PSI_CHECK_OFFSETOF, [
 438         _AC_CACHE_CHECK_INT(
 439                 [offset of $2 in $1],
 440                 [AS_TR_SH([ac_cv_offsetof_$1_$2])],
 441                 [(long int) (offsetof ($1, $2))],
 442                 [PSI_INCLUDES],
 443                 [AC_MSG_FAILURE([cannot compute offsetof ($1, $2)])]
 444         )
 445         AC_DEFINE_UNQUOTED(
 446                 AS_TR_CPP(offsetof_$1_$2),
 447                 $AS_TR_SH([ac_cv_offsetof_$1_$2]),
 448                 [The offset of `$2' in `$1', as computed by offsetof.]
 449         )
 450 ])
 451
 452
 453 dnl PSI_COMPUTE_STR(variable, string or expression)
 454 dnl Compute a string constant value in a similar manner like AC_COMPUTE_INT.
 455 AC_DEFUN(PSI_COMPUTE_STR, [
 456         AC_TRY_RUN(
 457                 PSI_INCLUDES
 458                 [int main() {
 459                         return EOF == fputs($2, fopen("conftest.out", "w"));
 460                 }
 461         ], [
 462                 eval $1=\\\"`cat conftest.out`\\\"
 463         ])
 464 ])
 465
 466 dnl PSI_CHECK_LIBJIT()
 467 dnl Check for libjit in $PHP_PSI_LIBJIT or standard locations
 468 dnl AC_DEFINEs HAVE_LIBJIT.
 469 AC_DEFUN(PSI_CHECK_LIBJIT, [
 470         AC_CACHE_CHECK(for libjit, psi_cv_libjit_dir, [
 471                 for psi_cv_libjit_dir in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
 472                 do
 473                         if test -e $psi_cv_libjit_dir/include/jit/jit.h
 474                         then
 475                                 break
 476                         fi
 477                         psi_cv_libjit_dir=
 478                 done
 479         ])
 480         if test -n "$psi_cv_libjit_dir"
 481         then
 482                 PHP_ADD_INCLUDE($psi_cv_libjit_dir/include)
 483                 PHP_ADD_LIBRARY_WITH_PATH(jit, $psi_cv_libjit_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 484                 AC_DEFINE(HAVE_LIBJIT, 1, Have libjit)
 485         else
 486                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
 487         fi
 488 ])
 489
 490 dnl PSI_CHECK_LIBFFI()
 491 dnl Check for libffi with `pkg-config`. If that fails, `configure` looks into
 492 dnl $PHP_PSI_LIBFFI or standard locations to find libjit deps.
 493 dnl Checks for availability of recent closure API:
 494 dnl \ffi_closure_alloc and \ffi_prep_closure.
 495 dnl Checks for availability of recent vararg API:
 496 dnl \ffi_prep_cif_var.
 497 dnl AC_DEFINEs HAVE_LIBFFI, PSI_HAVE_FFI_CLOSURE_ALLOC,
 498 dnl PSI_HAVE_FFI_PREP_CLOSURE and PSI_HAVE_FFO_PREP_VIF_VAR.
 499 AC_DEFUN(PSI_CHECK_LIBFFI, [
 500         AC_REQUIRE([PSI_PKG_CONFIG])dnl
 501
 502         AC_CACHE_CHECK(for libffi through pkg-config, psi_cv_libffi, [
 503         if $PKG_CONFIG --exists libffi
 504         then
 505                 psi_cv_libffi=true
 506         else
 507                 psi_cv_libffi=false
 508         fi])
 509
 510         if $psi_cv_libffi
 511         then
 512                 AC_MSG_CHECKING(for libffi)
 513                 psi_cv_libffi_dir=`$PKG_CONFIG --variable=prefix libffi`
 514                 AC_MSG_RESULT($psi_cv_libffi_dir)
 515                 PHP_EVAL_INCLINE(`$PKG_CONFIG --cflags libffi`)
 516                 PHP_EVAL_LIBLINE(`$PKG_CONFIG --libs libffi`, PSI_SHARED_LIBADD)
 517                 AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 518                 AC_DEFINE_UNQUOTED([PHP_PSI_LIBFFI_VERSION], ["`$PKG_CONFIG --modversion libffi`"], [libffi version])
 519         else
 520                 AC_CACHE_CHECK(for libffi, psi_cv_libffi_dir, [
 521                 for psi_cv_libffi_dir in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
 522                 do
 523                         if test -e $psi_cv_libffi_dir/include/ffi/ffi.h
 524                         then
 525                                 break
 526                         fi
 527                         psi_cv_libffi_dir=
 528                 done])
 529                 if test -n "$psi_cv_libffi_dir"
 530                 then
 531                         PHP_ADD_INCLUDE($psi_cv_libffi_dir/include/ffi)
 532                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $psi_cv_libffi_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 533                         AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 534                 else
 535                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
 536                 fi
 537         fi
 538         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
 539                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
 540                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
 541                 ], [], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 542                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
 543         ], [
 544                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
 545                         AC_CHECK_HEADERS(sys/mman.h)
 546                         PHP_CHECK_FUNC(mmap)
 547                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
 548                 ], [
 549                 ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 550         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 551         PHP_CHECK_LIBRARY(ffi, ffi_prep_cif_var, [
 552                 AC_DEFINE(PSI_HAVE_FFI_PREP_CIF_VAR, 1, [ ])
 553         ], [
 554         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 555 ])