git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi/psi.m4

   1 dnl PSI_CONFIG_INIT()
   2 dnl Creates stubs of the headers with pre-defined types etc.
   3 AC_DEFUN(PSI_CONFIG_INIT, [
   4         psi_save_LIBS=$LIBS
   5         LIBS=
   6
   7         AC_MSG_CHECKING([psi source dir])
   8         PHP_PSI_SRCDIR=PHP_EXT_SRCDIR(psi)
   9         AC_MSG_RESULT([$PHP_PSI_SRCDIR])
  10
  11         AC_MSG_CHECKING([psi build dir])
  12         case "PHP_EXT_BUILDDIR(psi)" in
  13         ""|.) PHP_PSI_BUILDDIR=$PHP_PSI_SRCDIR
  14                 ;;
  15         *)    PHP_PSI_BUILDDIR=PHP_EXT_BUILDDIR(psi)
  16                 ;;
  17         esac
  18         AC_MSG_RESULT([$PHP_PSI_BUILDDIR])
  19
  20         PSI_STDTYPES=
  21         PSI_CONSTS=
  22
  23         AC_CONFIG_FILES([$PHP_PSI_BUILDDIR/php_psi_predef.h:$PHP_PSI_SRCDIR/php_psi_predef.h.in])
  24
  25 ])
  26
  27 dnl PSI_CONFIG_DONE()
  28 dnl Finish the headers with the pre-defined types etc.
  29 AC_DEFUN(PSI_CONFIG_DONE, [
  30         psi_eval_LIBS=$LIBS
  31         LIBS=$psi_save_LIBS
  32         PHP_EVAL_LIBLINE($psi_eval_LIBS, PSI_SHARED_LIBADD)
  33
  34         AC_SUBST([PSI_STDTYPES])
  35         AC_SUBST([PSI_CPP_SEARCH])
  36         AC_SUBST([PSI_CPP_PREDEF])
  37
  38         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR)
  39         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src)
  40         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src/calc)
  41         PHP_ADD_INCLUDE($PHP_PSI_SRCDIR/src/types)
  42         PHP_ADD_INCLUDE($PHP_PSI_BUILDDIR)
  43         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src)
  44         PHP_ADD_BUILD_DIR($PHP_PSI_BUILDDIR/src/types)
  45
  46         PHP_PSI_HEADERS=" \
  47                 calc/basic.h calc/bin.h calc/bool.h calc/cast.h \
  48                 calc/unary.h calc/cmp.h calc/oper.h \
  49                 `(cd $PHP_PSI_SRCDIR/src && ls *.h types/*.h)` \
  50         "
  51         # parser_* should come first
  52         PHP_PSI_SOURCES=" \
  53                 src/parser_proc.c src/parser_scan.c \
  54                 `(cd $PHP_PSI_SRCDIR && ls src/*.c src/types/*.c \
  55                         | $EGREP -v '^src/parser_' \
  56                 )` \
  57         "
  58         PHP_PSI_GENERATED=" \
  59                 src/parser_proc.c src/parser_scan.c \
  60                 src/calc/basic.h src/calc/bin.h src/calc/bool.h src/calc/cast.h \
  61                 src/calc/unary.h src/calc/cmp.h src/calc/oper.h \
  62         "
  63
  64         PHP_SUBST(PHP_PSI_GENERATED)
  65         PHP_SUBST(PHP_PSI_HEADERS)
  66         PHP_SUBST(PHP_PSI_SOURCES)
  67
  68         PHP_SUBST(PHP_PSI_SRCDIR)
  69         PHP_SUBST(PHP_PSI_BUILDDIR)
  70 ])
  71
  72 dnl PSI_CHECK_GNU_SOURCE
  73 dnl Check whether _GNU_SOURCE is already defined.
  74 AC_DEFUN([PSI_CHECK_GNU_SOURCE], [
  75         AC_MSG_CHECKING([for _GNU_SOURCE])
  76         AC_EGREP_CPP([gnu_source_not_defined], [
  77                 #ifndef _GNU_SOURCE
  78                 gnu_source_not_defined
  79                 #endif
  80         ], [
  81                 AC_MSG_RESULT([needs define])
  82                 AC_DEFINE([_GNU_SOURCE], [1], [ ])
  83         ], [
  84                 AC_MSG_RESULT([already defined])
  85         ])
  86 ])
  87
  88 dnl PSI_CHECK_CPP
  89 dnl Queries the preprocessor about predefined macros and include search paths
  90 AC_DEFUN([PSI_CHECK_CPP], [
  91         AC_PROG_AWK
  92
  93         AC_MSG_CHECKING(for preprocessor defaults)
  94         psi_cpp_predef=`$CPP -Wp,-dM $CPPFLAGS -D_GNU_SOURCE -D_FILE_OFFSET_BITS=64 -U__BLOCKS__ - </dev/null`
  95         psi_cpp_search=`$CPP -Wp,-v $CPPFLAGS -D_GNU_SOURCE -D_FILE_OFFSET_BITS=64 - </dev/null 2>&1 >/dev/null \
  96                 | $AWK '
  97                         /include.*search.*start/ {
  98                                 capture = 1
  99                                 next
 100                         }
 101                         /@<:@Ee@:>@nd.*search/ {
 102                                 capture = 0
 103                         }
 104                         {
 105                                 if (capture)
 106                                         print $1
 107                         }
 108                 ' \
 109         `
 110         psi_cpp_predef_count=`printf %s "$psi_cpp_predef" | wc -l`
 111         psi_cpp_search_count=`printf %s "$psi_cpp_search" | wc -l`
 112
 113         AC_MSG_RESULT([$psi_cpp_predef_count predefined macros, and $psi_cpp_search_count search paths])
 114
 115         PSI_CPP_PREDEF=`printf "%s\n" "$psi_cpp_predef" | \
 116                 $AWK '{
 117                         gsub(/"/, "\\\\\"");
 118                         printf "\"%s\\\n\"\n", $[]0
 119                 }' \
 120         `
 121         PSI_CPP_SEARCH=`printf %s "$psi_cpp_search" | \
 122                 $AWK '
 123                         {
 124                                 if (i) printf "\":\" ";
 125                                 else   printf "    ";
 126                                 gsub(/^@<:@@<:@:space:@:>@@:>@+/,"");
 127                                 gsub(/@<:@@<:@:space:@:>@@:>@+$/,"");
 128                                 printf "\"%s\"\n", $[]0;
 129                                 ++i
 130                         }' \
 131         `
 132 ])
 133
 134 dnl PSI_CHECK_MAINTAINER_MODE
 135 dnl Check for --enable-psi-maintainer-mode
 136 dnl Enables Makefile dependencies and extra compile warnings
 137 AC_DEFUN([PSI_CHECK_MAINTAINER_MODE], [
 138         if test "$PHP_PSI_MAINTAINER_MODE" = "yes"; then
 139                 PSI_DEPS=true
 140                 PHP_SUBST(PSI_DEPS)
 141                 CFLAGS="$CFLAGS -Wall"
 142                 m4_foreach(flag, [
 143                         [fstack-protector],
 144                         [Wduplicate-decl-specifier],
 145                         [Wnull-dereference],
 146                         [Winit-self],
 147                         [Wimplicit-fallthrough=1],
 148                         [Wshift-overflow],
 149                         [Wuninitialized],
 150                         [Walloc-zero],
 151                         [Wduplicated-branches],
 152                         [Wduplicated-cond],
 153                         [Wtrampolines],
 154                         [Wpointer-arith],
 155                         [Wcast-align],
 156                         [Wmissing-prototypes],
 157                         [Wmissing-declarations],
 158                         [Wdisabled-optimization]],
 159                 [
 160                         AX_CHECK_COMPILE_FLAG([-][flag], [CFLAGS="$CFLAGS -"]flag)
 161                 ])
 162         else
 163                 PSI_DEPS=false
 164         fi
 165 ])
 166
 167 dnl PSI_CHECK_THREADED_PARSER
 168 dnl Check for --enable-psi-threaded-parser
 169 dnl Enables threaded parser if HAVE_PTHREAD && HAVE_ASPRINTF
 170 AC_DEFUN([PSI_CHECK_THREADED_PARSER], [
 171         if test "$PHP_PSI_THREADED_PARSER" = "yes"; then
 172                 AC_DEFINE([PSI_THREADED_PARSER], [HAVE_PTHREAD && HAVE_ASPRINTF],
 173                         [whether to enable the threaded parser])
 174         fi
 175 ])
 176
 177 AC_DEFUN(PSI_PTHREAD_ONCE, [
 178         AX_PTHREAD([
 179                 LIBS="$PTHREAD_LIBS $LIBS"
 180                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 181                 AC_DEFINE([HAVE_PTHREAD],[1],
 182                         [Define if you have POSIX threads libraries and header files.])
 183         ])
 184 ])
 185 AC_DEFUN(PSI_CHECK_PTHREAD, [
 186         AC_REQUIRE([PSI_PTHREAD_ONCE])
 187 ])
 188
 189 dnl PSI_PKG_CONFIG()
 190 dnl Check for `pkg-config` and add possible libjit and libffi directories to
 191 dnl $PKG_CONFIG_PATH, because those libs often ship with headers etc. in
 192 dnl arch-dependent locations.
 193 AC_DEFUN([PSI_PKG_CONFIG], [
 194         if test -z "$PKG_CONFIG"
 195         then
 196                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
 197         fi
 198         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
 199 ])
 200
 201 dnl PSI_SH_SIZEOF(type)
 202 dnl expand to shell variable $ac_cv_sizeof_<TYPE>
 203 AC_DEFUN([PSI_SH_SIZEOF], [$AS_TR_SH([ac_cv_sizeof_]$1)])
 204
 205 dnl PSI_SH_TEST_SIZEOF(type)
 206 dnl `if` condition to test if $ac_cv_sizeof_$1 is greater than 0.
 207 AC_DEFUN([PSI_SH_TEST_SIZEOF], [test -n "$AS_TR_SH([ac_cv_sizeof_]$1)" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0])
 208
 209 dnl PSI_CHECK_SIZEOF(type, special-includes)
 210 AC_DEFUN(PSI_CHECK_SIZEOF, [
 211         AC_CHECK_SIZEOF($1, [],
 212                 $2)
 213 ])
 214
 215 dnl PSI_CHECK_LIBJIT()
 216 dnl Check for libjit in $PHP_PSI_LIBJIT or standard locations
 217 dnl AC_DEFINEs HAVE_LIBJIT.
 218 AC_DEFUN(PSI_CHECK_LIBJIT, [
 219         AC_CACHE_CHECK(for libjit, psi_cv_libjit_dir, [
 220                 for psi_cv_libjit_dir in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
 221                 do
 222                         if test -e $psi_cv_libjit_dir/include/jit/jit.h
 223                         then
 224                                 break
 225                         fi
 226                         psi_cv_libjit_dir=
 227                 done
 228         ])
 229         if test -n "$psi_cv_libjit_dir"
 230         then
 231                 PHP_ADD_INCLUDE($psi_cv_libjit_dir/include)
 232                 PHP_ADD_LIBRARY_WITH_PATH(jit, $psi_cv_libjit_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 233                 AC_DEFINE(HAVE_LIBJIT, 1, Have libjit)
 234         else
 235                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
 236         fi
 237 ])
 238
 239 dnl PSI_CHECK_LIBFFI()
 240 dnl Check for libffi with `pkg-config`. If that fails, `configure` looks into
 241 dnl $PHP_PSI_LIBFFI or standard locations to find libjit deps.
 242 dnl Checks for availability of recent closure API:
 243 dnl \ffi_closure_alloc and \ffi_prep_closure.
 244 dnl Checks for availability of recent vararg API:
 245 dnl \ffi_prep_cif_var.
 246 dnl AC_DEFINEs HAVE_LIBFFI, PSI_HAVE_FFI_CLOSURE_ALLOC,
 247 dnl PSI_HAVE_FFI_PREP_CLOSURE and PSI_HAVE_FFO_PREP_VIF_VAR.
 248 AC_DEFUN(PSI_CHECK_LIBFFI, [
 249         AC_REQUIRE([PSI_PKG_CONFIG])dnl
 250
 251         AC_CACHE_CHECK(for libffi through pkg-config, psi_cv_libffi, [
 252         if $PKG_CONFIG --exists libffi
 253         then
 254                 psi_cv_libffi=true
 255         else
 256                 psi_cv_libffi=false
 257         fi])
 258
 259         if $psi_cv_libffi
 260         then
 261                 AC_MSG_CHECKING(for libffi)
 262                 psi_cv_libffi_dir=`$PKG_CONFIG --variable=prefix libffi`
 263                 AC_MSG_RESULT($psi_cv_libffi_dir)
 264                 PHP_EVAL_INCLINE([`$PKG_CONFIG --cflags libffi`])
 265                 PHP_EVAL_LIBLINE([`$PKG_CONFIG --libs libffi`], PSI_SHARED_LIBADD) dnl `
 266                 AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 267                 AC_DEFINE_UNQUOTED([PHP_PSI_LIBFFI_VERSION], ["`$PKG_CONFIG --modversion libffi`"], [libffi version])
 268         else
 269                 AC_CACHE_CHECK(for libffi, psi_cv_libffi_dir, [
 270                 for psi_cv_libffi_dir in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
 271                 do
 272                         if test -e $psi_cv_libffi_dir/include/ffi/ffi.h
 273                         then
 274                                 break
 275                         fi
 276                         psi_cv_libffi_dir=
 277                 done])
 278                 if test -n "$psi_cv_libffi_dir"
 279                 then
 280                         PHP_ADD_INCLUDE($psi_cv_libffi_dir/include/ffi)
 281                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $psi_cv_libffi_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 282                         AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 283                 else
 284                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
 285                 fi
 286         fi
 287
 288         save_CFLAGS=$CFLAGS
 289         CFLAGS="$CFLAGS $INCLUDES"
 290         AC_CHECK_DECL(FFI_STDCALL,[AC_DEFINE([HAVE_FFI_STDCALL],[1],[ ])],,[#include "ffi.h"])
 291         AC_CHECK_DECL(FFI_FASTCALL,[AC_DEFINE([HAVE_FFI_FASTCALL],[1],[ ])],,[#include "ffi.h"])
 292         CFLAGS=$save_CFLAGS
 293
 294         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
 295                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
 296                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
 297                 ], [], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 298                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
 299         ], [
 300                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
 301                         AC_CHECK_HEADERS(sys/mman.h)
 302                         PHP_CHECK_FUNC(mmap)
 303                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
 304                 ], [
 305                 ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 306         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 307         PHP_CHECK_LIBRARY(ffi, ffi_prep_cif_var, [
 308                 AC_DEFINE(PSI_HAVE_FFI_PREP_CIF_VAR, 1, [ ])
 309         ], [
 310         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 311 ])