git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi/psi.m4

   1 dnl PSI_CONFIG_INIT()
   2 dnl Creates stubs of the headers with pre-defined types etc.
   3 AC_DEFUN(PSI_CONFIG_INIT, [
   4         psi_save_LIBS=$LIBS
   5         LIBS=
   6
   7         AC_MSG_CHECKING([psi source dir])
   8         PHP_PSI_SRCDIR=PHP_EXT_SRCDIR(psi)
   9         AC_MSG_RESULT([$PHP_PSI_SRCDIR])
  10
  11         AC_MSG_CHECKING([psi build dir])
  12         case "PHP_EXT_BUILDDIR(psi)" in
  13         ""|.) PHP_PSI_BUILDDIR=$PHP_PSI_SRCDIR
  14                 ;;
  15         *)    PHP_PSI_BUILDDIR=PHP_EXT_BUILDDIR(psi)
  16                 ;;
  17         esac
  18         AC_MSG_RESULT([$PHP_PSI_BUILDDIR])
  19
  20         PSI_STDTYPES=
  21         PSI_CONSTS=
  22
  23         AC_CONFIG_FILES([$PHP_PSI_BUILDDIR/php_psi_predef.h:$PHP_PSI_SRCDIR/php_psi_predef.h.in])
  24
  25 ])
  26
  27 dnl PSI_CONFIG_DONE()
  28 dnl Finish the headers with the pre-defined types etc.
  29 AC_DEFUN(PSI_CONFIG_DONE, [
  30         psi_eval_LIBS=$LIBS
  31         LIBS=$psi_save_LIBS
  32         PHP_EVAL_LIBLINE($psi_eval_LIBS, PSI_SHARED_LIBADD)
  33
  34         AC_SUBST([PSI_STDTYPES])
  35         AC_SUBST([PSI_CPP_SEARCH])
  36         AC_SUBST([PSI_CPP_PREDEF])
  37
  38         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR)
  39         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src)
  40         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src/calc)
  41         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src/types)
  42         PHP_ADD_INCLUDE($PHP_PSI_BUILDDIR)
  43         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src)
  44         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src/types)
  45
  46         PHP_PSI_HEADERS=" \
  47                 calc/basic.h calc/bin.h calc/bool.h calc/cast.h \
  48                 calc/unary.h calc/cmp.h calc/oper.h \
  49                 `(cd $PHP_PSI_SRCDIR/src && ls *.h types/*.h)` \
  50         "
  51         # parser_* should come first
  52         PHP_PSI_SOURCES=" \
  53                 src/parser_proc.c src/parser_scan.c \
  54                 `(cd $PHP_PSI_SRCDIR && ls src/*.c src/types/*.c \
  55                         | $EGREP -v '^src/parser_' \
  56                 )` \
  57         "
  58         PHP_PSI_GENERATED=" \
  59                 src/parser_proc.c src/parser_scan.c \
  60                 src/calc/basic.h src/calc/bin.h src/calc/bool.h src/calc/cast.h \
  61                 src/calc/unary.h src/calc/cmp.h src/calc/oper.h \
  62         "
  63
  64         PHP_SUBST(PHP_PSI_GENERATED)
  65         PHP_SUBST(PHP_PSI_HEADERS)
  66         PHP_SUBST(PHP_PSI_SOURCES)
  67
  68         PHP_SUBST(PHP_PSI_SRCDIR)
  69         PHP_SUBST(PHP_PSI_BUILDDIR)
  70 ])
  71
  72 dnl PSI_CHECK_GNU_SOURCE
  73 dnl Check whether _GNU_SOURCE is already defined.
  74 AC_DEFUN([PSI_CHECK_GNU_SOURCE], [
  75         AC_MSG_CHECKING([for _GNU_SOURCE])
  76         AC_EGREP_CPP([gnu_source_not_defined], [
  77                 #ifndef _GNU_SOURCE
  78                 gnu_source_not_defined
  79                 #endif
  80         ], [
  81                 AC_MSG_RESULT([needs define])
  82                 AC_DEFINE([_GNU_SOURCE], [1], [ ])
  83         ], [
  84                 AC_MSG_RESULT([already defined])
  85         ])
  86 ])
  87
  88 dnl PSI_CHECK_CPP
  89 dnl Queries the preprocessor about predefined macros and include search paths
  90 AC_DEFUN([PSI_CHECK_CPP], [
  91         AC_PROG_AWK
  92
  93         AC_MSG_CHECKING(for preprocessor defaults)
  94         psi_cpp_predef=`$CPP -Wp,-dM $CPPFLAGS -D_GNU_SOURCE -D_FILE_OFFSET_BITS=64 -U__BLOCKS__ - </dev/null`
  95         psi_cpp_search=`$CPP -Wp,-v $CPPFLAGS -D_GNU_SOURCE -D_FILE_OFFSET_BITS=64 - </dev/null 2>&1 >/dev/null \
  96                 | $AWK '
  97                         /include.*search.*start/ {
  98                                 capture = 1
  99                                 next
 100                         }
 101                         /@<:@Ee@:>@nd.*search/ {
 102                                 capture = 0
 103                         }
 104                         {
 105                                 if (capture)
 106                                         print $1
 107                         }
 108                 ' \
 109         `
 110         psi_cpp_predef_count=`printf %s "$psi_cpp_predef" | wc -l`
 111         psi_cpp_search_count=`printf %s "$psi_cpp_search" | wc -l`
 112
 113         AC_MSG_RESULT([$psi_cpp_predef_count predefined macros, and $psi_cpp_search_count search paths])
 114
 115         PSI_CPP_PREDEF=`printf "%s\n" "$psi_cpp_predef" | \
 116                 $AWK '{
 117                         gsub(/"/, "\\\\\"");
 118                         printf "\"%s\\\n\"\n", $[]0
 119                 }' \
 120         `
 121         PSI_CPP_SEARCH=`printf %s "$psi_cpp_search" | \
 122                 $AWK '
 123                         {
 124                                 if (i) printf "\":\" ";
 125                                 else   printf "    ";
 126                                 gsub(/^@<:@@<:@:space:@:>@@:>@+/,"");
 127                                 gsub(/@<:@@<:@:space:@:>@@:>@+$/,"");
 128                                 printf "\"%s\"\n", $[]0;
 129                                 ++i
 130                         }' \
 131         `
 132 ])
 133
 134 dnl PSI_CHECK_MAINTAINER_MODE
 135 dnl Check for --enable-psi-maintainer-mode
 136 dnl Enables Makefile dependencies and extra compile warnings
 137 AC_DEFUN([PSI_CHECK_MAINTAINER_MODE], [
 138         if test "$PHP_PSI_MAINTAINER_MODE" = "yes"; then
 139                 PSI_DEPS=true
 140                 PHP_SUBST(PSI_DEPS)
 141                 CFLAGS="$CFLAGS -Wall -Wextra"
 142                 m4_foreach(flag, [
 143                         [fstack-protector],
 144                         [Wduplicate-decl-specifier],
 145                         [Wnull-dereference],
 146                         [Winit-self],
 147                         [Wimplicit-fallthrough=1],
 148                         [Wshift-overflow],
 149                         [Wuninitialized],
 150                         [Walloc-zero],
 151                         [Wduplicated-branches],
 152                         [Wduplicated-cond],
 153                         [Wtrampolines],
 154                         [Wpointer-arith],
 155                         [Wcast-align],
 156                         [Wmissing-prototypes],
 157                         [Wmissing-declarations],
 158                         [Wredundant-decls],
 159                         [Wdisabled-optimization],
 160                         [Wno-sign-compare],
 161                         [Wno-unused-parameter],
 162                         [Wno-cast-function-type]],
 163                 [
 164                         AX_CHECK_COMPILE_FLAG([-][flag], [CFLAGS="$CFLAGS -"]flag)
 165                 ])
 166         else
 167                 PSI_DEPS=false
 168         fi
 169 ])
 170
 171 dnl PSI_CHECK_THREADED_PARSER
 172 dnl Check for --enable-psi-threaded-parser
 173 dnl Enables threaded parser if HAVE_PTHREAD && HAVE_ASPRINTF
 174 AC_DEFUN([PSI_CHECK_THREADED_PARSER], [
 175         if test "$PHP_PSI_THREADED_PARSER" = "yes"; then
 176                 AC_DEFINE([PSI_THREADED_PARSER], [HAVE_PTHREAD && HAVE_ASPRINTF],
 177                         [whether to enable the threaded parser])
 178         fi
 179 ])
 180
 181 AC_DEFUN(PSI_PTHREAD_ONCE, [
 182         AX_PTHREAD([
 183                 LIBS="$PTHREAD_LIBS $LIBS"
 184                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 185                 AC_DEFINE([HAVE_PTHREAD],[1],
 186                         [Define if you have POSIX threads libraries and header files.])
 187         ])
 188 ])
 189 AC_DEFUN(PSI_CHECK_PTHREAD, [
 190         AC_REQUIRE([PSI_PTHREAD_ONCE])
 191 ])
 192
 193 dnl PSI_PKG_CONFIG()
 194 dnl Check for `pkg-config` and add possible libjit and libffi directories to
 195 dnl $PKG_CONFIG_PATH, because those libs often ship with headers etc. in
 196 dnl arch-dependent locations.
 197 AC_DEFUN([PSI_PKG_CONFIG], [
 198         if test -z "$PKG_CONFIG"
 199         then
 200                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
 201         fi
 202         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
 203 ])
 204
 205 dnl PSI_SH_SIZEOF(type)
 206 dnl expand to shell variable $ac_cv_sizeof_<TYPE>
 207 AC_DEFUN([PSI_SH_SIZEOF], [$AS_TR_SH([ac_cv_sizeof_]$1)])
 208
 209 dnl PSI_SH_TEST_SIZEOF(type)
 210 dnl `if` condition to test if $ac_cv_sizeof_$1 is greater than 0.
 211 AC_DEFUN([PSI_SH_TEST_SIZEOF], [test -n "$AS_TR_SH([ac_cv_sizeof_]$1)" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0])
 212
 213 dnl PSI_CHECK_SIZEOF(type, special-includes)
 214 AC_DEFUN(PSI_CHECK_SIZEOF, [
 215         AC_CHECK_SIZEOF($1, [],
 216                 $2)
 217 ])
 218
 219 dnl PSI_CHECK_LIBJIT()
 220 dnl Check for libjit in $PHP_PSI_LIBJIT or standard locations
 221 dnl AC_DEFINEs HAVE_LIBJIT.
 222 AC_DEFUN(PSI_CHECK_LIBJIT, [
 223         AC_CACHE_CHECK(for libjit, psi_cv_libjit_dir, [
 224                 for psi_cv_libjit_dir in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
 225                 do
 226                         if test -e $psi_cv_libjit_dir/include/jit/jit.h
 227                         then
 228                                 break
 229                         fi
 230                         psi_cv_libjit_dir=
 231                 done
 232         ])
 233         if test -n "$psi_cv_libjit_dir"
 234         then
 235                 PHP_ADD_INCLUDE($psi_cv_libjit_dir/include)
 236                 PHP_ADD_LIBRARY_WITH_PATH(jit, $psi_cv_libjit_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 237                 AC_DEFINE(HAVE_LIBJIT, 1, Have libjit)
 238         else
 239                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
 240         fi
 241 ])
 242
 243 dnl PSI_CHECK_LIBFFI()
 244 dnl Check for libffi with `pkg-config`. If that fails, `configure` looks into
 245 dnl $PHP_PSI_LIBFFI or standard locations to find libjit deps.
 246 dnl Checks for availability of recent closure API:
 247 dnl \ffi_closure_alloc and \ffi_prep_closure.
 248 dnl Checks for availability of recent vararg API:
 249 dnl \ffi_prep_cif_var.
 250 dnl AC_DEFINEs HAVE_LIBFFI, PSI_HAVE_FFI_CLOSURE_ALLOC,
 251 dnl PSI_HAVE_FFI_PREP_CLOSURE and PSI_HAVE_FFO_PREP_VIF_VAR.
 252 AC_DEFUN(PSI_CHECK_LIBFFI, [
 253         AC_REQUIRE([PSI_PKG_CONFIG])dnl
 254
 255         AC_CACHE_CHECK(for libffi through pkg-config, psi_cv_libffi, [
 256         if $PKG_CONFIG --exists libffi
 257         then
 258                 psi_cv_libffi=true
 259         else
 260                 psi_cv_libffi=false
 261         fi])
 262
 263         if $psi_cv_libffi
 264         then
 265                 AC_MSG_CHECKING(for libffi)
 266                 psi_cv_libffi_dir=`$PKG_CONFIG --variable=prefix libffi`
 267                 AC_MSG_RESULT($psi_cv_libffi_dir)
 268                 PHP_EVAL_INCLINE([`$PKG_CONFIG --cflags libffi`])
 269                 PHP_EVAL_LIBLINE([`$PKG_CONFIG --libs libffi`], PSI_SHARED_LIBADD) dnl `
 270                 AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 271                 AC_DEFINE_UNQUOTED([PHP_PSI_LIBFFI_VERSION], ["`$PKG_CONFIG --modversion libffi`"], [libffi version])
 272         else
 273                 AC_CACHE_CHECK(for libffi, psi_cv_libffi_dir, [
 274                 for psi_cv_libffi_dir in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
 275                 do
 276                         if test -e $psi_cv_libffi_dir/include/ffi/ffi.h
 277                         then
 278                                 break
 279                         fi
 280                         psi_cv_libffi_dir=
 281                 done])
 282                 if test -n "$psi_cv_libffi_dir"
 283                 then
 284                         PHP_ADD_INCLUDE($psi_cv_libffi_dir/include/ffi)
 285                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $psi_cv_libffi_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 286                         AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 287                 else
 288                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
 289                 fi
 290         fi
 291
 292         save_CFLAGS=$CFLAGS
 293         CFLAGS="$CFLAGS $INCLUDES"
 294         AC_CHECK_DECL(FFI_STDCALL,[AC_DEFINE([HAVE_FFI_STDCALL],[1],[ ])],,[#include "ffi.h"])
 295         AC_CHECK_DECL(FFI_FASTCALL,[AC_DEFINE([HAVE_FFI_FASTCALL],[1],[ ])],,[#include "ffi.h"])
 296         CFLAGS=$save_CFLAGS
 297
 298         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
 299                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
 300                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
 301                 ], [], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 302                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
 303         ], [
 304                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
 305                         AC_CHECK_HEADERS(sys/mman.h)
 306                         PHP_CHECK_FUNC(mmap)
 307                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
 308                 ], [
 309                 ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 310         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 311         PHP_CHECK_LIBRARY(ffi, ffi_prep_cif_var, [
 312                 AC_DEFINE(PSI_HAVE_FFI_PREP_CIF_VAR, 1, [ ])
 313         ], [
 314         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 315 ])