git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi.m4

   1 PSI_TYPES=
   2 PSI_STRUCTS=
   3 PSI_CONSTS=
   4 PSI_REDIRS=
   5 PSI_MACROS=
   6 PSI_DECLS=
   7 PSI_VA_DECLS=
   8
   9 psi_includes() {
  10         local have_
  11         have_=`AS_ECHO($ac_header) | $as_tr_cpp`
  12         cat <<EOF
  13 #ifdef HAVE_$have_
  14 # include <$ac_header>
  15 #endif
  16 EOF
  17 }
  18
  19 AC_DEFUN(PSI_INCLUDES, [AC_INCLUDES_DEFAULT()
  20 `psi_includes`])
  21
  22 AC_DEFUN(PSI_LEMON, [
  23         AC_ARG_VAR(LEMON, The lemon parser generator of the SQLite project)
  24         AC_PATH_PROG(LEMON, lemon, ./lemon)
  25         PHP_SUBST(LEMON)
  26 ])
  27
  28 AC_DEFUN([PSI_PKG_CONFIG], [
  29         if test -z "$PKG_CONFIG"
  30         then
  31                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
  32         fi
  33         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
  34 ])
  35
  36 AC_DEFUN(PSI_CHECK_SIZEOF, [
  37         AC_CHECK_SIZEOF($1, [], $2)
  38         if test "$AS_TR_SH([ac_cv_sizeof_]$1)"; then
  39                 add_int_const "AS_TR_CPP([SIZEOF_]$1)" "$AS_TR_SH([ac_cv_sizeof_]$1)"
  40         fi
  41 ])
  42
  43 AC_DEFUN(PSI_CHECK_OFFSETOF, [
  44         _AC_CACHE_CHECK_INT(
  45                 [offset of $2 in $1],
  46                 [AS_TR_SH([ac_cv_offsetof_$1_$2])],
  47                 [(long int) (offsetof ($1, $2))],
  48                 [PSI_INCLUDES],
  49                 [AC_MSG_FAILURE([cannot compute offsetof ($1, $2)])]
  50         )
  51         AC_DEFINE_UNQUOTED(
  52                 AS_TR_CPP(offsetof_$1_$2),
  53                 $AS_TR_SH([ac_cv_offsetof_$1_$2]),
  54                 [The offset of `$2' in `$1', as computed by offsetof.]
  55         )
  56 ])
  57
  58 AC_DEFUN(PSI_CHECK_LIBJIT, [
  59         PHP_ARG_WITH(psi-libjit, where to find libjit,
  60         [  --with-psi-libjit=DIR   PSI: path to libjit], [ ], [ ])
  61         AC_CACHE_CHECK(for libjit, psi_cv_libjit_dir, [
  62                 for psi_cv_libjit_dir in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
  63                 do
  64                         if test -e $psi_cv_libjit_dir/include/jit/jit.h
  65                         then
  66                                 break
  67                         fi
  68                         psi_cv_libjit_dir=
  69                 done
  70         ])
  71         if test -n "$psi_cv_libjit_dir"
  72         then
  73                 PHP_ADD_INCLUDE($psi_cv_libjit_dir/include)
  74                 PHP_ADD_LIBRARY_WITH_PATH(jit, $psi_cv_libjit_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
  75                 AC_DEFINE(HAVE_LIBJIT, 1, Have libjit)
  76         else
  77                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
  78         fi
  79 ])
  80
  81 PHP_ARG_WITH(psi-libffi, where to find libffi,
  82 [  --with-psi-libffi=DIR   PSI: path to libffi], [ ], [ ])
  83 AC_DEFUN(PSI_CHECK_LIBFFI, [
  84         AC_REQUIRE([PSI_PKG_CONFIG])dnl
  85
  86         AC_CACHE_CHECK(for libffi through pkg-config, psi_cv_libffi, [
  87         if $PKG_CONFIG --exists libffi
  88         then
  89                 psi_cv_libffi=true
  90         else
  91                 psi_cv_libffi=false
  92         fi])
  93         if $psi_cv_libffi
  94         then
  95                 AC_MSG_CHECKING(for libffi)
  96                 psi_cv_libffi_dir=`$PKG_CONFIG --variable=prefix libffi`
  97                 AC_MSG_RESULT($psi_cv_libffi_dir)
  98                 PHP_EVAL_INCLINE(`$PKG_CONFIG --cflags libffi`)
  99                 PHP_EVAL_LIBLINE(`$PKG_CONFIG --libs libffi`, PSI_SHARED_LIBADD)
 100                 AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 101         else
 102                 AC_CACHE_CHECK(for libffi, psi_cv_libffi_dir, [
 103                 for psi_cv_libffi_dir in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
 104                 do
 105                         if test -e $psi_cv_libffi_dir/include/ffi/ffi.h
 106                         then
 107                                 break
 108                         fi
 109                         psi_cv_libffi_dir=
 110                 done])
 111                 if test -n "$psi_cv_libffi_dir"
 112                 then
 113                         PHP_ADD_INCLUDE($psi_cv_libffi_dir/include/ffi)
 114                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $psi_cv_libffi_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 115                         AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 116                 else
 117                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
 118                 fi
 119         fi
 120         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
 121                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
 122                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
 123                 ], [], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 124                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
 125         ], [
 126                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
 127                         AC_CHECK_HEADERS(sys/mman.h)
 128                         PHP_CHECK_FUNC(mmap)
 129                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
 130                 ], [
 131                 ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 132         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 133         PHP_CHECK_LIBRARY(ffi, ffi_prep_cif_var, [
 134                 AC_DEFINE(PSI_HAVE_FFI_PREP_CIF_VAR, 1, [ ])
 135         ], [
 136         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 137 ])
 138
 139 dnl PSI_COMPUTE_STR(variable, string or expression)
 140 AC_DEFUN(PSI_COMPUTE_STR, [
 141         AC_TRY_RUN(
 142                 PSI_INCLUDES
 143                 [int main() {
 144                         return EOF == fputs($2, fopen("conftest.out", "w"));
 145                 }
 146         ], [
 147                 eval $1=\\\"`cat conftest.out`\\\"
 148         ])
 149 ])