git.m6w6.name Git - m6w6/ext-psi/blob - config.psi_decl.m4

   1 PSI_REDIRS=
   2 AC_DEFUN(PSI_REDIR, [psi_symbol=ifelse([$2],[],[$1],[$2])
   3         PSI_REDIRS="{\"$1\", (void(*)(void))$psi_symbol}, $PSI_REDIRS"])
   4
   5 dnl PSI_FUNC(fn, action-if-yes, action-if-no)
   6 AC_DEFUN(PSI_FUNC, [
   7         AC_REQUIRE([AC_PROG_NM])
   8         AC_REQUIRE([AC_PROG_AWK])
   9         psi_symbol=$1
  10         AC_CACHE_CHECK(for $1, psi_cv_fn_$1, [
  11                 psi_symbol_redirect=
  12                 AC_TRY_LINK(PSI_INCLUDES, [
  13                         void (*fn)(void) = (void (*)(void)) $psi_symbol;
  14                 ], [
  15                         psi_symbol_redirect=`$NM -g conftest$ac_exeext | $AWK -F" *|@" '/ U .*$1.*/ {print$[]3; exit}'`
  16                 ])
  17                 psi_cv_fn_$1=$psi_symbol_redirect
  18         ])
  19         case "$psi_cv_fn_$1" in
  20         "")
  21                 $3
  22                 ;;
  23         "$psi_symbol"|"_$psi_symbol")
  24                 $2
  25                 ;;
  26         *)
  27                 $2
  28                 PSI_REDIR($1)
  29                 ;;
  30         esac
  31 ])
  32
  33 AC_DEFUN(PSI_DECL_ARG, [
  34     m4_define([member_name], PSI_VAR_NAME($1))
  35     m4_define([member_type], PSI_TYPE_NAME($1))
  36     m4_define([pointer_level], m4_len(m4_bpatsubst($1, [[^*]])))
  37         m4_define([array_size], m4_bregexp($1, [\[\([0-9]+\)\]], [\1]))
  38         ifelse(array_size, [],
  39                 [m4_define([array_size], 0)],
  40                 [m4_define([pointer_level], m4_incr(pointer_level))]
  41         )
  42     if test -n "$psi_decl_args"; then
  43         psi_decl_args="$psi_decl_args, "
  44     fi
  45     psi_decl_args="[$psi_decl_args{]PSI_TYPE_PAIR(member_type)[, \"]member_name[\",] pointer_level, array_size[}]"
  46 ])
  47
  48 dnl PSI_DECL(type func, args)
  49 AC_DEFUN(PSI_DECL, [
  50         psi_decl_args=
  51         PSI_DECL_ARG($1)
  52         m4_case([$2],
  53                 [(void)], [],
  54                 [()], [],
  55                 [m4_map_args_sep([PSI_DECL_ARG(], [)], [], m4_bregexp($2, [(\(.*\))], [\1]))])
  56         PSI_FUNC(PSI_VAR_NAME($1), [
  57                 PSI_DECLS="{$psi_decl_args}, $PSI_DECLS"
  58         ], [
  59                 PSI_MACRO(PSI_VAR_NAME($1), $3, [
  60                         add_macro "PSI_TYPE_NAME($1)" "PSI_VAR_NAME($1)" "$3"
  61                         PSI_DECLS="{$psi_decl_args}, $PSI_DECLS"
  62                 ])
  63         ])
  64 ])